Contract Source Code:

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/utils/Counters.sol";
import "@openzeppelin/contracts/utils/cryptography/MerkleProof.sol";

/*
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMWX0kxddxk0NNX0kxdodxOKWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWWNNNWWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMW0d:'........,;'...'''..':xXMMMWNKOxxdxkOKNMMMMMMMWNXXXXNWMMMMMMMMWNK000XNWMMMWXKOkkkdlclokKWMMMMWXOkxxxxxxOKWNKOxdooodxOKNWMMMMMMMMMMWXko:;;;;;:odxkOXWMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMNOc..... ......,:ldkO000kdc..;kKkl;'.......';oONWXOoc;,''',:okKWMMNOl,....';lkXXd,......,;;..'oXMNkc'.........':;...',,''...;oO0Oxxk0XN0l'..............':xXWMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMWKl...........,lk0KKKXKKKKXXKk;..'..;ldkOOOkdl,..:c,..,:loolc;..'cOKl..;odxdl:..,;.....'lk0KKOl..cx:.....'cdkOko,..;dO0000Okxl,........,;..... ..;ldkOOOkdc'.,dXXkoox0WMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMWk,... .. ...;d0KKKXK0xc;o0XKKKO:..;xKKXKXKXKXK0x;...:k0KXKKXKKOd;..'..c0XXKXXKk;.......oKKKKKX0l.......'oOKKXKKKd'.:0XKKKKKKKK0l..,xkxo;......'lkKKXKKKKKXKOc..,,..'.'oXMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMNd..........,d0KKOddoc,..;dKXKKXKx'.;OXKXKXKKXXXKK0o'.,xKXKKKKXKKK0d,. 'xKKKKKKKXO;.... .dKKKKKKXx' ....;kKXXKKKKKx'.:0XKKKKKKXKX0:.'xKXK0x;...;kKXXKKKKKKKKKKKd'..,xOl..lXMMMMMMMMMMMMMMM
MMMMMMMMMMMMMNd..... ....cOKKX0l... .;x0KXKKKKX0c..dKKKKKK0xdOKKKKx,.,x0KKXXK0xldOOc..c0KKKKKXKKd. ....oKXKKKXKO;....,xKXXXKKKK0c..oKXXKKXKXKKX0:..xKKKKK0l..:OXXKKKKKKKKXXKKKx;;dKX0c..kMMMMMMMMMMMMMMM
MMMMMMMMMMMMWx..........l0KKKKK0x;. .dKKKKKKKKKKl..oKXKKKOc.'dKKKXKd'..';lddl;..:OK0l..c0XKKKKKXk, ....:0XKKKKKO;....dKXKXXKKXKd..:OXKXKOoccloo;..c0KOk0KX0c..l0XKKXK0kk0XKKKKKKKKKXKd..dWMMMMMMMMMMMMMM
MMMMMMMMMMMMO,.........l0KKKKKX0o...,kXKKKKKKXXKl..:dxkxl,..l0XKKKX0l...'.......l0KX0c..oKXKKKKXO;.....,kXKKKKXO;. .l0XXXKKKKKd'..dKKKX0c.  ...';oOkl'.lKKXO;.'xKKKK0l..oKXKKKKKXKKXKo..dWMMMMMMMMMMMMMM
MMMMMMMMMMMXc.........:0XKKKXKKd....,kXXKKKKKKX0:..,..... ..c0XKXKKXk,.,dl.......oKXXk,.,kKXKKKXO;.. ...dKKXXKXk,..;OKKKXKKK0o'. 'xKKKXO;... .lx:,,...,xKKKKx'.:OXXKd. .;OXXKKKKKXKK0c..kMMMMMMMMMMMMMMM
MMMMMMMMMMWx.........,kKKKKKKXk,... 'xKKKKKKKXKx,.;kx;.......c0XKKXX0l..oO:......'xKXKo..lKKKKXXk,.. ...lKXXKKKx' .dKKKKKXKk:....,kXKXXk,.....cko,.....:OKXK0l..oKX0c.  .oKKKKKKKXXKx,.:KMMMMMMMMMMMMMMM
MMMMMMMMMMK:....... .lKXKKKKX0c.... .lKKKXKKXK0c..oK0c........oKXKKKKd..c0k,......:OXXk,.;OXKKKKd. .....:0KKXKKo..;x0KKKK0o'.....,kXKKXx' ....;OXx' ....:OXKKk,.;OXO;....'d0XXKKKXKx;.'kWMMMMMMMMMMMMMMM
MMMMMMMMMMk'........,kXXKKKXKk,......'dKKKKKKOc..:OXO;........;OXKKKXx'.:00:..... .dKX0:.'xXXKX0c. .....,kXXKx:.....'o0Kk:.......;OXKKKd. ... 'xXO;......lKKK0c..dKk'.;d:..:x000Odc..'kWMMMMMMMMMMMMMMMM
MMMMMMMMMNo.... ....c0XKXXKXKo. .......::;;::,..lOKKx' ........dKXXKXk,.;OKc. .....c0XKl..oKKKXk,...... 'xXK0o;:looookKx'........:OXKKKd. ... .dK0:......,kXKKo..lKx'.:00o,..','......oNMMMMMMMMMMMMMMMM
MMMMMMMMMX:.........oKKXXXKX0c..........';:;'..'dKKKo. ...... .oKXKKXk'.;O0:. .....;OXKo..oKKXKo. ... . .xXKKKKKKOOOOKKx,. ......:OKKKKo. ... .dK0c.......oKKKx'.:0O:.c0XK0xolccldkOc..dWMMMMMMMMMMMMMMM
MMMMMMMMM0;....... 'xKKKKKKXO;.......,lk0KKKOd,.'dK0c. ...... .oKXKKKx..c0k,...... 'xKKo..oKXKO;.........cO0KKxc,'..;xKKx;.......:OKXKKo. ... .dX0c.......oKXXk,.;kOkxOKKKK00KXXXXKKk,.;KMMMMMMMMMMMMMMM
MMMMMMMMMO,........,kXKKKKKXO;......:OKKKKKXKKx,.;k0:........ .oKKKXKo..lKd. ......,kX0c..dKKKl. ..........;dOd:;...:OKKKOl......:OXKKKo. ..  'xX0c.......dKKXO;...''';cx0k;,dKKKKKXKl..kMMMMMMMMMMMMMMM
MMMMMMMMMO,........;OXKKKKXXO;.....;OXXKKXKKKX0c..d0:........ .dKKKXO:.'x0c........;OXO:.'xXKx'...;lodxkkd:..;xKO:..:OXXKXKd'. ..:0XKXKl. ....;OXO:......c0XKXk,..:llc,..,,..oKXKKKXKo..xWMMMMMMMMMMMMMM
MMMMMMMMM0,........,kXKKKKKX0c.....oKKKKKXKKXXKo..l0l. ..... .,kXXXKx'.:00:........oKKx'.:OXO:..ckKKXXXKKKKx,.'d0c. 'xXKKKKKx'...:0XKXKl. .. .c0Kd' ....:OKKKXk,.;OXKK0x;.. .dKKXKKXKo..dWMMMMMMMMMMMMMM
MMMMMMMMM0;....... 'xXKKKKKXKo. . 'xXKKKKKKKKXKo..oKx'...... .oKKKXO:..dKKo. .....l0X0c..oKKd..c0XKKXKKXXKKKx,.,xl. .lKKKKKXKx'..lKXXXKl......oK0:....;d0KKKXKd..c0XKKKKO:. 'xXKXKKXKo..xWMMMMMMMMMMMMMM
MMMMMMMMMK:....... .dKKKKKKKXk,.. 'xXKKKKKKKKX0:..dK0o.. ...'o0XKKKo..c0XK0o,..,:x0KKx'.;OXKkllOKKKKKKKKKXKKKo..cl. .;OXXKKKKKd'.;kKXXKl.....'xXKxccok0KKKKKKKl..oKXKKKKXk,..dKKKXKK0c.'kMMMMMMMMMMMMMMM
MMMMMMMMMNc.........:0XKKKKK0k:.  .oKKKXKKXKKKx'.;OXXKxc;,;lkKXKKKd'.;kKKKKK0OO0KKKXO;.'dKXKKKKXKKKKKKKKKKKKXk,.;c.  .oKXKKKKKKo..:OKKKl.....:OXKXKKXKKKXKKKKk,.,kKXKKKKKKd;ckKKKXKKO;.;0MMMMMMMMMMMMMMM
MMMMMMMMMWd..........dKKKKKk:......,xKKXXKKKXO:..dKKKKXKK0KKKKKKKd'.,kKXXXKKKXKKKKKO:..o0KXKXKKKKKKKKKKKKKKKXk'.;c.. .,kKKXKKKK0l..lKXKd'.....ckKKKXXKKKXKKKO:..oKKKKXXKKKKKKKKKXKKKd..lNMMMMMMMMMMMMMMM
MMMMMMMMMM0,.........,kKKXKOdodxdc'..l0XXKKX0c..l0XKKKKKKKKXKKK0o..;kKXXKKKKKKKKKKk:..l0XKKKXKKXKKKKKKXKKKXX0l..lo. . .;kKKKKKKKO;.'xXXKOxxdl,..oKXKKKKKKKKk:..l0XX0xox0KXKXKKXXKKKk,.;0MMMMMMMMMMMMMMMM
MMMMMMMMMMNl........ .;kKKKKKKXKKKOdld0XKKKOc..c0KXKKKKKKKKXKKk:..:OKKKXKKKKKKKX0d,.'o0K0dccok0KXKKKKKKKKXKkc..:kl. ....;xKKXKKXKl..oKXKKKKKXx'..cx0KKKK0kl'..c0XX0l...,okKKXKKXK0o,.,OWMMMMMMMMMMMMMMMM
MMMMMMMMMMM0;..........;xKXKKKKKKKKXXKKXKKk;. .cOKKKKKKKKKKKkc'...ckKXXKKKXKKK0x:..,x00kc.. ..,cokO00KK0Oxc'...::... .. ..cx0KKKk;..dKKKKK0Od;.....,cllc,.. ...:ll;...  ..;clllc:'..;0WMMMMMMMMMMMMMMMMM
MMMMMMMMMMMWk'..........'lOKKXKKKKKKKKKKkc......':okO000Oxl;........:oxOOOOkdc,.. ..;;,... .......',,,,'....................';:;'...;cc::;,........ ...  ... .... ...... .. .... ...lNMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMWk,............:oxO0KKKK0ko:.. .........',,'......... .. ...''..................  . ....  ................  .... .  ..... ..  .  ... .. ...........  ....... ..........'kWMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMW0:...............,;;;;'....'',,,,''......... ... ..',;;;;;,'..................',;;,...... ............,:::,...............';:ccc:;.............,;:;'................;kWMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMXd,................':loxkOO000K00Okdc,.........,lxO0KKKKK0Oko:'...........'lxO0KKKOo,.. ..........;oO0KKK0xc........ ..cx0KKKKXKKx'........'lk0KKKOd:..'ldc;''',;lkXMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMWXxc;'...... ...'o0KKKXKKKKKKKKKXXXK0o......'oOKXXKKXKKKKKXXKOl'........lOKXKOkOKKKOxl..........c0KXKKKKKKKd'........:0XKKKKKKKXk,.......:kKXKKKKKX0d,.,kNNXKXNWMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMWNKKOc..  ...dKXKKKKKKKKKKKKKXKKKK0l.  .'xKKKKKKKXKKKKXKKKKKo. ....,xKKKOl'.'o0KKXKo.........dKKKKXKKKXKKo........,kXKKKKKKKKd..... .cOKKKKKKKKKKKk;.'kWMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMWk'......:0XKKKKKXXKKKKKKKKKKKXKl. ..:0XXKKKK000KXKKXKKKKd. ...'xKXXO:. ..,kXKKK0l. .... .oKXKKXKKXKKXO;........lKKKKKKKK0c......;OKKKKKKKKKKKKKk,.;0MMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMK:..... .oKXKKKKKKKKKKXXKOooOK0o'.....;lllcc;'':kKKKKXXKO:.....oKXKKo. ....oKXKKXO;. .....c0XXKKKXXKKX0c. ......,kXKKXKKXk,.....,xKKKKKKKKXKKXXXKl..dWMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMk.....  .oKKKXKKKKOllkKXKl..';,...... .... ..;cdOK0kdolc'.....c0XKXk,......c0XKKXKo. .....;kXKKXXXKKKKKl. ..... .dKKKXKKKd. .. .oKKKKKKKKKKXXKKKO:..kWMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMNo........;OKKKKKXO:..dKKKo. .  ............,d0XKKO:..........,kKKKKd.......'xKKKXXk,..... .dKXKXKKKKKK0c.........lKXXKKKKo. . .c0KKXKKKKKKKKKXKx;..dNMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMNl.........;dOKK0k:..c0XKKd. ....;oo:......,xKXKKKo. ....... .lKXKXKl.. .....:OXXKK0:.......lKXKKKKKKKKO;....... .c0XKKKXKc.. .;OKKXKKKKKKKKKKkc...'OMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMNo...........',;,...l0XKKKx. ...c0XX0o.....dKXKXX0c..........'kXKKKKd'.......:OXXKKKl. .....c0XKKKKKKXKx'....... .c0XKKKKO:. .'oO0KXKKKKKKKKx:......cXMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMO'...........  ...dKKKKKKx' ..;OKKXK0:...:OXKKXX0:..........c0XKKXXKOdddxkkO0KXXKKKo.......:OXKKXKKKK0l. ...... .lKX0o:,'.......,dKKKKKK0d:........;0MMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMNx'... ..........;OKKKKKXx'  .oKXXKKKd. .oKKKKKX0:........ .oKKKKKKKKKKKXXKKKKXKKKKd. .....;OXKKKKKKXk,..........lKX0l;:cllooooookKKKKOo;..........lXMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMW0l;'...........c0XKXKKXk'  'kXKKKKXx' ,kKKKKXX0c. . .... 'xXKKKKXXKK0xkKKKKKKXKKKx. .... ,kKKXKKKXKo. .. ......:dxO0KKXK0OkO0KKXXKkc'...........cKMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMWNXKx'........lKKKXKKXk, .;OKKKKKXk, ;OXXKKKXKl........ ,kXKKKXKKX0c.;kXKKKKKKKXx' .... ,kXXKKKKXO:. .............,cd0x,...;xKXKd..... ......;xNMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMMM0,........oKKKKKKXO:..c0XKKKKXOc'l0XKXKKXKo. .......;OKKKKKKXXO;.,kXXKKKKKKXx' .....,kXKKKKKKx'..  ...;coxxxdl;..;ll,...l0XKkl,.......,lONMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMK;...... .lKKKKKKKKk:;xKKKKKKXK000KKKKKKKKx' .......:0XKKKKKKXk,.;OXXKKXKKKKx.......,kXKXKKKKl.....;okKKKKXKXKKx;..lo' ..oKXKK0kdc,...lKWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMXc...... .lKKKKKKKXKKKKKXXKKKKXKKKKKKKKKXXO;........c0XKKKKKKXk;.,k000KXXKKKd. .....;OXKXKKXO;...;x0KKKKKKKKKXXKOc..,'...'dKKKKXXK0xc'.'o0WMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMWo........:0KXXKKKXKXK0OkkxkkkO0KKKKKKKKXX0c........c0XKKKKKKX0:..,,',cox0KKo. .....:OKKKKKXk, .o0XKKKKKKKKKKKKXX0c.......,xKKKKKXXKKOo,.'oXMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMx........,kXKKKKKKOo:,'.......'l0XKKKKKKKKo. ......,d0KXXKKKKKo...:c,...o0Kl..... .:OKKKKXXx'.c0XKKKKKKKKKKKKKKKKk,.......;kKXKKXXXKKKOl'.;OWMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMO,........oKXKKKKKd,,;l;. .;oold0KKKKKKKKXx'.........':d0KKKKK0xdkKKO;..,kKo..';:,..;xKXKKX0xdOKKKKKKKKKKKKXKKKKX0:.... ...;kKKKKKKKKKXKx,.,kWMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMMWO:.........;OXKKKKKK00KKd. .;OXXKKKKKKKKKKXO:...;dkOxo;..:OXXKKKXXXKX0:..'xX0kxOKK0x,.'xKKKKXKKKKKKKKKKKKKKKKKKKKXO;.',. ....,xKKKXKKKKKXKk,.;0MMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMNd'........ .'dKXXKKKKXXKKd. ..c0KKKKKKKKKKKX0c..;OKKKXKKkod0XKKKKKKKKKk,..,kKXXKKKKX0c..oKXKKXKd:;lk0KXKKKKKKKKXXKOc..co' ......l0KKKKKKXKKKl..xMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMNd..........:ld0KKXXKKKXKK0c.....;x0KXKKKKKKKXKl..oKKKKKKKKKXKKKKKKKKXKk:. .oKKXKKKKKOl..;OXXXXKo.. ..;ldO0KKKK0Oxoc'..lOx'........;d0KKKKKKXO;.,OMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMO,....... .dKXXKKXKKKKKXKKo. ......;ok0KXXXXXKO;..oKXKKKKKXKKKKKXKKKK0d,..;o0KKK0Okdc'...,oxkxo:..........,;;:;'.....'ldo;...........;d0KKXKk:..dNMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMWo......   .o0KKXXKKKKKKKOl...... .. ..,:lloool,...'cdk0KKKKXKKKXKK0xl,....,;;;;;,'........................... .........................,cooc'..:KMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMWo........ ..,coxkkkkkxo:'. ............ ..... ........,;cloodddoc:'.........  .......................................... .............. .... ..:KMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMWk'...... ..............................................  .......  .................................................. .... .............. ......;KMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMNd......................':................................................  ........................................ .....:l;..................cXMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMNk;...... ..... .......xN0l'...............':,....................................................,,........';,.........lXWNOo;..............,OWMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMNkc'...............,kNMMWKxc,...........c0WXOdc;'........ ......cdoc;'.......';lxOkoc:,''''',:oONX0xdllloxKNXOdocccld0WMMMMMNOdc,........;o0WMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWXOdl:;,'''',;:okXWMMMMMMWN0kdlc:ccld0NMMMMMMNX0kdoc:;,,,,:ld0WMMWNXK000000XNWMMMMWWNXXXXXNWMMMMMMMMMMMMMMMMMMMWMMMMMMMMMMMMMWNKOkxxkOKNWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWNXXXXXXNWMMMMMMMMMMMMMMMMMWWMMMMMMMMMMMMMMMMMMWWNNNNWWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM

I see you nerd! ⌐⊙_⊙
*/

contract CoolKidsWalk is ERC721, Ownable {
    using Counters for Counters.Counter;

    Counters.Counter private _tokenIdCounter;
    uint256 public maxTokenSupply;

    uint256 public constant MAX_MINTS_PER_TXN = 3;
    uint256 public mintPrice = 0.055 ether;
    uint256 public maxPresaleMintsPerWallet = 2;

    bool public preSaleIsActive = false;
    bool public saleIsActive = false;
    mapping (address => uint256) public presaleMints;

    bool public isLocked = false;
    string public baseURI;
    string public provenance;

    address[5] private _shareholders;
    uint[5] private _shares;

    // replace with merkle root
    bytes32 public merkleRoot = 0xa7226142b67f7c1b77b3997e9cfbb8331d2e518be561419d7d4607b3fe5bafa4;

    event PaymentReleased(address to, uint256 amount);

    constructor(string memory name, string memory symbol, uint256 maxCKWSupply) ERC721(name, symbol) {
        maxTokenSupply = maxCKWSupply;

        _shareholders[0] = 0xaf705c1790719Dbe05663989402ff239f30AeF89; // Coolest Kid
        _shareholders[1] = 0xDc8Eb8d2D1babD956136b57B0B9F49b433c019e3; // Treasure-Seeker
        _shareholders[2] = 0x54d2df18A8445aFA139AE7Cc9423b7eeeB29d08d; // iwakvisual
        _shareholders[3] = 0x6812a0E76607bF63e558cFF5A373EF20d078A3a8; // TheButch
        _shareholders[4] = 0x4Fe33D85730b92640aC20916E72e3b4fd3c4CE26; // Project Wallet

        _shares[0] = 3000;
        _shares[1] = 3000;
        _shares[2] = 3000;
        _shares[3] = 500;
        _shares[4] = 500;
    }

    function setMaxTokenSupply(uint256 maxCKWSupply) external onlyOwner {
        require(!isLocked, "Locked");
        maxTokenSupply = maxCKWSupply;
    }

    function setMintPrice(uint256 newPrice) external onlyOwner {
        mintPrice = newPrice;
    }

    function setMaxPresaleMintsPerWallet(uint256 newLimit) external onlyOwner {
        maxPresaleMintsPerWallet = newLimit;
    }

    function setMerkleRoot(bytes32 newMerkleRoot) external onlyOwner {
        merkleRoot = newMerkleRoot;
    }

    function withdrawForGiveaway(uint256 amount, address payable to) external onlyOwner {
        Address.sendValue(to, amount);
        emit PaymentReleased(to, amount);
    }

    function withdraw(uint256 amount) external onlyOwner {
        require(address(this).balance >= amount, "Insufficient balance");
        
        uint256 totalShares = 10000;
        for (uint256 i = 0; i < 5; i++) {
            uint256 payment = amount * _shares[i] / totalShares;

            Address.sendValue(payable(_shareholders[i]), payment);
            emit PaymentReleased(_shareholders[i], payment);
        }
    }

    /*
    * Mint reserved NFTs for giveaways, devs, etc.
    */
    function reserveMint(uint256 reservedAmount, address mintAddress) public onlyOwner {        
        _mintMultiple(reservedAmount, mintAddress);
    }

    function _mintMultiple(uint256 numTokens, address mintAddress) internal {
        require(_tokenIdCounter.current() + numTokens <= maxTokenSupply, "Exceeds max supply");

        for (uint256 i = 0; i < numTokens; i++) {
            _tokenIdCounter.increment();
            _safeMint(mintAddress, _tokenIdCounter.current());
        }
    }

    /*
    * Pause sale if active, make active if paused.
    */
    function flipSaleState() external onlyOwner {
        saleIsActive = !saleIsActive;
    }

    /*
    * Pause pre-sale if active, make active if paused.
    */
    function flipPreSaleState() external onlyOwner {
        preSaleIsActive = !preSaleIsActive;
    }

    /*
    * Lock provenance, supply and base URI.
    */
    function lockProvenance() external onlyOwner {
        isLocked = true;
    }

    function totalSupply() external view returns (uint256) {
        return _tokenIdCounter.current();
    }

    function hashLeaf(address presaleAddress) public pure returns (bytes32) {
        return keccak256(abi.encodePacked(
            presaleAddress
        ));
    }

    /*
    * Mint Cool Kids Walk NFTs, woot!
    */
    function adoptCoolKids(uint256 numberOfTokens) public payable {
        require(saleIsActive, "Sale not live");
        require(numberOfTokens <= MAX_MINTS_PER_TXN, "Exceeds max per txn");
        require(mintPrice * numberOfTokens <= msg.value, "Incorrect ether value");

        _mintMultiple(numberOfTokens, msg.sender);
    }

    /*
    * Mint Cool Kids Walk NFTs during pre-sale
    */
    function presaleMint(uint256 numberOfTokens, bytes32[] calldata merkleProof) public payable {
        require(preSaleIsActive, "Presale not live");
        require(presaleMints[msg.sender] + numberOfTokens <= maxPresaleMintsPerWallet, "Exceeds max per wallet");
        require(mintPrice * numberOfTokens <= msg.value, "Incorrect ether value");

        // Compute the node and verify the merkle proof
        require(MerkleProof.verify(merkleProof, merkleRoot, hashLeaf(msg.sender)), "Invalid proof");

        presaleMints[msg.sender] += numberOfTokens;

        _mintMultiple(numberOfTokens, msg.sender);
    }

    function _baseURI() internal view virtual override returns (string memory) {
        return baseURI;
    }

    function setBaseURI(string memory newBaseURI) public onlyOwner {
        require(!isLocked, "Locked");
        baseURI = newBaseURI;
    }

    /*     
    * Set provenance once it's calculated.
    */
    function setProvenanceHash(string memory provenanceHash) public onlyOwner {
        require(!isLocked, "Locked");
        provenance = provenanceHash;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/cryptography/MerkleProof.sol)

pragma solidity ^0.8.0;

/**
 * @dev These functions deal with verification of Merkle Trees proofs.
 *
 * The proofs can be generated using the JavaScript library
 * https://github.com/miguelmota/merkletreejs[merkletreejs].
 * Note: the hashing algorithm should be keccak256 and pair sorting should be enabled.
 *
 * See `test/utils/cryptography/MerkleProof.test.js` for some examples.
 */
library MerkleProof {
    /**
     * @dev Returns true if a `leaf` can be proved to be a part of a Merkle tree
     * defined by `root`. For this, a `proof` must be provided, containing
     * sibling hashes on the branch from the leaf to the root of the tree. Each
     * pair of leaves and each pair of pre-images are assumed to be sorted.
     */
    function verify(
        bytes32[] memory proof,
        bytes32 root,
        bytes32 leaf
    ) internal pure returns (bool) {
        return processProof(proof, leaf) == root;
    }

    /**
     * @dev Returns the rebuilt hash obtained by traversing a Merklee tree up
     * from `leaf` using `proof`. A `proof` is valid if and only if the rebuilt
     * hash matches the root of the tree. When processing the proof, the pairs
     * of leafs & pre-images are assumed to be sorted.
     *
     * _Available since v4.4._
     */
    function processProof(bytes32[] memory proof, bytes32 leaf) internal pure returns (bytes32) {
        bytes32 computedHash = leaf;
        for (uint256 i = 0; i < proof.length; i++) {
            bytes32 proofElement = proof[i];
            if (computedHash <= proofElement) {
                // Hash(current computed hash + current element of the proof)
                computedHash = _efficientHash(computedHash, proofElement);
            } else {
                // Hash(current element of the proof + current computed hash)
                computedHash = _efficientHash(proofElement, computedHash);
            }
        }
        return computedHash;
    }

    function _efficientHash(bytes32 a, bytes32 b) private pure returns (bytes32 value) {
        assembly {
            mstore(0x00, a)
            mstore(0x20, b)
            value := keccak256(0x00, 0x40)
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Strings.sol)

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Counters.sol)

pragma solidity ^0.8.0;

/**
 * @title Counters
 * @author Matt Condon (@shrugs)
 * @dev Provides counters that can only be incremented, decremented or reset. This can be used e.g. to track the number
 * of elements in a mapping, issuing ERC721 ids, or counting request ids.
 *
 * Include with `using Counters for Counters.Counter;`
 */
library Counters {
    struct Counter {
        // This variable should never be directly accessed by users of the library: interactions must be restricted to
        // the library's function. As of Solidity v0.5.2, this cannot be enforced, though there is a proposal to add
        // this feature: see https://github.com/ethereum/solidity/issues/4637
        uint256 _value; // default: 0
    }

    function current(Counter storage counter) internal view returns (uint256) {
        return counter._value;
    }

    function increment(Counter storage counter) internal {
        unchecked {
            counter._value += 1;
        }
    }

    function decrement(Counter storage counter) internal {
        uint256 value = counter._value;
        require(value > 0, "Counter: decrement overflow");
        unchecked {
            counter._value = value - 1;
        }
    }

    function reset(Counter storage counter) internal {
        counter._value = 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC721/ERC721.sol)

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./extensions/IERC721Metadata.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/Strings.sol";
import "../../utils/introspection/ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        _setApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);

        _afterTokenTransfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);

        _afterTokenTransfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);

        _afterTokenTransfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Emits a {ApprovalForAll} event.
     */
    function _setApprovalForAll(
        address owner,
        address operator,
        bool approved
    ) internal virtual {
        require(owner != operator, "ERC721: approve to caller");
        _operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}