Contract

Contract Source Code (Solidity Standard Json-Input format)

IDE

• Blockscan IDE
• 🤖 Code ReaderBeta
• Remix IDE

More Options

• Similar
• Sol2Uml
• Submit Audit
• Compare

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

import { SafeERC20 } from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import { ERC20 } from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import { Ownable, Ownable2Step } from "@openzeppelin/contracts/access/Ownable2Step.sol";
import { MessageLib } from "../message-lib/MessageLib.sol";
import { IVaultNav } from "../vaultNav/IVaultNav.sol";
import { IAbridgeMessageHandler } from "../abridge/IAbridge.sol";
import { AbridgeMessageHandler } from "../abridge/AbridgeMessageHandler.sol";
import { IWithdrawPool } from "../interfaces/IWithdrawPool.sol";

contract WithdrawPool is AbridgeMessageHandler, Ownable2Step, IWithdrawPool {
    using SafeERC20 for IERC20;

    /// @notice vault type
    address public immutable LSD;
    /// @notice Address of the underlying token
    address public immutable UNDERLYING_TOKEN;
    /// @notice The address of smart savings contract on gravity.
    address public smartSavingsOnGravity;
    /// @notice Address of the unstaker
    address public unstaker;
    /// @notice Address of the vault nav contract
    IVaultNav public vaultNav;
    /// @notice Total unlocked LSD amount
    uint256 public totalPoolUnlocks;
    /// @notice Total lsd token burned from protocol
    uint256 public totalLsdBurned;
    /// @notice Mapping to track total pool claims by user
    mapping(address => uint256) public totalPoolClaimed;
    /// @notice Gas limit to execute lzReceive function on destination chain using LayerZero.
    uint128 public lzReceiveGasLimit = 100_000;

    modifier onlyUnstaker() {
        if (msg.sender != unstaker) {
            revert InvalidCaller();
        }
        _;
    }

    /// @dev Constructor to initialize the WithdrawPool contract.
    /// @param _owner The owner/admin of this contract.
    /// @param _abridge The address of the Abridge contract.
    /// @param _smartSavingsOnGravity The address of SmartSavings contract on Gravity.
    /// @param _vaultNav The address of the vault nav contract.
    /// @param _underlyingToken The address of the underlying token.
    /// @param _lsd The address of the LSD token.
    constructor(
        address _owner, // solhint-disable-line no-unused-vars
        address _abridge, // solhint-disable-line no-unused-vars
        address _smartSavingsOnGravity,
        address _vaultNav,
        address _underlyingToken,
        address _lsd
    ) Ownable(_owner) AbridgeMessageHandler(_abridge) {
        smartSavingsOnGravity = _smartSavingsOnGravity;
        vaultNav = IVaultNav(_vaultNav);
        UNDERLYING_TOKEN = _underlyingToken;
        if (_lsd == address(0)) {
            revert InvalidLSD();
        }
        LSD = _lsd;
    }

    /// @notice Fallback function to receive native tokens as gas fees
    receive() external payable {}

    /// @notice Sets the address of SmartSavings on the Ethereum
    /// @dev Emits a `SmartSavingsOnGravityUpdated` event.
    /// @param _smartSavings The address of the SmartSavings contract on the Ethereum
    function setSmartSavingOnGravity(address _smartSavings) external onlyOwner {
        smartSavingsOnGravity = _smartSavings;
        emit SmartSavingsOnGravityUpdated(_smartSavings);
    }

    /// @notice Sets the abridge address
    /// @param _abridge The address of the Abridge contract
    function setAbridge(address _abridge) external onlyOwner {
        _setAbridge(_abridge);
    }

    /// @notice Updates the message route for the sender, allow or disallowed.
    function updateRoute(address _sender, bool allowed) external onlyOwner {
        _updateRoute(_sender, allowed);
    }

    /// @notice Sets the unstaker address
    /// @param _unstaker The address of the unstaker
    function setUnstaker(address _unstaker) external onlyOwner {
        unstaker = _unstaker;
        emit SetUnstaker(_unstaker);
    }

    /// @notice Sets lzReceiveGasLimit
    /// @param _gasLimit The gas limit to execute lzReceive function on destination chain using LayerZero.
    function setLzReceiveGasLimit(uint128 _gasLimit) external onlyOwner {
        lzReceiveGasLimit = _gasLimit;
        emit SetLzReceiveGasLimit(_gasLimit);
    }

    /// @notice Adds underlying assets to this contract as new unlocked amount
    /// @dev This function handles the addition of unlocked amounts to the pool,
    /// supporting both native tokens (e.g., ETH) and ERC20 tokens, and emits an `Unlocked` event
    /// @param _unlockedLSDAmount New unlocked amount
    /// @param _amount Amount of LSD token
    function addPoolUnlocks(uint256 _unlockedLSDAmount, uint256 _amount) external payable onlyUnstaker {
        if (_unlockedLSDAmount == 0) {
            revert InvalidUnlockAmount();
        }
        totalPoolUnlocks += _unlockedLSDAmount;
        uint256 actualAmount = _amount;
        uint256 messageFee = msg.value;
        if (UNDERLYING_TOKEN == address(0)) {
            if (msg.value <= _amount) {
                revert InvalidUnlockAmount();
            }
            messageFee -= _amount;
        } else {
            // be compatible with reflection tokens
            uint256 balanceBefore = IERC20(UNDERLYING_TOKEN).balanceOf(address(this));
            IERC20(UNDERLYING_TOKEN).safeTransferFrom(msg.sender, address(this), _amount);
            uint256 balanceAfter = IERC20(UNDERLYING_TOKEN).balanceOf(address(this));
            actualAmount = balanceAfter - balanceBefore;
        }

        // check message fee
        uint256 _fee = unlockFee();
        if (messageFee < _fee) {
            revert InsufficientFee(_fee, messageFee);
        }
        _poolUnlocksAdded(messageFee);

        emit Unlocked(_unlockedLSDAmount, actualAmount);
    }

    /// @notice Withdraws unexpectedly received tokens
    /// @param _token The address of the token to withdraw
    /// @param _to The address to receive the withdrawn tokens
    function rescueWithdraw(address _token, address _to) external onlyOwner {
        if (_token == address(0)) {
            // Withdraw native tokens
            uint256 balance = address(this).balance;
            (bool sent, ) = _to.call{ value: balance }("");
            if (!sent) revert WithdrawSentFailed();
        } else {
            // Withdraw ERC20 tokens
            uint256 balance = IERC20(_token).balanceOf(address(this));
            IERC20(_token).safeTransfer(_to, balance);
        }
    }

    function handleMessage(
        address _from,
        bytes calldata _message,
        bytes32 _guid
    ) external override onlyAbridge returns (bytes4 response) {
        // 1. Parse `_message` and check message type
        MessageLib.Message memory m = MessageLib.unpack(_message);
        if (m.valueType != uint8(MessageLib.TOTAL_CLAIMS_TYPE)) {
            revert InvalidBridgeMessage();
        }
        // only smart saving contract can send this message to us.
        // a bit redundant, but it's better to be safe.
        if (_from != smartSavingsOnGravity) {
            revert InvalidBridgeMessageFrom(_from);
        }
        // 2. Call `_claim` if message type is `TOTAL_CLAIMS_TYPE`
        _claim(m.owner, m.value, m.timestamp, _guid);
        return IAbridgeMessageHandler.handleMessage.selector;
    }

    /// @notice Estimates unlocks message bridging fee.
    /// @return Amount of deposit fee.
    function unlockFee() public view returns (uint256) {
        (, uint256 amount) = abridge().estimateFee(
            smartSavingsOnGravity,
            lzReceiveGasLimit,
            MessageLib.pack(
                MessageLib.Message({
                    valueType: uint8(MessageLib.TOTAL_POOL_UNLOCKS_TYPE),
                    value: totalPoolUnlocks,
                    owner: address(this),
                    timestamp: 0
                })
            )
        );
        return amount;
    }

    /// @notice Claims unlocked token amount to `_receiver`
    /// @dev Updates totalPoolClaims, emits a `Claimed` event
    /// @param _receiver Address of the account to receive the claimed funds
    /// @param _totalClaims Accumulated unlocked lsd token amount
    /// @param _timestamp The timestamp when the withdrawal was initiated
    /// @param _guid The unique identifier for the received LayerZero message.
    function _claim(address _receiver, uint256 _totalClaims, uint256 _timestamp, bytes32 _guid) internal {
        if (_timestamp == 0) {
            revert InvalidTimestamp(_timestamp);
        }
        if (_totalClaims == 0) {
            revert InvalidClaimAmount(_totalClaims);
        }

        uint256 previousClaims = totalPoolClaimed[_receiver];
        if (previousClaims >= _totalClaims) {
            revert InvalidClaimAmount(_totalClaims);
        }
        totalPoolClaimed[_receiver] = _totalClaims;

        // current claim amount
        uint256 lsdTokenToBurn = _totalClaims - previousClaims;

        totalLsdBurned += lsdTokenToBurn;

        // 2. Get exchange rate of `_timestamp`
        uint256 underlyingTokenAmount = _claimAssetAmount(lsdTokenToBurn, _timestamp);
        if (underlyingTokenAmount == 0) {
            revert ClaimAmountTooSmall(lsdTokenToBurn);
        }

        if (UNDERLYING_TOKEN == address(0)) {
            // Withdraw native tokens
            // TODO: possible to setup a _receiver that does not accept native tokens
            // then the lzReceive will fail.
            (bool sent, ) = _receiver.call{ value: underlyingTokenAmount }("");
            if (!sent) revert SendFailed(_receiver, underlyingTokenAmount);
        } else {
            // Withdraw ERC20 tokens
            // If Reflection token, fees will be deducted from the underlying token.
            IERC20(UNDERLYING_TOKEN).safeTransfer(_receiver, underlyingTokenAmount);
        }

        emit Claimed(_receiver, underlyingTokenAmount, lsdTokenToBurn, _timestamp, _guid);
    }

    /// @dev Bridge a message to the smart saving contract with the total pool unlocks
    /// @param _fee The fee paid for sending the message
    function _poolUnlocksAdded(uint256 _fee) internal {
        // Pack the message with total pool unlocks information
        bytes memory message = MessageLib.pack(
            MessageLib.Message({
                valueType: uint8(MessageLib.TOTAL_POOL_UNLOCKS_TYPE),
                value: totalPoolUnlocks,
                owner: address(this),
                timestamp: 0 // Timestamp is not used in this context
            })
        );
        uint256 balanceBeforeSend = address(this).balance;
        // Send the message through the Abridge contract
        bytes32 guid = abridge().send{ value: _fee }(smartSavingsOnGravity, lzReceiveGasLimit, message);
        uint256 balanceAfterSend = address(this).balance;

        uint256 actuallyUsedFee = balanceBeforeSend - balanceAfterSend;
        // refund the unused fee
        if (actuallyUsedFee < _fee) {
            uint256 refundAmount = _fee - actuallyUsedFee;
            (bool sent, ) = msg.sender.call{ value: refundAmount }("");
            if (!sent) revert SendFailed(msg.sender, refundAmount);
        }

        emit PoolUnlocksBridged(totalPoolUnlocks, _fee, guid);
    }

    /// @notice Calculates the amount of unlocked underlying token
    /// @param _claimAmount The amount of LSD token
    /// @param _timestamp The timestamp when the withdrawal was initiated
    /// @return The amount of unlocked token
    function _claimAssetAmount(uint256 _claimAmount, uint256 _timestamp) internal view returns (uint256) {
        uint256 tokenDecimal;
        if (UNDERLYING_TOKEN == address(0)) {
            tokenDecimal = 18;
        } else {
            tokenDecimal = ERC20(UNDERLYING_TOKEN).decimals();
        }
        uint256 amount = vaultNav.lsdToTokenE18AtTime(LSD, _claimAmount, uint48(_timestamp)) /
            (10 ** (18 - tokenDecimal));
        if (amount == 0) {
            revert ClaimAmountTooSmall(_claimAmount);
        }
        return amount;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

import { IAbridge, IAbridgeMessageHandler } from "./IAbridge.sol";

/// @title AbridgeMessageHandler
/// @notice Abstract contract for handling messages received through the Abridge bridge
abstract contract AbridgeMessageHandler is IAbridgeMessageHandler {
    /// @notice The Abridge contract for bridging messages
    IAbridge private _abridge;

    /// @dev Emitted when the Abridge contract address is updated
    /// @param oldBridge The address of the previous Abridge contract
    /// @param newBridge The address of the new Abridge contract
    event AbridgeUpdated(address indexed oldBridge, address indexed newBridge);

    /// @dev Emitted when a route is updated for a sender
    /// @param sender The address of the sender
    /// @param allowed Whether the sender is allowed to use the route
    event RouteUpdated(address indexed sender, bool allowed);

    /// @dev Error thrown when a function is not called from the Abridge contract
    error NotCalledFromAbridge();

    /// @dev Modifier to ensure the function is called only from the Abridge contract
    modifier onlyAbridge() {
        if (msg.sender != address(_abridge)) {
            revert NotCalledFromAbridge();
        }
        _;
    }

    /// @dev Constructor to initialize the AbridgeMessageHandler
    /// @param abridge_ The address of the Abridge contract
    constructor(address abridge_) {
        _abridge = IAbridge(abridge_);
    }

    /// @notice Get the current Abridge contract
    /// @return The IAbridge interface of the current Abridge contract
    function abridge() public view returns (IAbridge) {
        return _abridge;
    }

    /// @dev Internal function to update the Abridge contract
    /// @param bridge The new Abridge contract
    function _setAbridge(address bridge) internal {
        address oldBridge = address(_abridge);
        _abridge = IAbridge(bridge);
        emit AbridgeUpdated(oldBridge, address(bridge));
    }

    /// @dev Internal function to update a route for a sender
    /// @param sender The address of the sender
    /// @param allowed Whether the sender is allowed to use the route
    function _updateRoute(address sender, bool allowed) internal {
        _abridge.updateRoute(sender, allowed);
        emit RouteUpdated(sender, allowed);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

/// @title BridgeReceiver
/// @notice Interface for contracts that can receive messages through the bridge
interface IAbridgeMessageHandler {
    /// @notice Handles incoming messages from the bridge.
    /// @param _from The address of the sender
    /// @param _msg The message data
    /// @return response The function selector to confirm successful handling
    function handleMessage(address _from, bytes calldata _msg, bytes32 guid) external returns (bytes4 response);
}

/// @title IAbridge
/// @notice Interface for the Abridge contract
interface IAbridge {
    /// @notice Emitted when a message is sent through the bridge
    event MessageSent(address indexed sender, address indexed receiver, bytes32 guid, uint256 fee);

    /// @notice Emitted when a message is received through the bridge
    event MessageReceived(address indexed sender, address indexed receiver, bytes32 guid);

    /// @notice Emitted when an authorized sender is updated
    event AuthorizedSenderUpdated(address indexed sender, bool authorized);

    /// @notice Emitted when a route is updated
    event RouteUpdated(address indexed receiver, address indexed sender, bool allowed);

    error InsufficientFee(uint256 _sent, uint256 _required);
    error UnauthorizedSender(address _sender);
    error DisallowedRoute(address _sender, address _receiver);
    error InvalidReceiverResponse(bytes4 _response);

    /// @notice Updates the route for a specific sender
    /// @param _sender Address of the sender
    /// @param _allowed Flag to allow or disallow the route
    function updateRoute(address _sender, bool _allowed) external;

    /// @notice Sends a message through the bridge
    /// @param _receiver Address of the receiver
    /// @param _executeGasLimit Gas limit for execution
    /// @param _msg The message to be sent
    /// @return _guid The unique identifier for the sent message
    function send(
        address _receiver,
        uint128 _executeGasLimit,
        bytes memory _msg
    ) external payable returns (bytes32 _guid);

    /// @notice The endpoint ID of the destination chain
    function eid() external view returns (uint32);

    /// @notice Checks if a sender is authorized
    /// @param sender The address of the sender to check
    /// @return authorized True if the sender is authorized, false otherwise
    function authorizedSenders(address sender) external view returns (bool authorized);

    /// @notice Estimates the fee for sending a message
    /// @param _receiver Address of the receiver
    /// @param _executeGasLimit Gas limit for execution
    /// @param _msg The message to be sent
    /// @return _token The token address for the fee (address(0) for native token)
    /// @return _fee The estimated fee amount
    function estimateFee(
        address _receiver,
        uint128 _executeGasLimit,
        bytes memory _msg
    ) external view returns (address _token, uint256 _fee);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

interface IWithdrawPool {
    event SetUnstaker(address unstaker);
    event SetLzReceiveGasLimit(uint128 gasLimit);
    event Unlocked(uint256 unlockedLSDAmount, uint256 amount);
    event SmartSavingsOnGravityUpdated(address addr);

    event PoolUnlocksBridged(uint256 totalPoolUnlocks, uint256 fee, bytes32 guid);
    event Claimed(address to, uint256 underlyingTokenAmount, uint256 amountOfLSD, uint256 timestamp, bytes32 guid);

    error InvalidCaller();
    error WithdrawSentFailed();
    error InvalidLSD();
    error InvalidUnlockAmount();
    error InvalidBridgeMessage();
    error InvalidBridgeMessageFrom(address _address);
    error InvalidUnderlyingToken();
    error InvalidNav(uint256 _nav);
    error InvalidClaimAmount(uint256 _amount);
    error InvalidTimestamp(uint256 _tradingDays);
    error ClaimAmountTooSmall(uint256 _amount);
    error InsufficientFee(uint256 wanted, uint256 provided);
    error SendFailed(address to, uint256 amount);

    function setUnstaker(address _unstaker) external;
    function rescueWithdraw(address _token, address _to) external;
    function addPoolUnlocks(uint256 _unlockedLSDAmount, uint256 _amount) external payable;
    function totalPoolUnlocks() external returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

library MessageLib {
    /// @notice Messages are transferred between chains as 44=byte long bytes
    ///        The first 8 bits are the value type.
    ///        The next 136 bits are the value amount.
    ///        The next 160 bits are the address related to the value.
    ///        The remaining 48 bits are the value timestamp.
    struct Message {
        uint8 valueType;
        uint256 value;
        address owner;
        uint256 timestamp;
    }

    uint256 internal constant _MAX_VALUE = type(uint136).max;
    uint256 internal constant _MAX_TIMESTAMP = type(uint48).max;

    uint8 public constant TOTAL_DEPOSITS_TYPE = 1;
    uint8 public constant TOTAL_POOL_UNLOCKS_TYPE = 2;
    uint8 public constant TOTAL_CLAIMS_TYPE = 3;
    uint8 public constant TOTAL_REQUESTS_TYPE = 4;

    error MessageLib_ValueOverflow();
    error MessageLib_TimestampOverflow();
    error MessageLib_InvalidMessageLength(uint256 length);

    ///
    /// @notice Extracts a Message from bytes.
    ///
    function unpack(bytes memory b) internal pure returns (Message memory m) {
        uint8 valueType;
        uint136 value;
        address owner;
        uint48 _timestamp;

        if (b.length != 44) revert MessageLib_InvalidMessageLength(b.length);

        /* solhint-disable no-inline-assembly */
        assembly {
            valueType := mload(add(b, 1))
            value := mload(add(b, 18))
            owner := mload(add(b, 38))
            _timestamp := mload(add(b, 44))
        }
        /* solhint-enable no-inline-assembly */

        return Message(valueType, value, owner, _timestamp);
    }

    ///
    /// @notice Packs a Message into bytes.
    ///
    function pack(Message memory m) internal pure returns (bytes memory) {
        if (m.value > _MAX_VALUE) revert MessageLib_ValueOverflow();
        if (m.timestamp > _MAX_TIMESTAMP) revert MessageLib_TimestampOverflow();

        return abi.encodePacked(m.valueType, uint136(m.value), m.owner, uint48(m.timestamp));
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

interface IVaultNav {
    event NavUpdated(address indexed lsd, uint256 nav, uint256 timestamp);
    event SetNavUpdater(address indexed lsd, address updater);

    error NavNotFound(uint48 _timestamp);
    error InvalidNavUpdater(address updater);
    error NavInvalidValue(uint256 nav);
    error TimestampTooLarge();
    error InvalidUpdatePeriod();
    error NavUpdateInvalidTimestamp();

    function appendNav(address lsd, uint256 nav, uint48 timestamp) external;
    function setNavUpdater(address lsd, address updater) external;
    function getNavByTimestamp(
        address vaultType,
        uint48 timestamp
    ) external view returns (uint256 nav, uint48 updateTime);

    function lsdToTokenE18AtTime(address _lsd, uint256 _amount, uint48 _timestamp) external view returns (uint256);
    function tokenE18ToLsdAtTime(
        address _lsd,
        uint256 _tokenAmountE18,
        uint48 _timestamp
    ) external view returns (uint256);
}

{
  "optimizer": {
    "enabled": true,
    "runs": 1000
  },
  "viaIR": true,
  "evmVersion": "paris",
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  },
  "metadata": {
    "useLiteralContent": true
  },
  "libraries": {}
}

• No Contract Security Audit Submitted- Submit Audit Here

[{"inputs":[{"internalType":"address","name":"_owner","type":"address"},{"internalType":"address","name":"_abridge","type":"address"},{"internalType":"address","name":"_smartSavingsOnGravity","type":"address"},{"internalType":"address","name":"_vaultNav","type":"address"},{"internalType":"address","name":"_underlyingToken","type":"address"},{"internalType":"address","name":"_lsd","type":"address"}],"stateMutability":"nonpayable","type":"constructor"},{"inputs":[{"internalType":"address","name":"target","type":"address"}],"name":"AddressEmptyCode","type":"error"},{"inputs":[{"internalType":"address","name":"account","type":"address"}],"name":"AddressInsufficientBalance","type":"error"},{"inputs":[{"internalType":"uint256","name":"_amount","type":"uint256"}],"name":"ClaimAmountTooSmall","type":"error"},{"inputs":[],"name":"FailedInnerCall","type":"error"},{"inputs":[{"internalType":"uint256","name":"wanted","type":"uint256"},{"internalType":"uint256","name":"provided","type":"uint256"}],"name":"InsufficientFee","type":"error"},{"inputs":[],"name":"InvalidBridgeMessage","type":"error"},{"inputs":[{"internalType":"address","name":"_address","type":"address"}],"name":"InvalidBridgeMessageFrom","type":"error"},{"inputs":[],"name":"InvalidCaller","type":"error"},{"inputs":[{"internalType":"uint256","name":"_amount","type":"uint256"}],"name":"InvalidClaimAmount","type":"error"},{"inputs":[],"name":"InvalidLSD","type":"error"},{"inputs":[{"internalType":"uint256","name":"_nav","type":"uint256"}],"name":"InvalidNav","type":"error"},{"inputs":[{"internalType":"uint256","name":"_tradingDays","type":"uint256"}],"name":"InvalidTimestamp","type":"error"},{"inputs":[],"name":"InvalidUnderlyingToken","type":"error"},{"inputs":[],"name":"InvalidUnlockAmount","type":"error"},{"inputs":[{"internalType":"uint256","name":"length","type":"uint256"}],"name":"MessageLib_InvalidMessageLength","type":"error"},{"inputs":[],"name":"MessageLib_TimestampOverflow","type":"error"},{"inputs":[],"name":"MessageLib_ValueOverflow","type":"error"},{"inputs":[],"name":"NotCalledFromAbridge","type":"error"},{"inputs":[{"internalType":"address","name":"owner","type":"address"}],"name":"OwnableInvalidOwner","type":"error"},{"inputs":[{"internalType":"address","name":"account","type":"address"}],"name":"OwnableUnauthorizedAccount","type":"error"},{"inputs":[{"internalType":"address","name":"token","type":"address"}],"name":"SafeERC20FailedOperation","type":"error"},{"inputs":[{"internalType":"address","name":"to","type":"address"},{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"SendFailed","type":"error"},{"inputs":[],"name":"WithdrawSentFailed","type":"error"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"oldBridge","type":"address"},{"indexed":true,"internalType":"address","name":"newBridge","type":"address"}],"name":"AbridgeUpdated","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"address","name":"to","type":"address"},{"indexed":false,"internalType":"uint256","name":"underlyingTokenAmount","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"amountOfLSD","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"timestamp","type":"uint256"},{"indexed":false,"internalType":"bytes32","name":"guid","type":"bytes32"}],"name":"Claimed","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"previousOwner","type":"address"},{"indexed":true,"internalType":"address","name":"newOwner","type":"address"}],"name":"OwnershipTransferStarted","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"previousOwner","type":"address"},{"indexed":true,"internalType":"address","name":"newOwner","type":"address"}],"name":"OwnershipTransferred","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint256","name":"totalPoolUnlocks","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"fee","type":"uint256"},{"indexed":false,"internalType":"bytes32","name":"guid","type":"bytes32"}],"name":"PoolUnlocksBridged","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"sender","type":"address"},{"indexed":false,"internalType":"bool","name":"allowed","type":"bool"}],"name":"RouteUpdated","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint128","name":"gasLimit","type":"uint128"}],"name":"SetLzReceiveGasLimit","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"address","name":"unstaker","type":"address"}],"name":"SetUnstaker","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"address","name":"addr","type":"address"}],"name":"SmartSavingsOnGravityUpdated","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint256","name":"unlockedLSDAmount","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"Unlocked","type":"event"},{"inputs":[],"name":"LSD","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"UNDERLYING_TOKEN","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"abridge","outputs":[{"internalType":"contract IAbridge","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"acceptOwnership","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"_unlockedLSDAmount","type":"uint256"},{"internalType":"uint256","name":"_amount","type":"uint256"}],"name":"addPoolUnlocks","outputs":[],"stateMutability":"payable","type":"function"},{"inputs":[{"internalType":"address","name":"_from","type":"address"},{"internalType":"bytes","name":"_message","type":"bytes"},{"internalType":"bytes32","name":"_guid","type":"bytes32"}],"name":"handleMessage","outputs":[{"internalType":"bytes4","name":"response","type":"bytes4"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"lzReceiveGasLimit","outputs":[{"internalType":"uint128","name":"","type":"uint128"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"owner","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"pendingOwner","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"renounceOwnership","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"_token","type":"address"},{"internalType":"address","name":"_to","type":"address"}],"name":"rescueWithdraw","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"_abridge","type":"address"}],"name":"setAbridge","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint128","name":"_gasLimit","type":"uint128"}],"name":"setLzReceiveGasLimit","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"_smartSavings","type":"address"}],"name":"setSmartSavingOnGravity","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"_unstaker","type":"address"}],"name":"setUnstaker","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"smartSavingsOnGravity","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalLsdBurned","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"","type":"address"}],"name":"totalPoolClaimed","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalPoolUnlocks","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"newOwner","type":"address"}],"name":"transferOwnership","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"unlockFee","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"unstaker","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"_sender","type":"address"},{"internalType":"bool","name":"allowed","type":"bool"}],"name":"updateRoute","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"vaultNav","outputs":[{"internalType":"contract IVaultNav","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"stateMutability":"payable","type":"receive"}]

0x6080604052600436101561001b575b361561001957600080fd5b005b60003560e01c806305d6cb961461019b578063099dabb51461019657806314747dad14610191578063232cec311461018c57806329db1be6146101875780632fe15402146101825780634a7acd831461017d5780635b12d7e2146101785780635f9d7a2f14610173578063715018a61461016e57806373e66cf51461016957806379ba509714610164578063895dde7b1461015f5780638da5cb5b1461015a5780638e91037914610155578063b1d4105b14610150578063b7f756351461014b578063e1697a2e14610146578063e30c397814610141578063e6add3011461013c578063f2fde38b14610137578063f777a63114610132578063fa8c42e91461012d5763fe6c84e40361000e576109d4565b6109ad565b6108b8565b610840565b61074f565b610728565b6106f8565b6106da565b61066c565b610600565b6105d9565b6105b6565b61051b565b6104d7565b61046f565b610451565b6103e5565b6103be565b610331565b6102ed565b6102af565b610288565b610261565b6101b6565b6001600160a01b038116036101b157565b600080fd5b346101b15760603660031901126101b1576004356101d3816101a0565b67ffffffffffffffff906024358281116101b157366023820112156101b15780600401359283116101b15736602484830101116101b1576102529261021f926024604435930190610c06565b6040517fffffffff0000000000000000000000000000000000000000000000000000000090911681529081906020820190565b0390f35b60009103126101b157565b346101b15760003660031901126101b15760206001600160a01b0360005416604051908152f35b346101b15760003660031901126101b15760206001600160a01b0360035416604051908152f35b346101b15760203660031901126101b1576001600160a01b036004356102d4816101a0565b1660005260086020526020604060002054604051908152f35b346101b15760003660031901126101b15760206040516001600160a01b037f000000000000000000000000dac17f958d2ee523a2206206994597c13d831ec7168152f35b346101b15760203660031901126101b1576004356fffffffffffffffffffffffffffffffff81168091036101b15760207f48a5221f185cf972fda53090126c8c1b4737d0296f486902ac6d9b2f87f883709161038b611312565b807fffffffffffffffffffffffffffffffff000000000000000000000000000000006009541617600955604051908152a1005b346101b15760003660031901126101b15760206001600160a01b0360055416604051908152f35b346101b15760203660031901126101b1577fd2cc6f43e75c95e2cb5ba97e0b49a87c2e1fbb4ebfb922eb9f764d28fb45c6bd60206001600160a01b0360043561042d816101a0565b610435611312565b16806001600160a01b03196004541617600455604051908152a1005b346101b15760003660031901126101b1576020600754604051908152f35b346101b1576000806003193601126104d457610489611312565b806001600160a01b036001600160a01b03198060025416600255600154908116600155167f8be0079c531659141344cd1fd0a4f28419497f9722a3daafe3b4186f6b6457e08280a380f35b80fd5b346101b15760003660031901126101b15760206040516001600160a01b037f000000000000000000000000917bfef9524731b8fee9c8726094a17f24191ef4168152f35b346101b1576000806003193601126104d4576002546001600160a01b033381831603610586576001600160a01b03198092166002556001549133908316176001553391167f8be0079c531659141344cd1fd0a4f28419497f9722a3daafe3b4186f6b6457e08380a380f35b60246040517f118cdaa7000000000000000000000000000000000000000000000000000000008152336004820152fd5b346101b15760003660031901126101b15760206105d1610eba565b604051908152f35b346101b15760003660031901126101b15760206001600160a01b0360015416604051908152f35b346101b15760203660031901126101b1577fbb8e3038bf525ca88eeb2530d4b112dd30d13da2af8deb8962c6cea47922939e60206001600160a01b03600435610648816101a0565b610650611312565b16806001600160a01b03196003541617600355604051908152a1005b346101b15760203660031901126101b157600435610689816101a0565b610691611312565b6000908154906001600160a01b0380911691826001600160a01b03198216178455167f8649f676b8e96cabaeb3cc05ea878533db943e44f4178953e4b45d8724eb2db48380a380f35b346101b15760003660031901126101b1576020600654604051908152f35b346101b15760003660031901126101b15760206fffffffffffffffffffffffffffffffff60095416604051908152f35b346101b15760003660031901126101b15760206001600160a01b0360025416604051908152f35b346101b15760403660031901126101b15760043561076c816101a0565b6001600160a01b0360243591610781836101a0565b610789611312565b16806107d4575060008080809347905af16107a2610fae565b50156107aa57005b60046040517f6ecddac7000000000000000000000000000000000000000000000000000000008152fd5b6040516370a0823160e01b815230600482015291602083602481855afa91821561083b576100199360009361080a575b50611484565b61082d91935060203d602011610834575b6108258183610d99565b810190610f9f565b9138610804565b503d61081b565b610eae565b346101b15760203660031901126101b15760043561085d816101a0565b610865611312565b6001600160a01b0380911690816001600160a01b03196002541617600255600154167f38d16b8cac22d99fc7c124b9cd0de2d3fa1faef420bfe791d8c362d765e22700600080a3005b801515036101b157565b346101b15760403660031901126101b1576004356108d5816101a0565b602435906108e2826108ae565b6108ea611312565b6001600160a01b039060009283918383541693843b156109a9576044849260405195869384927ff777a631000000000000000000000000000000000000000000000000000000008452169788600484015286151560248401525af190811561083b577fa8f00cc8874ff3b7c09b3f6834c3cbd5113c3e5625a3822822639329185dad359261098a92610990575b5060405190151581529081906020820190565b0390a280f35b8061099d6109a392610d64565b80610256565b38610977565b8380fd5b346101b15760003660031901126101b15760206001600160a01b0360045416604051908152f35b6040806003193601126101b15760048035602435916001600160a01b0392838254163303610bde578215610af257610a16610a1184600654610ff4565b600655565b809334907f000000000000000000000000dac17f958d2ee523a2206206994597c13d831ec7168015600014610b1a57505080341115610af257610a599034611014565b905b610a63610eba565b90818310610ab65750507f6a4ab9eaabc176a1c70b5f19a39c8f7a220e8f3f649ddb5a7e8c1f957ac112ab93610a9b610ab19261154d565b5191825260208201929092529081906040820190565b0390a1005b85517fa458261b000000000000000000000000000000000000000000000000000000008152908101918252602082018390529081906040010390fd5b5083517f40237973000000000000000000000000000000000000000000000000000000008152fd5b86516370a0823160e01b808252308287019081529597509294602094939085908390819083010381865afa93841561083b578592600095610bbb575b50610b63903033866114de565b885190815230888201908152909283918290819060200103915afa90811561083b57610b9893600092610b9e575b5050611014565b92610a5b565b610bb49250803d10610834576108258183610d99565b3880610b91565b610b63919550610bd790843d8611610834576108258183610d99565b9490610b56565b5083517f48f5c3ed000000000000000000000000000000000000000000000000000000008152fd5b939291906001600160a01b039182600054163303610d2457610c3291610c2d913691610de6565b611021565b90600360ff610c42845160ff1690565b1603610cfa57610c69610c5d6003546001600160a01b031690565b6001600160a01b031690565b90851603610cc057610c9c929350610c8b60408201516001600160a01b031690565b9060606020820151910151916110e6565b7f05d6cb960000000000000000000000000000000000000000000000000000000090565b6040517f875b3cd10000000000000000000000000000000000000000000000000000000081526001600160a01b0385166004820152602490fd5b60046040517f77fa6fb9000000000000000000000000000000000000000000000000000000008152fd5b60046040517f0b2caebb000000000000000000000000000000000000000000000000000000008152fd5b634e487b7160e01b600052604160045260246000fd5b67ffffffffffffffff8111610d7857604052565b610d4e565b6080810190811067ffffffffffffffff821117610d7857604052565b90601f8019910116810190811067ffffffffffffffff821117610d7857604052565b60405190610dc882610d7d565b565b67ffffffffffffffff8111610d7857601f01601f191660200190565b929192610df282610dca565b91610e006040519384610d99565b8294818452818301116101b1578281602093846000960137010152565b91908260409103126101b15760208251610e36816101a0565b92015190565b919392906001600160a01b031682526fffffffffffffffffffffffffffffffff6020941660208301526060604083015280519081606084015260005b828110610e9a57505060809293506000838284010152601f8019910116010190565b818101860151848201608001528501610e78565b6040513d6000823e3d90fd5b610f5b6040610ed4610c5d6000546001600160a01b031690565b6003546001600160a01b031690610efc6009546fffffffffffffffffffffffffffffffff1690565b610f25600654610f0a610dbb565b60028152906020820152308682015260006060820152611326565b928451958694859384937f5822a19400000000000000000000000000000000000000000000000000000000855260048501610e3c565b03915afa90811561083b57600091610f71575090565b610f93915060403d604011610f98575b610f8b8183610d99565b810190610e1d565b905090565b503d610f81565b908160209103126101b1575190565b3d15610fd9573d90610fbf82610dca565b91610fcd6040519384610d99565b82523d6000602084013e565b606090565b634e487b7160e01b600052601160045260246000fd5b9190820180921161100157565b610fde565b601203906012821161100157565b9190820391821161100157565b6000606060405161103181610d7d565b82815282602082015282604082015201528051602c81036110b3575065ffffffffffff6001820151916110aa60128201519170ffffffffffffffffffffffffffffffffff602c60268301519201519361109461108b610dbb565b60ff9098168852565b1660208601526001600160a01b03166040850152565b16606082015290565b6040517f2a5151c10000000000000000000000000000000000000000000000000000000081526004810191909152602490fd5b9093929382156112e05780156112ad57611113826001600160a01b03166000526008602052604060002090565b5490808210156112ad57908161114692611140856001600160a01b03166000526008602052604060002090565b55611014565b9161115b61115684600754610ff4565b600755565b6111658184611712565b92831561127a577f000000000000000000000000dac17f958d2ee523a2206206994597c13d831ec76001600160a01b0316806112425750600080808087875af16111ad610fae565b50156112155794611210917f637cc738898b2b3ea9460c84eee3ff086a182aa10aa064980a593722e1f49cff95965b60405195869586919260809396959491966001600160a01b0360a08501981684526020840152604083015260608201520152565b0390a1565b50506040516353a0add160e01b81526001600160a01b039190911660048201526024810191909152604490fd5b917f637cc738898b2b3ea9460c84eee3ff086a182aa10aa064980a593722e1f49cff959691611275868661121096611484565b6111dc565b6040517f0a8582780000000000000000000000000000000000000000000000000000000081526004810191909152602490fd5b6040517f27ab1ee20000000000000000000000000000000000000000000000000000000081526004810191909152602490fd5b6040517f25c2082800000000000000000000000000000000000000000000000000000000815260048101849052602490fd5b6001600160a01b0360015416330361058657565b6020810170ffffffffffffffffffffffffffffffffff908181511161145a57606083019165ffffffffffff8351116114305761142d926113866001600160a01b03604061141f9460ff89511696511697015116915165ffffffffffff1690565b9060405195869460208601927fffffffffffff0000000000000000000000000000000000000000000000000000927fff00000000000000000000000000000000000000000000000000000000000000602c969360f81b1685526effffffffffffffffffffffffffffff199060781b1660018501526bffffffffffffffffffffffff199060601b16601284015260d01b1660268201520190565b03601f198101835282610d99565b90565b60046040517f9fe1912c000000000000000000000000000000000000000000000000000000008152fd5b60046040517f5f3f8345000000000000000000000000000000000000000000000000000000008152fd5b6040517fa9059cbb0000000000000000000000000000000000000000000000000000000060208201526001600160a01b03929092166024830152604480830193909352918152610dc8916114d9606483610d99565b6118cf565b9290604051927f23b872dd0000000000000000000000000000000000000000000000000000000060208501526001600160a01b03809216602485015216604483015260648201526064815260a081019181831067ffffffffffffffff841117610d7857610dc8926040526118cf565b906006549161155a610dbb565b600281529260208401523060408401526115f561157e600094856060820152611326565b60204791611596610c5d88546001600160a01b031690565b6003546001600160a01b0316866115be6009546fffffffffffffffffffffffffffffffff1690565b91604051978895869485937ff0a147ad00000000000000000000000000000000000000000000000000000000855260048501610e3c565b03925af191821561083b5785926116a6575b50611613904790611014565b828110611661575b50600654604080519182526020820193909352918201529091507f3a5712a2fbe42d71c03f93ef6c3d0ec9c9df561f1564b78ae059fb742746f22f908060608101611210565b61166b9083611014565b9380808087335af161167b610fae565b5015611687578361161b565b6040516353a0add160e01b815233600482015260248101859052604490fd5b6116139192506116c49060203d602011610834576108258183610d99565b9190611607565b908160209103126101b1575160ff811681036101b15790565b604d811161100157600a0a90565b81156116fc570490565b634e487b7160e01b600052601260045260246000fd5b907f000000000000000000000000dac17f958d2ee523a2206206994597c13d831ec76001600160a01b0316908161184a576117e79150602065ffffffffffff6012925b61176a610c5d6005546001600160a01b031690565b906040518096819482937f75812baf00000000000000000000000000000000000000000000000000000000845216897f000000000000000000000000917bfef9524731b8fee9c8726094a17f24191ef46004850191604091949365ffffffffffff916001600160a01b036060860197168552602085015216910152565b03915afa90811561083b5761181692600092611821575b5061180b61181091611006565b6116e4565b906116f2565b90811561127a575090565b61181091925061184261180b9160203d602011610834576108258183610d99565b9291506117fe565b6020600492604051938480927f313ce5670000000000000000000000000000000000000000000000000000000082525afa91821561083b5765ffffffffffff60ff6117e7946020936000916118a2575b501692611755565b6118c29150843d86116118c8575b6118ba8183610d99565b8101906116cb565b3861189a565b503d6118b0565b6000806001600160a01b036118f993169360208151910182865af16118f2610fae565b9083611964565b8051908115159182611940575b505061190f5750565b602490604051907f5274afe70000000000000000000000000000000000000000000000000000000082526004820152fd5b81925090602091810103126101b1576020015161195c816108ae565b153880611906565b906119a3575080511561197957805190602001fd5b60046040517f1425ea42000000000000000000000000000000000000000000000000000000008152fd5b815115806119ee575b6119b4575090565b6024906001600160a01b03604051917f9996b315000000000000000000000000000000000000000000000000000000008352166004820152fd5b50803b156119ac56fea26469706673582212208d08053001c30103fb62fae4982251dc734f2555c4a943dc214050e9dcf37f4364736f6c63430008180033