Contract Name:
PixelClouds
Contract Source Code:
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
* @dev Contract module which provides a basic access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership}.
*
* This module is used through inheritance. It will make available the modifier
* `onlyOwner`, which can be applied to your functions to restrict their use to
* the owner.
*/
abstract contract Ownable is Context {
address private _owner;
event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
/**
* @dev Initializes the contract setting the deployer as the initial owner.
*/
constructor () {
address msgSender = _msgSender();
_owner = msgSender;
emit OwnershipTransferred(address(0), msgSender);
}
/**
* @dev Returns the address of the current owner.
*/
function owner() public view virtual returns (address) {
return _owner;
}
/**
* @dev Throws if called by any account other than the owner.
*/
modifier onlyOwner() {
require(owner() == _msgSender(), "Ownable: caller is not the owner");
_;
}
/**
* @dev Leaves the contract without owner. It will not be possible to call
* `onlyOwner` functions anymore. Can only be called by the current owner.
*
* NOTE: Renouncing ownership will leave the contract without an owner,
* thereby removing any functionality that is only available to the owner.
*/
function renounceOwnership() public virtual onlyOwner {
emit OwnershipTransferred(_owner, address(0));
_owner = address(0);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual onlyOwner {
require(newOwner != address(0), "Ownable: new owner is the zero address");
emit OwnershipTransferred(_owner, newOwner);
_owner = newOwner;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "../../utils/introspection/IERC165.sol";
/**
* @dev Required interface of an ERC721 compliant contract.
*/
interface IERC721 is IERC165 {
/**
* @dev Emitted when `tokenId` token is transferred from `from` to `to`.
*/
event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);
/**
* @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
*/
event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);
/**
* @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
*/
event ApprovalForAll(address indexed owner, address indexed operator, bool approved);
/**
* @dev Returns the number of tokens in ``owner``'s account.
*/
function balanceOf(address owner) external view returns (uint256 balance);
/**
* @dev Returns the owner of the `tokenId` token.
*
* Requirements:
*
* - `tokenId` must exist.
*/
function ownerOf(uint256 tokenId) external view returns (address owner);
/**
* @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
* are aware of the ERC721 protocol to prevent tokens from being forever locked.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `tokenId` token must exist and be owned by `from`.
* - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
* - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
*
* Emits a {Transfer} event.
*/
function safeTransferFrom(address from, address to, uint256 tokenId) external;
/**
* @dev Transfers `tokenId` token from `from` to `to`.
*
* WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `tokenId` token must be owned by `from`.
* - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
*
* Emits a {Transfer} event.
*/
function transferFrom(address from, address to, uint256 tokenId) external;
/**
* @dev Gives permission to `to` to transfer `tokenId` token to another account.
* The approval is cleared when the token is transferred.
*
* Only a single account can be approved at a time, so approving the zero address clears previous approvals.
*
* Requirements:
*
* - The caller must own the token or be an approved operator.
* - `tokenId` must exist.
*
* Emits an {Approval} event.
*/
function approve(address to, uint256 tokenId) external;
/**
* @dev Returns the account approved for `tokenId` token.
*
* Requirements:
*
* - `tokenId` must exist.
*/
function getApproved(uint256 tokenId) external view returns (address operator);
/**
* @dev Approve or remove `operator` as an operator for the caller.
* Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
*
* Requirements:
*
* - The `operator` cannot be the caller.
*
* Emits an {ApprovalForAll} event.
*/
function setApprovalForAll(address operator, bool _approved) external;
/**
* @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
*
* See {setApprovalForAll}
*/
function isApprovedForAll(address owner, address operator) external view returns (bool);
/**
* @dev Safely transfers `tokenId` token from `from` to `to`.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `tokenId` token must exist and be owned by `from`.
* - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
* - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
*
* Emits a {Transfer} event.
*/
function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @title ERC721 token receiver interface
* @dev Interface for any contract that wants to support safeTransfers
* from ERC721 asset contracts.
*/
interface IERC721Receiver {
/**
* @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
* by `operator` from `from`, this function is called.
*
* It must return its Solidity selector to confirm the token transfer.
* If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
*
* The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
*/
function onERC721Received(address operator, address from, uint256 tokenId, bytes calldata data) external returns (bytes4);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "../IERC721.sol";
/**
* @title ERC-721 Non-Fungible Token Standard, optional enumeration extension
* @dev See https://eips.ethereum.org/EIPS/eip-721
*/
interface IERC721Enumerable is IERC721 {
/**
* @dev Returns the total amount of tokens stored by the contract.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns a token ID owned by `owner` at a given `index` of its token list.
* Use along with {balanceOf} to enumerate all of ``owner``'s tokens.
*/
function tokenOfOwnerByIndex(address owner, uint256 index) external view returns (uint256 tokenId);
/**
* @dev Returns a token ID at a given `index` of all the tokens stored by the contract.
* Use along with {totalSupply} to enumerate all tokens.
*/
function tokenByIndex(uint256 index) external view returns (uint256);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "../IERC721.sol";
/**
* @title ERC-721 Non-Fungible Token Standard, optional metadata extension
* @dev See https://eips.ethereum.org/EIPS/eip-721
*/
interface IERC721Metadata is IERC721 {
/**
* @dev Returns the token collection name.
*/
function name() external view returns (string memory);
/**
* @dev Returns the token collection symbol.
*/
function symbol() external view returns (string memory);
/**
* @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
*/
function tokenURI(uint256 tokenId) external view returns (string memory);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize, which returns 0 for contracts in
// construction, since the code is only stored at the end of the
// constructor execution.
uint256 size;
// solhint-disable-next-line no-inline-assembly
assembly { size := extcodesize(account) }
return size > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(address(this).balance >= amount, "Address: insufficient balance");
// solhint-disable-next-line avoid-low-level-calls, avoid-call-value
(bool success, ) = recipient.call{ value: amount }("");
require(success, "Address: unable to send value, recipient may have reverted");
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain`call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCall(target, data, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
require(address(this).balance >= value, "Address: insufficient balance for call");
require(isContract(target), "Address: call to non-contract");
// solhint-disable-next-line avoid-low-level-calls
(bool success, bytes memory returndata) = target.call{ value: value }(data);
return _verifyCallResult(success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
return functionStaticCall(target, data, "Address: low-level static call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
require(isContract(target), "Address: static call to non-contract");
// solhint-disable-next-line avoid-low-level-calls
(bool success, bytes memory returndata) = target.staticcall(data);
return _verifyCallResult(success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
return functionDelegateCall(target, data, "Address: low-level delegate call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
require(isContract(target), "Address: delegate call to non-contract");
// solhint-disable-next-line avoid-low-level-calls
(bool success, bytes memory returndata) = target.delegatecall(data);
return _verifyCallResult(success, returndata, errorMessage);
}
function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
if (success) {
return returndata;
} else {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
// solhint-disable-next-line no-inline-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/*
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
return msg.data;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev String operations.
*/
library Strings {
bytes16 private constant alphabet = "0123456789abcdef";
/**
* @dev Converts a `uint256` to its ASCII `string` decimal representation.
*/
function toString(uint256 value) internal pure returns (string memory) {
// Inspired by OraclizeAPI's implementation - MIT licence
// https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol
if (value == 0) {
return "0";
}
uint256 temp = value;
uint256 digits;
while (temp != 0) {
digits++;
temp /= 10;
}
bytes memory buffer = new bytes(digits);
while (value != 0) {
digits -= 1;
buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
value /= 10;
}
return string(buffer);
}
/**
* @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
*/
function toHexString(uint256 value) internal pure returns (string memory) {
if (value == 0) {
return "0x00";
}
uint256 temp = value;
uint256 length = 0;
while (temp != 0) {
length++;
temp >>= 8;
}
return toHexString(value, length);
}
/**
* @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
*/
function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
bytes memory buffer = new bytes(2 * length + 2);
buffer[0] = "0";
buffer[1] = "x";
for (uint256 i = 2 * length + 1; i > 1; --i) {
buffer[i] = alphabet[value & 0xf];
value >>= 4;
}
require(value == 0, "Strings: hex length insufficient");
return string(buffer);
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
*
* These functions can be used to verify that a message was signed by the holder
* of the private keys of a given address.
*/
library ECDSA {
/**
* @dev Returns the address that signed a hashed message (`hash`) with
* `signature`. This address can then be used for verification purposes.
*
* The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
* this function rejects them by requiring the `s` value to be in the lower
* half order, and the `v` value to be either 27 or 28.
*
* IMPORTANT: `hash` _must_ be the result of a hash operation for the
* verification to be secure: it is possible to craft signatures that
* recover to arbitrary addresses for non-hashed data. A safe way to ensure
* this is by receiving a hash of the original message (which may otherwise
* be too long), and then calling {toEthSignedMessageHash} on it.
*/
function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
// Divide the signature in r, s and v variables
bytes32 r;
bytes32 s;
uint8 v;
// Check the signature length
// - case 65: r,s,v signature (standard)
// - case 64: r,vs signature (cf https://eips.ethereum.org/EIPS/eip-2098) _Available since v4.1._
if (signature.length == 65) {
// ecrecover takes the signature parameters, and the only way to get them
// currently is to use assembly.
// solhint-disable-next-line no-inline-assembly
assembly {
r := mload(add(signature, 0x20))
s := mload(add(signature, 0x40))
v := byte(0, mload(add(signature, 0x60)))
}
} else if (signature.length == 64) {
// ecrecover takes the signature parameters, and the only way to get them
// currently is to use assembly.
// solhint-disable-next-line no-inline-assembly
assembly {
let vs := mload(add(signature, 0x40))
r := mload(add(signature, 0x20))
s := and(vs, 0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff)
v := add(shr(255, vs), 27)
}
} else {
revert("ECDSA: invalid signature length");
}
return recover(hash, v, r, s);
}
/**
* @dev Overload of {ECDSA-recover} that receives the `v`,
* `r` and `s` signature fields separately.
*/
function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
// EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
// unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
// the valid range for s in (281): 0 < s < secp256k1n ÷ 2 + 1, and for v in (282): v ∈ {27, 28}. Most
// signatures from current libraries generate a unique signature with an s-value in the lower half order.
//
// If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
// with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
// vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
// these malleable signatures as well.
require(uint256(s) <= 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0, "ECDSA: invalid signature 's' value");
require(v == 27 || v == 28, "ECDSA: invalid signature 'v' value");
// If the signature is valid (and not malleable), return the signer address
address signer = ecrecover(hash, v, r, s);
require(signer != address(0), "ECDSA: invalid signature");
return signer;
}
/**
* @dev Returns an Ethereum Signed Message, created from a `hash`. This
* produces hash corresponding to the one signed with the
* https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
* JSON-RPC method as part of EIP-191.
*
* See {recover}.
*/
function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32) {
// 32 is the length in bytes of hash,
// enforced by the type signature above
return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n32", hash));
}
/**
* @dev Returns an Ethereum Signed Typed Data, created from a
* `domainSeparator` and a `structHash`. This produces hash corresponding
* to the one signed with the
* https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
* JSON-RPC method as part of EIP-712.
*
* See {recover}.
*/
function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32) {
return keccak256(abi.encodePacked("\x19\x01", domainSeparator, structHash));
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "./IERC165.sol";
/**
* @dev Implementation of the {IERC165} interface.
*
* Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
* for the additional interface id that will be supported. For example:
*
* ```solidity
* function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
* return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
* }
* ```
*
* Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
*/
abstract contract ERC165 is IERC165 {
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
return interfaceId == type(IERC165).interfaceId;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC165 standard, as defined in the
* https://eips.ethereum.org/EIPS/eip-165[EIP].
*
* Implementers can declare support of contract interfaces, which can then be
* queried by others ({ERC165Checker}).
*
* For an implementation, see {ERC165}.
*/
interface IERC165 {
/**
* @dev Returns true if this contract implements the interface defined by
* `interfaceId`. See the corresponding
* https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
* to learn more about how these ids are created.
*
* This function call must use less than 30 000 gas.
*/
function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.
/**
* @dev Wrappers over Solidity's arithmetic operations.
*
* NOTE: `SafeMath` is no longer needed starting with Solidity 0.8. The compiler
* now has built in overflow checking.
*/
library SafeMath {
/**
* @dev Returns the addition of two unsigned integers, with an overflow flag.
*
* _Available since v3.4._
*/
function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
unchecked {
uint256 c = a + b;
if (c < a) return (false, 0);
return (true, c);
}
}
/**
* @dev Returns the substraction of two unsigned integers, with an overflow flag.
*
* _Available since v3.4._
*/
function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
unchecked {
if (b > a) return (false, 0);
return (true, a - b);
}
}
/**
* @dev Returns the multiplication of two unsigned integers, with an overflow flag.
*
* _Available since v3.4._
*/
function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
unchecked {
// Gas optimization: this is cheaper than requiring 'a' not being zero, but the
// benefit is lost if 'b' is also tested.
// See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
if (a == 0) return (true, 0);
uint256 c = a * b;
if (c / a != b) return (false, 0);
return (true, c);
}
}
/**
* @dev Returns the division of two unsigned integers, with a division by zero flag.
*
* _Available since v3.4._
*/
function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
unchecked {
if (b == 0) return (false, 0);
return (true, a / b);
}
}
/**
* @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
*
* _Available since v3.4._
*/
function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
unchecked {
if (b == 0) return (false, 0);
return (true, a % b);
}
}
/**
* @dev Returns the addition of two unsigned integers, reverting on
* overflow.
*
* Counterpart to Solidity's `+` operator.
*
* Requirements:
*
* - Addition cannot overflow.
*/
function add(uint256 a, uint256 b) internal pure returns (uint256) {
return a + b;
}
/**
* @dev Returns the subtraction of two unsigned integers, reverting on
* overflow (when the result is negative).
*
* Counterpart to Solidity's `-` operator.
*
* Requirements:
*
* - Subtraction cannot overflow.
*/
function sub(uint256 a, uint256 b) internal pure returns (uint256) {
return a - b;
}
/**
* @dev Returns the multiplication of two unsigned integers, reverting on
* overflow.
*
* Counterpart to Solidity's `*` operator.
*
* Requirements:
*
* - Multiplication cannot overflow.
*/
function mul(uint256 a, uint256 b) internal pure returns (uint256) {
return a * b;
}
/**
* @dev Returns the integer division of two unsigned integers, reverting on
* division by zero. The result is rounded towards zero.
*
* Counterpart to Solidity's `/` operator.
*
* Requirements:
*
* - The divisor cannot be zero.
*/
function div(uint256 a, uint256 b) internal pure returns (uint256) {
return a / b;
}
/**
* @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
* reverting when dividing by zero.
*
* Counterpart to Solidity's `%` operator. This function uses a `revert`
* opcode (which leaves remaining gas untouched) while Solidity uses an
* invalid opcode to revert (consuming all remaining gas).
*
* Requirements:
*
* - The divisor cannot be zero.
*/
function mod(uint256 a, uint256 b) internal pure returns (uint256) {
return a % b;
}
/**
* @dev Returns the subtraction of two unsigned integers, reverting with custom message on
* overflow (when the result is negative).
*
* CAUTION: This function is deprecated because it requires allocating memory for the error
* message unnecessarily. For custom revert reasons use {trySub}.
*
* Counterpart to Solidity's `-` operator.
*
* Requirements:
*
* - Subtraction cannot overflow.
*/
function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
unchecked {
require(b <= a, errorMessage);
return a - b;
}
}
/**
* @dev Returns the integer division of two unsigned integers, reverting with custom message on
* division by zero. The result is rounded towards zero.
*
* Counterpart to Solidity's `%` operator. This function uses a `revert`
* opcode (which leaves remaining gas untouched) while Solidity uses an
* invalid opcode to revert (consuming all remaining gas).
*
* Counterpart to Solidity's `/` operator. Note: this function uses a
* `revert` opcode (which leaves remaining gas untouched) while Solidity
* uses an invalid opcode to revert (consuming all remaining gas).
*
* Requirements:
*
* - The divisor cannot be zero.
*/
function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
unchecked {
require(b > 0, errorMessage);
return a / b;
}
}
/**
* @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
* reverting with custom message when dividing by zero.
*
* CAUTION: This function is deprecated because it requires allocating memory for the error
* message unnecessarily. For custom revert reasons use {tryMod}.
*
* Counterpart to Solidity's `%` operator. This function uses a `revert`
* opcode (which leaves remaining gas untouched) while Solidity uses an
* invalid opcode to revert (consuming all remaining gas).
*
* Requirements:
*
* - The divisor cannot be zero.
*/
function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
unchecked {
require(b > 0, errorMessage);
return a % b;
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
//-----------------------------------------------------------------------------
// geneticchain.io - NextGen Generative NFT Platform
//-----------------------------------------------------------------------------
/*\_____________________________________________________________ .¿yy¿. __
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM```````/MMM\\\\\ \\$$$$$$S/ .
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM`` `/ yyyy ` _____J$$$^^^^/%#//
MMMMMMMMMMMMMMMMMMMYYYMMM```` `\/ .¿yü / $ùpüüü%%% | ``|//|` __
MMMMMYYYYMMMMMMM/` `| ___.¿yüy¿. .d$$$$ / $$$$SSSSM | | || MMNNNNNNM
M/`` ``\/` .¿ù%%/. |.d$$$$$$$b.$$$*°^ / o$$$ __ | | || MMMMMMMMM
M .¿yy¿. .dX$$$$$$7.|$$$$"^"$$$$$$o` /MM o$$$ MM | | || MMYYYYYYM
\\$$$$$$S/ .S$$o"^"4$$$$$$$` _ `SSSSS\ ____ MM |___|_|| MM ____
J$$$^^^^/%#//oSSS` YSSSSSS / pyyyüüü%%%XXXÙ$$$$ MM pyyyyyyy, `` ,$$$o
.$$$` ___ pyyyyyyyyyyyy//+ / $$$$$$SSSSSSSÙM$$$. `` .S&&T$T$$$byyd$$$$\
\$$7 `` //o$$SSXMMSSSS | / $$/&&X _ ___ %$$$byyd$$$X\$`/S$$$$$$$S\
o$$l .\\YS$$X>$X _ ___| | / $$/%$$b.,.d$$$\`7$$$$$$$$7`.$ `"***"` __
o$$l __ 7$$$X>$$b.,.d$$$\ | / $$.`7$$$$$$$$%` `*+SX+*|_\\$ /. ..\MM
o$$L MM !$$$$\$$$$$$$$$%|__| / $$// `*+XX*\'` `____ ` `/MMMMMMM
/$$X, `` ,S$$$$\ `*+XX*\'`____ / %SXX . ., NERV ___.¿yüy¿. /MMMMM
7$$$byyd$$$>$X\ .,,_ $$$$ ` ___ .y%%ü¿. _______ $.d$$$$$$$S. `MMMM
`/S$$$$$$$\\$J`.\\$$$ : $\`.¿yüy¿. `\\ $$$$$$S.//XXSSo $$$$$"^"$$$$. /MMM
y `"**"`"Xo$7J$$$$$\ $.d$$$$$$$b. ^``/$$$$.`$$$$o $$$$\ _ 'SSSo /MMM
M/.__ .,\Y$$$\\$$O` _/ $d$$$*°\ pyyyüüü%%%W $$$o.$$$$/ S$$$. ` S$To MMM
MMMM` \$P*$$X+ b$$l MM $$$$` _ $$$$$$SSSSM $$$X.$T&&X o$$$. ` S$To MMM
MMMX` $<.\X\` -X$$l MM $$$$ / $$/&&X X$$$/$/X$$dyS$$>. ` S$X%/ `MM
MMMM/ `"` . -$$$l MM yyyy / $$/%$$b.__.d$$$$/$.'7$$$$$$$. ` %SXXX. MM
MMMMM// ./M .<$$S, `` ,S$$> / $$.`7$$$$$$$$$$$/S//_'*+%%XX\ `._ /MM
MMMMMMMMMMMMM\ /$$$$byyd$$$$\ / $$// `*+XX+*XXXX ,. .\MMMMMMMMMMM
GENETIC/MMMMM\. /$$$$$$$$$$\| / %SXX ,_ . .\MMMMMMMMMMMMMMMMMMMMMMMM
CHAIN/MMMMMMMM/__ `*+YY+*`_\| /_______//MMMMMMMMMMMMMMMMMMMMMMMMMMM/-/-/-\*/
//-----------------------------------------------------------------------------
// Genetic Chain: GeneticChain721
//-----------------------------------------------------------------------------
// Author: papaver (@tronicdreams)
//-----------------------------------------------------------------------------
import "openzeppelin-solidity/contracts/access/Ownable.sol";
import "openzeppelin-solidity/contracts/utils/cryptography/ECDSA.sol";
import "openzeppelin-solidity/contracts/utils/Strings.sol";
import "./common/meta-transactions/ContentMixin.sol";
import "./common/meta-transactions/NativeMetaTransaction.sol";
import "./geneticchain/ERC721Sequential.sol";
import "./geneticchain/ERC721SeqEnumerable.sol";
import "./libraries/State.sol";
//------------------------------------------------------------------------------
// helper contracts
//------------------------------------------------------------------------------
contract OwnableDelegateProxy {}
//------------------------------------------------------------------------------
contract ProxyRegistry {
mapping(address => OwnableDelegateProxy) public proxies;
}
//------------------------------------------------------------------------------
// GeneticChain721
//------------------------------------------------------------------------------
/**
* @title GeneticChain721
*
* ERC721 contract with various features:
* - low-gas implmentation
* - off-chain whitelist verify (secure minting)
* - dynamic token allocation
* - artist allocation
* - gallery allocation
* - low-gas generative token hash
* - protected controlled burns
* - opensea proxy setup
* - simple funds withdrawl
*/
abstract contract GeneticChain721 is
ContextMixin,
ERC721SeqEnumerable,
NativeMetaTransaction,
Ownable
{
using ECDSA for bytes32;
using State for State.Data;
//-------------------------------------------------------------------------
// constants
//-------------------------------------------------------------------------
// erc721 metadata
string constant private __name = "Pixel Clouds";
string constant private __symbol = "GCP10";
// mint price
uint256 constant public memberPrice = .03 ether;
uint256 constant public publicPrice = .05 ether;
// verification address
address constant private _signer = 0x29a64385e02e7018F6Ec71e3Bf032790Fe42bF27;
// token limits
uint256 public immutable publicMax;
uint256 public immutable artistMax;
uint256 public immutable galleryMax;
// opensea proxy
address private immutable _proxyRegistryAddress;
//-------------------------------------------------------------------------
// fields
//-------------------------------------------------------------------------
// contract state
State.Data private _state;
// roles
address private _burnerAddress;
address[2] private _artistAddresses = [
0x324110e8A2f9D0D93ba9cba21688540b39cb79cb,
0x11102104A66De741479D9b73521A1e2a75d16E4e];
// track mint count per address
mapping (address => uint256) private _mints;
//-------------------------------------------------------------------------
// modifiers
//-------------------------------------------------------------------------
modifier validTokenId(uint256 tokenId) {
require(_exists(tokenId), "invalid token");
_;
}
//-------------------------------------------------------------------------
modifier approvedOrOwner(address operator, uint256 tokenId) {
require(_isApprovedOrOwner(operator, tokenId));
_;
}
//-------------------------------------------------------------------------
modifier isArtist() {
require(_msgSender() == _artistAddresses[0]
|| _msgSender() == _artistAddresses[1], "caller not artist");
_;
}
//-------------------------------------------------------------------------
modifier isBurner() {
require(_msgSender() == _burnerAddress, "caller not burner");
_;
}
//-------------------------------------------------------------------------
modifier notLocked() {
require(_state._locked == 0, "contract is locked");
_;
}
//-------------------------------------------------------------------------
// ctor
//-------------------------------------------------------------------------
constructor(
uint256[3] memory tokenMax_,
address proxyRegistryAddress)
ERC721Sequential(__name, __symbol)
{
publicMax = tokenMax_[0];
artistMax = tokenMax_[1];
galleryMax = tokenMax_[2];
_proxyRegistryAddress = proxyRegistryAddress;
_initializeEIP712(__name);
// start tokens at 1 index
_owners.push();
}
//-------------------------------------------------------------------------
// accessors
//-------------------------------------------------------------------------
/**
* Set artist address.
*/
function setArtistAddress(address artistAddress, uint256 index)
public onlyOwner
{
require(index < _artistAddresses.length, "invalid index");
_artistAddresses[index] = artistAddress;
}
//-------------------------------------------------------------------------
/**
* Set burner address.
*/
function setBurnerAddress(address burner)
public onlyOwner
{
_burnerAddress = burner;
}
//-------------------------------------------------------------------------
/**
* Enable public minting.
*/
function enablePublicMint()
public onlyOwner
{
_state.setLive(1);
}
//-------------------------------------------------------------------------
/**
* Check if public minting is live.
*/
function publicLive()
public view returns (bool)
{
return _state._live == 1;
}
//-------------------------------------------------------------------------
/**
* Lock contract. Disable public/member minting.
*/
function lockContract()
public onlyOwner
{
_state.setLocked(1);
}
//-------------------------------------------------------------------------
/**
* Check if contract is locked.
*/
function isLocked()
public view returns (bool)
{
return _state._locked == 1;
}
//-------------------------------------------------------------------------
/**
* Get total gallery has minted.
*/
function gallryMinted()
public view returns (uint256)
{
return _state._gallery;
}
//-------------------------------------------------------------------------
/**
* Get total artist has minted.
*/
function artistMinted()
public view returns (uint256)
{
return _state._artist;
}
//-------------------------------------------------------------------------
/**
* Get total public has minted.
*/
function publicMinted()
public view returns (uint256)
{
return _state._public;
}
//-------------------------------------------------------------------------
// security
//-------------------------------------------------------------------------
/**
* Validate hash contains input data.
*/
function validateHash(
bytes32 msgHash,
address sender,
uint256 allocation,
uint256 count)
private pure returns(bool)
{
return ECDSA.toEthSignedMessageHash(
keccak256(abi.encodePacked(sender, allocation, count))) == msgHash;
}
//-------------------------------------------------------------------------
/**
* Validate message was signed by signer.
*/
function validateSigner(bytes32 msgHash, bytes memory signature)
private pure returns(bool)
{
return msgHash.recover(signature) == _signer;
}
//-------------------------------------------------------------------------
// minting
//-------------------------------------------------------------------------
/**
* Allow anyone to mint tokens for the right price.
*/
function mint(uint256 count)
payable public notLocked
{
require(_state._live == 1, "public mint not live");
require(publicPrice * count == msg.value, "insufficient funds");
require(_state._public + count <= publicMax, "exceed public supply");
_state.addPublic(count);
for (uint256 i = 0; i < count; ++i) {
_safeMint(msg.sender);
}
}
//-------------------------------------------------------------------------
/**
* Mint count tokens using securely signed message.
*/
function secureMint(
bytes32 msgHash,
bytes calldata signature,
uint256 allocation,
uint256 count)
payable external notLocked
{
require(memberPrice * count == msg.value, "insufficient funds");
require(_state._public + count <= publicMax, "exceed public supply");
require(_mints[msg.sender] + count <= allocation, "exceed allocation");
require(validateSigner(msgHash, signature), "invalid signer");
require(validateHash(msgHash, msg.sender, allocation, count), "invalid hash");
_state.addPublic(count);
unchecked {
_mints[msg.sender] += count;
}
for (uint256 i = 0; i < count; ++i) {
_safeMint(msg.sender);
}
}
//-------------------------------------------------------------------------
/**
* @dev Mints a token to an address.
* @param _to address of the future owner of the token
*/
function galleryMintTo(address _to, uint256 count)
public onlyOwner
{
require(_state._gallery + count <= galleryMax, "exceed gallery supply");
_state.addGallery(count);
for (uint256 i = 0; i < count; ++i) {
_safeMint(_to);
}
}
//-------------------------------------------------------------------------
/**
* @dev Mints a token to an address.
* @param _to address of the future owner of the token
*/
function artistMintTo(address _to, uint256 count)
public isArtist
{
require(_state._artist + count <= artistMax, "exceed artist supply");
_state.addArtist(count);
for (uint256 i = 0; i < count; ++i) {
_safeMint(_to);
}
}
//-------------------------------------------------------------------------
/**
* @dev Burns `tokenId`. See {ERC721-_burn}.
*/
function burn(uint256 tokenId)
public isBurner
{
_burn(tokenId);
}
//-------------------------------------------------------------------------
// money
//-------------------------------------------------------------------------
/**
* Pull money out of this contract.
*/
function withdraw(address to, uint256 amount)
public onlyOwner
{
require(amount > 0, "amount empty");
require(amount <= address(this).balance, "amount exceeds balance");
require(to != address(0), "address null");
payable(to).transfer(amount);
}
//-------------------------------------------------------------------------
// approval
//-------------------------------------------------------------------------
/**
* Override isApprovedForAll to whitelist user's OpenSea proxy accounts
* to enable gas-less listings.
*/
function isApprovedForAll(address owner, address operator)
override public view returns (bool)
{
// whitelist OpenSea proxy contract for easy trading
ProxyRegistry proxyRegistry = ProxyRegistry(_proxyRegistryAddress);
if (address(proxyRegistry.proxies(owner)) == operator) {
return true;
}
return super.isApprovedForAll(owner, operator);
}
//-------------------------------------------------------------------------
/**
* This is used instead of msg.sender as transactions won't be sent by
* the original token owner, but by OpenSea.
*/
function _msgSender()
override internal view returns (address sender)
{
return ContextMixin.msgSender();
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
//-----------------------------------------------------------------------------
// geneticchain.io - NextGen Generative NFT Platform
//-----------------------------------------------------------------------------
/*\_____________________________________________________________ .¿yy¿. __
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM```````/MMM\\\\\ \\$$$$$$S/ .
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM`` `/ yyyy ` _____J$$$^^^^/%#//
MMMMMMMMMMMMMMMMMMMYYYMMM```` `\/ .¿yü / $ùpüüü%%% | ``|//|` __
MMMMMYYYYMMMMMMM/` `| ___.¿yüy¿. .d$$$$ / $$$$SSSSM | | || MMNNNNNNM
M/`` ``\/` .¿ù%%/. |.d$$$$$$$b.$$$*°^ / o$$$ __ | | || MMMMMMMMM
M .¿yy¿. .dX$$$$$$7.|$$$$"^"$$$$$$o` /MM o$$$ MM | | || MMYYYYYYM
\\$$$$$$S/ .S$$o"^"4$$$$$$$` _ `SSSSS\ ____ MM |___|_|| MM ____
J$$$^^^^/%#//oSSS` YSSSSSS / pyyyüüü%%%XXXÙ$$$$ MM pyyyyyyy, `` ,$$$o
.$$$` ___ pyyyyyyyyyyyy//+ / $$$$$$SSSSSSSÙM$$$. `` .S&&T$T$$$byyd$$$$\
\$$7 `` //o$$SSXMMSSSS | / $$/&&X _ ___ %$$$byyd$$$X\$`/S$$$$$$$S\
o$$l .\\YS$$X>$X _ ___| | / $$/%$$b.,.d$$$\`7$$$$$$$$7`.$ `"***"` __
o$$l __ 7$$$X>$$b.,.d$$$\ | / $$.`7$$$$$$$$%` `*+SX+*|_\\$ /. ..\MM
o$$L MM !$$$$\$$$$$$$$$%|__| / $$// `*+XX*\'` `____ ` `/MMMMMMM
/$$X, `` ,S$$$$\ `*+XX*\'`____ / %SXX . ., NERV ___.¿yüy¿. /MMMMM
7$$$byyd$$$>$X\ .,,_ $$$$ ` ___ .y%%ü¿. _______ $.d$$$$$$$S. `MMMM
`/S$$$$$$$\\$J`.\\$$$ : $\`.¿yüy¿. `\\ $$$$$$S.//XXSSo $$$$$"^"$$$$. /MMM
y `"**"`"Xo$7J$$$$$\ $.d$$$$$$$b. ^``/$$$$.`$$$$o $$$$\ _ 'SSSo /MMM
M/.__ .,\Y$$$\\$$O` _/ $d$$$*°\ pyyyüüü%%%W $$$o.$$$$/ S$$$. ` S$To MMM
MMMM` \$P*$$X+ b$$l MM $$$$` _ $$$$$$SSSSM $$$X.$T&&X o$$$. ` S$To MMM
MMMX` $<.\X\` -X$$l MM $$$$ / $$/&&X X$$$/$/X$$dyS$$>. ` S$X%/ `MM
MMMM/ `"` . -$$$l MM yyyy / $$/%$$b.__.d$$$$/$.'7$$$$$$$. ` %SXXX. MM
MMMMM// ./M .<$$S, `` ,S$$> / $$.`7$$$$$$$$$$$/S//_'*+%%XX\ `._ /MM
MMMMMMMMMMMMM\ /$$$$byyd$$$$\ / $$// `*+XX+*XXXX ,. .\MMMMMMMMMMM
GENETIC/MMMMM\. /$$$$$$$$$$\| / %SXX ,_ . .\MMMMMMMMMMMMMMMMMMMMMMMM
CHAIN/MMMMMMMM/__ `*+YY+*`_\| /_______//MMMMMMMMMMMMMMMMMMMMMMMMMMM/-/-/-\*/
//-----------------------------------------------------------------------------
// Genetic Chain: PixelClouds
//-----------------------------------------------------------------------------
// Author: papaver (@tronicdreams)
//-----------------------------------------------------------------------------
import "./GeneticChain721.sol";
//------------------------------------------------------------------------------
// GeneticChainMetadata
//------------------------------------------------------------------------------
/**
* @title PixelClouds
* GeneticChain - Project #10 - Pixel Clouds
*/
contract PixelClouds is GeneticChain721
{
//-------------------------------------------------------------------------
// structs
//-------------------------------------------------------------------------
struct IpfsAsset {
string name;
string hash;
}
//-------------------------------------------------------------------------
struct ArtState {
int64 rainMeter;
bool rain;
bool _set;
}
//-------------------------------------------------------------------------
// events
//-------------------------------------------------------------------------
event StateChange(address indexed owner, uint256 tokenId, ArtState state);
//-------------------------------------------------------------------------
// constants
//-------------------------------------------------------------------------
// metadata
uint256 constant public projectId = 10;
string constant public artist = "Cano";
string constant public description = "Pixel Clouds aim to create a new form of culture based on a shared aesthetic utilizing decentralized ownership of clouds with the option to control rain.";
// token data
uint256 private immutable _seed;
//-------------------------------------------------------------------------
// fields
//-------------------------------------------------------------------------
string public code;
string private _baseUri;
IpfsAsset[] public libraries;
// token state
mapping(uint256 => ArtState) _state;
//-------------------------------------------------------------------------
// ctor
//-------------------------------------------------------------------------
constructor(
IpfsAsset memory lib,
string memory baseUri_,
uint256[3] memory tokenMax_,
uint256 seed,
address proxyRegistryAddress)
GeneticChain721(
tokenMax_,
proxyRegistryAddress)
{
_baseUri = baseUri_;
_seed = seed;
addLibrary(lib.name, lib.hash);
}
//-------------------------------------------------------------------------
// accessors
//-------------------------------------------------------------------------
function setCode(string memory code_)
public
onlyOwner
notLocked
{
code = code_;
}
//-------------------------------------------------------------------------
function addLibrary(string memory name, string memory hash)
public
onlyOwner
notLocked
{
IpfsAsset memory lib = IpfsAsset(name, hash);
libraries.push(lib);
}
//-------------------------------------------------------------------------
function removeLibrary(uint256 index)
public
onlyOwner
notLocked
{
require(index < libraries.length);
libraries[index] = libraries[libraries.length-1];
libraries.pop();
}
//-------------------------------------------------------------------------
function getLibraryCount()
public
view
returns (uint256)
{
return libraries.length;
}
//-------------------------------------------------------------------------
function getLibraries()
public
view
returns (IpfsAsset[] memory)
{
IpfsAsset[] memory libs = new IpfsAsset[](libraries.length);
for (uint256 i = 0; i < libraries.length; ++i) {
IpfsAsset storage lib = libraries[i];
libs[i] = lib;
}
return libs;
}
//-------------------------------------------------------------------------
function setBaseTokenURI(string memory baseUri)
public
onlyOwner
{
_baseUri = baseUri;
}
//-------------------------------------------------------------------------
// ERC721Metadata
//-------------------------------------------------------------------------
function baseTokenURI()
public
view
returns (string memory)
{
return _baseUri;
}
//-------------------------------------------------------------------------
/**
* @dev Returns uri of a token. Not guarenteed token exists.
*/
function tokenURI(uint256 tokenId)
override
public
view
returns (string memory)
{
return string(abi.encodePacked(
baseTokenURI(), "/", Strings.toString(tokenId), "/meta"));
}
//-------------------------------------------------------------------------
// generative
//-------------------------------------------------------------------------
/**
* @dev Low-Gas alternative to storing the hash on the chain.
* @return generated hash associated with valid a token.
*/
function tokenHash(uint256 tokenId)
public
view
validTokenId(tokenId)
returns (bytes32)
{
return keccak256(
abi.encodePacked(
_seed,
tokenId,
address(this)));
}
//-------------------------------------------------------------------------
// state
//-------------------------------------------------------------------------
function state(uint256 tokenId)
public
view
validTokenId(tokenId)
returns (int64 rainMeter, bool rain)
{
if (_state[tokenId]._set == false) {
rain = false;
rainMeter = 0;
} else {
rain = _state[tokenId].rain;
rainMeter = _state[tokenId].rainMeter;
}
}
//-------------------------------------------------------------------------
/**
* Updates state of token, only owner or approved is allowed.
* @param tokenId - token to update state on
* @param rainMeter - rain meter; 0-89
* @param rain - control rain; true/false
*
* Emits a {StateUpdated} event.
*/
function updateState(uint256 tokenId, int64 rainMeter, bool rain)
public
approvedOrOwner(_msgSender(), tokenId)
{
require(0 <= rainMeter && rainMeter <= 89, "invalid rainMeter");
_state[tokenId].rain = rain;
_state[tokenId].rainMeter = rainMeter;
_state[tokenId]._set = true;
emit StateChange(msg.sender, tokenId, _state[tokenId]);
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
abstract contract ContextMixin {
function msgSender()
internal
view
returns (address payable sender)
{
if (msg.sender == address(this)) {
bytes memory array = msg.data;
uint256 index = msg.data.length;
assembly {
// Load the 32 bytes word from memory with the address on the lower 20 bytes, and mask those.
sender := and(
mload(add(array, index)),
0xffffffffffffffffffffffffffffffffffffffff
)
}
} else {
sender = payable(msg.sender);
}
return sender;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import {Initializable} from "./Initializable.sol";
contract EIP712Base is Initializable {
struct EIP712Domain {
string name;
string version;
address verifyingContract;
bytes32 salt;
}
string constant public ERC712_VERSION = "1";
bytes32 internal constant EIP712_DOMAIN_TYPEHASH = keccak256(
bytes(
"EIP712Domain(string name,string version,address verifyingContract,bytes32 salt)"
)
);
bytes32 internal domainSeperator;
// supposed to be called once while initializing.
// one of the contracts that inherits this contract follows proxy pattern
// so it is not possible to do this in a constructor
function _initializeEIP712(
string memory name
)
internal
initializer
{
_setDomainSeperator(name);
}
function _setDomainSeperator(string memory name) internal {
domainSeperator = keccak256(
abi.encode(
EIP712_DOMAIN_TYPEHASH,
keccak256(bytes(name)),
keccak256(bytes(ERC712_VERSION)),
address(this),
bytes32(getChainId())
)
);
}
function getDomainSeperator() public view returns (bytes32) {
return domainSeperator;
}
function getChainId() public view returns (uint256) {
uint256 id;
assembly {
id := chainid()
}
return id;
}
/**
* Accept message hash and returns hash message in EIP712 compatible form
* So that it can be used to recover signer from signature signed using EIP712 formatted data
* https://eips.ethereum.org/EIPS/eip-712
* "\\x19" makes the encoding deterministic
* "\\x01" is the version byte to make it compatible to EIP-191
*/
function toTypedMessageHash(bytes32 messageHash)
internal
view
returns (bytes32)
{
return
keccak256(
abi.encodePacked("\x19\x01", getDomainSeperator(), messageHash)
);
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
contract Initializable {
bool inited = false;
modifier initializer() {
require(!inited, "already inited");
_;
inited = true;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import {SafeMath} from "openzeppelin-solidity/contracts/utils/math/SafeMath.sol";
import {EIP712Base} from "./EIP712Base.sol";
contract NativeMetaTransaction is EIP712Base {
using SafeMath for uint256;
bytes32 private constant META_TRANSACTION_TYPEHASH = keccak256(
bytes(
"MetaTransaction(uint256 nonce,address from,bytes functionSignature)"
)
);
event MetaTransactionExecuted(
address userAddress,
address payable relayerAddress,
bytes functionSignature
);
mapping(address => uint256) nonces;
/*
* Meta transaction structure.
* No point of including value field here as if user is doing value transfer then he has the funds to pay for gas
* He should call the desired function directly in that case.
*/
struct MetaTransaction {
uint256 nonce;
address from;
bytes functionSignature;
}
function executeMetaTransaction(
address userAddress,
bytes memory functionSignature,
bytes32 sigR,
bytes32 sigS,
uint8 sigV
) public payable returns (bytes memory) {
MetaTransaction memory metaTx = MetaTransaction({
nonce: nonces[userAddress],
from: userAddress,
functionSignature: functionSignature
});
require(
verify(userAddress, metaTx, sigR, sigS, sigV),
"Signer and signature do not match"
);
// increase nonce for user (to avoid re-use)
nonces[userAddress] = nonces[userAddress].add(1);
emit MetaTransactionExecuted(
userAddress,
payable(msg.sender),
functionSignature
);
// Append userAddress and relayer address at the end to extract it from calling context
(bool success, bytes memory returnData) = address(this).call(
abi.encodePacked(functionSignature, userAddress)
);
require(success, "Function call not successful");
return returnData;
}
function hashMetaTransaction(MetaTransaction memory metaTx)
internal
pure
returns (bytes32)
{
return
keccak256(
abi.encode(
META_TRANSACTION_TYPEHASH,
metaTx.nonce,
metaTx.from,
keccak256(metaTx.functionSignature)
)
);
}
function getNonce(address user) public view returns (uint256 nonce) {
nonce = nonces[user];
}
function verify(
address signer,
MetaTransaction memory metaTx,
bytes32 sigR,
bytes32 sigS,
uint8 sigV
) internal view returns (bool) {
require(signer != address(0), "NativeMetaTransaction: INVALID_SIGNER");
return
signer ==
ecrecover(
toTypedMessageHash(hashMetaTransaction(metaTx)),
sigV,
sigR,
sigS
);
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
//------------------------------------------------------------------------------
// geneticchain.io - NextGen Generative NFT Platform
//------------------------------------------------------------------------------
// _______ __ __ ______ __ __
// | __|-----.-----.-----| |_|__|----. | | |--.---.-|__|-----.
// | | | -__| | -__| _| | __| | ---| | _ | | |
// |_______|_____|__|__|_____|____|__|____| |______|__|__|___._|__|__|__|
//
//------------------------------------------------------------------------------
// Genetic Chain: ERC721SeqEnumerable
//------------------------------------------------------------------------------
// Author: papaver (@tronicdreams)
//------------------------------------------------------------------------------
import "openzeppelin-solidity/contracts/token/ERC721/extensions/IERC721Enumerable.sol";
import "./ERC721Sequential.sol";
/**
* @dev This is a no storage implemntation of the optional extension {ERC721}
* defined in the EIP that adds enumerability of all the token ids in the
* contract as well as all token ids owned by each account. These functions
* are mainly for convienence and should NEVER be called from inside a
* contract on the chain.
*/
abstract contract ERC721SeqEnumerable is ERC721Sequential, IERC721Enumerable {
address constant zero = address(0);
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(
bytes4 interfaceId
) public view virtual override(IERC165, ERC721Sequential) returns (bool) {
return interfaceId == type(IERC721Enumerable).interfaceId
|| super.supportsInterface(interfaceId);
}
/**
* @dev See {IERC721Enumerable-tokenOfOwnerByIndex}.
*/
function tokenOfOwnerByIndex(
address owner,
uint256 index
) public view virtual override returns (uint256 tokenId) {
uint256 length = _owners.length;
unchecked {
for (; tokenId < length; ++tokenId) {
if (_owners[tokenId] == owner) {
if (index-- == 0) {
break;
}
}
}
}
require(tokenId < length, "ERC721Enumerable: owner index out of bounds");
}
/**
* @dev See {IERC721Enumerable-totalSupply}.
*/
function totalSupply() public view virtual override returns (uint256 supply) {
unchecked {
uint256 length = _owners.length;
for (uint256 tokenId = 0; tokenId < length; ++tokenId) {
if (_owners[tokenId] != zero) {
++supply;
}
}
}
}
/**
* @dev See {IERC721Enumerable-tokenByIndex}.
*/
function tokenByIndex(
uint256 index
) public view virtual override returns (uint256 tokenId) {
uint256 length = _owners.length;
unchecked {
for (; tokenId < length; ++tokenId) {
if (_owners[tokenId] != zero) {
if (index-- == 0) {
break;
}
}
}
}
require(tokenId < length, "ERC721Enumerable: global index out of bounds");
}
/**
* @dev Get all tokens owned by owner.
*/
function ownerTokens(
address owner
) public view returns (uint256[] memory) {
uint256 tokenCount = ERC721Sequential.balanceOf(owner);
require(tokenCount != 0, "ERC721Enumerable: owner owns no tokens");
uint256 length = _owners.length;
uint256[] memory tokenIds = new uint256[](tokenCount);
unchecked {
uint256 i = 0;
for (uint256 tokenId = 0; tokenId < length; ++tokenId) {
if (_owners[tokenId] == owner) {
tokenIds[i++] = tokenId;
}
}
}
return tokenIds;
}
}
// SPDX-License-Identifier: MIT
// Forked from: OpenZeppelin Contracts v4.4.0 (token/ERC721/ERC721.sol)
pragma solidity ^0.8.0;
//------------------------------------------------------------------------------
// geneticchain.io - NextGen Generative NFT Platform
//------------------------------------------------------------------------------
// _______ __ __ ______ __ __
// | __|-----.-----.-----| |_|__|----. | | |--.---.-|__|-----.
// | | | -__| | -__| _| | __| | ---| | _ | | |
// |_______|_____|__|__|_____|____|__|____| |______|__|__|___._|__|__|__|
//
//------------------------------------------------------------------------------
// Genetic Chain: ERC721Sequential
//------------------------------------------------------------------------------
// Author: papaver (@tronicdreams)
//------------------------------------------------------------------------------
import "openzeppelin-solidity/contracts/token/ERC721/IERC721.sol";
import "openzeppelin-solidity/contracts/token/ERC721/IERC721Receiver.sol";
import "openzeppelin-solidity/contracts/token/ERC721/extensions/IERC721Metadata.sol";
import "openzeppelin-solidity/contracts/utils/Address.sol";
import "openzeppelin-solidity/contracts/utils/Context.sol";
import "openzeppelin-solidity/contracts/utils/Strings.sol";
import "openzeppelin-solidity/contracts/utils/introspection/ERC165.sol";
/**
* @dev Implementation of https://eips.ethereum.org/EIPS/eip-721
* [ERC721] Non-Fungible Token Standard
*
* This implmentation of ERC721 assumes sequencial token creation to provide
* efficient minting. Storage for balance are no longer required reducing
* gas significantly. This comes at the price of calculating the balance by
* iterating through the entire array. The balanceOf function should NOT
* be used inside a contract. Gas usage will explode as the size of tokens
* increase. A convineiance function is provided which returns the entire
* list of owners whose index maps tokenIds to thier owners. Zero addresses
* indicate burned tokens.
*
*/
contract ERC721Sequential is Context, ERC165, IERC721, IERC721Metadata {
using Address for address;
using Strings for uint256;
// Token name
string private _name;
// Token symbol
string private _symbol;
// Mapping from token ID to owner address
address[] _owners;
// Mapping from token ID to approved address
mapping(uint256 => address) private _tokenApprovals;
// Mapping from owner to operator approvals
mapping(address => mapping(address => bool)) private _operatorApprovals;
/**
* @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
*/
constructor(string memory name_, string memory symbol_) {
_name = name_;
_symbol = symbol_;
}
/**
* @dev See {IERC165-supportsInterface}.
*/
function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
return
interfaceId == type(IERC721).interfaceId ||
interfaceId == type(IERC721Metadata).interfaceId ||
super.supportsInterface(interfaceId);
}
/**
* @dev See {IERC721-balanceOf}.
*/
function balanceOf(address owner) public view virtual override returns (uint256 balance) {
require(owner != address(0), "ERC721: balance query for the zero address");
unchecked {
uint256 length = _owners.length;
for (uint256 i = 0; i < length; ++i) {
if (_owners[i] == owner) {
++balance;
}
}
}
}
/**
* @dev See {IERC721-ownerOf}.
*/
function ownerOf(uint256 tokenId) public view virtual override returns (address) {
require(_exists(tokenId), "ERC721: owner query for nonexistent token");
address owner = _owners[tokenId];
return owner;
}
/**
* @dev Returns entire list of owner enumerated by thier tokenIds. Burned tokens
* will have a zero address.
*/
function owners() public view returns (address[] memory) {
address[] memory owners_ = _owners;
return owners_;
}
/**
* @dev Return largest tokenId minted.
*/
function maxTokenId() public view returns (uint256) {
return _owners.length - 1;
}
/**
* @dev See {IERC721Metadata-name}.
*/
function name() public view virtual override returns (string memory) {
return _name;
}
/**
* @dev See {IERC721Metadata-symbol}.
*/
function symbol() public view virtual override returns (string memory) {
return _symbol;
}
/**
* @dev See {IERC721Metadata-tokenURI}.
*/
function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");
string memory baseURI = _baseURI();
return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
}
/**
* @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
* token will be the concatenation of the `baseURI` and the `tokenId`. Empty
* by default, can be overriden in child contracts.
*/
function _baseURI() internal view virtual returns (string memory) {
return "";
}
/**
* @dev See {IERC721-approve}.
*/
function approve(address to, uint256 tokenId) public virtual override {
address owner = ERC721Sequential.ownerOf(tokenId);
require(to != owner, "ERC721: approval to current owner");
require(
_msgSender() == owner || isApprovedForAll(owner, _msgSender()),
"ERC721: approve caller is not owner nor approved for all"
);
_approve(to, tokenId);
}
/**
* @dev See {IERC721-getApproved}.
*/
function getApproved(uint256 tokenId) public view virtual override returns (address) {
require(_exists(tokenId), "ERC721: approved query for nonexistent token");
return _tokenApprovals[tokenId];
}
/**
* @dev See {IERC721-setApprovalForAll}.
*/
function setApprovalForAll(address operator, bool approved) public virtual override {
_setApprovalForAll(_msgSender(), operator, approved);
}
/**
* @dev See {IERC721-isApprovedForAll}.
*/
function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
return _operatorApprovals[owner][operator];
}
/**
* @dev See {IERC721-transferFrom}.
*/
function transferFrom(
address from,
address to,
uint256 tokenId
) public virtual override {
//solhint-disable-next-line max-line-length
require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
_transfer(from, to, tokenId);
}
/**
* @dev See {IERC721-safeTransferFrom}.
*/
function safeTransferFrom(
address from,
address to,
uint256 tokenId
) public virtual override {
safeTransferFrom(from, to, tokenId, "");
}
/**
* @dev See {IERC721-safeTransferFrom}.
*/
function safeTransferFrom(
address from,
address to,
uint256 tokenId,
bytes memory _data
) public virtual override {
require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
_safeTransfer(from, to, tokenId, _data);
}
/**
* @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
* are aware of the ERC721 protocol to prevent tokens from being forever locked.
*
* `_data` is additional data, it has no specified format and it is sent in call to `to`.
*
* This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
* implement alternative mechanisms to perform token transfer, such as signature-based.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `tokenId` token must exist and be owned by `from`.
* - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
*
* Emits a {Transfer} event.
*/
function _safeTransfer(
address from,
address to,
uint256 tokenId,
bytes memory _data
) internal virtual {
_transfer(from, to, tokenId);
require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
}
/**
* @dev Returns whether `tokenId` exists.
*
* Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
*
* Tokens start existing when they are minted (`_mint`),
* and stop existing when they are burned (`_burn`).
*/
function _exists(uint256 tokenId) internal view virtual returns (bool) {
return tokenId < _owners.length && _owners[tokenId] != address(0);
}
/**
* @dev Returns whether `spender` is allowed to manage `tokenId`.
*
* Requirements:
*
* - `tokenId` must exist.
*/
function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
require(_exists(tokenId), "ERC721: operator query for nonexistent token");
address owner = ERC721Sequential.ownerOf(tokenId);
return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
}
/**
* @dev Safely mints `tokenId` and transfers it to `to`.
*
* Requirements:
*
* - `tokenId` must not exist.
* - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
*
* Emits a {Transfer} event.
*/
function _safeMint(address to) internal virtual returns (uint256 tokenId) {
tokenId = _safeMint(to, "");
}
/**
* @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
* forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
*/
function _safeMint(
address to,
bytes memory _data
) internal virtual returns (uint256 tokenId) {
tokenId = _mint(to);
require(
_checkOnERC721Received(address(0), to, tokenId, _data),
"ERC721: transfer to non ERC721Receiver implementer"
);
}
/**
* @dev Mints `tokenId` and transfers it to `to`.
*
* WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
*
* Requirements:
*
* - `tokenId` must not exist.
* - `to` cannot be the zero address.
*
* Emits a {Transfer} event.
*/
function _mint(address to) internal virtual returns (uint256 tokenId) {
require(to != address(0), "ERC721: mint to the zero address");
tokenId = _owners.length;
_beforeTokenTransfer(address(0), to, tokenId);
_owners.push(to);
emit Transfer(address(0), to, tokenId);
}
/**
* @dev Destroys `tokenId`.
* The approval is cleared when the token is burned.
*
* Requirements:
*
* - `tokenId` must exist.
*
* Emits a {Transfer} event.
*/
function _burn(uint256 tokenId) internal virtual {
address owner = ERC721Sequential.ownerOf(tokenId);
_beforeTokenTransfer(owner, address(0), tokenId);
// Clear approvals
_approve(address(0), tokenId);
delete _owners[tokenId];
emit Transfer(owner, address(0), tokenId);
}
/**
* @dev Transfers `tokenId` from `from` to `to`.
* As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
*
* Requirements:
*
* - `to` cannot be the zero address.
* - `tokenId` token must be owned by `from`.
*
* Emits a {Transfer} event.
*/
function _transfer(
address from,
address to,
uint256 tokenId
) internal virtual {
require(ERC721Sequential.ownerOf(tokenId) == from, "ERC721: transfer of token that is not own");
require(to != address(0), "ERC721: transfer to the zero address");
_beforeTokenTransfer(from, to, tokenId);
// Clear approvals from the previous owner
_approve(address(0), tokenId);
_owners[tokenId] = to;
emit Transfer(from, to, tokenId);
}
/**
* @dev Approve `to` to operate on `tokenId`
*
* Emits a {Approval} event.
*/
function _approve(address to, uint256 tokenId) internal virtual {
_tokenApprovals[tokenId] = to;
emit Approval(ERC721Sequential.ownerOf(tokenId), to, tokenId);
}
/**
* @dev Approve `operator` to operate on all of `owner` tokens
*
* Emits a {ApprovalForAll} event.
*/
function _setApprovalForAll(
address owner,
address operator,
bool approved
) internal virtual {
require(owner != operator, "ERC721: approve to caller");
_operatorApprovals[owner][operator] = approved;
emit ApprovalForAll(owner, operator, approved);
}
/**
* @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
* The call is not executed if the target address is not a contract.
*
* @param from address representing the previous owner of the given token ID
* @param to target address that will receive the tokens
* @param tokenId uint256 ID of the token to be transferred
* @param _data bytes optional data to send along with the call
* @return bool whether the call correctly returned the expected magic value
*/
function _checkOnERC721Received(
address from,
address to,
uint256 tokenId,
bytes memory _data
) private returns (bool) {
if (to.isContract()) {
try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
return retval == IERC721Receiver.onERC721Received.selector;
} catch (bytes memory reason) {
if (reason.length == 0) {
revert("ERC721: transfer to non ERC721Receiver implementer");
} else {
assembly {
revert(add(32, reason), mload(reason))
}
}
}
} else {
return true;
}
}
/**
* @dev Hook that is called before any token transfer. This includes minting
* and burning.
*
* Calling conditions:
*
* - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
* transferred to `to`.
* - When `from` is zero, `tokenId` will be minted for `to`.
* - When `to` is zero, ``from``'s `tokenId` will be burned.
* - `from` and `to` are never both zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _beforeTokenTransfer(
address from,
address to,
uint256 tokenId
) internal virtual {}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
//------------------------------------------------------------------------------
// geneticchain.io - NextGen Generative NFT Platform
//------------------------------------------------------------------------------
// _______ __ __ ______ __ __
// | __|-----.-----.-----| |_|__|----. | | |--.---.-|__|-----.
// | | | -__| | -__| _| | __| | ---| | _ | | |
// |_______|_____|__|__|_____|____|__|____| |______|__|__|___._|__|__|__|
//
//------------------------------------------------------------------------------
// Genetic Chain: library/State
//------------------------------------------------------------------------------
// Author: papaver (@tronicdreams)
//------------------------------------------------------------------------------
/**
* @dev Handle contract state efficiently as possbile.
*/
library State {
struct Data {
uint16 _gallery;
uint16 _artist;
uint16 _public;
uint16 _live;
uint16 _locked;
uint176 _unused;
}
function addGallery(Data storage data, uint256 count)
internal
{
unchecked {
data._gallery += uint16(count);
}
}
function addArtist(Data storage data, uint256 count)
internal
{
unchecked {
data._artist += uint16(count);
}
}
function addPublic(Data storage data, uint256 count)
internal
{
unchecked {
data._public += uint16(count);
}
}
function setLive(Data storage data, uint256 enable)
internal
{
data._live = uint16(enable);
}
function setLocked(Data storage data, uint256 enable)
internal
{
data._locked = uint16(enable);
}
function set(Data storage data, uint256 _gallery, uint256 _artist, uint256 _public)
internal
{
data._gallery = uint16(_gallery);
data._artist = uint16(_artist);
data._public = uint16(_public);
}
}