Contract Name:
PaalXSwapContract
Contract Source Code:
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)
pragma solidity ^0.8.19;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
*
* Furthermore, `isContract` will also return true if the target contract within
* the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
* which only has an effect at the end of a transaction.
* ====
*
* [IMPORTANT]
* ====
* You shouldn't rely on `isContract` to protect against flash loan attacks!
*
* Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
* like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
* constructor.
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize/address.code.length, which returns 0
// for contracts in construction, since the code is only stored at the end
// of the constructor execution.
return account.code.length > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(
address(this).balance >= amount,
"Address: insufficient balance"
);
(bool success, ) = recipient.call{value: amount}("");
require(
success,
"Address: unable to send value, recipient may have reverted"
);
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data
) internal returns (bytes memory) {
return
functionCallWithValue(
target,
data,
0,
"Address: low-level call failed"
);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value
) internal returns (bytes memory) {
return
functionCallWithValue(
target,
data,
value,
"Address: low-level call with value failed"
);
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(
address(this).balance >= value,
"Address: insufficient balance for call"
);
(bool success, bytes memory returndata) = target.call{value: value}(
data
);
return
verifyCallResultFromTarget(
target,
success,
returndata,
errorMessage
);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data
) internal view returns (bytes memory) {
return
functionStaticCall(
target,
data,
"Address: low-level static call failed"
);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
(bool success, bytes memory returndata) = target.staticcall(data);
return
verifyCallResultFromTarget(
target,
success,
returndata,
errorMessage
);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data
) internal returns (bytes memory) {
return
functionDelegateCall(
target,
data,
"Address: low-level delegate call failed"
);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
(bool success, bytes memory returndata) = target.delegatecall(data);
return
verifyCallResultFromTarget(
target,
success,
returndata,
errorMessage
);
}
/**
* @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
* the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
*
* _Available since v4.8._
*/
function verifyCallResultFromTarget(
address target,
bool success,
bytes memory returndata,
string memory errorMessage
) internal view returns (bytes memory) {
if (success) {
if (returndata.length == 0) {
// only check isContract if the call was successful and the return data is empty
// otherwise we already know that it was a contract
require(isContract(target), "Address: call to non-contract");
}
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
/**
* @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
* revert reason or using the provided one.
*
* _Available since v4.3._
*/
function verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) internal pure returns (bytes memory) {
if (success) {
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
function _revert(
bytes memory returndata,
string memory errorMessage
) private pure {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
/// @solidity memory-safe-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)
pragma solidity ^0.8.0;
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
function _contextSuffixLength() internal view virtual returns (uint256) {
return 0;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
* https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
*
* Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
* presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
* need to send a transaction, and thus is not required to hold Ether at all.
*
* ==== Security Considerations
*
* There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
* expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
* considered as an intention to spend the allowance in any specific way. The second is that because permits have
* built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
* take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
* generally recommended is:
*
* ```solidity
* function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
* try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
* doThing(..., value);
* }
*
* function doThing(..., uint256 value) public {
* token.safeTransferFrom(msg.sender, address(this), value);
* ...
* }
* ```
*
* Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
* `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
* {SafeERC20-safeTransferFrom}).
*
* Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
* contracts should have entry points that don't rely on permit.
*/
interface IERC20Permit {
/**
* @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
* given ``owner``'s signed approval.
*
* IMPORTANT: The same issues {IERC20-approve} has related to transaction
* ordering also apply here.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `deadline` must be a timestamp in the future.
* - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
* over the EIP712-formatted function arguments.
* - the signature must use ``owner``'s current nonce (see {nonces}).
*
* For more information on the signature format, see the
* https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
* section].
*
* CAUTION: See Security Considerations above.
*/
function permit(
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external;
/**
* @dev Returns the current nonce for `owner`. This value must be
* included whenever a signature is generated for {permit}.
*
* Every successful call to {permit} increases ``owner``'s nonce by one. This
* prevents a signature from being used multiple times.
*/
function nonces(address owner) external view returns (uint256);
/**
* @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
*/
// solhint-disable-next-line func-name-mixedcase
function DOMAIN_SEPARATOR() external view returns (bytes32);
}
// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity >=0.6.2;
interface IUniswapV2Router01 {
function factory() external pure returns (address);
function WETH() external pure returns (address);
function addLiquidity(
address tokenA,
address tokenB,
uint amountADesired,
uint amountBDesired,
uint amountAMin,
uint amountBMin,
address to,
uint deadline
) external returns (uint amountA, uint amountB, uint liquidity);
function addLiquidityETH(
address token,
uint amountTokenDesired,
uint amountTokenMin,
uint amountETHMin,
address to,
uint deadline
) external payable returns (uint amountToken, uint amountETH, uint liquidity);
function removeLiquidity(
address tokenA,
address tokenB,
uint liquidity,
uint amountAMin,
uint amountBMin,
address to,
uint deadline
) external returns (uint amountA, uint amountB);
function removeLiquidityETH(
address token,
uint liquidity,
uint amountTokenMin,
uint amountETHMin,
address to,
uint deadline
) external returns (uint amountToken, uint amountETH);
function removeLiquidityWithPermit(
address tokenA,
address tokenB,
uint liquidity,
uint amountAMin,
uint amountBMin,
address to,
uint deadline,
bool approveMax, uint8 v, bytes32 r, bytes32 s
) external returns (uint amountA, uint amountB);
function removeLiquidityETHWithPermit(
address token,
uint liquidity,
uint amountTokenMin,
uint amountETHMin,
address to,
uint deadline,
bool approveMax, uint8 v, bytes32 r, bytes32 s
) external returns (uint amountToken, uint amountETH);
function swapExactTokensForTokens(
uint amountIn,
uint amountOutMin,
address[] calldata path,
address to,
uint deadline
) external returns (uint[] memory amounts);
function swapTokensForExactTokens(
uint amountOut,
uint amountInMax,
address[] calldata path,
address to,
uint deadline
) external returns (uint[] memory amounts);
function swapExactETHForTokens(uint amountOutMin, address[] calldata path, address to, uint deadline)
external
payable
returns (uint[] memory amounts);
function swapTokensForExactETH(uint amountOut, uint amountInMax, address[] calldata path, address to, uint deadline)
external
returns (uint[] memory amounts);
function swapExactTokensForETH(uint amountIn, uint amountOutMin, address[] calldata path, address to, uint deadline)
external
returns (uint[] memory amounts);
function swapETHForExactTokens(uint amountOut, address[] calldata path, address to, uint deadline)
external
payable
returns (uint[] memory amounts);
function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}
// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity >=0.6.2;
import './IUniswapV2Router01.sol';
interface IUniswapV2Router02 is IUniswapV2Router01 {
function removeLiquidityETHSupportingFeeOnTransferTokens(
address token,
uint liquidity,
uint amountTokenMin,
uint amountETHMin,
address to,
uint deadline
) external returns (uint amountETH);
function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
address token,
uint liquidity,
uint amountTokenMin,
uint amountETHMin,
address to,
uint deadline,
bool approveMax, uint8 v, bytes32 r, bytes32 s
) external returns (uint amountETH);
function swapExactTokensForTokensSupportingFeeOnTransferTokens(
uint amountIn,
uint amountOutMin,
address[] calldata path,
address to,
uint deadline
) external;
function swapExactETHForTokensSupportingFeeOnTransferTokens(
uint amountOutMin,
address[] calldata path,
address to,
uint deadline
) external payable;
function swapExactTokensForETHSupportingFeeOnTransferTokens(
uint amountIn,
uint amountOutMin,
address[] calldata path,
address to,
uint deadline
) external;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)
pragma solidity ^0.8.0;
import "./Context.sol";
/**
* @dev Contract module which provides a basic access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership}.
*
* This module is used through inheritance. It will make available the modifier
* `onlyOwner`, which can be applied to your functions to restrict their use to
* the owner.
*/
abstract contract Ownable is Context {
address private _owner;
event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
/**
* @dev Initializes the contract setting the deployer as the initial owner.
*/
constructor() {
_transferOwnership(_msgSender());
}
/**
* @dev Throws if called by any account other than the owner.
*/
modifier onlyOwner() {
_checkOwner();
_;
}
/**
* @dev Returns the address of the current owner.
*/
function owner() public view virtual returns (address) {
return _owner;
}
/**
* @dev Throws if the sender is not the owner.
*/
function _checkOwner() internal view virtual {
require(owner() == _msgSender(), "Ownable: caller is not the owner");
}
/**
* @dev Leaves the contract without owner. It will not be possible to call
* `onlyOwner` functions. Can only be called by the current owner.
*
* NOTE: Renouncing ownership will leave the contract without an owner,
* thereby disabling any functionality that is only available to the owner.
*/
function renounceOwnership() public virtual onlyOwner {
_transferOwnership(address(0));
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual onlyOwner {
require(newOwner != address(0), "Ownable: new owner is the zero address");
_transferOwnership(newOwner);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Internal function without access restriction.
*/
function _transferOwnership(address newOwner) internal virtual {
address oldOwner = _owner;
_owner = newOwner;
emit OwnershipTransferred(oldOwner, newOwner);
}
}
// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity 0.8.19;
import "./IERC20.sol";
import "./SafeERC20.sol";
import "./Ownable.sol";
import "./Context.sol";
import "./ReentrancyGuard.sol";
import "./IUniswapV2Router02.sol";
/// @title PaalX Swap Smart Contract
/// @author Juan Snaider Cruickshank / Github: jscrui / Linkedin: juan-snaider-cruickshank
/// @notice This contract is a new layer for the Uniswap v2 Router, it allows users to swap tokens, Ether and tokens for Ether.
/// @dev All ownable functions are implemented with the onlyOwner modifier and it should be used with Multisignature wallet.
contract PaalXSwapContract is Context, Ownable, ReentrancyGuard {
using SafeERC20 for IERC20;
IUniswapV2Router02 public router;
address constant NATIVE_TOKEN = 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE;
uint256 public swappingFee;
uint256 public swappingFeeDivisior;
uint256 public referralFee;
bool public isStopped;
bool public isReferralStopped;
mapping(address referrer => mapping(address tokenAddress => uint256 feeAmount))
public referrals; // mapping(referrer => mapping(tokenAddress => feeAmount))
mapping(address referrer => mapping(address sender => bool isReferredBy))
public referredBy; // mapping(referrer => mapping(msg.sender => true))
mapping(address token => uint256 totalReferralFee)
public totalReferralFeePerToken;
event Buy(
address indexed sender,
uint256 amountIn,
address indexed tokenAddr,
uint256 amountOut
);
event Sell(
address indexed sender,
uint256 amountIn,
address indexed tokenAddr,
uint256 amountOut
);
event SellTokensForTokens(
address indexed sender,
address indexed tokenIn,
uint256 amountIn,
address indexed tokenOut,
uint256 amountOut
);
event ClaimedReferralFee(
address indexed sender,
uint256 amountClaimed,
address token
);
event PausedReferrals(bool);
/**
* @param _router the address of the Uniswap v2 Router or compatible.
*/
constructor(IUniswapV2Router02 _router) {
router = _router;
swappingFee = 1000;
swappingFeeDivisior = 100000;
referralFee = 10000; // 10%
}
/**
* @notice Returns the amount after fee is deducted.
* @param _amount the amount to be deducted.
* @return newAmount the amount after the fee is deducted.
*/
function getAmountAfterFee(
uint256 _amount
) internal view returns (uint256) {
return
(_amount * (swappingFeeDivisior - swappingFee)) /
swappingFeeDivisior;
}
/**
* @notice Swaps Ether for tokens.
* @dev the caller must send Ether along with the transaction.
* @param _tokenOut the address of the token to be received.
* @param _amountOutMin the minimum amount of tokens to receive; the transaction will revert if not met.
* @param _deadline the deadline for the swap to be executed.
* @param _referrer address who referred msg.sender.
* @return amountOut the amount of tokens received.
*/
function swapExactETHForTokens(
address _tokenOut,
uint256 _amountOutMin,
uint256 _deadline,
address _referrer
) external payable nonReentrant returns (uint256 amountOut) {
require(!isStopped, "PAALXSWAP: Contract is not active");
require(_tokenOut != address(0), "PAALXSWAP: Invalid _tokenOut");
require(msg.value > 0, "PAALXSWAP: Not enough Ether");
IERC20 token = IERC20(_tokenOut);
// Calculate the amount to be swapped after the fee is deducted
uint256 amountAfterFee = getAmountAfterFee(msg.value);
// Set up the path for the swap
address[] memory path = new address[](2);
path[0] = router.WETH();
path[1] = _tokenOut;
// Record sender's initial tokenOut balance
uint256 beforeBalance = token.balanceOf(msg.sender);
// Perform token swap
router.swapExactETHForTokensSupportingFeeOnTransferTokens{
value: amountAfterFee
}(_amountOutMin, path, msg.sender, block.timestamp + _deadline);
// Record sender's final tokenOut balance
uint256 afterBalance = token.balanceOf(msg.sender);
// Calculate the amount of tokenOut received
amountOut = afterBalance - beforeBalance;
_updateReferrerReward(
_referrer,
msg.value - amountAfterFee,
NATIVE_TOKEN
);
emit Buy(msg.sender, msg.value, _tokenOut, amountOut);
}
/**
* @notice Swaps tokens for Ether.
* @dev the caller must have approved this contract to spend the token on their behalf.
* @param _tokenIn the address of the token to be swapped.
* @param _amountIn the amount of tokens to be swapped.
* @param _amountOutMin the minimum amount of Ether to receive; the transaction will revert if not met.
* @param _deadline the deadline for the swap to be executed.
* @param _referrer address who referred msg.sender.
* @return amountOut the amount of Ether received.
*/
function swapExactTokensForETH(
address _tokenIn,
uint256 _amountIn,
uint256 _amountOutMin,
uint256 _deadline,
address _referrer
) external nonReentrant returns (uint256 amountOut) {
require(!isStopped, "PAALXSWAP: Contract is not active");
require(_tokenIn != address(0), "PAALXSWAP: Invalid _tokenIn");
require(_amountIn > 0, "PAALXSWAP: Invalid amountIn");
IERC20 token = IERC20(_tokenIn);
// Record contract's initial balance
uint256 initialBalance = token.balanceOf(address(this));
// Transfer tokens from the sender to this contract
token.safeTransferFrom(msg.sender, address(this), _amountIn);
// Record the actual tokens received after any fee-on-transfer
uint256 actualReceived = token.balanceOf(address(this)) -
initialBalance;
// Calculate the amount to be swapped after the fee is deducted
uint256 actualReceivedAfterFee = getAmountAfterFee(actualReceived);
// Approve the router to spend the tokens for the swap
token.safeApprove(address(router), actualReceivedAfterFee);
// Set up the path for the swap
address[] memory path = new address[](2);
path[0] = _tokenIn;
path[1] = router.WETH();
// Record sender's initial Ether balance
uint256 beforeBalance = msg.sender.balance;
// Perform the token swap
router.swapExactTokensForETHSupportingFeeOnTransferTokens(
actualReceivedAfterFee,
_amountOutMin,
path,
msg.sender,
block.timestamp + _deadline
);
// Record sender's final Ether balance
uint256 afterBalance = msg.sender.balance;
// Calculate the amount of Ether received by the sender
amountOut = afterBalance - beforeBalance;
_updateReferrerReward(
_referrer,
actualReceived - actualReceivedAfterFee,
_tokenIn
);
emit Sell(msg.sender, _amountIn, _tokenIn, amountOut);
}
/**
* @notice Swaps tokens for tokens.
* @dev the caller must have approved this contract to spend the token on their behalf.
* @param _tokenIn the address of the token to be swapped.
* @param _tokenOut the address of the token to be received.
* @param _amountIn the amount of tokens to be swapped.
* @param _amountOutMin the minimum amount of tokenOut to be received; the transaction will revert if not met.
* @param _deadline the deadline for the swap to be executed.
* @param _hasPair check if the addresses has a pair if not we use weth as a intermediary
* @return amountOut the amount of tokens received.
* @param _referrer address who referred msg.sender.
*/
function swapExactTokensForTokens(
address _tokenIn,
address _tokenOut,
uint256 _amountIn,
uint256 _amountOutMin,
uint256 _deadline,
bool _hasPair,
address _referrer
) external nonReentrant returns (uint256 amountOut) {
require(!isStopped, "PAALXSWAP: Contract is not active");
require(
_tokenIn != address(0) && _tokenOut != address(0),
"PAALXSWAP: Invalid tokenIn/tokenOut address"
);
require(_amountIn > 0, "PAALXSWAP: Invalid amountIn");
IERC20 tokenInContract = IERC20(_tokenIn);
IERC20 tokenOutContract = IERC20(_tokenOut);
// Record contract's initial balance of _tokenIn
uint256 initialBalanceTokenIn = tokenInContract.balanceOf(
address(this)
);
// Transfer the _amountIn tokens from the sender to this contract
tokenInContract.safeTransferFrom(msg.sender, address(this), _amountIn);
// Calculate the actual tokens received after any fee-on-transfer
uint256 actualReceived = tokenInContract.balanceOf(address(this)) -
initialBalanceTokenIn;
// Calculate the amount to be swapped after the fee is deducted
uint256 actualReceivedAfterFee = getAmountAfterFee(actualReceived);
// Record sender's initial balance of tokenOut
uint256 initialBalanceTokenOut = tokenOutContract.balanceOf(msg.sender);
// Set up the path for the swap based on the hasPair flag
address[] memory path;
if (_hasPair) {
path = new address[](2);
path[0] = _tokenIn;
path[1] = _tokenOut;
} else {
path = new address[](3);
path[0] = _tokenIn;
path[1] = router.WETH(); // Use WETH as an intermediary
path[2] = _tokenOut;
}
// Approve the router to spend the tokens for the swap
tokenInContract.safeApprove(address(router), actualReceivedAfterFee);
// Perform the token swap
router.swapExactTokensForTokensSupportingFeeOnTransferTokens(
actualReceivedAfterFee,
_amountOutMin,
path,
msg.sender,
block.timestamp + _deadline
);
// Record sender's final tokenOut balance
uint256 afterBalance = tokenOutContract.balanceOf(msg.sender);
// Calculate the amount of tokenOut received by the sender
amountOut = afterBalance - initialBalanceTokenOut;
_updateReferrerReward(
_referrer,
actualReceived - actualReceivedAfterFee,
_tokenIn
);
emit SellTokensForTokens(
msg.sender,
_tokenIn,
_amountIn,
_tokenOut,
amountOut
);
}
/**
* @notice Set the router used for the swaps.
* @param _newRouter the address of the new Uniswap v2 Router or compatible.
*/
function setRouter(IUniswapV2Router02 _newRouter) external onlyOwner {
require(
address(_newRouter) != address(0),
"PAALXSWAP: Invalid address"
);
router = _newRouter;
}
/**
* @notice Withdraws all the Ether held by the contract.
* @dev Only callable by the owner.
*/
function withdrawEther() external onlyOwner {
uint256 withdrawableETH = address(this).balance -
totalReferralFeePerToken[NATIVE_TOKEN];
require(withdrawableETH > 0, "No Eth in Contract");
payable(owner()).transfer(withdrawableETH);
}
/**
* @notice Withdraws all the tokens held by the contract.
* @dev Only callable by the owner.
* @param _tokenAddress the address of the token to be withdrawn
*/
function withdrawERC20(
address _tokenAddress
) external onlyOwner returns (bool result) {
IERC20 token = IERC20(_tokenAddress);
uint256 withdrawableTokenAmount = token.balanceOf(address(this)) -
totalReferralFeePerToken[_tokenAddress];
result = token.transfer(msg.sender, withdrawableTokenAmount);
}
/**
* @notice Updates the referral fee.
* @param _referrer address who referred msg.sender.
* @param _swappingFeeAmount amount of fee generated by transaction.
* @param _token address of tokenIn for transaction.
*/
function _updateReferrerReward(
address _referrer,
uint256 _swappingFeeAmount,
address _token
) internal {
if (
_referrer != address(0) &&
!isReferralStopped &&
_referrer != msg.sender
) {
uint256 referrersFee = (_swappingFeeAmount * referralFee) /
swappingFeeDivisior;
if (referredBy[_referrer][msg.sender]) {
referrals[_referrer][_token] += referrersFee;
} else {
referredBy[_referrer][msg.sender] = true;
referrals[_referrer][_token] += referrersFee;
}
totalReferralFeePerToken[_token] += referrersFee;
}
}
/**
* @notice transfers referral fee of a token to msg.sender
* @param _token address to claim
*/
function claimReferralFee(address _token) external nonReentrant {
uint256 amountToClaim = referrals[msg.sender][_token];
require(amountToClaim > 0, "No Fee to Claim");
referrals[msg.sender][_token] = 0;
totalReferralFeePerToken[_token] -= amountToClaim;
if (_token == NATIVE_TOKEN) payable(msg.sender).transfer(amountToClaim);
else IERC20(_token).safeTransfer(msg.sender, amountToClaim);
emit ClaimedReferralFee(msg.sender, amountToClaim, _token);
}
/**
* @notice Set the swapping fee.
* @dev The swapping fee is a percentage of the amount to be swapped and should be less than 5%. Only callable by the owner.
* @param _swappingFee the new swapping fee in percentage
* @param _swappingFeeDivisior the new swapping fee divisior
*
* Example:
* 1% = 1000 / 100000
* 0.1% = 100 / 100000
* 0.01% = 10 / 100000
*/
function setSwappingFee(
uint256 _swappingFee,
uint256 _swappingFeeDivisior
) external onlyOwner {
require(_swappingFeeDivisior != 0, "PAALXSWAP: Divisor cannot be zero");
require(
(_swappingFee * 100) / _swappingFeeDivisior < 5,
"PAALXSWAP: Fee must be < 5%"
);
swappingFee = _swappingFee;
swappingFeeDivisior = _swappingFeeDivisior;
}
/**
* @notice Update referralFeePercent.
* @param _referralFee new referral fee percentage.
* @dev only contract Owner can call this function.
*/
function updateReferralFee(uint256 _referralFee) external onlyOwner {
referralFee = _referralFee;
}
/**
* @notice This function is used to stop the contract in case of emergency.
* @param _isStopped the new state of the contract
* @dev Only callable by the owner.
*/
function emergencyStop(bool _isStopped) external onlyOwner {
isStopped = _isStopped;
}
/**
* @notice This function is used to stop the contract in case of emergency and withdraw all the funds.
* @param _isStopped the new state of the contract
* @dev Only callable by the owner.
*/
function emergencyStopAndWithdraw(bool _isStopped) external onlyOwner {
isStopped = _isStopped;
payable(owner()).transfer(address(this).balance);
}
/**
* @notice Checks referrers claimable fee balance for a token.
* @param _referrer address to check.
* @param _token address to check.
* @return claimableReferralFee the amount _referrer can claim.
*/
function checkReferralReward(
address _referrer,
address _token
) public view returns (uint256 claimableReferralFee) {
claimableReferralFee = referrals[_referrer][_token];
}
/**
* @notice pause referrals
* @dev only contract Owner can call this function.
*/
function pauseRefferals() external onlyOwner {
require(isReferralStopped == false, "Already Paused");
isReferralStopped = true;
emit PausedReferrals(true);
}
/**
* @notice resume referrals
* @dev only contract Owner can call this function.
*/
function resumeRefferals() external onlyOwner {
require(isReferralStopped == true, "Already Active");
isReferralStopped = false;
emit PausedReferrals(false);
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)
pragma solidity ^0.8.0;
/**
* @dev Contract module that helps prevent reentrant calls to a function.
*
* Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
* available, which can be applied to functions to make sure there are no nested
* (reentrant) calls to them.
*
* Note that because there is a single `nonReentrant` guard, functions marked as
* `nonReentrant` may not call one another. This can be worked around by making
* those functions `private`, and then adding `external` `nonReentrant` entry
* points to them.
*
* TIP: If you would like to learn more about reentrancy and alternative ways
* to protect against it, check out our blog post
* https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
*/
abstract contract ReentrancyGuard {
// Booleans are more expensive than uint256 or any type that takes up a full
// word because each write operation emits an extra SLOAD to first read the
// slot's contents, replace the bits taken up by the boolean, and then write
// back. This is the compiler's defense against contract upgrades and
// pointer aliasing, and it cannot be disabled.
// The values being non-zero value makes deployment a bit more expensive,
// but in exchange the refund on every call to nonReentrant will be lower in
// amount. Since refunds are capped to a percentage of the total
// transaction's gas, it is best to keep them low in cases like this one, to
// increase the likelihood of the full refund coming into effect.
uint256 private constant _NOT_ENTERED = 1;
uint256 private constant _ENTERED = 2;
uint256 private _status;
constructor() {
_status = _NOT_ENTERED;
}
/**
* @dev Prevents a contract from calling itself, directly or indirectly.
* Calling a `nonReentrant` function from another `nonReentrant`
* function is not supported. It is possible to prevent this from happening
* by making the `nonReentrant` function external, and making it call a
* `private` function that does the actual work.
*/
modifier nonReentrant() {
_nonReentrantBefore();
_;
_nonReentrantAfter();
}
function _nonReentrantBefore() private {
// On the first call to nonReentrant, _status will be _NOT_ENTERED
require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
// Any calls to nonReentrant after this point will fail
_status = _ENTERED;
}
function _nonReentrantAfter() private {
// By storing the original value once again, a refund is triggered (see
// https://eips.ethereum.org/EIPS/eip-2200)
_status = _NOT_ENTERED;
}
/**
* @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
* `nonReentrant` function in the call stack.
*/
function _reentrancyGuardEntered() internal view returns (bool) {
return _status == _ENTERED;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "./IERC20.sol";
import "./IERC20Permit.sol";
import "./Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
/**
* @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeTransfer(IERC20 token, address to, uint256 value) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
}
/**
* @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
* calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
*/
function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
}
/**
* @dev Deprecated. This function has issues similar to the ones found in
* {IERC20-approve}, and its usage is discouraged.
*
* Whenever possible, use {safeIncreaseAllowance} and
* {safeDecreaseAllowance} instead.
*/
function safeApprove(IERC20 token, address spender, uint256 value) internal {
// safeApprove should only be called when setting an initial allowance,
// or when resetting it to zero. To increase and decrease it, use
// 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
require(
(value == 0) || (token.allowance(address(this), spender) == 0),
"SafeERC20: approve from non-zero to non-zero allowance"
);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
}
/**
* @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
uint256 oldAllowance = token.allowance(address(this), spender);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
}
/**
* @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
unchecked {
uint256 oldAllowance = token.allowance(address(this), spender);
require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
}
}
/**
* @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
* to be set to zero before setting it to a non-zero value, such as USDT.
*/
function forceApprove(IERC20 token, address spender, uint256 value) internal {
bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);
if (!_callOptionalReturnBool(token, approvalCall)) {
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
_callOptionalReturn(token, approvalCall);
}
}
/**
* @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
* Revert on invalid signature.
*/
function safePermit(
IERC20Permit token,
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) internal {
uint256 nonceBefore = token.nonces(owner);
token.permit(owner, spender, value, deadline, v, r, s);
uint256 nonceAfter = token.nonces(owner);
require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*
* This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
*/
function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
// and not revert is the subcall reverts.
(bool success, bytes memory returndata) = address(token).call(data);
return
success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
}
}