Contract Source Code:
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.19;
import "https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.9.0/contracts/token/ERC20/ERC20.sol";
import "https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.9.0/contracts/access/Ownable.sol";
/**
* Website: https://anonzk.io/
* Twitter: https://twitter.com/AnonAZK
* Telegram: https://t.me/AnonZKPortal
* Docs: https://docs.anonzk.io/
*
* ▄████████ ███▄▄▄▄ ▄██████▄ ███▄▄▄▄ ▄███████▄ ▄█ ▄█▄
* ███ ███ ███▀▀▀██▄ ███ ███ ███▀▀▀██▄ ██▀ ▄██ ███ ▄███▀
* ███ ███ ███ ███ ███ ███ ███ ███ ▄███▀ ███▐██▀
* ███ ███ ███ ███ ███ ███ ███ ███ ▀█▀▄███▀▄▄ ▄█████▀
* ▀███████████ ███ ███ ███ ███ ███ ███ ▄███▀ ▀ ▀▀█████▄
* ███ ███ ███ ███ ███ ███ ███ ███ ▄███▀ ███▐██▄
* ███ ███ ███ ███ ███ ███ ███ ███ ███▄ ▄█ ███ ▀███▄
* ███ █▀ ▀█ █▀ ▀██████▀ ▀█ █▀ ▀████████▀ ███ ▀█▀
* ▀
*/
interface IUniswapV2Router02 {
function factory() external pure returns (address);
function WETH() external pure returns (address);
function swapExactTokensForETHSupportingFeeOnTransferTokens(
uint256 amountIn,
uint256 amountOutMin,
address[] calldata path,
address to,
uint256 deadline
) external;
function addLiquidityETH(
address token,
uint256 amountTokenDesired,
uint256 amountTokenMin,
uint256 amountETHMin,
address to,
uint256 deadline
) external payable returns (uint256 amountToken, uint256 amountETH, uint256 liquidity);
}
interface IUniswapV2Factory {
function createPair(address tokenA, address tokenB) external returns (address pair);
}
contract AnonZK is ERC20, Ownable {
// events
event UpdateUniswapV2Router(address indexed newAddress, address indexed oldAddress);
event ExcludeFromFees(address indexed account, bool excluded);
event ExcludeFromMaxTransaction(address indexed account, bool excluded);
event SetAutomatedMarketMakerPair(address indexed pair, bool indexed value);
event SwapAndLiquify(uint256 tokensSwapped, uint256 ethReceived, uint256 tokensIntoLiquidity);
// errors
error ERC20FromZero();
error ERC20ToZero();
error TradingNotActive();
error BuyTransferExceedsMaxTransactionAmount();
error BuyExceedsMaxWallet();
error SellTransferExceedsMaxTransactionAmount();
error MaxWallet();
error FeeTooHigh();
error SwapAmountTooLow();
error SwapAmountTooHigh();
error MigrationNotEnabled();
error SupplyExceeded();
// constants
uint256 public constant MAX_SUPPLY = 10 * 1e6 ether;
address constant DEV_WALLET = 0xC8aFc08747213Da2Ab68373E5B261dd304390270;
IUniswapV2Router02 public constant UNISWAP_V2_ROUTER =
IUniswapV2Router02(0x7a250d5630B4cF539739dF2C5dAcb4c659F2488D);
address public immutable UNISWAP_V2_PAIR;
address private constant BURN_ADDRESS = address(0xdEaD);
address private constant AZKV1 = 0x5408245a4D7c685F59cE6D3b8B35916dd6c11A99;
uint256 private constant INITIAL_MAX_TRANSACTION_AMOUNT = 2 * 1e5 ether; // 2% from total supply maxTransactionAmountTxn
uint256 private constant INITIAL_MAX_WALLET = 2 * 1e5 ether; // 2% from total supply maxWallet
uint256 private constant INITIAL_BUY_LIQUIDITY_FEE = 5;
uint256 private constant INITIAL_BUY_DEV_FEE = 5;
uint256 private constant INITIAL_SELL_LIQUIDITY_FEE = 10;
uint256 private constant INITIAL_SELL_DEV_FEE = 10;
uint256 private constant MAX_TOTAL_FEE = 10;
// states
bool public tradingEnabled = false;
bool public swapEnabled = false;
bool public limitsEnabled = true;
bool public migrationEnabled = false;
uint256 public maxTransactionAmount;
uint256 public maxWallet;
uint256 public swapTokensAtAmount;
uint256 public buyLiquidityFee;
uint256 public buyDevFee;
uint256 public sellLiquidityFee;
uint256 public sellDevFee;
uint256 public tokensForLiquidity;
uint256 public tokensForDev;
bool private isSwapping;
// - exclude from fees and max transaction amount
mapping(address => bool) public isExcludedFromFees;
mapping(address => bool) public isExcludedMaxTransactionAmount;
// - store addresses that a automatic market maker pairs. Any transfer *to* these addresses
// could be subject to a maximum transfer amount
mapping(address => bool) public automatedMarketMakerPairs;
// constructor
constructor() ERC20("AnonZK", unicode"AZK") {
// create uniswap pair
address _uniswapPair =
IUniswapV2Factory(UNISWAP_V2_ROUTER.factory()).createPair(address(this), UNISWAP_V2_ROUTER.WETH());
UNISWAP_V2_PAIR = _uniswapPair;
// initialize states
maxTransactionAmount = INITIAL_MAX_TRANSACTION_AMOUNT;
maxWallet = INITIAL_MAX_WALLET;
swapTokensAtAmount = MAX_SUPPLY / 1000; // 0.1% swap wallet
buyLiquidityFee = INITIAL_BUY_LIQUIDITY_FEE;
buyDevFee = INITIAL_BUY_DEV_FEE;
sellLiquidityFee = INITIAL_SELL_LIQUIDITY_FEE;
sellDevFee = INITIAL_SELL_DEV_FEE;
// exclude from paying fees or having max transaction amount
excludeFromFees(msg.sender, true);
excludeFromFees(DEV_WALLET, true);
excludeFromFees(address(this), true);
excludeFromFees(BURN_ADDRESS, true);
excludeFromFees(address(0), true);
excludeFromMaxTransaction(address(UNISWAP_V2_ROUTER), true);
excludeFromMaxTransaction(address(_uniswapPair), true);
excludeFromMaxTransaction(msg.sender, true);
excludeFromMaxTransaction(DEV_WALLET, true);
excludeFromMaxTransaction(address(this), true);
excludeFromMaxTransaction(BURN_ADDRESS, true);
excludeFromMaxTransaction(address(0), true);
// set amm pair
_setAutomatedMarketMakerPair(address(_uniswapPair), true);
}
// receive
receive() external payable {}
// migrate
function migrate(uint256 amount) external {
if (!migrationEnabled) revert MigrationNotEnabled();
uint256 _totalSupply = totalSupply();
if (_totalSupply + amount > MAX_SUPPLY) revert SupplyExceeded();
IERC20(AZKV1).transferFrom(msg.sender, DEV_WALLET, amount);
_mint(msg.sender, amount);
}
// transfer
function _transfer(address from, address to, uint256 amount) internal override {
bool isBuying = automatedMarketMakerPairs[from] && !isExcludedMaxTransactionAmount[to];
bool isSelling = automatedMarketMakerPairs[to] && !isExcludedMaxTransactionAmount[from];
bool isOwner = from == owner() || to == owner();
bool isBurning = to == BURN_ADDRESS;
// check limits
if (limitsEnabled && !isSwapping && !isOwner && !isBurning) {
if (!tradingEnabled) {
if (!isExcludedFromFees[from] && !isExcludedFromFees[to]) {
revert TradingNotActive();
}
}
if (isBuying) {
if (amount > maxTransactionAmount) {
revert BuyTransferExceedsMaxTransactionAmount();
}
if (amount + balanceOf(to) > maxWallet) {
revert BuyExceedsMaxWallet();
}
} else if (isSelling) {
if (amount > maxTransactionAmount) {
revert SellTransferExceedsMaxTransactionAmount();
}
} else if (!isExcludedMaxTransactionAmount[to]) {
if (amount + balanceOf(to) > maxWallet) {
revert MaxWallet();
}
}
}
// swap
if (
swapEnabled && balanceOf(address(this)) >= swapTokensAtAmount && !isSwapping
&& !automatedMarketMakerPairs[from] && !isExcludedFromFees[from] && !isExcludedFromFees[to]
) {
isSwapping = true;
_swap();
isSwapping = false;
}
// fees
uint256 fees = 0;
if (!isSwapping && !isExcludedFromFees[from] && !isExcludedFromFees[to]) {
// only take fees on buys/sells, never on wallet transfers
uint256 sellTotalFees = sellLiquidityFee + sellDevFee;
uint256 buyTotalFees = buyLiquidityFee + buyDevFee;
// on sell
if (automatedMarketMakerPairs[to] && sellTotalFees > 0) {
fees = (amount * sellTotalFees) / 100;
tokensForLiquidity += (fees * sellLiquidityFee) / sellTotalFees;
tokensForDev += (fees * sellDevFee) / sellTotalFees;
super._transfer(from, address(this), fees);
}
// on buy
else if (automatedMarketMakerPairs[from] && buyTotalFees > 0) {
fees = (amount * buyTotalFees) / 100;
tokensForLiquidity += (fees * buyLiquidityFee) / buyTotalFees;
tokensForDev += (fees * buyDevFee) / buyTotalFees;
super._transfer(from, address(this), fees);
}
}
super._transfer(from, to, amount - fees);
}
// owners only
function excludeFromMaxTransaction(address addr, bool excluded) public onlyOwner {
isExcludedMaxTransactionAmount[addr] = excluded;
emit ExcludeFromMaxTransaction(addr, excluded);
}
function excludeFromFees(address addr, bool excluded) public onlyOwner {
isExcludedFromFees[addr] = excluded;
emit ExcludeFromFees(addr, excluded);
}
function enableTrading() external onlyOwner {
tradingEnabled = true;
swapEnabled = true;
}
function removeLimits() external onlyOwner {
limitsEnabled = false;
}
function setFees(uint256 _buyLiquidityFee, uint256 _buyDevFee, uint256 _sellLiquidityFee, uint256 _sellDevFee)
external
onlyOwner
{
if (_buyLiquidityFee + _buyDevFee > MAX_TOTAL_FEE) {
revert FeeTooHigh();
}
if (_sellLiquidityFee + _sellDevFee > MAX_TOTAL_FEE) {
revert FeeTooHigh();
}
buyLiquidityFee = _buyLiquidityFee;
buyDevFee = _buyDevFee;
sellLiquidityFee = _sellLiquidityFee;
sellDevFee = _sellDevFee;
}
function setSwapTokensAtAmount(uint256 newAmount) external onlyOwner {
uint256 _totalSupply = totalSupply();
if (newAmount < _totalSupply / 100000) {
revert SwapAmountTooLow();
}
if (newAmount > (_totalSupply * 5) / 1000) {
revert SwapAmountTooHigh();
}
swapTokensAtAmount = newAmount;
}
function setSwapEnabled(bool enabled) external onlyOwner {
swapEnabled = enabled;
}
function setMaxTransactionAmount(uint256 max) external onlyOwner {
maxTransactionAmount = max;
}
function setMaxWallet(uint256 max) external onlyOwner {
maxWallet = max;
}
function clearStuckBalance() external onlyOwner {
(bool success,) = payable(msg.sender).call{value: address(this).balance}("");
require(success);
}
function clearStuckToken() external onlyOwner {
_transfer(address(this), msg.sender, balanceOf(address(this)));
}
function setEnableMigration(bool e) external onlyOwner {
migrationEnabled = e;
}
struct Airdrop {
uint256 amount;
address addr;
}
function airdrop(Airdrop[] calldata arr) external onlyOwner {
uint256 _totalSupply = totalSupply();
uint256 _amount = 0;
for (uint256 i = 0; i < arr.length; i++) {
_amount += arr[i].amount;
if (_totalSupply + _amount > MAX_SUPPLY) revert SupplyExceeded();
_mint(arr[i].addr, arr[i].amount);
}
}
// private
function _setAutomatedMarketMakerPair(address pair, bool value) private {
automatedMarketMakerPairs[pair] = value;
emit SetAutomatedMarketMakerPair(pair, value);
}
function _swapTokensForEth(uint256 tokenAmount) private {
// generate the uniswap pair path of token -> weth
address[] memory path = new address[](2);
path[0] = address(this);
path[1] = UNISWAP_V2_ROUTER.WETH();
_approve(address(this), address(UNISWAP_V2_ROUTER), tokenAmount);
// make the swap
UNISWAP_V2_ROUTER.swapExactTokensForETHSupportingFeeOnTransferTokens(
tokenAmount, 0, path, address(this), block.timestamp
);
}
function _addLiquidity(uint256 tokenAmount, uint256 ethAmount) private {
// approve token transfer
_approve(address(this), address(UNISWAP_V2_ROUTER), tokenAmount);
// add liquidity
UNISWAP_V2_ROUTER.addLiquidityETH{value: ethAmount}(
address(this), tokenAmount, 0, 0, DEV_WALLET, block.timestamp
);
}
function _swap() private {
uint256 contractBalance = balanceOf(address(this));
uint256 totalTokensToSwap = tokensForLiquidity + tokensForDev;
// nothing to swap
if (contractBalance == 0 || totalTokensToSwap == 0) {
return;
}
// swap amount
uint256 swapAmount = contractBalance;
if (swapAmount > swapTokensAtAmount * 20) {
swapAmount = swapTokensAtAmount * 20;
}
// split liquidity tokens - 0.5 keep as is, 0.5 swap to ETH
uint256 totalLiquidityTokens = (swapAmount * tokensForLiquidity) / totalTokensToSwap;
uint256 liquidityTokens = totalLiquidityTokens / 2;
uint256 devTokens = swapAmount - totalLiquidityTokens;
uint256 liquidityETHTokens = totalLiquidityTokens - liquidityTokens;
uint256 initialETHBalance = address(this).balance;
_swapTokensForEth(devTokens + liquidityETHTokens);
uint256 gainedETH = address(this).balance - initialETHBalance;
uint256 ethForLiquidity = (gainedETH * liquidityETHTokens) / (liquidityETHTokens + devTokens);
// reset states
tokensForLiquidity = 0;
tokensForDev = 0;
// add liquidity
if (liquidityTokens > 0 && ethForLiquidity > 0) {
_addLiquidity(liquidityTokens, ethForLiquidity);
emit SwapAndLiquify(devTokens + liquidityETHTokens, gainedETH, liquidityTokens);
}
// dev transfer
(bool success,) = payable(address(DEV_WALLET)).call{value: address(this).balance}("");
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
* @dev Contract module which provides a basic access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership}.
*
* This module is used through inheritance. It will make available the modifier
* `onlyOwner`, which can be applied to your functions to restrict their use to
* the owner.
*/
abstract contract Ownable is Context {
address private _owner;
event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
/**
* @dev Initializes the contract setting the deployer as the initial owner.
*/
constructor() {
_transferOwnership(_msgSender());
}
/**
* @dev Throws if called by any account other than the owner.
*/
modifier onlyOwner() {
_checkOwner();
_;
}
/**
* @dev Returns the address of the current owner.
*/
function owner() public view virtual returns (address) {
return _owner;
}
/**
* @dev Throws if the sender is not the owner.
*/
function _checkOwner() internal view virtual {
require(owner() == _msgSender(), "Ownable: caller is not the owner");
}
/**
* @dev Leaves the contract without owner. It will not be possible to call
* `onlyOwner` functions. Can only be called by the current owner.
*
* NOTE: Renouncing ownership will leave the contract without an owner,
* thereby disabling any functionality that is only available to the owner.
*/
function renounceOwnership() public virtual onlyOwner {
_transferOwnership(address(0));
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual onlyOwner {
require(newOwner != address(0), "Ownable: new owner is the zero address");
_transferOwnership(newOwner);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Internal function without access restriction.
*/
function _transferOwnership(address newOwner) internal virtual {
address oldOwner = _owner;
_owner = newOwner;
emit OwnershipTransferred(oldOwner, newOwner);
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/ERC20.sol)
pragma solidity ^0.8.0;
import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";
/**
* @dev Implementation of the {IERC20} interface.
*
* This implementation is agnostic to the way tokens are created. This means
* that a supply mechanism has to be added in a derived contract using {_mint}.
* For a generic mechanism see {ERC20PresetMinterPauser}.
*
* TIP: For a detailed writeup see our guide
* https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
* to implement supply mechanisms].
*
* The default value of {decimals} is 18. To change this, you should override
* this function so it returns a different value.
*
* We have followed general OpenZeppelin Contracts guidelines: functions revert
* instead returning `false` on failure. This behavior is nonetheless
* conventional and does not conflict with the expectations of ERC20
* applications.
*
* Additionally, an {Approval} event is emitted on calls to {transferFrom}.
* This allows applications to reconstruct the allowance for all accounts just
* by listening to said events. Other implementations of the EIP may not emit
* these events, as it isn't required by the specification.
*
* Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
* functions have been added to mitigate the well-known issues around setting
* allowances. See {IERC20-approve}.
*/
contract ERC20 is Context, IERC20, IERC20Metadata {
mapping(address => uint256) private _balances;
mapping(address => mapping(address => uint256)) private _allowances;
uint256 private _totalSupply;
string private _name;
string private _symbol;
/**
* @dev Sets the values for {name} and {symbol}.
*
* All two of these values are immutable: they can only be set once during
* construction.
*/
constructor(string memory name_, string memory symbol_) {
_name = name_;
_symbol = symbol_;
}
/**
* @dev Returns the name of the token.
*/
function name() public view virtual override returns (string memory) {
return _name;
}
/**
* @dev Returns the symbol of the token, usually a shorter version of the
* name.
*/
function symbol() public view virtual override returns (string memory) {
return _symbol;
}
/**
* @dev Returns the number of decimals used to get its user representation.
* For example, if `decimals` equals `2`, a balance of `505` tokens should
* be displayed to a user as `5.05` (`505 / 10 ** 2`).
*
* Tokens usually opt for a value of 18, imitating the relationship between
* Ether and Wei. This is the default value returned by this function, unless
* it's overridden.
*
* NOTE: This information is only used for _display_ purposes: it in
* no way affects any of the arithmetic of the contract, including
* {IERC20-balanceOf} and {IERC20-transfer}.
*/
function decimals() public view virtual override returns (uint8) {
return 18;
}
/**
* @dev See {IERC20-totalSupply}.
*/
function totalSupply() public view virtual override returns (uint256) {
return _totalSupply;
}
/**
* @dev See {IERC20-balanceOf}.
*/
function balanceOf(address account) public view virtual override returns (uint256) {
return _balances[account];
}
/**
* @dev See {IERC20-transfer}.
*
* Requirements:
*
* - `to` cannot be the zero address.
* - the caller must have a balance of at least `amount`.
*/
function transfer(address to, uint256 amount) public virtual override returns (bool) {
address owner = _msgSender();
_transfer(owner, to, amount);
return true;
}
/**
* @dev See {IERC20-allowance}.
*/
function allowance(address owner, address spender) public view virtual override returns (uint256) {
return _allowances[owner][spender];
}
/**
* @dev See {IERC20-approve}.
*
* NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
* `transferFrom`. This is semantically equivalent to an infinite approval.
*
* Requirements:
*
* - `spender` cannot be the zero address.
*/
function approve(address spender, uint256 amount) public virtual override returns (bool) {
address owner = _msgSender();
_approve(owner, spender, amount);
return true;
}
/**
* @dev See {IERC20-transferFrom}.
*
* Emits an {Approval} event indicating the updated allowance. This is not
* required by the EIP. See the note at the beginning of {ERC20}.
*
* NOTE: Does not update the allowance if the current allowance
* is the maximum `uint256`.
*
* Requirements:
*
* - `from` and `to` cannot be the zero address.
* - `from` must have a balance of at least `amount`.
* - the caller must have allowance for ``from``'s tokens of at least
* `amount`.
*/
function transferFrom(address from, address to, uint256 amount) public virtual override returns (bool) {
address spender = _msgSender();
_spendAllowance(from, spender, amount);
_transfer(from, to, amount);
return true;
}
/**
* @dev Atomically increases the allowance granted to `spender` by the caller.
*
* This is an alternative to {approve} that can be used as a mitigation for
* problems described in {IERC20-approve}.
*
* Emits an {Approval} event indicating the updated allowance.
*
* Requirements:
*
* - `spender` cannot be the zero address.
*/
function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
address owner = _msgSender();
_approve(owner, spender, allowance(owner, spender) + addedValue);
return true;
}
/**
* @dev Atomically decreases the allowance granted to `spender` by the caller.
*
* This is an alternative to {approve} that can be used as a mitigation for
* problems described in {IERC20-approve}.
*
* Emits an {Approval} event indicating the updated allowance.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `spender` must have allowance for the caller of at least
* `subtractedValue`.
*/
function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
address owner = _msgSender();
uint256 currentAllowance = allowance(owner, spender);
require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
unchecked {
_approve(owner, spender, currentAllowance - subtractedValue);
}
return true;
}
/**
* @dev Moves `amount` of tokens from `from` to `to`.
*
* This internal function is equivalent to {transfer}, and can be used to
* e.g. implement automatic token fees, slashing mechanisms, etc.
*
* Emits a {Transfer} event.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `from` must have a balance of at least `amount`.
*/
function _transfer(address from, address to, uint256 amount) internal virtual {
require(from != address(0), "ERC20: transfer from the zero address");
require(to != address(0), "ERC20: transfer to the zero address");
_beforeTokenTransfer(from, to, amount);
uint256 fromBalance = _balances[from];
require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
unchecked {
_balances[from] = fromBalance - amount;
// Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
// decrementing then incrementing.
_balances[to] += amount;
}
emit Transfer(from, to, amount);
_afterTokenTransfer(from, to, amount);
}
/** @dev Creates `amount` tokens and assigns them to `account`, increasing
* the total supply.
*
* Emits a {Transfer} event with `from` set to the zero address.
*
* Requirements:
*
* - `account` cannot be the zero address.
*/
function _mint(address account, uint256 amount) internal virtual {
require(account != address(0), "ERC20: mint to the zero address");
_beforeTokenTransfer(address(0), account, amount);
_totalSupply += amount;
unchecked {
// Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
_balances[account] += amount;
}
emit Transfer(address(0), account, amount);
_afterTokenTransfer(address(0), account, amount);
}
/**
* @dev Destroys `amount` tokens from `account`, reducing the
* total supply.
*
* Emits a {Transfer} event with `to` set to the zero address.
*
* Requirements:
*
* - `account` cannot be the zero address.
* - `account` must have at least `amount` tokens.
*/
function _burn(address account, uint256 amount) internal virtual {
require(account != address(0), "ERC20: burn from the zero address");
_beforeTokenTransfer(account, address(0), amount);
uint256 accountBalance = _balances[account];
require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
unchecked {
_balances[account] = accountBalance - amount;
// Overflow not possible: amount <= accountBalance <= totalSupply.
_totalSupply -= amount;
}
emit Transfer(account, address(0), amount);
_afterTokenTransfer(account, address(0), amount);
}
/**
* @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
*
* This internal function is equivalent to `approve`, and can be used to
* e.g. set automatic allowances for certain subsystems, etc.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `owner` cannot be the zero address.
* - `spender` cannot be the zero address.
*/
function _approve(address owner, address spender, uint256 amount) internal virtual {
require(owner != address(0), "ERC20: approve from the zero address");
require(spender != address(0), "ERC20: approve to the zero address");
_allowances[owner][spender] = amount;
emit Approval(owner, spender, amount);
}
/**
* @dev Updates `owner` s allowance for `spender` based on spent `amount`.
*
* Does not update the allowance amount in case of infinite allowance.
* Revert if not enough allowance is available.
*
* Might emit an {Approval} event.
*/
function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
uint256 currentAllowance = allowance(owner, spender);
if (currentAllowance != type(uint256).max) {
require(currentAllowance >= amount, "ERC20: insufficient allowance");
unchecked {
_approve(owner, spender, currentAllowance - amount);
}
}
}
/**
* @dev Hook that is called before any transfer of tokens. This includes
* minting and burning.
*
* Calling conditions:
*
* - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
* will be transferred to `to`.
* - when `from` is zero, `amount` tokens will be minted for `to`.
* - when `to` is zero, `amount` of ``from``'s tokens will be burned.
* - `from` and `to` are never both zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}
/**
* @dev Hook that is called after any transfer of tokens. This includes
* minting and burning.
*
* Calling conditions:
*
* - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
* has been transferred to `to`.
* - when `from` is zero, `amount` tokens have been minted for `to`.
* - when `to` is zero, `amount` of ``from``'s tokens have been burned.
* - `from` and `to` are never both zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)
pragma solidity ^0.8.0;
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
/**
* @dev Interface for the optional metadata functions from the ERC20 standard.
*
* _Available since v4.1._
*/
interface IERC20Metadata is IERC20 {
/**
* @dev Returns the name of the token.
*/
function name() external view returns (string memory);
/**
* @dev Returns the symbol of the token.
*/
function symbol() external view returns (string memory);
/**
* @dev Returns the decimals places of the token.
*/
function decimals() external view returns (uint8);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(address from, address to, uint256 amount) external returns (bool);
}