Contract Source Code:

pragma solidity ^0.5.0;

/**
 * @title Roles
 * @dev Library for managing addresses assigned to a Role.
 */
library Roles {
    struct Role {
        mapping (address => bool) bearer;
    }

    /**
     * @dev give an account access to this role
     */
    function add(Role storage role, address account) internal {
        require(account != address(0));
        require(!has(role, account));

        role.bearer[account] = true;
    }

    /**
     * @dev remove an account's access to this role
     */
    function remove(Role storage role, address account) internal {
        require(account != address(0));
        require(has(role, account));

        role.bearer[account] = false;
    }

    /**
     * @dev check if an account has this role
     * @return bool
     */
    function has(Role storage role, address account) internal view returns (bool) {
        require(account != address(0));
        return role.bearer[account];
    }
}


/**
 * @title SafeMath
 * @dev Unsigned math operations with safety checks that revert on error
 */
library SafeMath {
    /**
    * @dev Multiplies two unsigned integers, reverts on overflow.
    */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b);

        return c;
    }

    /**
    * @dev Integer division of two unsigned integers truncating the quotient, reverts on division by zero.
    */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
    * @dev Subtracts two unsigned integers, reverts on overflow (i.e. if subtrahend is greater than minuend).
    */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a);
        uint256 c = a - b;

        return c;
    }

    /**
    * @dev Adds two unsigned integers, reverts on overflow.
    */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a);

        return c;
    }

    /**
    * @dev Divides two unsigned integers and returns the remainder (unsigned integer modulo),
    * reverts when dividing by zero.
    */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b != 0);
        return a % b;
    }
}


/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
interface IERC20 {
    function transfer(address to, uint256 value) external returns (bool);

    function approve(address spender, uint256 value) external returns (bool);

    function transferFrom(address from, address to, uint256 value) external returns (bool);

    function totalSupply() external view returns (uint256);

    function balanceOf(address who) external view returns (uint256);

    function allowance(address owner, address spender) external view returns (uint256);

    event Transfer(address indexed from, address indexed to, uint256 value);

    event Approval(address indexed owner, address indexed spender, uint256 value);
}





/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure.
 * To use this library you can add a `using SafeERC20 for ERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using SafeMath for uint256;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        require(token.transfer(to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        require(token.transferFrom(from, to, value));
    }

    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require((value == 0) || (token.allowance(msg.sender, spender) == 0));
        require(token.approve(spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).add(value);
        require(token.approve(spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).sub(value);
        require(token.approve(spender, newAllowance));
    }
}




contract PauserRole {
    using Roles for Roles.Role;

    event PauserAdded(address indexed account);
    event PauserRemoved(address indexed account);

    Roles.Role private _pausers;

    constructor () internal {
        _addPauser(msg.sender);
    }

    modifier onlyPauser() {
        require(isPauser(msg.sender));
        _;
    }

    function isPauser(address account) public view returns (bool) {
        return _pausers.has(account);
    }

    function addPauser(address account) public onlyPauser {
        _addPauser(account);
    }

    function renouncePauser() public {
        _removePauser(msg.sender);
    }

    function _addPauser(address account) internal {
        _pausers.add(account);
        emit PauserAdded(account);
    }

    function _removePauser(address account) internal {
        _pausers.remove(account);
        emit PauserRemoved(account);
    }
}





/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * https://github.com/ethereum/EIPs/blob/master/EIPS/eip-20.md
 * Originally based on code by FirstBlood:
 * https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 *
 * This implementation emits additional Approval events, allowing applications to reconstruct the allowance status for
 * all accounts just by listening to said events. Note that this isn't required by the specification, and other
 * compliant implementations may not do it.
 */
contract ERC20 is IERC20 {
    using SafeMath for uint256;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowed;

    uint256 private _totalSupply;

    /**
    * @dev Total number of tokens in existence
    */
    function totalSupply() public view returns (uint256) {
        return _totalSupply;
    }

    /**
    * @dev Gets the balance of the specified address.
    * @param owner The address to query the balance of.
    * @return An uint256 representing the amount owned by the passed address.
    */
    function balanceOf(address owner) public view returns (uint256) {
        return _balances[owner];
    }

    /**
     * @dev Function to check the amount of tokens that an owner allowed to a spender.
     * @param owner address The address which owns the funds.
     * @param spender address The address which will spend the funds.
     * @return A uint256 specifying the amount of tokens still available for the spender.
     */
    function allowance(address owner, address spender) public view returns (uint256) {
        return _allowed[owner][spender];
    }

    /**
    * @dev Transfer token for a specified address
    * @param to The address to transfer to.
    * @param value The amount to be transferred.
    */
    function transfer(address to, uint256 value) public returns (bool) {
        _transfer(msg.sender, to, value);
        return true;
    }

    /**
     * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
     * Beware that changing an allowance with this method brings the risk that someone may use both the old
     * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
     * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     */
    function approve(address spender, uint256 value) public returns (bool) {
        require(spender != address(0));

        _allowed[msg.sender][spender] = value;
        emit Approval(msg.sender, spender, value);
        return true;
    }

    /**
     * @dev Transfer tokens from one address to another.
     * Note that while this function emits an Approval event, this is not required as per the specification,
     * and other compliant implementations may not emit the event.
     * @param from address The address which you want to send tokens from
     * @param to address The address which you want to transfer to
     * @param value uint256 the amount of tokens to be transferred
     */
    function transferFrom(address from, address to, uint256 value) public returns (bool) {
        _allowed[from][msg.sender] = _allowed[from][msg.sender].sub(value);
        _transfer(from, to, value);
        emit Approval(from, msg.sender, _allowed[from][msg.sender]);
        return true;
    }

    /**
     * @dev Increase the amount of tokens that an owner allowed to a spender.
     * approve should be called when allowed_[_spender] == 0. To increment
     * allowed value is better to use this function to avoid 2 calls (and wait until
     * the first transaction is mined)
     * From MonolithDAO Token.sol
     * Emits an Approval event.
     * @param spender The address which will spend the funds.
     * @param addedValue The amount of tokens to increase the allowance by.
     */
    function increaseAllowance(address spender, uint256 addedValue) public returns (bool) {
        require(spender != address(0));

        _allowed[msg.sender][spender] = _allowed[msg.sender][spender].add(addedValue);
        emit Approval(msg.sender, spender, _allowed[msg.sender][spender]);
        return true;
    }

    /**
     * @dev Decrease the amount of tokens that an owner allowed to a spender.
     * approve should be called when allowed_[_spender] == 0. To decrement
     * allowed value is better to use this function to avoid 2 calls (and wait until
     * the first transaction is mined)
     * From MonolithDAO Token.sol
     * Emits an Approval event.
     * @param spender The address which will spend the funds.
     * @param subtractedValue The amount of tokens to decrease the allowance by.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public returns (bool) {
        require(spender != address(0));

        _allowed[msg.sender][spender] = _allowed[msg.sender][spender].sub(subtractedValue);
        emit Approval(msg.sender, spender, _allowed[msg.sender][spender]);
        return true;
    }

    /**
    * @dev Transfer token for a specified addresses
    * @param from The address to transfer from.
    * @param to The address to transfer to.
    * @param value The amount to be transferred.
    */
    function _transfer(address from, address to, uint256 value) internal {
        require(to != address(0));

        _balances[from] = _balances[from].sub(value);
        _balances[to] = _balances[to].add(value);
        emit Transfer(from, to, value);
    }

    /**
     * @dev Internal function that mints an amount of the token and assigns it to
     * an account. This encapsulates the modification of balances such that the
     * proper events are emitted.
     * @param account The account that will receive the created tokens.
     * @param value The amount that will be created.
     */
    function _mint(address account, uint256 value) internal {
        require(account != address(0));

        _totalSupply = _totalSupply.add(value);
        _balances[account] = _balances[account].add(value);
        emit Transfer(address(0), account, value);
    }

    /**
     * @dev Internal function that burns an amount of the token of a given
     * account.
     * @param account The account whose tokens will be burnt.
     * @param value The amount that will be burnt.
     */
    function _burn(address account, uint256 value) internal {
        require(account != address(0));

        _totalSupply = _totalSupply.sub(value);
        _balances[account] = _balances[account].sub(value);
        emit Transfer(account, address(0), value);
    }

    /**
     * @dev Internal function that burns an amount of the token of a given
     * account, deducting from the sender's allowance for said account. Uses the
     * internal burn function.
     * Emits an Approval event (reflecting the reduced allowance).
     * @param account The account whose tokens will be burnt.
     * @param value The amount that will be burnt.
     */
    function _burnFrom(address account, uint256 value) internal {
        _allowed[account][msg.sender] = _allowed[account][msg.sender].sub(value);
        _burn(account, value);
        emit Approval(account, msg.sender, _allowed[account][msg.sender]);
    }
}




contract MinterRole {
    using Roles for Roles.Role;

    event MinterAdded(address indexed account);
    event MinterRemoved(address indexed account);

    Roles.Role private _minters;

    constructor () internal {
        _addMinter(msg.sender);
    }

    modifier onlyMinter() {
        require(isMinter(msg.sender));
        _;
    }

    function isMinter(address account) public view returns (bool) {
        return _minters.has(account);
    }

    function addMinter(address account) public onlyMinter {
        _addMinter(account);
    }

    function renounceMinter() public {
        _removeMinter(msg.sender);
    }

    function _addMinter(address account) internal {
        _minters.add(account);
        emit MinterAdded(account);
    }

    function _removeMinter(address account) internal {
        _minters.remove(account);
        emit MinterRemoved(account);
    }
}




/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev The Ownable constructor sets the original `owner` of the contract to the sender
     * account.
     */
    constructor () internal {
        _owner = msg.sender;
        emit OwnershipTransferred(address(0), _owner);
    }

    /**
     * @return the address of the owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(isOwner());
        _;
    }

    /**
     * @return true if `msg.sender` is the owner of the contract.
     */
    function isOwner() public view returns (bool) {
        return msg.sender == _owner;
    }

    /**
     * @dev Allows the current owner to relinquish control of the contract.
     * @notice Renouncing to ownership will leave the contract without an owner.
     * It will not be possible to call the functions with the `onlyOwner`
     * modifier anymore.
     */
    function renounceOwnership() public onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Allows the current owner to transfer control of the contract to a newOwner.
     * @param newOwner The address to transfer ownership to.
     */
    function transferOwnership(address newOwner) public onlyOwner {
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers control of the contract to a newOwner.
     * @param newOwner The address to transfer ownership to.
     */
    function _transferOwnership(address newOwner) internal {
        require(newOwner != address(0));
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}





/**
 * @title Burnable Token
 * @dev Token that can be irreversibly burned (destroyed).
 */
contract ERC20Burnable is ERC20 {
    /**
     * @dev Burns a specific amount of tokens.
     * @param value The amount of token to be burned.
     */
    function burn(uint256 value) public {
        _burn(msg.sender, value);
    }

    /**
     * @dev Burns a specific amount of tokens from the target address and decrements allowance
     * @param from address The address which you want to send tokens from
     * @param value uint256 The amount of token to be burned
     */
    function burnFrom(address from, uint256 value) public {
        _burnFrom(from, value);
    }
}






/**
 * @title ERC20Mintable
 * @dev ERC20 minting logic
 */
contract ERC20Mintable is ERC20, MinterRole {
    /**
     * @dev Function to mint tokens
     * @param to The address that will receive the minted tokens.
     * @param value The amount of tokens to mint.
     * @return A boolean that indicates if the operation was successful.
     */
    function mint(address to, uint256 value) public onlyMinter returns (bool) {
        _mint(to, value);
        return true;
    }
}








/**
 * @title Pausable
 * @dev Base contract which allows children to implement an emergency stop mechanism.
 */
contract Pausable is PauserRole {
    event Paused(address account);
    event Unpaused(address account);

    bool private _paused;

    constructor () internal {
        _paused = false;
    }

    /**
     * @return true if the contract is paused, false otherwise.
     */
    function paused() public view returns (bool) {
        return _paused;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     */
    modifier whenNotPaused() {
        require(!_paused);
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     */
    modifier whenPaused() {
        require(_paused);
        _;
    }

    /**
     * @dev called by the owner to pause, triggers stopped state
     */
    function pause() public onlyPauser whenNotPaused {
        _paused = true;
        emit Paused(msg.sender);
    }

    /**
     * @dev called by the owner to unpause, returns to normal state
     */
    function unpause() public onlyPauser whenPaused {
        _paused = false;
        emit Unpaused(msg.sender);
    }
}


/**
 * @title Pausable token
 * @dev ERC20 modified with pausable transfers.
 **/
contract ERC20Pausable is ERC20, Pausable {
    function transfer(address to, uint256 value) public whenNotPaused returns (bool) {
        return super.transfer(to, value);
    }

    function transferFrom(address from, address to, uint256 value) public whenNotPaused returns (bool) {
        return super.transferFrom(from, to, value);
    }

    function approve(address spender, uint256 value) public whenNotPaused returns (bool) {
        return super.approve(spender, value);
    }

    function increaseAllowance(address spender, uint addedValue) public whenNotPaused returns (bool success) {
        return super.increaseAllowance(spender, addedValue);
    }

    function decreaseAllowance(address spender, uint subtractedValue) public whenNotPaused returns (bool success) {
        return super.decreaseAllowance(spender, subtractedValue);
    }
}





/**
 * @title ERC20Detailed token
 * @dev The decimals are only for visualization purposes.
 * All the operations are done using the smallest and indivisible token unit,
 * just as on Ethereum all the operations are done in wei.
 */
contract ERC20Detailed is IERC20 {
    string private _name;
    string private _symbol;
    uint8 private _decimals;

    constructor (string memory name, string memory symbol, uint8 decimals) public {
        _name = name;
        _symbol = symbol;
        _decimals = decimals;
    }

    /**
     * @return the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @return the symbol of the token.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @return the number of decimals of the token.
     */
    function decimals() public view returns (uint8) {
        return _decimals;
    }
}





contract TokenWhitelist is Ownable {

    mapping(address => bool) private whitelist;

    event Whitelisted(address indexed wallet);
    event Dewhitelisted(address indexed wallet);

    function enableWallet(address _wallet) public onlyOwner {
        require(_wallet != address(0), "Invalid wallet");
        whitelist[_wallet] = true;
        emit Whitelisted(_wallet);
    }
    
    function enableWalletBatch(address[] memory _wallets) public onlyOwner {
        for (uint256 i = 0; i < _wallets.length; i++) {
            enableWallet(_wallets[i]);
        }
    }


    function disableWallet(address _wallet) public onlyOwner {
        require(_wallet != address(0), "Invalid wallet");
        whitelist[_wallet] = false;
        emit Dewhitelisted(_wallet);
    }

    
    function disableWalletBatch(address[] memory _wallets) public onlyOwner {
        for (uint256 i = 0; i < _wallets.length; i++) {
            disableWallet(_wallets[i]);
        }
    }
    
    function checkWhitelisted(address _wallet) public view returns (bool){
        return whitelist[_wallet];
    }
    
}
















contract TrustedRole is Ownable {
    using Roles for Roles.Role;

    event TrustedAdded(address indexed account);
    event TrustedRemoved(address indexed account);

    Roles.Role private trusted;

    constructor() internal {
        _addTrusted(msg.sender);
    }

    modifier onlyOwnerOrTrusted() {
        require(isOwner() || isTrusted(msg.sender), "Only owner or trusted allowed");
        _;
    }

    modifier onlyTrusted() {
        require(isTrusted(msg.sender), "Only trusted allowed");
        _;
    }

    function isTrusted(address account) public view returns (bool) {
        return trusted.has(account);
    }

    function addTrusted(address account) public onlyOwner {
        _addTrusted(account);
    }

    function removeTrusted(address account) public onlyOwner {
        _removeTrusted(account);
    }

    function _addTrusted(address account) internal {
        trusted.add(account);
        emit TrustedAdded(account);
    }

    function _removeTrusted(address account) internal {
        trusted.remove(account);
        emit TrustedRemoved(account);
    }
}


/**
 * @title MultiTokenDividend
 *
 * Based on https://medium.com/%40weka/dividend-bearing-tokens-on-ethereum-42d01c710657
 * Distributes dividends on multiple currencies: ETH and ERC20
 */
contract MultiTokenDividend is Ownable, TrustedRole {
    using SafeMath for uint256;
    using SafeERC20 for IERC20;

    // Stores each account preferred payment method and balance
    struct Account {
        address tokenAddress;
        uint256 amount;
        uint256 lastTotalDividendPoints;
    }
    mapping(address => Account) public accounts;

    // Stores information about each payment method
    struct Dividend {
        uint256 totalDividendPoints;
        uint256 unclaimedDividends;
        uint256 totalSupply;
    }
    mapping(address => Dividend) public tokenDividends;

    // Main token for calculation of dividends
    ERC20Detailed private _sharesToken;

    // Constant to allow division by totalSupply (from the article)
    uint256 private X;

    // Disbursement failure for tracking
    event TransferFailure(address indexed beneficiary);

    constructor(ERC20Detailed token, uint256 const) public {
        _sharesToken = token;
        X = const;
    }

    // Access
    modifier onlyToken() {
        require(msg.sender == address(_sharesToken), "Only the token allowed");
        _;
    }

    // Receive and collect funds
    function() external payable {}
    function collect(address tokenAddress) public onlyOwner {
        if (tokenAddress == address(0)) {
            address(uint160(owner())).transfer(address(this).balance);
        }
        else {
            IERC20 token = IERC20(tokenAddress);
            token.safeTransfer(owner(), token.balanceOf(address(this)));
        }
    }

    function setPaymentMethod(address beneficiary, address tokenAddress) public onlyOwnerOrTrusted {
        // Ensure he doesn't lose his unclaimed dividends
        updateAccount(beneficiary);
        require(accounts[beneficiary].amount == 0, "Withdraw the balance before changing payout token");

        // Set the new payment method
        address oldToken = accounts[beneficiary].tokenAddress;
        accounts[beneficiary].tokenAddress = tokenAddress;
        accounts[beneficiary].lastTotalDividendPoints = tokenDividends[tokenAddress].totalDividendPoints;
        
        // Move his pool of tokens to another payment method
        uint256 beneficiaryShares = _sharesToken.balanceOf(beneficiary);
        tokenDividends[oldToken].totalSupply = tokenDividends[oldToken].totalSupply.sub(beneficiaryShares);
        tokenDividends[tokenAddress].totalSupply = tokenDividends[tokenAddress].totalSupply.add(beneficiaryShares);
    }

    function dividendsOwing(address beneficiary) internal view returns(uint256) {
        Account storage account = accounts[beneficiary];
        uint256 newDividendPoints = tokenDividends[account.tokenAddress].totalDividendPoints.sub(account.lastTotalDividendPoints);
        return _sharesToken.balanceOf(beneficiary).mul(newDividendPoints).div(X);
    }

    function updateAccount(address account) public onlyOwnerOrTrusted {
        _updateAccount(account);
    }

    function _updateAccount(address account) internal {
        uint256 owing = dividendsOwing(account);
        Dividend storage dividend = tokenDividends[accounts[account].tokenAddress];
        if (owing > 0) {
            dividend.unclaimedDividends = dividend.unclaimedDividends.sub(owing);
            accounts[account].amount = accounts[account].amount.add(owing);
        }
        // Prevent new account holders to claim past dividends
        if (accounts[account].lastTotalDividendPoints != dividend.totalDividendPoints) {
            accounts[account].lastTotalDividendPoints = dividend.totalDividendPoints;
        }
    }

    // Register dividends for these payment methods
    function addDividends(address[] memory tokens) public onlyOwner {
        for (uint256 i = 0; i < tokens.length; i++) {
            address token = tokens[i];
            uint256 tokenAmount = 0;
            
            // Get the total amount to distribute
            if (token == address(0)) {
                // ETH
                tokenAmount = address(this).balance;
            }
            else {
                // ERC20
                tokenAmount = IERC20(token).balanceOf(address(this));
            }

            Dividend storage dividend = tokenDividends[token];

            // Subtract unclaimed tokens
            if (tokenAmount > dividend.unclaimedDividends) {
                tokenAmount = tokenAmount - dividend.unclaimedDividends;
                dividend.totalDividendPoints = dividend.totalDividendPoints.add(
                    tokenAmount.mul(X).div(dividend.totalSupply)
                );
                dividend.unclaimedDividends = dividend.unclaimedDividends.add(tokenAmount);
            }
        }
    }

    // Send the dividends to their accounts
    // Iterate offchain to prevent hitting the gas limit
    function disburse(address payable[] calldata beneficiaries) external onlyOwner {
        for (uint256 i = 0; i < beneficiaries.length; i++) {
            address payable acc = beneficiaries[i];
            updateAccount(acc);

            bool success = _disburse(acc);
            if (!success) {
                emit TransferFailure(acc);
            }
        }
    }

    function withdraw() public {
        _updateAccount(msg.sender);
        require(_disburse(msg.sender), "Failed to transfer ETH");
    }

    function _disburse(address payable beneficiary) internal returns (bool) {
        Account storage account = accounts[beneficiary];
        uint256 amount = account.amount;
        if (amount == 0) return true;
        
        // Set to 0 before transfering
        account.amount = 0;

        if (account.tokenAddress == address(0)) {
            // ETH disbursement
            bool success = beneficiary.send(amount);
            if (!success) {
                account.amount = amount;
            }
            return success;
        }
        else {
            // ERC20 disbursement
            IERC20 token = IERC20(account.tokenAddress);
            token.safeTransfer(beneficiary, amount);
            return true;
        }
    }

    /**
     * Changes to totalSupply
     */
    function _registerBurn(address from, uint256 amount) public onlyToken {
        _updateAccount(from);
        Dividend storage tokenDividend = tokenDividends[accounts[from].tokenAddress];
        tokenDividend.totalSupply = tokenDividend.totalSupply.sub(amount);
    }
    function _registerMint(address to, uint256 amount) public onlyToken {
        _updateAccount(to);
        Dividend storage tokenDividend = tokenDividends[accounts[to].tokenAddress];
        tokenDividend.totalSupply = tokenDividend.totalSupply.add(amount);
    }
    function _registerTransfer(address from, address to, uint256 amount) public onlyToken {
        _updateAccount(from);
        _updateAccount(to);
        if (accounts[from].tokenAddress != accounts[to].tokenAddress) {
            Dividend storage fromDividend = tokenDividends[accounts[from].tokenAddress];
            fromDividend.totalSupply = fromDividend.totalSupply.sub(amount);
            
            Dividend storage toDividend = tokenDividends[accounts[to].tokenAddress];
            toDividend.totalSupply = toDividend.totalSupply.add(amount);
        }
    }
}


contract ERC20MultiDividend is Ownable, ERC20 {
    MultiTokenDividend internal _dividend;

    constructor() internal {}

    function setDividendContract(MultiTokenDividend dividend) external onlyOwner {
        _dividend = dividend;
    }

    /**
     * Notify MultiTokenDividend of changes
     */
    function _burn(address account, uint256 value) internal {
        _dividend._registerBurn(account, value);
        super._burn(account, value);
    }
    function _mint(address account, uint256 value) internal {
        _dividend._registerMint(account, value);
        super._mint(account, value);
    }
    function _transfer(address from, address to, uint256 value) internal {
        _dividend._registerTransfer(from, to, value);
        super._transfer(from, to, value);
    }
}

contract ReitBZ is Ownable, ERC20MultiDividend, ERC20Burnable, ERC20Mintable, ERC20Pausable, ERC20Detailed {

    TokenWhitelist public whitelist;

    constructor() public
    ERC20Detailed("ReitBZ", "RBZ", 18) {
        whitelist = new TokenWhitelist();
    }

    // Distribution Functions
    // Whitelist Functions
    function transferOwnership(address newOwner) public onlyOwner {
        super.transferOwnership(newOwner);
        _addMinter(newOwner);
        _removeMinter(msg.sender);
        _addPauser(newOwner);
        _removePauser(msg.sender);
    }

    function addToWhitelistBatch(address[] calldata wallets) external onlyOwner {
        whitelist.enableWalletBatch(wallets);
    }

    function addToWhitelist(address wallet) public onlyOwner {
        whitelist.enableWallet(wallet);
    }

    function removeFromWhitelist(address wallet) public onlyOwner {
        whitelist.disableWallet(wallet);
    }

    function removeFromWhitelistBatch(address[] calldata wallets) external onlyOwner {
        whitelist.disableWalletBatch(wallets);
    }

    function checkWhitelisted(address wallet) public view returns (bool) {
        return whitelist.checkWhitelisted(wallet);
    }

    // ERC20Burnable Functions

    function burn(uint256 value) public onlyOwner {
        super.burn(value);
    }

    function burnFrom(address from, uint256 value) public onlyOwner {
        _burn(from, value);
    }

    // ERC20Mintable Functions

    function mint(address to, uint256 value) public returns (bool) {
        require(whitelist.checkWhitelisted(to), "Receiver is not whitelisted.");
        return super.mint(to, value);
    }

    // ERC20 Functions

    function transfer(address to, uint256 value) public returns (bool) {
        require(whitelist.checkWhitelisted(msg.sender), "Sender is not whitelisted.");
        require(whitelist.checkWhitelisted(to), "Receiver is not whitelisted.");
        return super.transfer(to, value);
    }

    function transferFrom(address from,address to, uint256 value) public returns (bool) {
        require(whitelist.checkWhitelisted(msg.sender), "Transaction sender is not whitelisted.");
        require(whitelist.checkWhitelisted(from), "Token sender is not whitelisted.");
        require(whitelist.checkWhitelisted(to), "Receiver is not whitelisted.");
        return super.transferFrom(from, to, value);
    }

    function approve(address spender, uint256 value) public returns (bool) {
        require(whitelist.checkWhitelisted(msg.sender), "Sender is not whitelisted.");
        require(whitelist.checkWhitelisted(spender), "Spender is not whitelisted.");
        return super.approve(spender, value);
    }

    function increaseAllowance(address spender, uint addedValue) public returns (bool success) {
        require(whitelist.checkWhitelisted(msg.sender), "Sender is not whitelisted.");
        require(whitelist.checkWhitelisted(spender), "Spender is not whitelisted.");
        return super.increaseAllowance(spender, addedValue);
    }

    function decreaseAllowance(address spender, uint subtractedValue) public returns (bool success) {
        require(whitelist.checkWhitelisted(msg.sender), "Sender is not whitelisted.");
        require(whitelist.checkWhitelisted(spender), "Spender is not whitelisted.");
        return super.decreaseAllowance(spender, subtractedValue);
    }

}