Contract Name:
ZapInCurveGVault
Contract Source Code:
// Copyright (C) 2021 Zapper (Zapper.fi)
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU Affero General Public License as published by
// the Free Software Foundation, either version 2 of the License, or
// (at your option) any later version.
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
// See the GNU Affero General Public License for more details.
///@author Zapper, modified and adapted for Grizzly.fi.
///@notice This contract adds liquidity to Curve pools with ETH or ERC20 tokens and subsequently deposits into a gVault.
///@notice These files have been changed from the original Zapper ones.
// SPDX-License-Identifier: GPL-2.0
pragma solidity 0.8.0;
import {IVault} from "./interfaces/IVault.sol";
import {IWETH} from "./interfaces/IWETH.sol";
import {IERC20} from "./interfaces/IERC20.sol";
import {ICurveSwap} from "./interfaces/ICurveSwap.sol";
import {ICurveEthSwap} from "./interfaces/ICurveEthSwap.sol";
import {ICurveRegistry} from "./interfaces/ICurveRegistry.sol";
import {ZapInBase} from "./ZapInBase.sol";
import {SafeERC20} from "./libraries/SafeERC20.sol";
contract ZapInCurveGVault is ZapInBase {
using SafeERC20 for IERC20;
ICurveRegistry public curveReg;
address private constant wethTokenAddress =
0xC02aaA39b223FE8D0A0e5C4F27eAD9083C756Cc2;
constructor(ICurveRegistry _curveRegistry) {
curveReg = _curveRegistry;
approvedTargets[0xDef1C0ded9bec7F1a1670819833240f027b25EfF] = true;
}
event zapInCurve(address sender, address pool, uint256 tokensRec);
event zapInVault(address sender, address gVault, uint256 sharesRec);
event curveRegistryUpdated(
ICurveRegistry newCurveReg,
ICurveRegistry oldCurveReg
);
event Sweep(address indexed token, uint256 amount);
/**
@notice This function adds liquidity to a Curve pool with ETH or ERC20 tokens
@param fromTokenAddress The token used for entry (address(0) if ether)
@param toTokenAddress The intermediate ERC20 token to swap to
@param swapAddress Curve swap address for the pool
@param incomingTokenQty The amount of fromTokenAddress to invest
@param minPoolTokens The minimum acceptable quantity of Curve LP to receive. Reverts otherwise!
@param swapTarget Execution target for the first swap
@param swapData DEX quote data
// Vault Deposit
@param gVault Grizzly Vault address
@return sharesReceived Quantity of Grizzly Vault shares received
*/
function ZapIn(
address fromTokenAddress,
address toTokenAddress,
address swapAddress,
uint256 incomingTokenQty,
uint256 minPoolTokens,
address swapTarget,
bytes calldata swapData,
address gVault,
bytes32 referral
) external payable stopInEmergency returns (uint256 sharesReceived) {
uint256 toInvest = _pullTokens(fromTokenAddress, incomingTokenQty);
if (fromTokenAddress == address(0)) {
fromTokenAddress = ETHAddress;
}
// Perform zapIn to Curve LP Tokens
uint256 crvTokensBought = _performZapIn(
fromTokenAddress,
toTokenAddress,
swapAddress,
toInvest,
swapTarget,
swapData
);
require(
crvTokensBought > minPoolTokens,
"Received less than minPoolTokens"
);
address poolTokenAddress = curveReg.getTokenAddress(swapAddress);
emit zapInCurve(msg.sender, poolTokenAddress, crvTokensBought);
// Safety check for underlying Vault Token = address LP
require(poolTokenAddress == IVault(gVault).token(), "Wrong LpAddress");
// Here we deposit the Curve LP tokens into the corresponding gVault
sharesReceived = _vaultDeposit(
poolTokenAddress,
crvTokensBought,
gVault,
referral
);
}
function _vaultDeposit(
address underlyingVaultToken,
uint256 amount,
address gVault,
bytes32 referral
) internal returns (uint256 tokensReceived) {
_approveToken(underlyingVaultToken, gVault);
uint256 iniGVaultBal = IERC20(gVault).balanceOf(address(this));
IVault(gVault).deposit(amount, address(this), referral);
tokensReceived = IERC20(gVault).balanceOf(address(this)) - iniGVaultBal;
IERC20(gVault).safeTransfer(msg.sender, tokensReceived);
emit zapInVault(msg.sender, gVault, tokensReceived);
}
function _performZapIn(
address fromTokenAddress,
address toTokenAddress,
address swapAddress,
uint256 toInvest,
address swapTarget,
bytes memory swapData
) internal returns (uint256 crvTokensBought) {
(bool isUnderlying, uint8 underlyingIndex) = curveReg.isUnderlyingToken(
swapAddress,
fromTokenAddress
);
if (isUnderlying) {
crvTokensBought = _enterCurve(
swapAddress,
toInvest,
underlyingIndex
);
} else {
// Swap tokens using 0x swap
uint256 tokensBought = _fillQuote(
fromTokenAddress,
toTokenAddress,
toInvest,
swapTarget,
swapData
);
if (toTokenAddress == address(0)) toTokenAddress = ETHAddress;
// Get underlying token index
(isUnderlying, underlyingIndex) = curveReg.isUnderlyingToken(
swapAddress,
toTokenAddress
);
if (isUnderlying) {
crvTokensBought = _enterCurve(
swapAddress,
tokensBought,
underlyingIndex
);
} else {
(uint256 tokens, uint8 metaIndex) = _enterMetaPool(
swapAddress,
toTokenAddress,
tokensBought
);
crvTokensBought = _enterCurve(swapAddress, tokens, metaIndex);
}
}
}
/**
@notice This function gets adds the liquidity for meta pools and returns the token index and swap tokens
@param swapAddress Curve swap address for the pool
@param toTokenAddress The ERC20 token to which from token to be convert
@param swapTokens quantity of toToken to invest
@return tokensBought quantity of curve LP acquired
@return index index of LP token in swapAddress whose pool tokens were acquired
*/
function _enterMetaPool(
address swapAddress,
address toTokenAddress,
uint256 swapTokens
) internal returns (uint256 tokensBought, uint8 index) {
address[4] memory poolTokens = curveReg.getPoolTokens(swapAddress);
for (uint8 i = 0; i < 4; i++) {
address intermediateSwapAddress = curveReg.getSwapAddress(
poolTokens[i]
);
if (intermediateSwapAddress != address(0)) {
(, index) = curveReg.isUnderlyingToken(
intermediateSwapAddress,
toTokenAddress
);
tokensBought = _enterCurve(
intermediateSwapAddress,
swapTokens,
index
);
return (tokensBought, i);
}
}
}
function _fillQuote(
address fromTokenAddress,
address toTokenAddress,
uint256 amount,
address swapTarget,
bytes memory swapData
) internal returns (uint256 amountBought) {
if (fromTokenAddress == toTokenAddress) {
return amount;
}
if (swapTarget == wethTokenAddress) {
IWETH(wethTokenAddress).deposit{value: amount}();
return amount;
}
uint256 valueToSend;
if (fromTokenAddress == ETHAddress) {
valueToSend = amount;
} else {
_approveToken(fromTokenAddress, swapTarget, amount);
}
uint256 initialBalance = _getBalance(toTokenAddress);
require(approvedTargets[swapTarget], "Target not Authorized");
(bool success, ) = swapTarget.call{value: valueToSend}(swapData);
require(success, "Error Swapping Tokens");
amountBought = _getBalance(toTokenAddress) - initialBalance;
require(amountBought > 0, "Swapped To Invalid Intermediate");
}
/**
@notice This function adds liquidity to a curve pool
@param swapAddress Curve swap address for the pool
@param amount The quantity of tokens being added as liquidity
@param index The token index for the add_liquidity call
@return crvTokensBought the quantity of curve LP tokens received
*/
function _enterCurve(
address swapAddress,
uint256 amount,
uint8 index
) internal returns (uint256 crvTokensBought) {
address tokenAddress = curveReg.getTokenAddress(swapAddress);
address depositAddress = curveReg.getDepositAddress(swapAddress);
uint256 initialBalance = _getBalance(tokenAddress);
address entryToken = curveReg.getPoolTokens(swapAddress)[index];
if (entryToken != ETHAddress) {
IERC20(entryToken).safeIncreaseAllowance(
address(depositAddress),
amount
);
}
uint256 numTokens = curveReg.getNumTokens(swapAddress);
bool addUnderlying = curveReg.shouldAddUnderlying(swapAddress);
if (numTokens == 4) {
uint256[4] memory amounts;
amounts[index] = amount;
if (addUnderlying) {
ICurveSwap(depositAddress).add_liquidity(amounts, 0, true);
} else {
ICurveSwap(depositAddress).add_liquidity(amounts, 0);
}
} else if (numTokens == 3) {
uint256[3] memory amounts;
amounts[index] = amount;
if (addUnderlying) {
ICurveSwap(depositAddress).add_liquidity(amounts, 0, true);
} else {
ICurveSwap(depositAddress).add_liquidity(amounts, 0);
}
} else {
uint256[2] memory amounts;
amounts[index] = amount;
if (curveReg.isEthPool(depositAddress)) {
ICurveEthSwap(depositAddress).add_liquidity{value: amount}(
amounts,
0
);
} else if (addUnderlying) {
ICurveSwap(depositAddress).add_liquidity(amounts, 0, true);
} else {
ICurveSwap(depositAddress).add_liquidity(amounts, 0);
}
}
crvTokensBought = _getBalance(tokenAddress) - initialBalance;
}
function updateCurveRegistry(ICurveRegistry newCurveRegistry)
external
onlyOwner
{
require(newCurveRegistry != curveReg, "Already using this Registry");
ICurveRegistry oldCurveReg = curveReg;
curveReg = newCurveRegistry;
emit curveRegistryUpdated(curveReg, oldCurveReg);
}
/// @notice Sweep tokens or ETH in case they get stuck in the contract
function sweep(address[] memory _tokens, bool _ETH) external onlyOwner {
if (_ETH) {
uint256 balance = address(this).balance;
(bool success, ) = msg.sender.call{value: address(this).balance}(
""
);
require(success, "Sending ETH failed");
emit Sweep(ETHAddress, balance);
}
for (uint256 i = 0; i < _tokens.length; i++) {
uint256 amount = IERC20(_tokens[i]).balanceOf(address(this));
IERC20(_tokens[i]).safeTransfer(owner(), amount);
emit Sweep(_tokens[i], amount);
}
}
}
interface IVault {
function deposit(uint256) external;
function deposit(uint256 amount, address recipient)
external
returns (uint256);
function deposit(uint256 amount, address recipient, bytes32 referral)
external
returns (uint256);
function withdraw(uint256) external;
function withdraw(uint256 maxShares, address recipient)
external
returns (uint256);
function withdraw(uint256 maxShares, address recipient, uint256 maxLoss, address endRecipient)
external
returns (uint256);
function getPricePerFullShare() external view returns (uint256);
function token() external view returns (address);
function decimals() external view returns (uint256);
// V2
function pricePerShare() external view returns (uint256);
}
interface IWETH {
function deposit() external payable;
function withdraw(uint256 wad) external;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP. Does not include
* the optional functions; to access them see {ERC20Detailed}.
*/
interface IERC20 {
function decimals() external view returns (uint8);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `recipient`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address recipient, uint256 amount)
external
returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender)
external
view
returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `sender` to `recipient` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(
address sender,
address recipient,
uint256 amount
) external returns (bool);
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(
address indexed owner,
address indexed spender,
uint256 value
);
}
interface ICurveSwap {
function coins(int128 arg0) external view returns (address);
function underlying_coins(int128 arg0) external view returns (address);
function add_liquidity(uint256[4] calldata amounts, uint256 min_mint_amount)
external;
function add_liquidity(
uint256[4] calldata amounts,
uint256 min_mint_amount,
bool addUnderlying
) external;
function add_liquidity(uint256[3] calldata amounts, uint256 min_mint_amount)
external;
function add_liquidity(
uint256[3] calldata amounts,
uint256 min_mint_amount,
bool addUnderlying
) external;
function add_liquidity(uint256[2] calldata amounts, uint256 min_mint_amount)
external;
function add_liquidity(
uint256[2] calldata amounts,
uint256 min_mint_amount,
bool addUnderlying
) external;
}
interface ICurveEthSwap {
function add_liquidity(uint256[2] calldata amounts, uint256 min_mint_amount)
external
payable
returns (uint256);
}
interface ICurveRegistry {
function getSwapAddress(address tokenAddress)
external
view
returns (address swapAddress);
function getTokenAddress(address swapAddress)
external
view
returns (address tokenAddress);
function getDepositAddress(address swapAddress)
external
view
returns (address depositAddress);
function getPoolTokens(address swapAddress)
external
view
returns (address[4] memory poolTokens);
function shouldAddUnderlying(address swapAddress)
external
view
returns (bool);
function getNumTokens(address swapAddress)
external
view
returns (uint8 numTokens);
function isBtcPool(address swapAddress) external view returns (bool);
function isEthPool(address swapAddress) external view returns (bool);
function isUnderlyingToken(
address swapAddress,
address tokenContractAddress
) external view returns (bool, uint8);
}
// SPDX-License-Identifier: GPL-2.0
pragma solidity 0.8.0;
import {IERC20} from "./interfaces/IERC20.sol";
import {Ownable} from "./libraries/Ownable.sol";
import {Address} from "./libraries/Address.sol";
import {SafeERC20} from "./libraries/SafeERC20.sol";
abstract contract ZapInBase is Ownable {
using SafeERC20 for IERC20;
bool public stopped = false;
// SwapTarget => approval status
mapping(address => bool) public approvedTargets;
address internal constant ETHAddress =
0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE;
event ApprovedTarget(address target, bool approved);
event Stopped(bool stopped);
// Circuit breaker modifiers
modifier stopInEmergency() {
if (stopped) {
revert("Paused");
} else {
_;
}
}
function _pullTokens(address token, uint256 amount)
internal
returns (uint256)
{
if (token == address(0)) {
require(msg.value > 0, "No eth sent");
return msg.value;
}
require(amount > 0, "Invalid token amount");
require(msg.value == 0, "Eth sent with token");
// Transfer token
require(
IERC20(token).allowance(msg.sender, address(this)) >= amount,
"Token is not approved"
);
IERC20(token).safeTransferFrom(msg.sender, address(this), amount);
return amount;
}
function _getBalance(address token)
internal
view
returns (uint256 balance)
{
if (token == address(0)) {
balance = address(this).balance;
} else {
balance = IERC20(token).balanceOf(address(this));
}
}
function _approveToken(address token, address spender) internal {
IERC20 _token = IERC20(token);
if (_token.allowance(address(this), spender) > 0) return;
else {
_token.safeApprove(spender, type(uint256).max);
}
}
function _approveToken(
address token,
address spender,
uint256 amount
) internal {
IERC20(token).safeApprove(spender, 0);
IERC20(token).safeApprove(spender, amount);
}
// - to Pause the contract
function toggleContractActive() external onlyOwner {
stopped = !stopped;
emit Stopped(stopped);
}
///@notice Withdraw tokens like a sweep function
function withdrawTokens(address[] calldata tokens) external onlyOwner {
for (uint256 i = 0; i < tokens.length; i++) {
uint256 qty;
// Check weather if is native or just ERC20
if (tokens[i] == ETHAddress) {
qty = address(this).balance;
Address.sendValue(payable(owner()), qty);
} else {
qty = IERC20(tokens[i]).balanceOf(address(this));
IERC20(tokens[i]).safeTransfer(owner(), qty);
}
}
}
function setApprovedTargets(
address[] calldata targets,
bool[] calldata isApproved
) external onlyOwner {
require(targets.length == isApproved.length, "Invalid Input length");
for (uint256 i = 0; i < targets.length; i++) {
approvedTargets[targets[i]] = isApproved[i];
emit ApprovedTarget(targets[i], isApproved[i]);
}
}
receive() external payable {
require(msg.sender != tx.origin, "Do not send ETH directly");
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import {IERC20} from "../interfaces/IERC20.sol";
import {Address} from "./Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
function safeTransfer(
IERC20 token,
address to,
uint256 value
) internal {
_callOptionalReturn(
token,
abi.encodeWithSelector(token.transfer.selector, to, value)
);
}
function safeTransferFrom(
IERC20 token,
address from,
address to,
uint256 value
) internal {
_callOptionalReturn(
token,
abi.encodeWithSelector(token.transferFrom.selector, from, to, value)
);
}
/**
* @dev Deprecated. This function has issues similar to the ones found in
* {IERC20-approve}, and its usage is discouraged.
*
* Whenever possible, use {safeIncreaseAllowance} and
* {safeDecreaseAllowance} instead.
*/
function safeApprove(
IERC20 token,
address spender,
uint256 value
) internal {
// safeApprove should only be called when setting an initial allowance,
// or when resetting it to zero. To increase and decrease it, use
// 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
// solhint-disable-next-line max-line-length
require(
(value == 0) || (token.allowance(address(this), spender) == 0),
"SafeERC20: approve from non-zero to non-zero allowance"
);
_callOptionalReturn(
token,
abi.encodeWithSelector(token.approve.selector, spender, value)
);
}
function safeIncreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
uint256 newAllowance = token.allowance(address(this), spender) + value;
_callOptionalReturn(
token,
abi.encodeWithSelector(
token.approve.selector,
spender,
newAllowance
)
);
}
function safeDecreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
unchecked {
uint256 oldAllowance = token.allowance(address(this), spender);
require(
oldAllowance >= value,
"SafeERC20: decreased allowance below zero"
);
uint256 newAllowance = oldAllowance - value;
_callOptionalReturn(
token,
abi.encodeWithSelector(
token.approve.selector,
spender,
newAllowance
)
);
}
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(
data,
"SafeERC20: low-level call failed"
);
if (returndata.length > 0) {
// Return data is optional
// solhint-disable-next-line max-line-length
require(
abi.decode(returndata, (bool)),
"SafeERC20: ERC20 operation did not succeed"
);
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import {Context} from "./Context.sol";
/**
* @dev Contract module which provides a basic access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership}.
*
* This module is used through inheritance. It will make available the modifier
* `onlyOwner`, which can be applied to your functions to restrict their use to
* the owner.
*/
abstract contract Ownable is Context {
address private _owner;
event OwnershipTransferred(
address indexed previousOwner,
address indexed newOwner
);
/**
* @dev Initializes the contract setting the deployer as the initial owner.
*/
constructor() {
address msgSender = _msgSender();
_owner = msgSender;
emit OwnershipTransferred(address(0), msgSender);
}
/**
* @dev Returns the address of the current owner.
*/
function owner() public view virtual returns (address) {
return _owner;
}
/**
* @dev Throws if called by any account other than the owner.
*/
modifier onlyOwner() {
require(owner() == _msgSender(), "Ownable: caller is not the owner");
_;
}
/**
* @dev Leaves the contract without owner. It will not be possible to call
* `onlyOwner` functions anymore. Can only be called by the current owner.
*
* NOTE: Renouncing ownership will leave the contract without an owner,
* thereby removing any functionality that is only available to the owner.
*/
function renounceOwnership() public virtual onlyOwner {
emit OwnershipTransferred(_owner, address(0));
_owner = address(0);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual onlyOwner {
require(
newOwner != address(0),
"Ownable: new owner is the zero address"
);
emit OwnershipTransferred(_owner, newOwner);
_owner = newOwner;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize, which returns 0 for contracts in
// construction, since the code is only stored at the end of the
// constructor execution.
uint256 size;
// solhint-disable-next-line no-inline-assembly
assembly {
size := extcodesize(account)
}
return size > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(
address(this).balance >= amount,
"Address: insufficient balance"
);
// solhint-disable-next-line avoid-low-level-calls, avoid-call-value
(bool success, ) = recipient.call{value: amount}("");
require(
success,
"Address: unable to send value, recipient may have reverted"
);
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain`call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data)
internal
returns (bytes memory)
{
return functionCall(target, data, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value
) internal returns (bytes memory) {
return
functionCallWithValue(
target,
data,
value,
"Address: low-level call with value failed"
);
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(
address(this).balance >= value,
"Address: insufficient balance for call"
);
require(isContract(target), "Address: call to non-contract");
// solhint-disable-next-line avoid-low-level-calls
(bool success, bytes memory returndata) = target.call{value: value}(
data
);
return _verifyCallResult(success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data)
internal
view
returns (bytes memory)
{
return
functionStaticCall(
target,
data,
"Address: low-level static call failed"
);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
require(isContract(target), "Address: static call to non-contract");
// solhint-disable-next-line avoid-low-level-calls
(bool success, bytes memory returndata) = target.staticcall(data);
return _verifyCallResult(success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data)
internal
returns (bytes memory)
{
return
functionDelegateCall(
target,
data,
"Address: low-level delegate call failed"
);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
require(isContract(target), "Address: delegate call to non-contract");
// solhint-disable-next-line avoid-low-level-calls
(bool success, bytes memory returndata) = target.delegatecall(data);
return _verifyCallResult(success, returndata, errorMessage);
}
function _verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) private pure returns (bytes memory) {
if (success) {
return returndata;
} else {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
// solhint-disable-next-line no-inline-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/*
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
return msg.data;
}
}