Contract Source Code:

pragma solidity ^0.4.18;

// File: contracts/math/SafeMath.sol

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {

  /**
  * @dev Multiplies two numbers, throws on overflow.
  */
  function mul(uint256 a, uint256 b) internal pure returns (uint256) {
    if (a == 0) {
      return 0;
    }
    uint256 c = a * b;
    assert(c / a == b);
    return c;
  }

  /**
  * @dev Integer division of two numbers, truncating the quotient.
  */
  function div(uint256 a, uint256 b) internal pure returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return c;
  }

  /**
  * @dev Substracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend).
  */
  function sub(uint256 a, uint256 b) internal pure returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  /**
  * @dev Adds two numbers, throws on overflow.
  */
  function add(uint256 a, uint256 b) internal pure returns (uint256) {
    uint256 c = a + b;
    assert(c >= a);
    return c;
  }
}

// File: contracts/Dividends.sol

contract DividendContract {
  using SafeMath for uint256;
  event Dividends(uint256 round, uint256 value);
  event ClaimDividends(address investor, uint256 value);

  uint256 totalDividendsAmount = 0;
  uint256 totalDividendsRounds = 0;
  uint256 totalUnPayedDividendsAmount = 0;
  mapping(address => uint256) payedDividends;


  function getTotalDividendsAmount() public constant returns (uint256) {
    return totalDividendsAmount;
  }

  function getTotalDividendsRounds() public constant returns (uint256) {
    return totalDividendsRounds;
  }

  function getTotalUnPayedDividendsAmount() public constant returns (uint256) {
    return totalUnPayedDividendsAmount;
  }

  function dividendsAmount(address investor) public constant returns (uint256);
  function claimDividends() payable public;

  function payDividends() payable public {
    require(msg.value > 0);
    totalDividendsAmount = totalDividendsAmount.add(msg.value);
    totalUnPayedDividendsAmount = totalUnPayedDividendsAmount.add(msg.value);
    totalDividendsRounds += 1;
    Dividends(totalDividendsRounds, msg.value);
  }
}

// File: contracts/token/ERC20/ERC20Basic.sol

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
  function totalSupply() public view returns (uint256);
  function balanceOf(address who) public view returns (uint256);
  function transfer(address to, uint256 value) public returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

// File: contracts/token/ERC20/ERC20.sol

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender) public view returns (uint256);
  function transferFrom(address from, address to, uint256 value) public returns (bool);
  function approve(address spender, uint256 value) public returns (bool);
  event Approval(address indexed owner, address indexed spender, uint256 value);
}

// File: contracts/ESlotsICOToken.sol

contract ESlotsICOToken is ERC20, DividendContract {

    string public constant name = "Ethereum Slot Machine Token";
    string public constant symbol = "EST";
    uint8 public constant decimals = 18;

    function maxTokensToSale() public view returns (uint256);
    function availableTokens() public view returns (uint256);
    function completeICO() public;
    function connectCrowdsaleContract(address crowdsaleContract) public;
}

// File: contracts/ownership/Ownable.sol

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {
  address public owner;


  event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);


  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  function Ownable() public {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) public onlyOwner {
    require(newOwner != address(0));
    OwnershipTransferred(owner, newOwner);
    owner = newOwner;
  }

}

// File: contracts/token/ERC20/BasicToken.sol

/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances.
 */
contract BasicToken is ERC20Basic {
  using SafeMath for uint256;

  mapping(address => uint256) balances;

  uint256 totalSupply_;

  /**
  * @dev total number of tokens in existence
  */
  function totalSupply() public view returns (uint256) {
    return totalSupply_;
  }

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) public returns (bool) {
    require(_to != address(0));
    require(_value <= balances[msg.sender]);

    // SafeMath.sub will throw if there is not enough balance.
    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of.
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) public view returns (uint256 balance) {
    return balances[_owner];
  }

}

// File: contracts/token/ERC20/BurnableToken.sol

/**
 * @title Burnable Token
 * @dev Token that can be irreversibly burned (destroyed).
 */
contract BurnableToken is BasicToken {

  event Burn(address indexed burner, uint256 value);

  /**
   * @dev Burns a specific amount of tokens.
   * @param _value The amount of token to be burned.
   */
  function burn(uint256 _value) public {
    require(_value <= balances[msg.sender]);
    // no need to require value <= totalSupply, since that would imply the
    // sender's balance is greater than the totalSupply, which *should* be an assertion failure

    address burner = msg.sender;
    balances[burner] = balances[burner].sub(_value);
    totalSupply_ = totalSupply_.sub(_value);
    Burn(burner, _value);
  }
}

// File: contracts/token/ERC20/StandardToken.sol

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * @dev https://github.com/ethereum/EIPs/issues/20
 * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) internal allowed;


  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amount of tokens to be transferred
   */
  function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
    require(_to != address(0));
    require(_value <= balances[_from]);
    require(_value <= allowed[_from][msg.sender]);

    balances[_from] = balances[_from].sub(_value);
    balances[_to] = balances[_to].add(_value);
    allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
    Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
   *
   * Beware that changing an allowance with this method brings the risk that someone may use both the old
   * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
   * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
   * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) public returns (bool) {
    allowed[msg.sender][_spender] = _value;
    Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifying the amount of tokens still available for the spender.
   */
  function allowance(address _owner, address _spender) public view returns (uint256) {
    return allowed[_owner][_spender];
  }

  /**
   * @dev Increase the amount of tokens that an owner allowed to a spender.
   *
   * approve should be called when allowed[_spender] == 0. To increment
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _addedValue The amount of tokens to increase the allowance by.
   */
  function increaseApproval(address _spender, uint _addedValue) public returns (bool) {
    allowed[msg.sender][_spender] = allowed[msg.sender][_spender].add(_addedValue);
    Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
    return true;
  }

  /**
   * @dev Decrease the amount of tokens that an owner allowed to a spender.
   *
   * approve should be called when allowed[_spender] == 0. To decrement
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _subtractedValue The amount of tokens to decrease the allowance by.
   */
  function decreaseApproval(address _spender, uint _subtractedValue) public returns (bool) {
    uint oldValue = allowed[msg.sender][_spender];
    if (_subtractedValue > oldValue) {
      allowed[msg.sender][_spender] = 0;
    } else {
      allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
    }
    Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
    return true;
  }

}

// File: contracts/ESlotsToken.sol

/**
 * @title eSlotsToken
 * @dev See more info https://eslots.io
 */
contract ESlotsToken is Ownable, StandardToken, ESlotsICOToken {

  event Burn(address indexed burner, uint256 value);

  enum State { ActiveICO, CompletedICO }
  State public state;

  uint256 public constant INITIAL_SUPPLY = 50000000 * (10 ** uint256(decimals));

  address founders = 0x7b97B31E12f7d029769c53cB91c83d29611A4F7A;
  uint256 public constant foundersStake = 10; //10% to founders
  uint256 public constant dividendRoundsBeforeFoundersStakeUnlock = 4;
  uint256 maxFoundersTokens;
  uint256 tokensToSale;

  uint256 transferGASUsage;

  /**
   * @dev Constructor that gives msg.sender all of existing tokens.
   */
  function ESlotsToken() public {
    totalSupply_ = INITIAL_SUPPLY;
    maxFoundersTokens = INITIAL_SUPPLY.mul(foundersStake).div(100);
    tokensToSale = INITIAL_SUPPLY - maxFoundersTokens;
    balances[msg.sender] = tokensToSale;
    Transfer(0x0, msg.sender, balances[msg.sender]);
    state = State.ActiveICO;
    transferGASUsage = 21000;
  }

  function maxTokensToSale() public view returns (uint256) {
    return tokensToSale;
  }

  function availableTokens() public view returns (uint256) {
    return balances[owner];
  }

  function setGasUsage(uint256 newGasUsage) public onlyOwner {
    transferGASUsage = newGasUsage;
  }

  //run it after ESlotsCrowdsale contract is deployed to approve token spending
  function connectCrowdsaleContract(address crowdsaleContract) public onlyOwner {
    approve(crowdsaleContract, balances[owner]);
  }

  //burn unsold tokens
  function completeICO() public onlyOwner {
    require(state == State.ActiveICO);
    state = State.CompletedICO;
    uint256 soldTokens = tokensToSale.sub(balances[owner]);
    uint256 foundersTokens = soldTokens.mul(foundersStake).div(100);
    if(foundersTokens > maxFoundersTokens) {
      //normally we never reach this point
      foundersTokens = maxFoundersTokens;
    }
    BasicToken.transfer(founders, foundersTokens);
    totalSupply_ = soldTokens.add(foundersTokens);
    balances[owner] = 0;
    Burn(msg.sender, INITIAL_SUPPLY.sub(totalSupply_));
  }


  //handle dividends
  function transfer(address _to, uint256 _value) public returns (bool) {
    if(msg.sender == founders) {
      //lock operation with tokens for founders
      require(totalDividendsAmount > 0 && totalDividendsRounds > dividendRoundsBeforeFoundersStakeUnlock);
    }
    //transfer is allowed only then all dividends are claimed
    require(payedDividends[msg.sender] == totalDividendsAmount);
    require(balances[_to] == 0 || payedDividends[_to] == totalDividendsAmount);
    bool res =  BasicToken.transfer(_to, _value);
    if(res && payedDividends[_to] != totalDividendsAmount) {
      payedDividends[_to] = totalDividendsAmount;
    }
    return res;
  }

  function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
    if(msg.sender == founders) {
      //lock operation with tokens for founders
      require(totalDividendsAmount > 0 && totalDividendsRounds > dividendRoundsBeforeFoundersStakeUnlock);
    }
    //transfer is allowed only then all dividends are claimed
    require(payedDividends[_from] == totalDividendsAmount);
    require(balances[_to] == 0 || payedDividends[_to] == totalDividendsAmount);
    bool res = StandardToken.transferFrom(_from, _to, _value);
    if(res && payedDividends[_to] != totalDividendsAmount) {
      payedDividends[_to] = totalDividendsAmount;
    }
    return res;
  }

  //Dividends

  modifier onlyThenCompletedICO {
    require(state == State.CompletedICO);
    _;
  }

  function dividendsAmount(address investor) public onlyThenCompletedICO constant returns (uint256)  {
    if(totalSupply_ == 0) {return 0;}
    if(balances[investor] == 0) {return 0;}
    if(payedDividends[investor] >= totalDividendsAmount) {return 0;}
    return (totalDividendsAmount - payedDividends[investor]).mul(balances[investor]).div(totalSupply_);
  }

  function claimDividends() payable public onlyThenCompletedICO {
    //gasUsage = 0 because a caller pays for that
    sendDividends(msg.sender, 0);

  }

  //force dividend payments if they hasn't been claimed by token holder before
  function pushDividends(address investor) payable public onlyThenCompletedICO {
    //because we pay for gas
    sendDividends(investor, transferGASUsage.mul(tx.gasprice));
  }

  function sendDividends(address investor, uint256 gasUsage) internal {
    uint256 value = dividendsAmount(investor);
    require(value > gasUsage);
    payedDividends[investor] = totalDividendsAmount;
    totalUnPayedDividendsAmount = totalUnPayedDividendsAmount.sub(value);
    investor.transfer(value.sub(gasUsage));
    ClaimDividends(investor, value);
  }

  function payDividends() payable public onlyThenCompletedICO {
    DividendContract.payDividends();
  }
}