Contract Source Code:

/*

   _____                        _                               
  / ____|                      | |                              
 | |  __   _ __    ___    ___  | |   __ _   _ __     ___    ___ 
 | | |_ | | '__|  / _ \  / _ \ | |  / _` | | '_ \   / __|  / _ \
 | |__| | | |    |  __/ |  __/ | | | (_| | | | | | | (__  |  __/
  \_____| |_|     \___|  \___| |_|  \__,_| |_| |_|  \___|  \___|
                                                                
                                                                                                    
                                                      
Official Links

Website: https://greelance.com/
Twitter: https://twitter.com/GreelanceI
Telegram: https://t.me/greelancer 
Discord: https://discord.gg/ukNCBwQCD9
*/

// SPDX-License-Identifier: MIT

pragma solidity 0.8.19;

interface IERC20 {
    function totalSupply() external view returns (uint256);

    function balanceOf(address account) external view returns (uint256);

    function transfer(
        address recipient,
        uint256 amount
    ) external returns (bool);

    function allowance(
        address owner,
        address spender
    ) external view returns (uint256);

    function approve(address spender, uint256 amount) external returns (bool);

    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );
}

interface IERC20Metadata is IERC20 {
    function name() external view returns (string memory);

    function symbol() external view returns (string memory);

    function decimals() external view returns (uint8);
}

abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(
        address indexed previousOwner,
        address indexed newOwner
    );

    constructor() {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    function owner() public view returns (address) {
        return _owner;
    }

    modifier onlyOwner() {
        require(_owner == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(
            newOwner != address(0),
            "Ownable: new owner is the zero address"
        );
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    function name() public view virtual override returns (string memory) {
        return _name;
    }

    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    function decimals() public view virtual override returns (uint8) {
        return 9;
    }

    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    function balanceOf(
        address account
    ) public view virtual override returns (uint256) {
        return _balances[account];
    }

    function transfer(
        address recipient,
        uint256 amount
    ) public virtual override returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    function allowance(
        address owner,
        address spender
    ) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    function approve(
        address spender,
        uint256 amount
    ) public virtual override returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) public virtual override returns (bool) {
        uint256 currentAllowance = _allowances[sender][_msgSender()];
        if (currentAllowance != type(uint256).max) {
            require(
                currentAllowance >= amount,
                "ERC20: transfer amount exceeds allowance"
            );
            unchecked {
                _approve(sender, _msgSender(), currentAllowance - amount);
            }
        }

        _transfer(sender, recipient, amount);

        return true;
    }

    function increaseAllowance(
        address spender,
        uint256 addedValue
    ) public virtual returns (bool) {
        _approve(
            _msgSender(),
            spender,
            _allowances[_msgSender()][spender] + addedValue
        );
        return true;
    }

    function decreaseAllowance(
        address spender,
        uint256 subtractedValue
    ) public virtual returns (bool) {
        uint256 currentAllowance = _allowances[_msgSender()][spender];
        require(
            currentAllowance >= subtractedValue,
            "ERC20: decreased allowance below zero"
        );
        unchecked {
            _approve(_msgSender(), spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    function _transfer(
        address sender,
        address recipient,
        uint256 amount
    ) internal virtual {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(sender, recipient, amount);

        uint256 senderBalance = _balances[sender];
        require(
            senderBalance >= amount,
            "ERC20: transfer amount exceeds balance"
        );
        unchecked {
            _balances[sender] = senderBalance - amount;
        }
        _balances[recipient] += amount;

        emit Transfer(sender, recipient, amount);

        _afterTokenTransfer(sender, recipient, amount);
    }

    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        _balances[account] += amount;
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
        }
        _totalSupply -= amount;

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}

contract Greelance is ERC20, Ownable {
    address public uniswapV2Pair;

    mapping(address => bool) private _isExcludedFromFees;

    uint256 public taxFeeOnBuy;
    uint256 public taxFeeOnSell;

    address public taxCollector;

    bool public tradingEnabled;
    bool private tokenMinted = false;
    uint256 public maxSellableAmount;
    bool public maxSellableRestrictionEnabled = false;
    bool public trading24HrsRestrictionEnabled = false;
    mapping(address => uint256) public tradingIn24Hours;
    mapping(address => uint256) public lastTradeTime;

    event ExcludeFromFees(address indexed account, bool isExcluded);

    constructor() ERC20("Greelance", "GRL") {
        taxCollector = owner();
        _isExcludedFromFees[owner()] = true;
        _isExcludedFromFees[address(this)] = true;
    }

    receive() external payable {}

    function mint() external onlyOwner {
        require(!tokenMinted, "Tokens already minted!");
        tokenMinted = true;
        _mint(owner(), 2000000000 * (10 ** decimals()));
    }

    function setMaxSellableAmount(uint256 _maxAmount) external onlyOwner {
        require(_maxAmount > 0, "Invalid amount!");
        maxSellableAmount = _maxAmount;
        maxSellableRestrictionEnabled = true;
    }

    function removeMaxSellableRestriction() external onlyOwner {
        maxSellableRestrictionEnabled = false;
    }

    function excludeFromFees(address account) external onlyOwner {
        require(
            !_isExcludedFromFees[account],
            "Account already excluded"
        );
        _isExcludedFromFees[account] = true;

        emit ExcludeFromFees(account, true);
    }

    function enable24HrsRestriction() external onlyOwner {
        trading24HrsRestrictionEnabled = true;
    }

    function disable24HrsRestriction() external onlyOwner {
        trading24HrsRestrictionEnabled = false;
    }

    function setUniswapPair(address _uniswapV2Pair) external onlyOwner {
        uniswapV2Pair = _uniswapV2Pair;
    }

    function isExcludedFromFees(address account) public view returns (bool) {
        return _isExcludedFromFees[account];
    }

    function setBuyTaxPercentage(uint256 _taxAmount) external onlyOwner {
        require(_taxAmount <= 20, "Tax not more than 20!");
        taxFeeOnBuy = _taxAmount;
    }

    function setSellTaxPercentage(uint256 _taxAmount) external onlyOwner {
        require(_taxAmount <= 20, "Tax not more than 20!");
        taxFeeOnSell = _taxAmount;
    }

    function enableTrading() external onlyOwner {
        require(!tradingEnabled, "Trading already enabled.");
        tradingEnabled = true;
    }

    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal override {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");
        require(tradingEnabled || _isExcludedFromFees[from] || _isExcludedFromFees[to], "Trading not yet enabled!");

        if (amount == 0) {
            super._transfer(from, to, 0);
            lastTradeTime[from] = block.timestamp;
            return;
        }

        bool shouldApplyFees = !(_isExcludedFromFees[from] ||
            _isExcludedFromFees[to]);
        uint256 fees = shouldApplyFees
            ? (amount * (from == uniswapV2Pair ? taxFeeOnBuy : taxFeeOnSell)) /
                100
            : 0;

        if (shouldApplyFees) {
            if (from != uniswapV2Pair) {

                if (maxSellableRestrictionEnabled) {
                    require(
                        amount <= maxSellableAmount,
                        "Amount is greater than MaxSellableAmount"
                    );
                }

                if (trading24HrsRestrictionEnabled) {
                    if (
                        maxSellableRestrictionEnabled &&
                        block.timestamp - lastTradeTime[from] >= 1 days
                    ) {
                        tradingIn24Hours[from] = 0;
                    } else if (
                        tradingIn24Hours[from] + amount > maxSellableAmount
                    ) {
                        require(
                            block.timestamp - lastTradeTime[from] >= 1 days,
                            "Transfer restricted before 24 hours"
                        );
                    }

                    if (maxSellableRestrictionEnabled) {
                        tradingIn24Hours[from] += amount;
                    }
                }
            }
        }

        if (fees > 0) {
            super._transfer(from, taxCollector, fees);
            amount -= fees;
        }

        super._transfer(from, to, amount);
        lastTradeTime[from] = block.timestamp;
    }
}