Contract Name:
ERC20RewardApeV1
Contract Source Code:
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;
/*
______ ______
/ \ / \
| ▓▓▓▓▓▓\ ______ ______ | ▓▓▓▓▓▓\__ __ __ ______ ______
| ▓▓__| ▓▓/ \ / \| ▓▓___\▓▓ \ | \ | \| \ / \
| ▓▓ ▓▓ ▓▓▓▓▓▓\ ▓▓▓▓▓▓\\▓▓ \| ▓▓ | ▓▓ | ▓▓ \▓▓▓▓▓▓\ ▓▓▓▓▓▓\
| ▓▓▓▓▓▓▓▓ ▓▓ | ▓▓ ▓▓ ▓▓_\▓▓▓▓▓▓\ ▓▓ | ▓▓ | ▓▓/ ▓▓ ▓▓ | ▓▓
| ▓▓ | ▓▓ ▓▓__/ ▓▓ ▓▓▓▓▓▓▓▓ \__| ▓▓ ▓▓_/ ▓▓_/ ▓▓ ▓▓▓▓▓▓▓ ▓▓__/ ▓▓
| ▓▓ | ▓▓ ▓▓ ▓▓\▓▓ \\▓▓ ▓▓\▓▓ ▓▓ ▓▓\▓▓ ▓▓ ▓▓ ▓▓
\▓▓ \▓▓ ▓▓▓▓▓▓▓ \▓▓▓▓▓▓▓ \▓▓▓▓▓▓ \▓▓▓▓▓\▓▓▓▓ \▓▓▓▓▓▓▓ ▓▓▓▓▓▓▓
| ▓▓ | ▓▓
| ▓▓ | ▓▓
\▓▓ \▓▓
* App: https://ApeSwap.finance
* Medium: https://ape-swap.medium.com
* Twitter: https://twitter.com/ape_swap
* Telegram: https://t.me/ape_swap
* Announcements: https://t.me/ape_swap_news
* Discord: https://discord.com/ApeSwap
* Reddit: https://reddit.com/r/ApeSwap
* Instagram: https://instagram.com/ApeSwap.finance
* GitHub: https://github.com/ApeSwapFinance
*/
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/proxy/utils/Initializable.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
contract ERC20RewardApeV1 is ReentrancyGuard, Ownable, Initializable {
using SafeERC20 for IERC20;
// Info of each user.
struct UserInfo {
uint256 amount; // How many LP tokens the user has provided.
uint256 rewardDebt; // Reward debt. See explanation below.
}
// Info of each pool.
struct PoolInfo {
IERC20 lpToken; // Address of LP token contract.
uint256 allocPoint; // How many allocation points assigned to this pool. Rewards to distribute per second.
uint256 lastRewardTime; // Last timestamp that Rewards distribution occurs.
uint256 accRewardTokenPerShare; // Accumulated Rewards per share, times 1e30. See below.
}
// The stake token
IERC20 public STAKE_TOKEN;
// The reward token
IERC20 public REWARD_TOKEN;
// Is native token reward
bool public isNativeTokenReward;
// Reward tokens created per second.
uint256 public rewardPerSecond;
// Keep track of number of tokens staked in case the contract earns reflect fees
uint256 public totalStaked = 0;
// Keep track of number of reward tokens paid to find remaining reward balance
uint256 public totalRewardsPaid = 0;
// Keep track of number of reward tokens paid to find remaining reward balance
uint256 public totalRewardsAllocated = 0;
// Info of each pool.
PoolInfo public poolInfo;
// Info of each user that stakes LP tokens.
mapping(address => UserInfo) public userInfo;
// Total allocation points. Must be the sum of all allocation points in all pools.
uint256 private totalAllocPoint = 0;
// The timestamp number when Reward mining starts.
uint256 public startTime;
// The timestamp number when mining ends.
uint256 public bonusEndTime;
event Deposit(address indexed sender, address indexed user, uint256 amount);
event DepositRewards(uint256 amount);
event Withdraw(address indexed user, uint256 amount);
event EmergencyWithdraw(address indexed user, uint256 amount);
event SkimStakeTokenFees(address indexed user, uint256 amount);
event LogUpdatePool(uint256 bonusEndTime, uint256 rewardPerSecond);
event EmergencyRewardWithdraw(address indexed user, uint256 amount);
event EmergencySweepWithdraw(
address indexed user,
IERC20 indexed token,
uint256 amount
);
function initialize(
IERC20 _stakeToken,
IERC20 _rewardToken,
uint256 _rewardPerSecond,
uint256 _startTime,
uint256 _bonusEndTime
) external initializer {
if (address(_rewardToken) == address(0)) {
isNativeTokenReward = true;
}
STAKE_TOKEN = _stakeToken;
REWARD_TOKEN = _rewardToken;
rewardPerSecond = _rewardPerSecond;
startTime = _startTime;
bonusEndTime = _bonusEndTime;
// staking pool
poolInfo = PoolInfo({
lpToken: _stakeToken,
allocPoint: 1000,
lastRewardTime: startTime,
accRewardTokenPerShare: 0
});
totalAllocPoint = 1000;
}
// Return reward multiplier over the given _from to _to timestamp.
function getMultiplier(uint256 _from, uint256 _to)
public
view
returns (uint256)
{
if (_to <= bonusEndTime) {
return _to - _from;
} else if (_from >= bonusEndTime) {
return 0;
} else {
return bonusEndTime - _from;
}
}
/// @param _bonusEndTime The timestamp when rewards will end
function setBonusEndTime(uint256 _bonusEndTime) external onlyOwner {
require(
_bonusEndTime > block.timestamp,
"new bonus end timestamp must be greater than current"
);
bonusEndTime = _bonusEndTime;
emit LogUpdatePool(bonusEndTime, rewardPerSecond);
}
// View function to see pending Reward on frontend.
function pendingReward(address _user)
external
view
returns (uint256 pending)
{
UserInfo storage user = userInfo[_user];
uint256 accRewardTokenPerShare = poolInfo.accRewardTokenPerShare;
if (block.timestamp > poolInfo.lastRewardTime && totalStaked != 0) {
uint256 multiplier = getMultiplier(
poolInfo.lastRewardTime,
block.timestamp
);
uint256 tokenReward = (multiplier *
rewardPerSecond *
poolInfo.allocPoint) / totalAllocPoint;
accRewardTokenPerShare =
accRewardTokenPerShare +
((tokenReward * 1e30) / totalStaked);
}
pending =
(user.amount * accRewardTokenPerShare) /
1e30 -
user.rewardDebt;
}
// Update reward variables of the given pool to be up-to-date.
function updatePool() public {
if (block.timestamp <= poolInfo.lastRewardTime) {
return;
}
if (totalStaked == 0) {
poolInfo.lastRewardTime = block.timestamp;
return;
}
uint256 multiplier = getMultiplier(
poolInfo.lastRewardTime,
block.timestamp
);
uint256 tokenReward = (multiplier *
rewardPerSecond *
poolInfo.allocPoint) / totalAllocPoint;
totalRewardsAllocated += tokenReward;
poolInfo.accRewardTokenPerShare =
poolInfo.accRewardTokenPerShare +
((tokenReward * 1e30) / totalStaked);
poolInfo.lastRewardTime = block.timestamp;
}
/// Deposit staking token into the contract to earn rewards.
/// @dev Since this contract needs to be supplied with rewards we are
/// sending the balance of the contract if the pending rewards are higher
/// @param _amount The amount of staking tokens to deposit
function deposit(uint256 _amount) external nonReentrant {
_depositTo(_amount, msg.sender);
}
function depositTo(uint256 _amount, address _user) external nonReentrant {
require(_user != address(0), "Can't deposit for null address");
_depositTo(_amount, _user);
}
function _depositTo(uint256 _amount, address _user) internal {
UserInfo storage user = userInfo[_user];
updatePool();
if (user.amount > 0) {
uint256 pending = (user.amount * poolInfo.accRewardTokenPerShare) /
1e30 -
user.rewardDebt;
if (pending > 0) {
// If rewardBalance is low then revert to avoid losing the user's rewards
require(
rewardBalance() >= pending,
"insufficient reward balance"
);
safeTransferRewardInternal(_user, pending, true);
}
}
uint256 finalDepositAmount = 0;
if (_amount > 0) {
uint256 preStakeBalance = STAKE_TOKEN.balanceOf(address(this));
poolInfo.lpToken.safeTransferFrom(
address(msg.sender),
address(this),
_amount
);
finalDepositAmount =
STAKE_TOKEN.balanceOf(address(this)) -
preStakeBalance;
user.amount = user.amount + finalDepositAmount;
totalStaked = totalStaked + finalDepositAmount;
}
user.rewardDebt =
(user.amount * poolInfo.accRewardTokenPerShare) /
1e30;
emit Deposit(msg.sender, _user, finalDepositAmount);
}
/// Withdraw rewards and/or staked tokens. Pass a 0 amount to withdraw only rewards
/// @param _amount The amount of staking tokens to withdraw
function withdraw(uint256 _amount) external nonReentrant {
UserInfo storage user = userInfo[msg.sender];
require(user.amount >= _amount, "withdraw: not good");
updatePool();
uint256 pending = (user.amount * poolInfo.accRewardTokenPerShare) /
1e30 -
user.rewardDebt;
if (pending > 0) {
// If rewardBalance is low then revert to avoid losing the user's rewards
require(rewardBalance() >= pending, "insufficient reward balance");
safeTransferRewardInternal(address(msg.sender), pending, true);
}
if (_amount > 0) {
user.amount = user.amount - _amount;
poolInfo.lpToken.safeTransfer(address(msg.sender), _amount);
totalStaked = totalStaked - _amount;
}
user.rewardDebt =
(user.amount * poolInfo.accRewardTokenPerShare) /
1e30;
emit Withdraw(msg.sender, _amount);
}
/// Obtain the reward balance of this contract
/// @return wei balance of contract
function rewardBalance() public view returns (uint256) {
if (isNativeTokenReward) {
return address(this).balance;
} else {
// Return ERC20 balance
uint256 balance = REWARD_TOKEN.balanceOf(address(this));
if (STAKE_TOKEN == REWARD_TOKEN) {
return balance - totalStaked;
}
return balance;
}
}
/// Get the balance of rewards that have not been harvested
/// @return wei balance of rewards left to be paid
function getUnharvestedRewards() public view returns (uint256) {
return totalRewardsAllocated - totalRewardsPaid;
}
// Deposit Rewards into contract
function depositRewards(uint256 _amount) external {
require(!isNativeTokenReward, "Reward is native token");
require(_amount > 0, "Deposit value must be greater than 0.");
REWARD_TOKEN.safeTransferFrom(
address(msg.sender),
address(this),
_amount
);
emit DepositRewards(_amount);
}
/// @param _to address to send reward token to
/// @param _amount value of reward token to transfer
function safeTransferRewardInternal(
address _to,
uint256 _amount,
bool _sumRewards
) internal {
require(_amount <= rewardBalance(), "not enough reward token");
if (_sumRewards) {
totalRewardsPaid += _amount;
}
if (isNativeTokenReward) {
// Transfer native token to address
(bool success, ) = _to.call{gas: 23000, value: _amount}("");
require(success, "TransferHelper: NATIVE_TRANSFER_FAILED");
} else {
// Transfer ERC20 to address
REWARD_TOKEN.safeTransfer(_to, _amount);
}
}
/// @dev Obtain the stake balance of this contract
function totalStakeTokenBalance() public view returns (uint256) {
if (STAKE_TOKEN == REWARD_TOKEN) return totalStaked;
return STAKE_TOKEN.balanceOf(address(this));
}
/// @dev Obtain the stake token fees (if any) earned by reflect token
/// @notice If STAKE_TOKEN == REWARD_TOKEN there are no fees to skim
function getStakeTokenFeeBalance() public view returns (uint256) {
return totalStakeTokenBalance() - totalStaked;
}
/* Admin Functions */
/// @param _rewardPerSecond The amount of reward tokens to be given per second
function setRewardPerSecond(uint256 _rewardPerSecond) external onlyOwner {
rewardPerSecond = _rewardPerSecond;
emit LogUpdatePool(bonusEndTime, rewardPerSecond);
}
/// @dev Remove excess stake tokens earned by reflect fees
function skimStakeTokenFees(address _to) external onlyOwner {
uint256 stakeTokenFeeBalance = getStakeTokenFeeBalance();
STAKE_TOKEN.safeTransfer(_to, stakeTokenFeeBalance);
emit SkimStakeTokenFees(_to, stakeTokenFeeBalance);
}
/* Emergency Functions */
// Withdraw without caring about rewards. EMERGENCY ONLY.
function emergencyWithdraw() external nonReentrant {
UserInfo storage user = userInfo[msg.sender];
poolInfo.lpToken.safeTransfer(address(msg.sender), user.amount);
totalStaked = totalStaked - user.amount;
user.amount = 0;
user.rewardDebt = 0;
emit EmergencyWithdraw(msg.sender, user.amount);
}
// Withdraw reward. EMERGENCY ONLY.
function emergencyRewardWithdraw(uint256 _amount) external onlyOwner {
// Withdraw rewards
safeTransferRewardInternal(msg.sender, _amount, false);
emit EmergencyRewardWithdraw(msg.sender, _amount);
}
/// @notice A public function to sweep accidental BEP20 transfers to this contract.
/// Tokens are sent to owner
/// @param token The address of the BEP20 token to sweep
function sweepToken(IERC20 token) external onlyOwner {
require(
address(token) != address(STAKE_TOKEN),
"can not sweep stake token"
);
require(
address(token) != address(REWARD_TOKEN),
"can not sweep reward token"
);
uint256 balance = token.balanceOf(address(this));
token.safeTransfer(msg.sender, balance);
emit EmergencySweepWithdraw(msg.sender, token, balance);
}
receive() external payable {
if (!isNativeTokenReward) {
revert("Reward token is not native");
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `recipient`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address recipient, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `sender` to `recipient` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(
address sender,
address recipient,
uint256 amount
) external returns (bool);
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "../IERC20.sol";
import "../../../utils/Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
function safeTransfer(
IERC20 token,
address to,
uint256 value
) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
}
function safeTransferFrom(
IERC20 token,
address from,
address to,
uint256 value
) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
}
/**
* @dev Deprecated. This function has issues similar to the ones found in
* {IERC20-approve}, and its usage is discouraged.
*
* Whenever possible, use {safeIncreaseAllowance} and
* {safeDecreaseAllowance} instead.
*/
function safeApprove(
IERC20 token,
address spender,
uint256 value
) internal {
// safeApprove should only be called when setting an initial allowance,
// or when resetting it to zero. To increase and decrease it, use
// 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
require(
(value == 0) || (token.allowance(address(this), spender) == 0),
"SafeERC20: approve from non-zero to non-zero allowance"
);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
}
function safeIncreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
uint256 newAllowance = token.allowance(address(this), spender) + value;
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
}
function safeDecreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
unchecked {
uint256 oldAllowance = token.allowance(address(this), spender);
require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
uint256 newAllowance = oldAllowance - value;
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
}
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
if (returndata.length > 0) {
// Return data is optional
require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize, which returns 0 for contracts in
// construction, since the code is only stored at the end of the
// constructor execution.
uint256 size;
assembly {
size := extcodesize(account)
}
return size > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(address(this).balance >= amount, "Address: insufficient balance");
(bool success, ) = recipient.call{value: amount}("");
require(success, "Address: unable to send value, recipient may have reverted");
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCall(target, data, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value
) internal returns (bytes memory) {
return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(address(this).balance >= value, "Address: insufficient balance for call");
require(isContract(target), "Address: call to non-contract");
(bool success, bytes memory returndata) = target.call{value: value}(data);
return verifyCallResult(success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
return functionStaticCall(target, data, "Address: low-level static call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
require(isContract(target), "Address: static call to non-contract");
(bool success, bytes memory returndata) = target.staticcall(data);
return verifyCallResult(success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
return functionDelegateCall(target, data, "Address: low-level delegate call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
require(isContract(target), "Address: delegate call to non-contract");
(bool success, bytes memory returndata) = target.delegatecall(data);
return verifyCallResult(success, returndata, errorMessage);
}
/**
* @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
* revert reason using the provided one.
*
* _Available since v4.3._
*/
function verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) internal pure returns (bytes memory) {
if (success) {
return returndata;
} else {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
* @dev Contract module which provides a basic access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership}.
*
* This module is used through inheritance. It will make available the modifier
* `onlyOwner`, which can be applied to your functions to restrict their use to
* the owner.
*/
abstract contract Ownable is Context {
address private _owner;
event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
/**
* @dev Initializes the contract setting the deployer as the initial owner.
*/
constructor() {
_setOwner(_msgSender());
}
/**
* @dev Returns the address of the current owner.
*/
function owner() public view virtual returns (address) {
return _owner;
}
/**
* @dev Throws if called by any account other than the owner.
*/
modifier onlyOwner() {
require(owner() == _msgSender(), "Ownable: caller is not the owner");
_;
}
/**
* @dev Leaves the contract without owner. It will not be possible to call
* `onlyOwner` functions anymore. Can only be called by the current owner.
*
* NOTE: Renouncing ownership will leave the contract without an owner,
* thereby removing any functionality that is only available to the owner.
*/
function renounceOwnership() public virtual onlyOwner {
_setOwner(address(0));
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual onlyOwner {
require(newOwner != address(0), "Ownable: new owner is the zero address");
_setOwner(newOwner);
}
function _setOwner(address newOwner) private {
address oldOwner = _owner;
_owner = newOwner;
emit OwnershipTransferred(oldOwner, newOwner);
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
* behind a proxy. Since a proxied contract can't have a constructor, it's common to move constructor logic to an
* external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
* function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
*
* TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
* possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
*
* CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
* that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
*/
abstract contract Initializable {
/**
* @dev Indicates that the contract has been initialized.
*/
bool private _initialized;
/**
* @dev Indicates that the contract is in the process of being initialized.
*/
bool private _initializing;
/**
* @dev Modifier to protect an initializer function from being invoked twice.
*/
modifier initializer() {
require(_initializing || !_initialized, "Initializable: contract is already initialized");
bool isTopLevelCall = !_initializing;
if (isTopLevelCall) {
_initializing = true;
_initialized = true;
}
_;
if (isTopLevelCall) {
_initializing = false;
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev Contract module that helps prevent reentrant calls to a function.
*
* Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
* available, which can be applied to functions to make sure there are no nested
* (reentrant) calls to them.
*
* Note that because there is a single `nonReentrant` guard, functions marked as
* `nonReentrant` may not call one another. This can be worked around by making
* those functions `private`, and then adding `external` `nonReentrant` entry
* points to them.
*
* TIP: If you would like to learn more about reentrancy and alternative ways
* to protect against it, check out our blog post
* https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
*/
abstract contract ReentrancyGuard {
// Booleans are more expensive than uint256 or any type that takes up a full
// word because each write operation emits an extra SLOAD to first read the
// slot's contents, replace the bits taken up by the boolean, and then write
// back. This is the compiler's defense against contract upgrades and
// pointer aliasing, and it cannot be disabled.
// The values being non-zero value makes deployment a bit more expensive,
// but in exchange the refund on every call to nonReentrant will be lower in
// amount. Since refunds are capped to a percentage of the total
// transaction's gas, it is best to keep them low in cases like this one, to
// increase the likelihood of the full refund coming into effect.
uint256 private constant _NOT_ENTERED = 1;
uint256 private constant _ENTERED = 2;
uint256 private _status;
constructor() {
_status = _NOT_ENTERED;
}
/**
* @dev Prevents a contract from calling itself, directly or indirectly.
* Calling a `nonReentrant` function from another `nonReentrant`
* function is not supported. It is possible to prevent this from happening
* by making the `nonReentrant` function external, and make it call a
* `private` function that does the actual work.
*/
modifier nonReentrant() {
// On the first call to nonReentrant, _notEntered will be true
require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
// Any calls to nonReentrant after this point will fail
_status = _ENTERED;
_;
// By storing the original value once again, a refund is triggered (see
// https://eips.ethereum.org/EIPS/eip-2200)
_status = _NOT_ENTERED;
}
}