Contract

Contract Source Code (Solidity Multiple files format)

IDE

• Blockscan IDE
• 🤖 Code ReaderBeta
• Remix IDE

More Options

• Is this a proxy?
• Similar
• Sol2Uml
• Submit Audit
• Compare

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.17;

import "./Dependencies.sol";
import "./Fiefdoms.sol";


contract FiefdomProxy is Proxy {
  bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;

  struct AddressSlot {
    address value;
  }

  function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
    assembly {
      r.slot := slot
    }
  }

  function _implementation() internal override view returns (address) {
    return getAddressSlot(_IMPLEMENTATION_SLOT).value;
  }

  function implementation() public view returns (address) {
    return _implementation();
  }

  // Defer all functionality to the given archetype contract
  constructor() {
    address fiefdomArchetype = Fiefdoms(msg.sender).fiefdomArchetype();
    uint256 fiefdomId = Fiefdoms(msg.sender).totalSupply();
    getAddressSlot(_IMPLEMENTATION_SLOT).value = fiefdomArchetype;

    // Invoke the preInitialize function on itself, as defined by the archetype contract
    Address.functionDelegateCall(
        fiefdomArchetype,
        abi.encodeWithSignature("initialize(address,uint256)", msg.sender, fiefdomId),
        "Address: low-level delegate call failed"
    );
  }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.17;

import "./Dependencies.sol";
import "./Fiefdoms.sol";
import "./FiefdomArchetype.sol";

contract BaseTokenURI {
  using Strings for uint256;

  Fiefdoms private immutable fiefdoms;

  constructor() {
    fiefdoms = Fiefdoms(msg.sender);
  }

  function tokenURI(uint256 tokenId) external view returns (string memory) {
    bytes memory name = abi.encodePacked('Fiefdom Vassal #', tokenId.toString());
    address fiefdomAddr = fiefdoms.tokenIdToFiefdom(tokenId);

    bool isActivated = FiefdomArchetype(fiefdomAddr).isActivated();
    uint256 foundedAt = FiefdomArchetype(fiefdomAddr).foundedAt();

    string memory pColor = isActivated ? '#fff' : '#000';
    string memory sColor = isActivated ? '#000' : '#fff';
    string memory state = isActivated ? 'Activated' : 'Unactivated';

    bytes memory attributes = abi.encodePacked(
      '[{"trait_type": "Activated", "value":',
      isActivated ? '"true"' : '"false"',
      '},{"trait_type": "Fiefdom", "value": "0x',
      toString(fiefdomAddr),
      '"},{"trait_type": "Founded At", "value": "',
      foundedAt.toString(),
      '"}]'
    );


    bytes memory background = abi.encodePacked(
      '<rect x="0" y="0" width="100%" height="100%" fill="', pColor,'"/>',
      '<rect x="23.78px" y="23.78px" width="1141.44" height="793.44px" fill="none" stroke="', sColor,'" stroke-width="2"/>'
    );

    bytes memory textName = abi.encodePacked(
      '<text x="50%" y="47%" font-size="105px" fill="',
      sColor,
      '" dominant-baseline="middle" text-anchor="middle">',
      name,
      '</text>'
    );

    bytes memory textAddr = abi.encodePacked(
      '<text x="50%" y="58%" font-size="42px" fill="', sColor,'" font-family="monospace" dominant-baseline="middle" text-anchor="middle">0x',
      toString(fiefdomAddr),
      '</text>'
    );

    bytes memory encodedImage = abi.encodePacked(
      '"data:image/svg+xml;base64,',
      Base64.encode(abi.encodePacked(
        '<svg xmlns="http://www.w3.org/2000/svg" viewBox="0 0 1189 841">',
        background,
        textName,
        textAddr,
        '</svg>'
      )),
      '",'
    );

    bytes memory description = abi.encodePacked(
      '"',
      state,
      ' ',
      name,
      ' of 0x',
      toString(fiefdomAddr),
      '",'
    );

    bytes memory json = abi.encodePacked(
      'data:application/json;utf8,',
      '{"name": "', name,'",',
      '"description": ', description,
      '"external_url": "https://steviep.xyz/fiefdoms",'
      '"image": ', encodedImage,
      '"attributes":', attributes,
      '}'
    );
    return string(json);
  }

  function toString(address x) internal pure returns (string memory) {
    bytes memory s = new bytes(40);
    for (uint i = 0; i < 20; i++) {
      bytes1 b = bytes1(uint8(uint(uint160(x)) / (2**(8*(19 - i)))));
      bytes1 hi = bytes1(uint8(b) / 16);
      bytes1 lo = bytes1(uint8(b) - 16 * uint8(hi));
      s[2*i] = char(hi);
      s[2*i+1] = char(lo);
    }
    return string(s);
  }

  function char(bytes1 b) internal pure returns (bytes1 c) {
    if (uint8(b) < 10) return bytes1(uint8(b) + 0x30);
    else return bytes1(uint8(b) + 0x57);
  }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.17;

import "./Dependencies.sol";
import "./Fiefdoms.sol";
import "./FiefdomArchetype.sol";

contract DefaultTokenURI {
  using Strings for uint256;

  function tokenURI(uint256 tokenId) external view returns (string memory) {
    FiefdomArchetype fiefdom = FiefdomArchetype(msg.sender);


    bytes memory name = abi.encodePacked('Fiefdom ', fiefdom.fiefdomId().toString(), ', Token ', tokenId.toString());

    bytes memory background = abi.encodePacked(
      '<rect x="0" y="0" width="100%" height="100%" fill="#000"/>',
      '<rect x="23.78px" y="23.78px" width="1141.44" height="793.44px" fill="none" stroke="#fff" stroke-width="5"/>'
    );

    bytes memory textFiefdom = abi.encodePacked(
      '<text x="50%" y="38%" class="t">',
      'Fiefdom ',
      fiefdom.fiefdomId().toString(),
      '</text>'
    );

    bytes memory textToken = abi.encodePacked(
      '<text x="50%" y="62%" class="t">',
      'Token ',
      tokenId.toString(),
      '</text>'
    );

    bytes memory encodedImage = abi.encodePacked(
      '"data:image/svg+xml;base64,',
      Base64.encode(abi.encodePacked(
        '<svg xmlns="http://www.w3.org/2000/svg" viewBox="0 0 1189 841"><style>.t{font-size:160px;font-family:sans-serif;fill:#fff;dominant-baseline:middle;text-anchor:middle;}</style>',
        background,
        textFiefdom,
        textToken,
        '</svg>'
      )),
      '"'
    );


    bytes memory json = abi.encodePacked(
      'data:application/json;utf8,',
      '{"name": "', name,'",',
      '"description": "The start of something new.",',
      '"image": ', encodedImage,
      '}'
    );
    return string(json);
  }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}



/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}



/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}


/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}



/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /*
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */

    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}


/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /*
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */

    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}



/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}



/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _setOwner(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _setOwner(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _setOwner(newOwner);
    }

    function _setOwner(address newOwner) private {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}




/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        require(operator != _msgSender(), "ERC721: approve to caller");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer of token that is not own");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver(to).onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}

/**
 * @title ERC721 Burnable Token
 * @dev ERC721 Token that can be burned (destroyed).
 */
abstract contract ERC721Burnable is Context, ERC721 {
    /**
     * @dev Burns `tokenId`. See {ERC721-_burn}.
     *
     * Requirements:
     *
     * - The caller must own `tokenId` or be an approved operator.
     */
    function burn(uint256 tokenId) public virtual {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");
        _burn(tokenId);
    }
}



interface IERC1155Receiver is IERC165 {
    /**
     * @dev Handles the receipt of a single ERC1155 token type. This function is
     * called at the end of a `safeTransferFrom` after the balance has been updated.
     *
     * NOTE: To accept the transfer, this must return
     * `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))`
     * (i.e. 0xf23a6e61, or its own function selector).
     *
     * @param operator The address which initiated the transfer (i.e. msg.sender)
     * @param from The address which previously owned the token
     * @param id The ID of the token being transferred
     * @param value The amount of tokens being transferred
     * @param data Additional data with no specified format
     * @return `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))` if transfer is allowed
     */
    function onERC1155Received(
        address operator,
        address from,
        uint256 id,
        uint256 value,
        bytes calldata data
    ) external returns (bytes4);

    /**
     * @dev Handles the receipt of a multiple ERC1155 token types. This function
     * is called at the end of a `safeBatchTransferFrom` after the balances have
     * been updated.
     *
     * NOTE: To accept the transfer(s), this must return
     * `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))`
     * (i.e. 0xbc197c81, or its own function selector).
     *
     * @param operator The address which initiated the batch transfer (i.e. msg.sender)
     * @param from The address which previously owned the token
     * @param ids An array containing ids of each token being transferred (order and length must match values array)
     * @param values An array containing amounts of each token being transferred (order and length must match ids array)
     * @param data Additional data with no specified format
     * @return `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))` if transfer is allowed
     */
    function onERC1155BatchReceived(
        address operator,
        address from,
        uint256[] calldata ids,
        uint256[] calldata values,
        bytes calldata data
    ) external returns (bytes4);
}



// OpenZeppelin Contracts (last updated v4.6.0) (proxy/Proxy.sol)


/**
 * @dev This abstract contract provides a fallback function that delegates all calls to another contract using the EVM
 * instruction `delegatecall`. We refer to the second contract as the _implementation_ behind the proxy, and it has to
 * be specified by overriding the virtual {_implementation} function.
 *
 * Additionally, delegation to the implementation can be triggered manually through the {_fallback} function, or to a
 * different contract through the {_delegate} function.
 *
 * The success and return data of the delegated call will be returned back to the caller of the proxy.
 */
abstract contract Proxy {
    /**
     * @dev Delegates the current call to `implementation`.
     *
     * This function does not return to its internal call site, it will return directly to the external caller.
     */
    function _delegate(address implementation) internal virtual {
        assembly {
            // Copy msg.data. We take full control of memory in this inline assembly
            // block because it will not return to Solidity code. We overwrite the
            // Solidity scratch pad at memory position 0.
            calldatacopy(0, 0, calldatasize())

            // Call the implementation.
            // out and outsize are 0 because we don't know the size yet.
            let result := delegatecall(gas(), implementation, 0, calldatasize(), 0, 0)

            // Copy the returned data.
            returndatacopy(0, 0, returndatasize())

            switch result
            // delegatecall returns 0 on error.
            case 0 {
                revert(0, returndatasize())
            }
            default {
                return(0, returndatasize())
            }
        }
    }

    /**
     * @dev This is a virtual function that should be overridden so it returns the address to which the fallback function
     * and {_fallback} should delegate.
     */
    function _implementation() internal view virtual returns (address);

    /**
     * @dev Delegates the current call to the address returned by `_implementation()`.
     *
     * This function does not return to its internal call site, it will return directly to the external caller.
     */
    function _fallback() internal virtual {
        _beforeFallback();
        _delegate(_implementation());
    }

    /**
     * @dev Fallback function that delegates calls to the address returned by `_implementation()`. Will run if no other
     * function in the contract matches the call data.
     */
    fallback() external payable virtual {
        _fallback();
    }

    /**
     * @dev Fallback function that delegates calls to the address returned by `_implementation()`. Will run if call data
     * is empty.
     */
    receive() external payable virtual {
        _fallback();
    }

    /**
     * @dev Hook that is called before falling back to the implementation. Can happen as part of a manual `_fallback`
     * call, or as part of the Solidity `fallback` or `receive` functions.
     *
     * If overridden should call `super._beforeFallback()`.
     */
    function _beforeFallback() internal virtual {}
}


/// [MIT License]
/// @title Base64
/// @notice Provides a function for encoding some bytes in base64
/// @author Brecht Devos <[email protected]>
library Base64 {
    bytes internal constant TABLE = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/";

    /// @notice Encodes some bytes to the base64 representation
    function encode(bytes memory data) internal pure returns (string memory) {
        uint256 len = data.length;
        if (len == 0) return "";

        // multiply by 4/3 rounded up
        uint256 encodedLen = 4 * ((len + 2) / 3);

        // Add some extra buffer at the end
        bytes memory result = new bytes(encodedLen + 32);

        bytes memory table = TABLE;

        assembly {
            let tablePtr := add(table, 1)
            let resultPtr := add(result, 32)

            for {
                let i := 0
            } lt(i, len) {

            } {
                i := add(i, 3)
                let input := and(mload(add(data, i)), 0xffffff)

                let out := mload(add(tablePtr, and(shr(18, input), 0x3F)))
                out := shl(8, out)
                out := add(out, and(mload(add(tablePtr, and(shr(12, input), 0x3F))), 0xFF))
                out := shl(8, out)
                out := add(out, and(mload(add(tablePtr, and(shr(6, input), 0x3F))), 0xFF))
                out := shl(8, out)
                out := add(out, and(mload(add(tablePtr, and(input, 0x3F))), 0xFF))
                out := shl(224, out)

                mstore(resultPtr, out)

                resultPtr := add(resultPtr, 4)
            }

            switch mod(len, 3)
            case 1 {
                mstore(sub(resultPtr, 2), shl(240, 0x3d3d))
            }
            case 2 {
                mstore(sub(resultPtr, 1), shl(248, 0x3d))
            }

            mstore(result, encodedLen)
        }

        return string(result);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.17;

import "./Dependencies.sol";

interface IERC721Hooks {
  function parent() external returns (address);
  function beforeTokenTransfer(address from, address to, uint256 tokenId) external;
  function beforeApprove(address to, uint256 tokenId) external;
  function beforeSetApprovalForAll(address operator, bool approved) external;
}

contract ERC721HooksBase is IERC721Hooks {
  address public parent;

  constructor(address _parent) {
    parent = _parent;
  }

  modifier onlyParent() {
    require(msg.sender == parent, "Only parent ERC721 can call hooks");
    _;
  }

  function _beforeTokenTransfer(address from, address to, uint256 tokenId) internal virtual {}
  function beforeTokenTransfer(address from, address to, uint256 tokenId) external onlyParent {
    _beforeTokenTransfer(from, to, tokenId);
  }

  function _beforeApprove(address to, uint256 tokenId) internal virtual {}
  function beforeApprove(address to, uint256 tokenId) external onlyParent {
    _beforeApprove(to, tokenId);
  }

  function _beforeSetApprovalForAll(address operator, bool approved) internal virtual {}
  function beforeSetApprovalForAll(address operator, bool approved) external onlyParent {
    _beforeSetApprovalForAll(operator, approved);
  }
}

// SPDX-License-Identifier: MIT

/*
 ________  _____  ________  ________  ______      ___   ____    ____
|_   __  ||_   _||_   __  ||_   __  ||_   _ `.  .'   `.|_   \  /   _|
  | |_ \_|  | |    | |_ \_|  | |_ \_|  | | `. \/  .-.  \ |   \/   |
  |  _|     | |    |  _| _   |  _|     | |  | || |   | | | |\  /| |
 _| |_     _| |_  _| |__/ | _| |_     _| |_.' /\  `-'  /_| |_\/_| |_
|_____|   |_____||________||_____|   |______.'  `.___.'|_____||_____|
      _       _______      ______  ____  ____  ________  _________  ____  ____  _______  ________
     / \     |_   __ \   .' ___  ||_   ||   _||_   __  ||  _   _  ||_  _||_  _||_   __ \|_   __  |
    / _ \      | |__) | / .'   \_|  | |__| |    | |_ \_||_/ | | \_|  \ \  / /    | |__) | | |_ \_|
   / ___ \     |  __ /  | |         |  __  |    |  _| _     | |       \ \/ /     |  ___/  |  _| _
 _/ /   \ \_  _| |  \ \_\ `.___.'\ _| |  | |_  _| |__/ |   _| |_      _|  |_    _| |_    _| |__/ |
|____| |____||____| |___|`.____ .'|____||____||________|  |_____|    |______|  |_____|  |________|

by steviep.eth (2022)


All Fiefdom Proxy contracts inherit the behavior of the Fiefdom Archetype.

Upon publication, a fiefdom contract will set a placeholder name and symbol, record the timestamp
of its founding at, and will mint token #0 to itself.

Ownership over the Fiefdom will follow the owner of the corresponding Vassal token, which is manage by
the Fiefdom Kingdom contract.

At any point, the Vassal owner may choose to activate the Fiefdom. This will set the contract's name,
symbol, license, max supply of tokens, tokenURI contract, and hooks contract. While name and symbol are fixed, maxSupply
and tokenURIContract can be updated later. maxSupply and tokenURI can also be frozen by the Vassal owner. The passed hooks
contract address allows for the Vassal owner to define extra behavior that runs before transfers and approvals.

The Vassal owner will be the default minter of the contract, but can also set the minter to another
address. In practice, the minter will be a separate minting contract. The minter can mint tokens using
any of three methods: mint, mintBatch, and mintBatchTo.

If set to 0x0, tokenURI logic will default to the default token URI contract set at the kingdom level. Otherwise,
the Fiefdom may freely change its token URI contract.

*/

import "./DefaultTokenURI.sol";
import "./BaseTokenURI.sol";
import "./ERC721Hooks.sol";
import "./Dependencies.sol";
import "./Fiefdoms.sol";

pragma solidity ^0.8.17;

interface ITokenURI {
  function tokenURI(uint256 tokenId) external view returns (string memory uri);
}

/// @title Fiefdom Archetype
/// @author steviep.eth, julien.eth
/// @notice ERC721 collection contract controlled by the vassal that holds its corresponding fiefdom token
contract FiefdomArchetype is ERC721Burnable {
  using Strings for uint256;

  /// @notice Main Fiefdoms contract address
  Fiefdoms public kingdom;

  /// @notice Called when tokens are minted, transferred, burned, and when approvals are set
  /// @dev To use, extend the ERC721HooksBase contract, override the required virtual functions, deploy with this
  ///      fiefdom contract's address set as its parent, and pass its address to activate()
  IERC721Hooks public erc721Hooks;

  /// @notice True after activate() has been called
  bool public isActivated;

  /// @notice True when token URI contract can no longer be changed
  bool public tokenURIFrozen;

  /// @notice True when max supply can no longer change
  bool public maxSupplyFrozen;

  /// @notice Address that is allowed to mint tokens
  address public minter;

  /// @notice ID of this fiefdom
  uint256 public fiefdomId;

  /// @notice License of project
  string public license;

  /// @notice Max supply of collection
  uint256 public maxSupply;

  /// @notice Timestamp when this contract was created
  uint256 public foundedAt;

  string private _name;
  string private _symbol;
  uint256 private _totalSupply;
  bool private _isInitialized;
  address private _royaltyBeneficiary;
  uint16 private _royaltyBasisPoints;
  address private _tokenURIContract;

  /// @notice Arbitrary event emitted by contract owner
  /// @param poster Address of initiator
  /// @param eventType Type of event
  /// @param content Content of event
  event ProjectEvent(address indexed poster, string indexed eventType, string content);

  /// @notice Arbitrary event related to a specific token emitted by contract owner or token holder
  /// @param poster Address of initiator
  /// @param tokenId ID of token
  /// @param eventType Type of event
  /// @param content Content of event
  event TokenEvent(address indexed poster, uint256 indexed tokenId, string indexed eventType, string content);

  /// @notice Emitted when a range of tokens has their metadata updated
  /// @param _fromTokenId The first ID of the token in the range
  /// @param _toTokenId The last ID of the token in the range
  /// @dev See EIP-4906: https://eips.ethereum.org/EIPS/eip-4906
  event BatchMetadataUpdate(uint256 _fromTokenId, uint256 _toTokenId);

  /// @notice Emitted when a token's metadata is updated
  /// @param _tokenId The ID of the updated token
  /// @dev See EIP-4906: https://eips.ethereum.org/EIPS/eip-4906
  event MetadataUpdate(uint256 _tokenId);

  /// @dev This is only called when the first archetype contract is initially published
  constructor() ERC721('', '') {
    initialize(msg.sender, 0);
  }

  /// @notice Initializes contract by minting token 0 to itself and setting a default name and symbol
  /// @param _kingdom Address of the main Fiefdoms contract
  /// @param _fiefdomId Token ID of this fiefdom
  /// @dev Called by the proxy contract immediately after a copy of this contract is published
  function initialize(address _kingdom, uint256 _fiefdomId) public {
    require(!_isInitialized, "Can't initialize more than once");
    _isInitialized = true;

    // Since constructor is not called (or called the first time with empty values)
    _name = string(abi.encodePacked('Fiefdom ', _fiefdomId.toString()));
    _symbol = string(abi.encodePacked('FIEF', _fiefdomId.toString()));
    kingdom = Fiefdoms(_kingdom);
    fiefdomId = _fiefdomId;
    foundedAt = block.timestamp;

    _totalSupply = 1;
    _mint(address(this), 0);
  }

  /// @notice Instantiates the collection beyond the 0th mint and sends the 0th token to the caller
  /// @param name_ Name to be set on collection
  /// @param symbol_ Symbol to be set on collection
  /// @param license_ License to be set on project
  /// @param maxSupply_ Max supply to be set on collection
  /// @param tokenURIContract_ Contract used to return metadata for each token (optional)
  /// @param erc721Hooks_ Contract called when tokens are minted, transferred, burned, and when approvals are set (optional)
  function activate(
    string memory name_,
    string memory symbol_,
    string memory license_,
    uint256 maxSupply_,
    address tokenURIContract_,
    address erc721Hooks_
  ) public onlyOwner {
    // Require that it can only be called once
    require(!isActivated, "Fiefdom has already been activated");

    // Set the name/symbol
    _name = name_;
    _symbol = symbol_;

    // Set the max token supply
    maxSupply = maxSupply_;

    // Set the defailt minter address + ERC2981 royalty beneficiary
    minter = msg.sender;
    _royaltyBeneficiary = msg.sender;
    _royaltyBasisPoints = 1000;

    // Set the tokenURI contract
    _tokenURIContract = tokenURIContract_;

    license = license_;
    isActivated = true;

    // Recover the 0th token
    _transfer(address(this), msg.sender, 0);
    emit MetadataUpdate(0);
    kingdom.activation(fiefdomId);

    // Set hooks if contract address provided
    if (address(erc721Hooks_) != address(0)) {
      erc721Hooks = IERC721Hooks(erc721Hooks_);
      require(erc721Hooks.parent() == address(this), "Passed ERC721Hooks contract is not configured for this Fiefdom");
    }
  }

  // HOOKS

  /// @notice Register calls to erc721Hooks on transfers (including mints and burns)
  /// @param from Address of sender (zero when being minted)
  /// @param to Address of receiver (zero when burning)
  /// @param tokenId ID of token being transferred (or minted or burned)
  function _beforeTokenTransfer(address from, address to, uint256 tokenId) internal virtual override {
    if (address(erc721Hooks) != address(0)) erc721Hooks.beforeTokenTransfer(from, to, tokenId);
  }

  /// @notice Register calls to erc721Hooks on token approvals
  /// @param to Address to be approved
  /// @param tokenId ID of token being approved of
  function approve(address to, uint256 tokenId) public virtual override {
    if (address(erc721Hooks) != address(0)) erc721Hooks.beforeApprove(to, tokenId);
    super.approve(to, tokenId);
  }

  /// @notice Register calls to erc721Hooks on operator approvals
  /// @param operator Address of operator
  /// @param approved True when operator is being approved, false when approval is being revoked
  function setApprovalForAll(address operator, bool approved) public virtual override {
    if (address(erc721Hooks) != address(0)) erc721Hooks.beforeSetApprovalForAll(operator, approved);
    super.setApprovalForAll(operator, approved);
  }


  // OWNERSHIP

  /// @notice Emitted when fiefdom token is transferred to a new owner
  /// @param previousOwner Previous owner of fiefdom token
  /// @param newOwner New owner of fiefdom token
  event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

  /// @notice Contract owner
  /// @dev The owner of this contract is the owner of the corresponding fiefdom token
  function owner() public view virtual returns (address) {
    return kingdom.ownerOf(fiefdomId);
  }

  modifier onlyOwner() {
    require(owner() == msg.sender, "Ownable: caller is not the owner");
    _;
  }

  /// @notice Notes a transfer in contract ownership
  /// @param previousOwner Previous owner of fiefdom token
  /// @param newOwner New owner of fiefdom token
  /// @dev Called by Fiefdoms whenever the corresponding fiefdom token is traded
  function transferOwnership(address previousOwner, address newOwner) external {
    require(msg.sender == address(kingdom), 'Ownership can only be transferred by the kingdom');
    emit OwnershipTransferred(previousOwner, newOwner);
  }

  // VARIABLES

  // BASE FUNCTIONALITY

  /// @notice Current total supply of collection
  /// @return Total supply
  function totalSupply() external view returns (uint256) {
    return _totalSupply;
  }

  /// @notice Checks if given token ID exists
  /// @param tokenId Token to run existence check on
  /// @return True if token exists
  function exists(uint256 tokenId) external view returns (bool) {
    return _exists(tokenId);
  }

  /// @notice Name of collection
  /// @return Name
  function name() public view virtual override(ERC721) returns (string memory) {
   return  _name;
  }

  /// @notice Symbol of collection
  /// @return Symbol
  function symbol() public view virtual override(ERC721) returns (string memory) {
    return _symbol;
  }

  // MINTING

  /// @notice Mints a new token
  /// @param to Address to receive new token
  /// @param tokenId ID of new token
  function mint(address to, uint256 tokenId) external {
    require(minter == msg.sender, 'Caller is not the minting address');
    require(_totalSupply < maxSupply, 'Cannot create more tokens');

    _mint(to, tokenId);
    _totalSupply += 1;
  }

  /// @notice Mints one new token to each provided address
  /// @param to Addresses to each receive one new token
  /// @param tokenIdStart ID of first new token
  function mintBatch(address[] calldata to, uint256 tokenIdStart) external {
    require(minter == msg.sender, 'Caller is not the minting address');

    uint256 amount = to.length;
    require(_totalSupply + amount <= maxSupply, 'Cannot create more tokens');

    for (uint256 i; i < amount; i++) {
      _mint(to[i], tokenIdStart + i);
      _totalSupply++;
    }
  }

  /// @notice Mints a batch of new tokens to a single address
  /// @param to Address to receive all new tokens
  /// @param amount Amount of tokens to mint
  /// @param tokenIdStart ID of first new token
  function mintBatchTo(address to, uint256 amount, uint256 tokenIdStart) external {
    require(minter == msg.sender, 'Caller is not the minting address');
    require(_totalSupply + amount <= maxSupply, 'Cannot create more tokens');

    for (uint256 i; i < amount; i++) {
      _mint(to, tokenIdStart + i);
      _totalSupply++;
    }
  }

  /// @notice Token URI
  /// @param tokenId Token ID to look up URI of
  /// @return Token URI
  function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
    return ITokenURI(tokenURIContract()).tokenURI(tokenId);
  }

  /// @notice Address of Token URI contract
  /// @return Address of custom Token URI contract if set, otherwise the Kingdom's default
  function tokenURIContract() public view returns (address) {
    return _tokenURIContract == address(0)
      ? kingdom.defaultTokenURIContract()
      : _tokenURIContract;
  }

  // Contract owner actions

  /// @notice Sets a custom Token URI contract
  /// @param tokenURIContract_ Address of Token URI contract to set
  function setTokenURIContract(address tokenURIContract_) external onlyOwner {
    require(!tokenURIFrozen, 'Token URI has been frozen');
    _tokenURIContract = tokenURIContract_;
    emit BatchMetadataUpdate(0, _totalSupply);
  }

  /// @notice Disallow changes to Token URI contract address
  function freezeTokenURI() external onlyOwner {
    require(isActivated, 'Fiefdom must be activated');
    tokenURIFrozen = true;
  }

  /// @notice Sets the max supply of the collection
  /// @param newMaxSupply Max supply to set
  function setMaxSupply(uint256 newMaxSupply) external onlyOwner {
    require(isActivated, 'Fiefdom must be activated');
    require(newMaxSupply >= _totalSupply, 'maxSupply must be >= than totalSupply');
    require(!maxSupplyFrozen, 'maxSupply has been frozen');
    maxSupply = newMaxSupply;
  }

  /// @notice Disallow changes to max supply
  function freezeMaxSupply() external onlyOwner {
    require(isActivated, 'Fiefdom must be activated');
    maxSupplyFrozen = true;
  }

  /// @notice Sets the license of the project
  /// @param newLicense License
  function setLicense(string calldata newLicense) external onlyOwner {
    license = newLicense;
  }

  /// @notice Sets minter address
  /// @param newMinter Minter address to set
  function setMinter(address newMinter) external onlyOwner {
    minter = newMinter;
  }

  /// @notice Sets royalty info for the collection
  /// @param royaltyBeneficiary Address to receive royalties
  /// @param royaltyBasisPoints Basis points of royalty commission
  /// @dev See EIP-2981: https://eips.ethereum.org/EIPS/eip-2981
  function setRoyaltyInfo(
    address royaltyBeneficiary,
    uint16 royaltyBasisPoints
  ) external onlyOwner {
    _royaltyBeneficiary = royaltyBeneficiary;
    _royaltyBasisPoints = royaltyBasisPoints;
  }

  /// @notice Called with the sale price to determine how much royalty is owed and to whom.
  /// @param (unused)
  /// @param _salePrice The sale price of the NFT asset specified by _tokenId
  /// @return receiver Address of who should be sent the royalty payment
  /// @return royaltyAmount The royalty payment amount for _salePrice
  /// @dev See EIP-2981: https://eips.ethereum.org/EIPS/eip-2981
  function royaltyInfo(uint256, uint256 _salePrice) external view returns (address, uint256) {
    return (_royaltyBeneficiary, _salePrice * _royaltyBasisPoints / 10000);
  }

  /// @notice Query if a contract implements an interface
  /// @param interfaceId The interface identifier, as specified in ERC-165
  /// @return `true` if the contract implements `interfaceId` and
  ///         `interfaceId` is not 0xffffffff, `false` otherwise
  /// @dev Interface identification is specified in ERC-165. This function
  ///      uses less than 30,000 gas. See: https://eips.ethereum.org/EIPS/eip-165
  ///      See EIP-2981: https://eips.ethereum.org/EIPS/eip-2981
  ///      See EIP-4906: https://eips.ethereum.org/EIPS/eip-4906
  function supportsInterface(bytes4 interfaceId) public view virtual override(ERC721) returns (bool) {
    // ERC2981 & ERC4906
    return interfaceId == bytes4(0x2a55205a) || interfaceId == bytes4(0x49064906) || super.supportsInterface(interfaceId);
  }

  // Events

  /// @notice Emit an arbitrary event related to a token
  /// @param tokenId ID of the token this event is related to
  /// @param eventType Type of event to emit
  /// @param content Text to be included in event
  /// @dev Can be called either by contract owner or token holder
  function emitTokenEvent(uint256 tokenId, string calldata eventType, string calldata content) external {
    require(
      owner() == msg.sender || ERC721.ownerOf(tokenId) == msg.sender,
      'Only project or token owner can emit token event'
    );
    emit TokenEvent(msg.sender, tokenId, eventType, content);
  }

  /// @notice Emit an arbitrary event related to the project
  /// @param eventType Type of event to emit
  /// @param content Text to be included in event
  /// @dev Can only be called either by contract owner
  function emitProjectEvent(string calldata eventType, string calldata content) external onlyOwner {
    emit ProjectEvent(msg.sender, eventType, content);
  }
}

// SPDX-License-Identifier: MIT

/*
 ________  _____  ________  ________  ______      ___   ____    ____
|_   __  ||_   _||_   __  ||_   __  ||_   _ `.  .'   `.|_   \  /   _|
  | |_ \_|  | |    | |_ \_|  | |_ \_|  | | `. \/  .-.  \ |   \/   |
  |  _|     | |    |  _| _   |  _|     | |  | || |   | | | |\  /| |
 _| |_     _| |_  _| |__/ | _| |_     _| |_.' /\  `-'  /_| |_\/_| |_
|_____|   |_____||________||_____|   |______.'  `.___.'|_____||_____|
 ___  ____   _____  ____  _____   ______  ______      ___   ____    ____
|_  ||_  _| |_   _||_   \|_   _|.' ___  ||_   _ `.  .'   `.|_   \  /   _|
  | |_/ /     | |    |   \ | | / .'   \_|  | | `. \/  .-.  \ |   \/   |
  |  __'.     | |    | |\ \| | | |   ____  | |  | || |   | | | |\  /| |
 _| |  \ \_  _| |_  _| |_\   |_\ `.___]  |_| |_.' /\  `-'  /_| |_\/_| |_
|____||____||_____||_____|\____|`._____.'|______.'  `.___.'|_____||_____|

by steviep.eth (2022)


The Fiefdoms Kingdom is an ERC721 collection of 721 Vassal tokens.

Each Vassal token gives the token holder ownership over a separate, unique ERC721
contract (a "Fiefdom").

Transferring a Vassal token will also transfer ownership over that Fiefdom.

Minting a Vassal token will create a proxy contract, which inherits all of its behavior
from the Fiefdom Archetype.

Vassal #0 controls the domain of the Fiefdom Archetype directly.

Fiefdoms may collect own royalties without restriction on all tokens within their domain,
but Vassal tokens are subject to the strict trading rules of the broader kingdom.

*/

import "./Dependencies.sol";
import "./BaseTokenURI.sol";
import "./DefaultTokenURI.sol";
import "./FiefdomProxy.sol";
import "./FiefdomArchetype.sol";

pragma solidity ^0.8.17;

/// @title Fiefdoms
/// @author steviep.eth, julien.eth
/// @notice ERC721 collection contract where ownership of a token grants the tooken holder ownership over a Fiefdom contract
contract Fiefdoms is ERC721, Ownable {
  /// @notice License of Fiefdoms parent project - Does not pertain to the license of any tokens minted by Fiefdom contracts
  string public license = 'CC0';

  /// @notice Address that is permissioned to mint new tokens
  address public minter;

  /// @notice Address of the default tokenURI contract used by fiefdoms for mint 0
  address public fiefdomArchetype;

  /// @notice Address of the default tokenURI contract used by fiefdoms for mint 0
  address public defaultTokenURIContract;

  /// @notice True when only operators on the allow list may be approved
  bool public useOperatorAllowList = true;

  /// @notice Max supply of collection
  uint256 public constant maxSupply = 721;

  /// @notice Mapping from vassal's token id to fiefdom address
  mapping(uint256 => address) public tokenIdToFiefdom;

  /// @notice Allow lise of all operators allowed t
  mapping(address => bool) public operatorAllowList;

  BaseTokenURI private _tokenURIContract;
  uint256 private _totalSupply = 1;
  address private _royaltyBeneficiary;
  uint16 private _royaltyBasisPoints = 1000;

  /// @notice Arbitrary event emitted by contract owner
  /// @param poster Address of initiator
  /// @param eventType Type of event
  /// @param content Content of event
  event ProjectEvent(address indexed poster, string indexed eventType, string content);

  /// @notice Arbitrary event related to a specific token emitted by contract owner or token holder
  /// @param poster Address of initiator
  /// @param tokenId ID of token
  /// @param eventType Type of event
  /// @param content Content of event
  event TokenEvent(address indexed poster, uint256 indexed tokenId, string indexed eventType, string content);

  /// @notice Emitted when a range of tokens has their metadata updated
  /// @param _fromTokenId The first ID of the token in the range
  /// @param _toTokenId The last ID of the token in the range
  /// @dev See EIP-4906: https://eips.ethereum.org/EIPS/eip-4906
  event BatchMetadataUpdate(uint256 _fromTokenId, uint256 _toTokenId);

  /// @notice Emitted when a token's metadata is updated
  /// @param _tokenId The ID of the updated token
  /// @dev See EIP-4906: https://eips.ethereum.org/EIPS/eip-4906
  event MetadataUpdate(uint256 _tokenId);

  /// @notice Emitted when a fiefdom is first activated
  /// @param fiefdom The ID of the fiefdom being activated
  event Activation(uint256 fiefdom);

  // SETUP

  /// @dev Sets base variables, mints token #0 to the deployer, and publishes the FiefdomArchetype contract
  constructor() ERC721('Fiefdoms', 'FIEF') {
    minter = msg.sender;
    _royaltyBeneficiary = msg.sender;
    _tokenURIContract = new BaseTokenURI();
    defaultTokenURIContract = address(new DefaultTokenURI());

    // Publish an archetype contract. All proxy contracts will derive its functionality from this
    fiefdomArchetype = address(new FiefdomArchetype());

    // Token 0 will use the archetype contract directly instead of a proxy
    _mint(msg.sender, 0);

    tokenIdToFiefdom[0] = fiefdomArchetype;
  }


  // BASE FUNCTIONALITY

  /// @notice Current total supply of collection
  /// @return Total supply
  function totalSupply() external view returns (uint256) {
    return _totalSupply;
  }

  /// @notice Checks if given token ID exists
  /// @param tokenId Token to run existence check on
  /// @return True if token exists
  function exists(uint256 tokenId) external view returns (bool) {
    return _exists(tokenId);
  }

  /// @notice Alias of Fiefdoms contract owner
  function overlord() external view returns (address) {
    return owner();
  }

  /// @dev Override's the default _transfer function to also transfer ownership over the corresponding fiefdom
  function _transfer(
    address from,
    address to,
    uint256 tokenId
  ) internal virtual override {
    // When this token is transferred, also transfer ownership over its fiefdom
    FiefdomArchetype(tokenIdToFiefdom[tokenId]).transferOwnership(from, to);
    return super._transfer(from, to, tokenId);
  }

  /// @notice Emits Activation and MetadataUpdate events upon fiefdom activation
  /// @param tokenId Token Id of fiefdom being activated
  /// @dev This can only be called by the fiefdom upon its activation
  function activation(uint256 tokenId) external {
    require(tokenIdToFiefdom[tokenId] == msg.sender);
    emit MetadataUpdate(tokenId);
    emit Activation(tokenId);
  }

  // MINTING

  /// @notice Mints a new token
  /// @param to Address to receive new token
  function mint(address to) external {
    require(minter == msg.sender, 'Caller is not the minting address');
    require(_totalSupply < maxSupply, 'Cannot create more fiefdoms');

    _mint(to, _totalSupply);

    // Publish a new proxy contract for this token
    FiefdomProxy proxy = new FiefdomProxy();
    tokenIdToFiefdom[_totalSupply] = address(proxy);

    _totalSupply += 1;
  }

  /// @notice Mints a batch of new tokens to a single address
  /// @param to Address to receive all new tokens
  /// @param amount Amount of tokens to mint
  function mintBatch(address to, uint256 amount) external {
    require(minter == msg.sender, 'Caller is not the minting address');
    require(_totalSupply + amount <= maxSupply, 'Cannot create more fiefdoms');

    for (uint256 i; i < amount; i++) {
      _mint(to, _totalSupply);
      FiefdomProxy proxy = new FiefdomProxy();
      tokenIdToFiefdom[_totalSupply] = address(proxy);
      _totalSupply++;
    }
  }

  /// @notice Reassigns the minter permission
  /// @param newMinter Address of new minter
  function setMinter(address newMinter) external onlyOwner {
    minter = newMinter;
  }

  // ROYALTIES
  // Fiefdoms may collect their own royalties without restriction, but must follow the rules of the broader kingdom

  /// @notice Override the standard approve function to revert if approving an un-ALed operator
  /// @param to Address of operator
  /// @param tokenId Id of token to approve
  function approve(address to, uint256 tokenId) public virtual override {
    if (useOperatorAllowList) require(operatorAllowList[to], 'Operator must be on Allow List');
    super.approve(to, tokenId);
  }

  /// @notice Override the standard setApprovalForAll function to revert if approving an un-ALed operator
  /// @param operator Address of operator
  /// @param approved Approval status of operator
  function setApprovalForAll(address operator, bool approved) public virtual override {
    if (useOperatorAllowList && approved) require(operatorAllowList[operator], 'Operator must be on Allow List');
    super.setApprovalForAll(operator, approved);
  }

  /// @notice Override the standard getApproved function to return false for un-ALed operators
  /// @param tokenId Id of token
  function getApproved(uint256 tokenId) public view virtual override returns (address) {
    address operator = super.getApproved(tokenId);
    if (useOperatorAllowList) {
      return operatorAllowList[operator] ? operator : address(0);
    } else {
      return operator;
    }
  }

  /// @notice Override the standard isApprovedForAll function to return false for un-ALed operators
  /// @param owner Address of owner
  /// @param operator Address of operator
  function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
    if (useOperatorAllowList && !operatorAllowList[operator]) {
      return false;
    } else {
      return super.isApprovedForAll(owner, operator);
    }
  }

  /// @notice Denotes whether an operator allow list should be used
  /// @param _useOperatorAllowList New useOperatorAllowList value
  function updateUseOperatorAllowList(bool _useOperatorAllowList) external onlyOwner {
    useOperatorAllowList = _useOperatorAllowList;
  }

  /// @notice Update the allow list status of a single operator
  /// @param operator Address of operator
  /// @param allowListStatus New allow list status
  function updateOperatorAllowList(address operator, bool allowListStatus) external onlyOwner {
    operatorAllowList[operator] = allowListStatus;
  }

  /// @notice Sets royalty info for the collection
  /// @param royaltyBeneficiary Address to receive royalties
  /// @param royaltyBasisPoints Basis points of royalty commission
  /// @dev See EIP-2981: https://eips.ethereum.org/EIPS/eip-2981
  function setRoyaltyInfo(
    address royaltyBeneficiary,
    uint16 royaltyBasisPoints
  ) external onlyOwner {
    _royaltyBeneficiary = royaltyBeneficiary;
    _royaltyBasisPoints = royaltyBasisPoints;
  }

  /// @notice Called with the sale price to determine how much royalty is owed and to whom.
  /// @param (unused)
  /// @param _salePrice The sale price of the NFT asset specified by _tokenId
  /// @return receiver Address of who should be sent the royalty payment
  /// @return royaltyAmount The royalty payment amount for _salePrice
  /// @dev See EIP-2981: https://eips.ethereum.org/EIPS/eip-2981
  function royaltyInfo(uint256, uint256 _salePrice) external view returns (address, uint256) {
    return (_royaltyBeneficiary, _salePrice * _royaltyBasisPoints / 10000);
  }

  /// @notice Query if a contract implements an interface
  /// @param interfaceId The interface identifier, as specified in ERC-165
  /// @return `true` if the contract implements `interfaceId` and
  ///         `interfaceId` is not 0xffffffff, `false` otherwise
  /// @dev Interface identification is specified in ERC-165. This function
  ///      uses less than 30,000 gas. See: https://eips.ethereum.org/EIPS/eip-165
  ///      See EIP-2981: https://eips.ethereum.org/EIPS/eip-2981
  ///      See EIP-4906: https://eips.ethereum.org/EIPS/eip-4906
  function supportsInterface(bytes4 interfaceId) public view virtual override(ERC721) returns (bool) {
    // ERC2981 & ERC4906
    return interfaceId == bytes4(0x2a55205a) || interfaceId == bytes4(0x49064906) || super.supportsInterface(interfaceId);
  }


  // TOKEN URI

  /// @notice Token URI
  /// @param tokenId Token ID to look up URI of
  /// @return Token URI
  function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
    return _tokenURIContract.tokenURI(tokenId);
  }

  /// @notice Set the Token URI contract for Vassal tokens
  /// @param _tokenURIAddress New address of Token URI contract
  function setTokenURIContract(address _tokenURIAddress) external onlyOwner {
    _tokenURIContract = BaseTokenURI(_tokenURIAddress);
    emit BatchMetadataUpdate(0, _totalSupply);
  }

  /// @notice Set the default Token URI contract for all Fiefdoms in the Kingdom
  /// @param newDefault Address of the new default Token URI contract
  function setDefaultTokenURIContract(address newDefault) external onlyOwner {
    defaultTokenURIContract = newDefault;
  }

  /// @notice Address of Token URI contract
  /// @return Address of the Token URI contract
  function tokenURIContract() external view returns (address) {
    return address(_tokenURIContract);
  }

  // EVENTS

  /// @notice Emit an arbitrary event related to a token
  /// @param tokenId ID of the token this event is related to
  /// @param eventType Type of event to emit
  /// @param content Text to be included in event
  /// @dev Can be called either by contract owner or token holder
  function emitTokenEvent(uint256 tokenId, string calldata eventType, string calldata content) external {
    require(
      owner() == msg.sender || ERC721.ownerOf(tokenId) == msg.sender,
      'Only project or token owner can emit token event'
    );
    emit TokenEvent(msg.sender, tokenId, eventType, content);
  }

  /// @notice Emit an arbitrary event related to the project
  /// @param eventType Type of event to emit
  /// @param content Text to be included in event
  /// @dev Can only be called either by contract owner
  function emitProjectEvent(string calldata eventType, string calldata content) external onlyOwner {
    emit ProjectEvent(msg.sender, eventType, content);
  }
}

• No Contract Security Audit Submitted- Submit Audit Here

[{"inputs":[],"stateMutability":"nonpayable","type":"constructor"},{"stateMutability":"payable","type":"fallback"},{"inputs":[],"name":"implementation","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"stateMutability":"payable","type":"receive"}]

0x6080604052600436106100225760003560e01c80635c60da1b1461003b57610031565b366100315761002f610066565b005b610039610066565b005b34801561004757600080fd5b50610050610080565b60405161005d91906102a0565b60405180910390f35b61006e61015c565b61007e61007961015e565b6101b5565b565b600061008a61015e565b905090565b606061009a846101db565b6100d9576040517f08c379a00000000000000000000000000000000000000000000000000000000081526004016100d09061033e565b60405180910390fd5b6000808573ffffffffffffffffffffffffffffffffffffffff168560405161010191906103cf565b600060405180830381855af49150503d806000811461013c576040519150601f19603f3d011682016040523d82523d6000602084013e610141565b606091505b50915091506101518282866101ee565b925050509392505050565b565b600061018c7f360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc60001b610255565b60000160009054906101000a900473ffffffffffffffffffffffffffffffffffffffff16905090565b3660008037600080366000845af43d6000803e80600081146101d6573d6000f35b3d6000fd5b600080823b905060008111915050919050565b606083156101fe5782905061024e565b6000835111156102115782518084602001fd5b816040517f08c379a0000000000000000000000000000000000000000000000000000000008152600401610245919061043b565b60405180910390fd5b9392505050565b6000819050919050565b600073ffffffffffffffffffffffffffffffffffffffff82169050919050565b600061028a8261025f565b9050919050565b61029a8161027f565b82525050565b60006020820190506102b56000830184610291565b92915050565b600082825260208201905092915050565b7f416464726573733a2064656c65676174652063616c6c20746f206e6f6e2d636f60008201527f6e74726163740000000000000000000000000000000000000000000000000000602082015250565b60006103286026836102bb565b9150610333826102cc565b604082019050919050565b600060208201905081810360008301526103578161031b565b9050919050565b600081519050919050565b600081905092915050565b60005b83811015610392578082015181840152602081019050610377565b60008484015250505050565b60006103a98261035e565b6103b38185610369565b93506103c3818560208601610374565b80840191505092915050565b60006103db828461039e565b915081905092915050565b600081519050919050565b6000601f19601f8301169050919050565b600061040d826103e6565b61041781856102bb565b9350610427818560208601610374565b610430816103f1565b840191505092915050565b600060208201905081810360008301526104558184610402565b90509291505056fea26469706673582212206a65ebc26c4a23594b24507af7aeb33e13284ae7d151a182d5854a7dc585396964736f6c63430008110033

115:1139:5:-:0;;;;;;;;;;;;;;;;;;;;;;;38859:11:2;:9;:11::i;:::-;115:1139:5;;38636:11:2;:9;:11::i;:::-;115:1139:5;584:91;;;;;;;;;;;;;:::i;:::-;;;;;;;:::i;:::-;;;;;;;;38283:110:2;38331:17;:15;:17::i;:::-;38358:28;38368:17;:15;:17::i;:::-;38358:9;:28::i;:::-;38283:110::o;584:91:5:-;631:7;653:17;:15;:17::i;:::-;646:24;;584:91;:::o;13298:387:2:-;13439:12;13471:18;13482:6;13471:10;:18::i;:::-;13463:69;;;;;;;;;;;;:::i;:::-;;;;;;;;;13544:12;13558:23;13585:6;:19;;13605:4;13585:25;;;;;;:::i;:::-;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;13543:67;;;;13627:51;13644:7;13653:10;13665:12;13627:16;:51::i;:::-;13620:58;;;;13298:387;;;;;:::o;39159:46::-;:::o;452:128:5:-;511:7;533:36;199:66;548:20;;533:14;:36::i;:::-;:42;;;;;;;;;;;;526:49;;452:128;:::o;36909:895:2:-;37247:14;37244:1;37241;37228:34;37461:1;37458;37442:14;37439:1;37423:14;37416:5;37403:60;37537:16;37534:1;37531;37516:38;37575:6;37647:1;37642:66;;;;37757:16;37754:1;37747:27;37642:66;37677:16;37674:1;37667:27;7462:377;7522:4;7725:12;7790:7;7778:20;7770:28;;7831:1;7824:4;:8;7817:15;;;7462:377;;;:::o;13905:692::-;14051:12;14079:7;14075:516;;;14109:10;14102:17;;;;14075:516;14240:1;14220:10;:17;:21;14216:365;;;14414:10;14408:17;14474:15;14461:10;14457:2;14453:19;14446:44;14216:365;14553:12;14546:20;;;;;;;;;;;:::i;:::-;;;;;;;;13905:692;;;;;;:::o;317:131:5:-;378:21;434:4;424:14;;317:131;;;:::o;7:126:7:-;44:7;84:42;77:5;73:54;62:65;;7:126;;;:::o;139:96::-;176:7;205:24;223:5;205:24;:::i;:::-;194:35;;139:96;;;:::o;241:118::-;328:24;346:5;328:24;:::i;:::-;323:3;316:37;241:118;;:::o;365:222::-;458:4;496:2;485:9;481:18;473:26;;509:71;577:1;566:9;562:17;553:6;509:71;:::i;:::-;365:222;;;;:::o;593:169::-;677:11;711:6;706:3;699:19;751:4;746:3;742:14;727:29;;593:169;;;;:::o;768:225::-;908:34;904:1;896:6;892:14;885:58;977:8;972:2;964:6;960:15;953:33;768:225;:::o;999:366::-;1141:3;1162:67;1226:2;1221:3;1162:67;:::i;:::-;1155:74;;1238:93;1327:3;1238:93;:::i;:::-;1356:2;1351:3;1347:12;1340:19;;999:366;;;:::o;1371:419::-;1537:4;1575:2;1564:9;1560:18;1552:26;;1624:9;1618:4;1614:20;1610:1;1599:9;1595:17;1588:47;1652:131;1778:4;1652:131;:::i;:::-;1644:139;;1371:419;;;:::o;1796:98::-;1847:6;1881:5;1875:12;1865:22;;1796:98;;;:::o;1900:147::-;2001:11;2038:3;2023:18;;1900:147;;;;:::o;2053:246::-;2134:1;2144:113;2158:6;2155:1;2152:13;2144:113;;;2243:1;2238:3;2234:11;2228:18;2224:1;2219:3;2215:11;2208:39;2180:2;2177:1;2173:10;2168:15;;2144:113;;;2291:1;2282:6;2277:3;2273:16;2266:27;2115:184;2053:246;;;:::o;2305:386::-;2409:3;2437:38;2469:5;2437:38;:::i;:::-;2491:88;2572:6;2567:3;2491:88;:::i;:::-;2484:95;;2588:65;2646:6;2641:3;2634:4;2627:5;2623:16;2588:65;:::i;:::-;2678:6;2673:3;2669:16;2662:23;;2413:278;2305:386;;;;:::o;2697:271::-;2827:3;2849:93;2938:3;2929:6;2849:93;:::i;:::-;2842:100;;2959:3;2952:10;;2697:271;;;;:::o;2974:99::-;3026:6;3060:5;3054:12;3044:22;;2974:99;;;:::o;3079:102::-;3120:6;3171:2;3167:7;3162:2;3155:5;3151:14;3147:28;3137:38;;3079:102;;;:::o;3187:377::-;3275:3;3303:39;3336:5;3303:39;:::i;:::-;3358:71;3422:6;3417:3;3358:71;:::i;:::-;3351:78;;3438:65;3496:6;3491:3;3484:4;3477:5;3473:16;3438:65;:::i;:::-;3528:29;3550:6;3528:29;:::i;:::-;3523:3;3519:39;3512:46;;3279:285;3187:377;;;;:::o;3570:313::-;3683:4;3721:2;3710:9;3706:18;3698:26;;3770:9;3764:4;3760:20;3756:1;3745:9;3741:17;3734:47;3798:78;3871:4;3862:6;3798:78;:::i;:::-;3790:86;;3570:313;;;;:::o

ipfs://6a65ebc26c4a23594b24507af7aeb33e13284ae7d151a182d5854a7dc5853969