Contract Source Code:
// SPDX-License-Identifier: AGPL-3.0-or-later
pragma solidity 0.8.17;
import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import { SafeERC20 } from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import { Address } from "@openzeppelin/contracts/utils/Address.sol";
import { ICurvePool } from "../interfaces/ICurvePool.sol";
import { IVault } from "../interfaces/IVault.sol";
/**
* @title ETHAdapter
* @notice A Proxy contract responsible for converting ETH into stETH and depositing into the Vault
* @author Pods Finance
*/
contract ETHAdapter {
using SafeERC20 for IERC20;
using Address for address payable;
/**
* @notice Curve's pool ETH <> stETH
*/
ICurvePool public immutable pool;
/**
* @notice ETH coin index in the Curve Pool
*/
int128 public constant ETH_INDEX = 0;
/**
* @notice stETH coin index in the Curve Pool
*/
int128 public constant STETH_INDEX = 1;
/**
* @notice ETH token address representation
*/
address public constant ETH_ADDRESS = 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE;
/**
* @notice stETH token address representation
*/
address public constant STETH_ADDRESS = 0xae7ab96520DE3A18E5e111B5EaAb095312D7fE84;
error ETHAdapter__IncompatibleVault();
error ETHAdapter__IncompatiblePool();
constructor(ICurvePool _pool) {
if (
_pool.coins(uint256(uint128(ETH_INDEX))) != ETH_ADDRESS ||
_pool.coins(uint256(uint128(STETH_INDEX))) != STETH_ADDRESS
) revert ETHAdapter__IncompatiblePool();
pool = _pool;
}
/**
* @notice Convert `ethAmount` ETH to stETH using Curve pool
* @param ethAmount Amount of ETH to convert
* @return uint256 Amount of stETH received in exchange
*/
function convertToSTETH(uint256 ethAmount) external view returns (uint256) {
return pool.get_dy(ETH_INDEX, STETH_INDEX, ethAmount);
}
/**
* @notice Convert 'stETHAmount' stETH to ETH using Curve pool
* @param stETHAmount Amount of stETH to convert
* @return uint256 Amount of ETH received in exchange
*/
function convertToETH(uint256 stETHAmount) external view returns (uint256) {
return pool.get_dy(STETH_INDEX, ETH_INDEX, stETHAmount);
}
/**
* @notice Deposit `msg.value` of ETH, convert to stETH and deposit into `vault`
* @param vault Pods' strategy vault that will receive the stETH
* @param receiver Address that will be the owner of the Vault's shares
* @param minOutput slippage control. Minimum acceptable amount of stETH
* @return uint256 Amount of shares returned by vault ERC4626 contract
*/
function deposit(
IVault vault,
address receiver,
uint256 minOutput
) external payable returns (uint256) {
if (vault.asset() != STETH_ADDRESS) revert ETHAdapter__IncompatibleVault();
uint256 assets = pool.exchange{ value: msg.value }(ETH_INDEX, STETH_INDEX, msg.value, minOutput);
IERC20(vault.asset()).safeIncreaseAllowance(address(vault), assets);
return vault.deposit(assets, receiver);
}
/**
* @notice Redeem `shares` shares, receive stETH, trade stETH for ETH and send to receiver
* @param vault Pods' strategy vault that will receive the shares and payback stETH
* @param shares Amount of Vault's shares to redeem
* @param receiver Address that will receive back the ETH withdrawn from the `vault`
* @param minOutput slippage control. Minimum acceptable amount of ETH
* @return uint256 Amount of assets received from Vault ERC4626
*/
function redeem(
IVault vault,
uint256 shares,
address receiver,
uint256 minOutput
) external returns (uint256) {
uint256 assets = vault.redeem(shares, address(this), msg.sender);
_returnETH(vault, receiver, minOutput);
return assets;
}
/**
* @notice redeemWithPermit `shares` shares, receive stETH, trade stETH for ETH and send to receiver
* @dev Do not need to approve the shares in advance. The vault tokenized shares supports Permit
* @param vault Pods' strategy vault that will receive the shares and payback stETH
* @param shares Amount of Vault's shares to redeem
* @param receiver Address that will receive back the ETH withdrawn from `vault`
* @param minOutput slippage control. Minimum acceptable amount of ETH
* @param deadline deadline that this transaction will be valid
* @param v recovery id
* @param r ECDSA signature output
* @param s ECDSA signature output
* @return assets Amount of assets received from Vault ERC4626
*/
function redeemWithPermit(
IVault vault,
uint256 shares,
address receiver,
uint256 minOutput,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external returns (uint256 assets) {
vault.permit(msg.sender, address(this), shares, deadline, v, r, s);
assets = vault.redeem(shares, address(this), msg.sender);
_returnETH(vault, receiver, minOutput);
}
/**
* @notice Withdraw `assets` assets, receive stETH, trade stETH for ETH and send to receiver
* @dev Do not need to approve the shares in advance. The vault tokenized shares supports Permit
* @param vault Pods' strategy vault that will receive the shares and payback stETH
* @param assets Amount of assets (stETH) to redeem
* @param receiver Address that will receive back the ETH withdrawn from the Vault
* @param minOutput slippage control. Minimum acceptable amount of ETH
* @return shares Amount of shares burned in order to receive assets
*/
function withdraw(
IVault vault,
uint256 assets,
address receiver,
uint256 minOutput
) external returns (uint256 shares) {
shares = vault.withdraw(assets, address(this), msg.sender);
_returnETH(vault, receiver, minOutput);
}
/**
* @notice withdrawWithPermit `assets` assets, receive stETH, trade stETH for ETH and send to receiver
* @dev Do not need to approve the shares in advance. Vault's tokenized shares supports Permit
* @param vault Pods' strategy vault that will receive the shares and payback stETH
* @param assets Amount of assets (stETH) to redeem
* @param receiver Address that will receive back the ETH withdrawn from the Vault
* @param minOutput slippage control. Minimum acceptable amount of ETH
* @param deadline deadline that this transaction will be valid
* @param v recovery id
* @param r ECDSA signature output
* @param s ECDSA signature output
* @return shares Amount of shares burned in order to receive assets
*/
function withdrawWithPermit(
IVault vault,
uint256 assets,
address receiver,
uint256 minOutput,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external returns (uint256 shares) {
shares = vault.convertToShares(assets);
vault.permit(msg.sender, address(this), shares, deadline, v, r, s);
shares = vault.withdraw(assets, address(this), msg.sender);
_returnETH(vault, receiver, minOutput);
}
/* We need this default function because this contract will
receive ETH from the Curve pool
*/
receive() external payable {}
/**
* @dev internal function used to convert stETH into ETH and send back
* to receiver
*/
function _returnETH(
IVault vault,
address receiver,
uint256 minOutput
) internal {
if (vault.asset() != STETH_ADDRESS) revert ETHAdapter__IncompatibleVault();
IERC20 asset = IERC20(vault.asset());
uint256 balance = asset.balanceOf(address(this));
asset.safeIncreaseAllowance(address(pool), balance);
pool.exchange(STETH_INDEX, ETH_INDEX, balance, minOutput);
payable(receiver).sendValue(address(this).balance);
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(
address from,
address to,
uint256 amount
) external returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
function safeTransfer(
IERC20 token,
address to,
uint256 value
) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
}
function safeTransferFrom(
IERC20 token,
address from,
address to,
uint256 value
) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
}
/**
* @dev Deprecated. This function has issues similar to the ones found in
* {IERC20-approve}, and its usage is discouraged.
*
* Whenever possible, use {safeIncreaseAllowance} and
* {safeDecreaseAllowance} instead.
*/
function safeApprove(
IERC20 token,
address spender,
uint256 value
) internal {
// safeApprove should only be called when setting an initial allowance,
// or when resetting it to zero. To increase and decrease it, use
// 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
require(
(value == 0) || (token.allowance(address(this), spender) == 0),
"SafeERC20: approve from non-zero to non-zero allowance"
);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
}
function safeIncreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
uint256 newAllowance = token.allowance(address(this), spender) + value;
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
}
function safeDecreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
unchecked {
uint256 oldAllowance = token.allowance(address(this), spender);
require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
uint256 newAllowance = oldAllowance - value;
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
}
}
function safePermit(
IERC20Permit token,
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) internal {
uint256 nonceBefore = token.nonces(owner);
token.permit(owner, spender, value, deadline, v, r, s);
uint256 nonceAfter = token.nonces(owner);
require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
if (returndata.length > 0) {
// Return data is optional
require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
* ====
*
* [IMPORTANT]
* ====
* You shouldn't rely on `isContract` to protect against flash loan attacks!
*
* Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
* like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
* constructor.
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize/address.code.length, which returns 0
// for contracts in construction, since the code is only stored at the end
// of the constructor execution.
return account.code.length > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(address(this).balance >= amount, "Address: insufficient balance");
(bool success, ) = recipient.call{value: amount}("");
require(success, "Address: unable to send value, recipient may have reverted");
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value
) internal returns (bytes memory) {
return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(address(this).balance >= value, "Address: insufficient balance for call");
(bool success, bytes memory returndata) = target.call{value: value}(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
return functionStaticCall(target, data, "Address: low-level static call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
(bool success, bytes memory returndata) = target.staticcall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
return functionDelegateCall(target, data, "Address: low-level delegate call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
(bool success, bytes memory returndata) = target.delegatecall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
* the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
*
* _Available since v4.8._
*/
function verifyCallResultFromTarget(
address target,
bool success,
bytes memory returndata,
string memory errorMessage
) internal view returns (bytes memory) {
if (success) {
if (returndata.length == 0) {
// only check isContract if the call was successful and the return data is empty
// otherwise we already know that it was a contract
require(isContract(target), "Address: call to non-contract");
}
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
/**
* @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
* revert reason or using the provided one.
*
* _Available since v4.3._
*/
function verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) internal pure returns (bytes memory) {
if (success) {
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
function _revert(bytes memory returndata, string memory errorMessage) private pure {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
/// @solidity memory-safe-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
}
// SPDX-License-Identifier: AGPL-3.0-or-later
pragma solidity 0.8.17;
/**
* @title ICurvePool Curve ETH/stETH StableSwap
* @notice Curve ETH/stETH StableSwap Interface
* @author Pods Finance
*/
interface ICurvePool {
/**
* @notice Perform an exchange between two coins
* @dev Index values can be found via the `coins` public getter method
* @param from Index value for the coin to send
* @param to Index value of the coin to receive
* @param input Amount of `from` being exchanged
* @param minOutput Minimum amount of `to` to receive
* @return output Actual amount of `to` received
*/
function exchange(
int128 from,
int128 to,
uint256 input,
uint256 minOutput
) external payable returns (uint256 output);
/**
* @notice Check price between two coins
* @dev Index values can be found via the `coins` public getter method
* @param from Index value for the coin to send
* @param to Index value of the coin to receive
* @param input Amount of `from` being exchanged
* @return output estimated `to` received
*/
function get_dy(
int128 from,
int128 to,
uint256 input
) external view returns (uint256 output);
function coins(uint256 index) external view returns (address);
}
// SPDX-License-Identifier: AGPL-3.0-or-later
pragma solidity 0.8.17;
import { IERC20Permit } from "@openzeppelin/contracts/token/ERC20/extensions/draft-IERC20Permit.sol";
import { IERC4626 } from "@openzeppelin/contracts/interfaces/IERC4626.sol";
/**
* @title IVault
* @notice Interface contract for Pods Vault
* @author Pods Finance
*/
interface IVault is IERC4626, IERC20Permit {
error IVault__CallerIsNotTheController();
error IVault__NotProcessingDeposits();
error IVault__AlreadyProcessingDeposits();
error IVault__ForbiddenWhileProcessingDeposits();
error IVault__ZeroAssets();
error IVault__MigrationNotAllowed();
error IVault__AssetsUnderMinimumAmount(uint256 assets);
event FeeCollected(uint256 fee);
event RoundStarted(uint32 indexed roundId, uint256 amountAddedToStrategy);
event RoundEnded(uint32 indexed roundId);
event DepositProcessed(address indexed owner, uint32 indexed roundId, uint256 assets, uint256 shares);
event DepositRefunded(address indexed owner, uint32 indexed roundId, uint256 assets);
event Migrated(address indexed caller, address indexed from, address indexed to, uint256 assets, uint256 shares);
/**
* @dev Describes the vault state variables.
*/
struct VaultState {
uint256 processedDeposits;
uint256 totalIdleAssets;
uint32 currentRoundId;
uint40 lastEndRoundTimestamp;
bool isProcessingDeposits;
}
struct Fractional {
uint256 numerator;
uint256 denominator;
}
/**
* @notice Returns the current round ID.
*/
function currentRoundId() external view returns (uint32);
/**
* @notice Determines whether the Vault is in the processing deposits state.
* @dev While it's processing deposits, `processDeposits` can be called and new shares can be created.
* During this period deposits, mints, withdraws and redeems are blocked.
*/
function isProcessingDeposits() external view returns (bool);
/**
* @notice Returns the amount of processed deposits entering the next round.
*/
function processedDeposits() external view returns (uint256);
/**
* @notice Returns the fee charged on withdraws.
*/
function getWithdrawFeeRatio() external view returns (uint256);
/**
* @notice Returns the vault controller
*/
function controller() external view returns (address);
/**
* @notice Outputs the amount of asset tokens of an `owner` is idle, waiting for the next round.
*/
function idleAssetsOf(address owner) external view returns (uint256);
/**
* @notice Outputs the amount of asset tokens of an `owner` are either waiting for the next round,
* deposited or committed.
*/
function assetsOf(address owner) external view returns (uint256);
/**
* @notice Outputs the amount of asset tokens is idle, waiting for the next round.
*/
function totalIdleAssets() external view returns (uint256);
/**
* @notice Outputs current size of the deposit queue.
*/
function depositQueueSize() external view returns (uint256);
/**
* @notice Outputs addresses in the deposit queue
*/
function queuedDeposits() external view returns (address[] memory);
/**
* @notice Deposit ERC20 tokens with permit, a gasless token approval.
* @dev Mints shares to receiver by depositing exactly amount of underlying tokens.
*
* For more information on the signature format, see the EIP2612 specification:
* https://eips.ethereum.org/EIPS/eip-2612#specification
*/
function depositWithPermit(
uint256 assets,
address receiver,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external returns (uint256);
/**
* @notice Mint shares with permit, a gasless token approval.
* @dev Mints exactly shares to receiver by depositing amount of underlying tokens.
*
* For more information on the signature format, see the EIP2612 specification:
* https://eips.ethereum.org/EIPS/eip-2612#specification
*/
function mintWithPermit(
uint256 shares,
address receiver,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external returns (uint256);
/**
* @notice Starts the next round, sending the idle funds to the
* strategy where it should start accruing yield.
* @return The new round id
*/
function startRound() external returns (uint32);
/**
* @notice Closes the round, allowing deposits to the next round be processed.
* and opens the window for withdraws.
*/
function endRound() external;
/**
* @notice Withdraw all user assets in unprocessed deposits.
*/
function refund() external returns (uint256 assets);
/**
* @notice Migrate assets from this vault to the next vault.
* @dev The `newVault` will be assigned by the ConfigurationManager
*/
function migrate() external;
/**
* @notice Handle migrated assets.
* @return Estimation of shares created.
*/
function handleMigration(uint256 assets, address receiver) external returns (uint256);
/**
* @notice Distribute shares to depositors queued in the deposit queue, effectively including their assets in the next round.
*
* @param depositors Array of owner addresses to process
*/
function processQueuedDeposits(address[] calldata depositors) external;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
* https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
*
* Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
* presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
* need to send a transaction, and thus is not required to hold Ether at all.
*/
interface IERC20Permit {
/**
* @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
* given ``owner``'s signed approval.
*
* IMPORTANT: The same issues {IERC20-approve} has related to transaction
* ordering also apply here.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `deadline` must be a timestamp in the future.
* - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
* over the EIP712-formatted function arguments.
* - the signature must use ``owner``'s current nonce (see {nonces}).
*
* For more information on the signature format, see the
* https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
* section].
*/
function permit(
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external;
/**
* @dev Returns the current nonce for `owner`. This value must be
* included whenever a signature is generated for {permit}.
*
* Every successful call to {permit} increases ``owner``'s nonce by one. This
* prevents a signature from being used multiple times.
*/
function nonces(address owner) external view returns (uint256);
/**
* @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
*/
// solhint-disable-next-line func-name-mixedcase
function DOMAIN_SEPARATOR() external view returns (bytes32);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (interfaces/IERC4626.sol)
pragma solidity ^0.8.0;
import "../token/ERC20/IERC20.sol";
import "../token/ERC20/extensions/IERC20Metadata.sol";
/**
* @dev Interface of the ERC4626 "Tokenized Vault Standard", as defined in
* https://eips.ethereum.org/EIPS/eip-4626[ERC-4626].
*
* _Available since v4.7._
*/
interface IERC4626 is IERC20, IERC20Metadata {
event Deposit(address indexed sender, address indexed owner, uint256 assets, uint256 shares);
event Withdraw(
address indexed sender,
address indexed receiver,
address indexed owner,
uint256 assets,
uint256 shares
);
/**
* @dev Returns the address of the underlying token used for the Vault for accounting, depositing, and withdrawing.
*
* - MUST be an ERC-20 token contract.
* - MUST NOT revert.
*/
function asset() external view returns (address assetTokenAddress);
/**
* @dev Returns the total amount of the underlying asset that is “managed” by Vault.
*
* - SHOULD include any compounding that occurs from yield.
* - MUST be inclusive of any fees that are charged against assets in the Vault.
* - MUST NOT revert.
*/
function totalAssets() external view returns (uint256 totalManagedAssets);
/**
* @dev Returns the amount of shares that the Vault would exchange for the amount of assets provided, in an ideal
* scenario where all the conditions are met.
*
* - MUST NOT be inclusive of any fees that are charged against assets in the Vault.
* - MUST NOT show any variations depending on the caller.
* - MUST NOT reflect slippage or other on-chain conditions, when performing the actual exchange.
* - MUST NOT revert.
*
* NOTE: This calculation MAY NOT reflect the “per-user” price-per-share, and instead should reflect the
* “average-user’s” price-per-share, meaning what the average user should expect to see when exchanging to and
* from.
*/
function convertToShares(uint256 assets) external view returns (uint256 shares);
/**
* @dev Returns the amount of assets that the Vault would exchange for the amount of shares provided, in an ideal
* scenario where all the conditions are met.
*
* - MUST NOT be inclusive of any fees that are charged against assets in the Vault.
* - MUST NOT show any variations depending on the caller.
* - MUST NOT reflect slippage or other on-chain conditions, when performing the actual exchange.
* - MUST NOT revert.
*
* NOTE: This calculation MAY NOT reflect the “per-user” price-per-share, and instead should reflect the
* “average-user’s” price-per-share, meaning what the average user should expect to see when exchanging to and
* from.
*/
function convertToAssets(uint256 shares) external view returns (uint256 assets);
/**
* @dev Returns the maximum amount of the underlying asset that can be deposited into the Vault for the receiver,
* through a deposit call.
*
* - MUST return a limited value if receiver is subject to some deposit limit.
* - MUST return 2 ** 256 - 1 if there is no limit on the maximum amount of assets that may be deposited.
* - MUST NOT revert.
*/
function maxDeposit(address receiver) external view returns (uint256 maxAssets);
/**
* @dev Allows an on-chain or off-chain user to simulate the effects of their deposit at the current block, given
* current on-chain conditions.
*
* - MUST return as close to and no more than the exact amount of Vault shares that would be minted in a deposit
* call in the same transaction. I.e. deposit should return the same or more shares as previewDeposit if called
* in the same transaction.
* - MUST NOT account for deposit limits like those returned from maxDeposit and should always act as though the
* deposit would be accepted, regardless if the user has enough tokens approved, etc.
* - MUST be inclusive of deposit fees. Integrators should be aware of the existence of deposit fees.
* - MUST NOT revert.
*
* NOTE: any unfavorable discrepancy between convertToShares and previewDeposit SHOULD be considered slippage in
* share price or some other type of condition, meaning the depositor will lose assets by depositing.
*/
function previewDeposit(uint256 assets) external view returns (uint256 shares);
/**
* @dev Mints shares Vault shares to receiver by depositing exactly amount of underlying tokens.
*
* - MUST emit the Deposit event.
* - MAY support an additional flow in which the underlying tokens are owned by the Vault contract before the
* deposit execution, and are accounted for during deposit.
* - MUST revert if all of assets cannot be deposited (due to deposit limit being reached, slippage, the user not
* approving enough underlying tokens to the Vault contract, etc).
*
* NOTE: most implementations will require pre-approval of the Vault with the Vault’s underlying asset token.
*/
function deposit(uint256 assets, address receiver) external returns (uint256 shares);
/**
* @dev Returns the maximum amount of the Vault shares that can be minted for the receiver, through a mint call.
* - MUST return a limited value if receiver is subject to some mint limit.
* - MUST return 2 ** 256 - 1 if there is no limit on the maximum amount of shares that may be minted.
* - MUST NOT revert.
*/
function maxMint(address receiver) external view returns (uint256 maxShares);
/**
* @dev Allows an on-chain or off-chain user to simulate the effects of their mint at the current block, given
* current on-chain conditions.
*
* - MUST return as close to and no fewer than the exact amount of assets that would be deposited in a mint call
* in the same transaction. I.e. mint should return the same or fewer assets as previewMint if called in the
* same transaction.
* - MUST NOT account for mint limits like those returned from maxMint and should always act as though the mint
* would be accepted, regardless if the user has enough tokens approved, etc.
* - MUST be inclusive of deposit fees. Integrators should be aware of the existence of deposit fees.
* - MUST NOT revert.
*
* NOTE: any unfavorable discrepancy between convertToAssets and previewMint SHOULD be considered slippage in
* share price or some other type of condition, meaning the depositor will lose assets by minting.
*/
function previewMint(uint256 shares) external view returns (uint256 assets);
/**
* @dev Mints exactly shares Vault shares to receiver by depositing amount of underlying tokens.
*
* - MUST emit the Deposit event.
* - MAY support an additional flow in which the underlying tokens are owned by the Vault contract before the mint
* execution, and are accounted for during mint.
* - MUST revert if all of shares cannot be minted (due to deposit limit being reached, slippage, the user not
* approving enough underlying tokens to the Vault contract, etc).
*
* NOTE: most implementations will require pre-approval of the Vault with the Vault’s underlying asset token.
*/
function mint(uint256 shares, address receiver) external returns (uint256 assets);
/**
* @dev Returns the maximum amount of the underlying asset that can be withdrawn from the owner balance in the
* Vault, through a withdraw call.
*
* - MUST return a limited value if owner is subject to some withdrawal limit or timelock.
* - MUST NOT revert.
*/
function maxWithdraw(address owner) external view returns (uint256 maxAssets);
/**
* @dev Allows an on-chain or off-chain user to simulate the effects of their withdrawal at the current block,
* given current on-chain conditions.
*
* - MUST return as close to and no fewer than the exact amount of Vault shares that would be burned in a withdraw
* call in the same transaction. I.e. withdraw should return the same or fewer shares as previewWithdraw if
* called
* in the same transaction.
* - MUST NOT account for withdrawal limits like those returned from maxWithdraw and should always act as though
* the withdrawal would be accepted, regardless if the user has enough shares, etc.
* - MUST be inclusive of withdrawal fees. Integrators should be aware of the existence of withdrawal fees.
* - MUST NOT revert.
*
* NOTE: any unfavorable discrepancy between convertToShares and previewWithdraw SHOULD be considered slippage in
* share price or some other type of condition, meaning the depositor will lose assets by depositing.
*/
function previewWithdraw(uint256 assets) external view returns (uint256 shares);
/**
* @dev Burns shares from owner and sends exactly assets of underlying tokens to receiver.
*
* - MUST emit the Withdraw event.
* - MAY support an additional flow in which the underlying tokens are owned by the Vault contract before the
* withdraw execution, and are accounted for during withdraw.
* - MUST revert if all of assets cannot be withdrawn (due to withdrawal limit being reached, slippage, the owner
* not having enough shares, etc).
*
* Note that some implementations will require pre-requesting to the Vault before a withdrawal may be performed.
* Those methods should be performed separately.
*/
function withdraw(
uint256 assets,
address receiver,
address owner
) external returns (uint256 shares);
/**
* @dev Returns the maximum amount of Vault shares that can be redeemed from the owner balance in the Vault,
* through a redeem call.
*
* - MUST return a limited value if owner is subject to some withdrawal limit or timelock.
* - MUST return balanceOf(owner) if owner is not subject to any withdrawal limit or timelock.
* - MUST NOT revert.
*/
function maxRedeem(address owner) external view returns (uint256 maxShares);
/**
* @dev Allows an on-chain or off-chain user to simulate the effects of their redeemption at the current block,
* given current on-chain conditions.
*
* - MUST return as close to and no more than the exact amount of assets that would be withdrawn in a redeem call
* in the same transaction. I.e. redeem should return the same or more assets as previewRedeem if called in the
* same transaction.
* - MUST NOT account for redemption limits like those returned from maxRedeem and should always act as though the
* redemption would be accepted, regardless if the user has enough shares, etc.
* - MUST be inclusive of withdrawal fees. Integrators should be aware of the existence of withdrawal fees.
* - MUST NOT revert.
*
* NOTE: any unfavorable discrepancy between convertToAssets and previewRedeem SHOULD be considered slippage in
* share price or some other type of condition, meaning the depositor will lose assets by redeeming.
*/
function previewRedeem(uint256 shares) external view returns (uint256 assets);
/**
* @dev Burns exactly shares from owner and sends assets of underlying tokens to receiver.
*
* - MUST emit the Withdraw event.
* - MAY support an additional flow in which the underlying tokens are owned by the Vault contract before the
* redeem execution, and are accounted for during redeem.
* - MUST revert if all of shares cannot be redeemed (due to withdrawal limit being reached, slippage, the owner
* not having enough shares, etc).
*
* NOTE: some implementations will require pre-requesting to the Vault before a withdrawal may be performed.
* Those methods should be performed separately.
*/
function redeem(
uint256 shares,
address receiver,
address owner
) external returns (uint256 assets);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
/**
* @dev Interface for the optional metadata functions from the ERC20 standard.
*
* _Available since v4.1._
*/
interface IERC20Metadata is IERC20 {
/**
* @dev Returns the name of the token.
*/
function name() external view returns (string memory);
/**
* @dev Returns the symbol of the token.
*/
function symbol() external view returns (string memory);
/**
* @dev Returns the decimals places of the token.
*/
function decimals() external view returns (uint8);
}