Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.23;

import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "./IGame.sol";

contract Game is IGame, Ownable, ReentrancyGuard {
    uint256 constant _gameStartTime = 24 hours;
    uint256 constant _secondsPerTokenMax = 600;
    uint256 constant _periodTimer = 72 hours;
    uint256 constant _periodsForAccountReward = 0;
    uint256 constant _tokenDecimals = 10 ** 9;
    uint256 constant _gameClaimTimer = 48 hours;  

    IERC20 immutable _token;
    uint256 _gameNumberSnap;
    uint256 _gameRewardNumberSnap;
    uint256 _gameEthForRewardTotalSnap;
    uint256 _gameTokensStackedNumberSnap;
    uint256 _secondsPerToken = 20;
    uint256 _startTime;
    uint256 _gameEndTime;
    uint256 _gameTokensStakedTotal;
    uint256 _totalStackedTokensSnap;
    uint256 _ethTotalForPeriod;
    uint256 _periodNumberSnap;
    mapping(address => AccountData) _accounts;

    constructor(address tokenAddress_) Ownable(msg.sender) {
        _token = IERC20(tokenAddress_);
    }

    modifier whenStarted() {
        require(this.isStarted(), "not started");
        _;
    }

    modifier whenNotGameClaimState() {
        require(!_isGameEnd(), "the game is in claim state now");
        _;
    }

    modifier noContracts() {
        require(msg.sender == tx.origin, "no contracts allowed");
        _;
    }

    receive() external payable {}

    function _sendEther(address to, uint256 count) internal nonReentrant {
        if (count == 0) return;
        payable(to).transfer(count);
    }

    function start() external onlyOwner {
        require(!this.isStarted());
        _startTime = block.timestamp;
        _gameEndTime = block.timestamp + _gameStartTime;
        _gameNumberSnap = 1;
    }

    function startTime() external view returns (uint256) {
        return _startTime;
    }

    function isGameEnd() external view returns (bool) {
        return _isGameEnd();
    }

    function _isGameEnd() private view returns (bool) {
        return
            _gameEndTime > 0 &&
            block.timestamp >= _gameEndTime &&
            block.timestamp < _newGameTime();
    }

    function newGameTime() external view returns (uint256) {
        return _newGameTime();
    }

    function _newGameTime() private view returns (uint256) {
        if (_gameEndTime == 0) return 0;
        return _gameEndTime + _gameClaimTimer;
    }

    function gameClaimTimer() external pure returns (uint256) {
        return _gameClaimTimer;
    }

    function isGameDirty() external view returns (bool) {
        return _isGameDirty();
    }

    function _isGameDirty() private view returns (bool) {
        return _gameEndTime > 0 && block.timestamp >= _newGameTime();
    }

    function isGameEthSnapNumberDirty() external view returns (bool) {
        return _isGameEthSnapNumberDirty();
    }

    function _isGameEthSnapNumberDirty() private view returns (bool) {
        if (!_isStarted()) return true;
        return (_gameEndTime > 0 && (_gameRewardNumberSnap != _gameNumber()));
    }

    function _isTokensStakedGameTotalDirty() private view returns (bool) {
        return _gameNumber() > _gameTokensStackedNumberSnap;
    }

    function _tryUpdateGameRewardSnap() private {
        if (block.timestamp < _gameEndTime) return;
        if (!_isGameEthSnapNumberDirty()) return;
        _gameRewardNumberSnap = _gameNumber();
        _gameEthForRewardTotalSnap = address(this).balance;
    }

    function _tryUpdateTokensStakedGameTotal() private {
        if (!_isTokensStakedGameTotalDirty()) return;
        _gameTokensStackedNumberSnap = _gameNumber();
        _gameTokensStakedTotal = 0;
    }

    function gameEthForRewardTotal() external view returns (uint256) {
        return _gameEthForRewardTotal();
    }

    function _gameEthForRewardTotal() private view returns (uint256) {
        if (_isGameEthSnapNumberDirty()) return address(this).balance;
        return _gameEthForRewardTotalSnap;
    }

    function tokensStakedGameTotal() external view returns (uint256) {
        return _tokensStakedGameTotal();
    }

    function _tokensStakedGameTotal() private view returns (uint256) {
        if (!_isTokensStakedGameTotalDirty()) return _gameTokensStakedTotal;
        return 0;
    }

    function _tryRestartGame() private {
        if (!_isGameDirty()) return;
        _startTime = block.timestamp;
        _gameEndTime = block.timestamp + _gameStartTime;
        ++_gameNumberSnap;
    }

    function gameNumber() external view returns (uint256) {
        return _gameNumber();
    }

    function _gameNumber() private view returns (uint256) {
        if (!_isStarted()) return 0;
        if (!_isGameDirty()) return _gameNumberSnap;
        return _gameNumberSnap + 1;
    }

    function periodNumber() external view returns (uint256) {
        return _periodNumber();
    }

    function _periodNumber() private view returns (uint256) {
        if (!_isStarted()) return 0;
        return (block.timestamp - _startTime) / _periodTimer;
    }

    function periodTimeLeft() external view returns (uint256) {
        if (!_isStarted()) return _periodTimer;
        if (_isGameEnd()) return 0;
        return _periodTimer - ((block.timestamp - _startTime) % _periodTimer);
    }

    function gameTimeLeft() external view returns (uint256) {
        if (!_isStarted()) return _gameStartTime;
        if (_isGameEnd()) return 0;
        return _gameEndTime - block.timestamp;
    }

    function _isPeriodDirty() private view returns (bool) {
        if (!_isStarted()) return false;
        if (_isGameEnd()) return false;
        return _periodNumberSnap != _periodNumber();
    }

    function periodTimer() external pure returns (uint256) {
        return _periodTimer;
    }

    function isStarted() external view returns (bool) {
        return _isStarted();
    }

    function _isStarted() private view returns (bool) {
        return _startTime != 0;
    }

    function tokenAddress() external view returns (address) {
        return address(_token);
    }

    function secondsPerToken() external view returns (uint256) {
        return _secondsPerToken;
    }

    function setSecondsPerToken(uint256 newSecondsPerToken) external onlyOwner {
        require(newSecondsPerToken <= _secondsPerTokenMax);
        _secondsPerToken = newSecondsPerToken;
    }

    function gameEndTime() external view returns (uint256) {
        return _gameEndTime;
    }

    function periodEndTime() external view returns (uint256) {
        if (!_isStarted()) return 0;
        if (_isGameEnd()) return 0;
        return
            _startTime +
            _periodTimer *
            (1 + (block.timestamp - _startTime) / _periodTimer);
    }

    function tokensStakedOnPeriod() external view returns (uint256) {
        return _tokensStakedOnPeriod();
    }

    function _tokensStakedOnPeriod() private view returns (uint256) {
        if (_isPeriodDirty()) return _tokensStakedGameTotal();
        return _totalStackedTokensSnap;
    }

    function tokenStakedAccount(
        address account
    ) external view returns (uint256) {
        return _tokenStakedAccount(_accounts[account]);
    }

    function _tokenStakedAccount(
        AccountData memory data
    ) private view returns (uint256) {
        if (data.gameNumber != _gameNumber()) return 0;
        return data.count;
    }

    function ethRewardOnPeriod() external view returns (uint256) {
        return _ethRewardOnPeriod();
    }

    function _ethRewardOnPeriod() private view returns (uint256) {
        if (!_isPeriodDirty()) return _ethTotalForPeriod;
        return _getEthForPeriod();
    }

    function ethRewardOnPeriodCalculated() external view returns (uint256) {
        return _getEthForPeriod();
    }

    function _getEthForPeriod() private view returns (uint256) {
        uint256 balance = address(this).balance;
        if (balance < 10e18) return balance / 2;
        if (balance < 20e18) return (balance * 40) / 100;
        if (balance < 40e18) return (balance * 30) / 100;
        if (balance < 80e18) return (balance * 20) / 100;
        return balance / 10;
    }

    function tryUpdateSnap() public {
        _tryRestartGame();
        _tryUpdateGameRewardSnap();
        _tryUpdatePeriodSnap();
        _tryUpdateTokensStakedGameTotal();
    }

    function _tryUpdatePeriodSnap() private {
        if (!_isPeriodDirty()) return;
        _ethTotalForPeriod = _getEthForPeriod();
        _periodNumberSnap = _periodNumber();
        _totalStackedTokensSnap = _tokensStakedGameTotal();
    }

    function pressButton(uint256 count) external {
        _addStake(msg.sender, count);
    }

    function _addStake(
        address account,
        uint256 count
    ) private whenStarted whenNotGameClaimState noContracts {
        tryUpdateSnap();
        AccountData storage data = _accounts[account];
        _claim(account, data);
        _token.transferFrom(account, address(_token), count);
        data.count = _tokenStakedAccount(data) + count;
        data.gameNumber = _gameNumber();
        data.period = _periodNumber();
        _gameEndTime += (_secondsPerToken * count) / _tokenDecimals;
        _gameTokensStakedTotal += count;
    }

    function claim() external {
        AccountData storage data = _accounts[msg.sender];
        require(_canClaim(data), "can not claim");
        _claim(msg.sender, _accounts[msg.sender]);
    }

    function _claim(
        address account,
        AccountData storage data
    ) private noContracts {
        tryUpdateSnap();
        if (!_canClaim(data)) return;
        uint256 count = _ethForClaimForAccount(data);
        data.claimedGame = _gameNumber();
        _sendEther(account, count);
    }

    function claimOnPeriod() external {
        AccountData storage data = _accounts[msg.sender];
        require(_canClaimOnPeriod(data), "can not claim on period");
        _claimOnPeriod(msg.sender, data);
    }

    function _claimOnPeriod(
        address account,
        AccountData storage data
    ) private noContracts {
        if (!_canClaimOnPeriod(data)) return;
        uint256 count = _ethForClaimForAccountOnPeriod(data);
        data.period = _periodNumber();
        _sendEther(account, count);
    }

    function canClaimOnPeriod(address account) external view returns (bool) {
        return _canClaimOnPeriod(_accounts[account]);
    }

    function _canClaimOnPeriod(
        AccountData memory data
    ) private view returns (bool) {
        if (_isGameEnd()) return false;
        if (_tokenStakedAccount(data) == 0) return false;
        if (data.period + _periodsForAccountReward >= _periodNumber())
            return false;
        return true;
    }

    function canClaim(address account) external view returns (bool) {
        return _canClaim(_accounts[account]);
    }

    function _canClaim(AccountData memory data) private view returns (bool) {
        if (!_isGameEnd()) return false;
        if (data.claimedGame == _gameNumber()) return false;
        if (_tokenStakedAccount(data) == 0) return false;
        return true;
    }

    function ethForClaimForAccount(
        address account
    ) external view returns (uint256) {
        return _ethForClaimForAccount(_accounts[account]);
    }

    function _ethForClaimForAccount(
        AccountData memory data
    ) private view returns (uint256) {
        if (!_canClaim(data)) return 0;
        return _ethForClaimForTokens(_tokenStakedAccount(data));
    }

    function ethForClaimForAccountPredicted(
        address account
    ) external view returns (uint256) {
        return _ethForClaimForTokens(_tokenStakedAccount(_accounts[account]));
    }

    function ethForClaimForTokens(
        uint256 count
    ) external view returns (uint256) {
        return _ethForClaimForTokens(count);
    }

    function _ethForClaimForTokens(
        uint256 count
    ) private view returns (uint256) {
        return (_gameEthForRewardTotal() * count) / _tokensStakedGameTotal();
    }

    function ethForClaimForAccountOnPeriod(
        address account
    ) external view returns (uint256) {
        return _ethForClaimForAccountOnPeriod(_accounts[account]);
    }

    function _ethForClaimForAccountOnPeriod(
        AccountData memory data
    ) private view returns (uint256) {
        if (!_canClaimOnPeriod(data)) return 0;
        return _ethForClaimForTokensOnPeriod(_tokenStakedAccount(data));
    }

    function ethForClaimForTokensOnPeriod(
        uint256 count
    ) external view returns (uint256) {
        return _ethForClaimForTokensOnPeriod(count);
    }

    function ethForClaimForTokensOnPeriodPrediction(
        uint256 count
    ) external view returns (uint256) {
        return _ethForClaimForTokensOnPeriodPrediction(count);
    }

    function _ethForClaimForTokensOnPeriodPrediction(
        uint256 count
    ) private view returns (uint256) {
        return (_getEthForPeriod() * count) / _tokensStakedGameTotal();
    }

    function ethForClaimForAccountOnPeriodPrediction(
        address account
    ) external view returns (uint256) {
        return
            _ethForClaimForTokensOnPeriodPrediction(
                _tokenStakedAccount(_accounts[account])
            );
    }

    function _ethForClaimForTokensOnPeriod(
        uint256 count
    ) private view returns (uint256) {
        return (_ethRewardOnPeriod() * count) / _tokensStakedGameTotal();
    }

    function getAccountData(
        address account
    ) external view returns (AccountData memory) {
        return _accounts[account];
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.23;

struct AccountData {
    uint256 count;
    uint256 period;
    uint256 claimedGame;
    uint256 gameNumber;
}

interface IGame {
    function isStarted() external view returns (bool);

    function startTime() external view returns (uint256);

    function isGameEnd() external view returns (bool);

    /// @dev new game time. only if game end
    function newGameTime() external view returns (uint256);

    function gameClaimTimer() external view returns (uint256);

    function gameNumber() external view returns (uint256);

    function periodNumber() external view returns (uint256);

    function periodTimer() external view returns (uint256);

    function tokenAddress() external view returns (address);

    function secondsPerToken() external view returns (uint256);

    function gameEndTime() external view returns (uint256);

    function periodEndTime() external view returns (uint256);

    function tokensStakedGameTotal() external view returns (uint256);

    function tokensStakedOnPeriod() external view returns (uint256);

    function tokenStakedAccount(
        address account
    ) external view returns (uint256);

    function ethRewardOnPeriod() external view returns (uint256);

    function ethRewardOnPeriodCalculated() external view returns (uint256);

    function pressButton(uint256 count) external;

    function canClaim(address account) external view returns (bool);

    function canClaimOnPeriod(address account) external view returns (bool);

    function claim() external;

    function claimOnPeriod() external;

    function ethForClaimForAccount(
        address account
    ) external view returns (uint256);

    function ethForClaimForAccountPredicted(
        address account
    ) external view returns (uint256);

    function ethForClaimForTokens(
        uint256 count
    ) external view returns (uint256);

    function ethForClaimForAccountOnPeriod(
        address account
    ) external view returns (uint256);

    function ethForClaimForTokensOnPeriod(
        uint256 count
    ) external view returns (uint256);

    function ethForClaimForTokensOnPeriodPrediction(
        uint256 count
    ) external view returns (uint256);

    function ethForClaimForAccountOnPeriodPrediction(
        address account
    ) external view returns (uint256);

    function gameTimeLeft() external view returns (uint256);

    function periodTimeLeft() external view returns (uint256);

    function getAccountData(
        address account
    ) external view returns (AccountData memory);
}