Contract Name:
RewardManager
Contract Source Code:
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import "../interfaces/pools/IConicPool.sol";
import "../interfaces/pools/ILpToken.sol";
import "../interfaces/pools/IRewardManager.sol";
import "../interfaces/IConvexHandler.sol";
import "../interfaces/ICurveHandler.sol";
import "../interfaces/IController.sol";
import "../interfaces/IOracle.sol";
import "../interfaces/tokenomics/IInflationManager.sol";
import "../interfaces/tokenomics/ILpTokenStaker.sol";
import "../interfaces/tokenomics/ICNCLockerV2.sol";
import "../interfaces/vendor/ICurvePoolV2.sol";
import "../interfaces/vendor/UniswapRouter02.sol";
import "../libraries/ScaledMath.sol";
contract RewardManager is IRewardManager, Ownable {
using ScaledMath for uint256;
using SafeERC20 for IERC20;
using EnumerableSet for EnumerableSet.AddressSet;
IERC20 public constant CVX = IERC20(0x4e3FBD56CD56c3e72c1403e103b45Db9da5B9D2B);
IERC20 public constant CRV = IERC20(0xD533a949740bb3306d119CC777fa900bA034cd52);
IERC20 public constant WETH = IERC20(0xC02aaA39b223FE8D0A0e5C4F27eAD9083C756Cc2);
IERC20 public constant CNC = IERC20(0x9aE380F0272E2162340a5bB646c354271c0F5cFC);
UniswapRouter02 public constant SUSHISWAP =
UniswapRouter02(0xd9e1cE17f2641f24aE83637ab66a2cca9C378B9F);
ICurvePoolV2 public constant CNC_ETH_POOL =
ICurvePoolV2(0x838af967537350D2C44ABB8c010E49E32673ab94);
uint256 public constant MAX_FEE_PERCENTAGE = 3e17;
uint256 public constant SLIPPAGE_THRESHOLD = 0.95e18; // 5% slippage as a multiplier
bytes32 internal constant _CNC_KEY = "cnc";
bytes32 internal constant _CRV_KEY = "crv";
bytes32 internal constant _CVX_KEY = "cvx";
address public immutable override pool;
ILpToken public immutable lpToken;
IERC20 public immutable underlying;
IController public immutable controller;
ICNCLockerV2 public immutable locker;
uint256 internal _oldCrvBalance;
uint256 internal _oldCvxBalance;
EnumerableSet.AddressSet internal _extraRewards;
mapping(address => address) public extraRewardsCurvePool;
mapping(bytes32 => RewardMeta) internal _rewardsMeta;
bool public feesEnabled;
uint256 public feePercentage;
constructor(
address _controller,
address _pool,
address _lpToken,
address _underlying,
address cncLocker
) {
pool = _pool;
lpToken = ILpToken(_lpToken);
underlying = IERC20(_underlying);
controller = IController(_controller);
WETH.safeApprove(address(CNC_ETH_POOL), type(uint256).max);
locker = ICNCLockerV2(cncLocker);
}
/// @notice Updates the internal fee accounting state. Returns `true` if rewards were claimed
function poolCheckpoint() public override returns (bool) {
IConvexHandler convexHandler = IConvexHandler(controller.convexHandler());
(uint256 crvEarned, uint256 cvxEarned, uint256 cncEarned) = _getEarnedRewards(
convexHandler
);
uint256 crvFee;
uint256 cvxFee;
if (feesEnabled) {
crvFee = crvEarned.mulDown(feePercentage);
cvxFee = cvxEarned.mulDown(feePercentage);
crvEarned = crvEarned - crvFee;
cvxEarned = cvxEarned - cvxFee;
}
uint256 _totalStaked = controller.lpTokenStaker().getBalanceForPool(pool);
if (_totalStaked > 0) {
_updateEarned(_CVX_KEY, cvxEarned, _totalStaked);
_updateEarned(_CRV_KEY, crvEarned, _totalStaked);
_updateEarned(_CNC_KEY, cncEarned, _totalStaked);
}
if (!feesEnabled) {
return false;
}
bool rewardsClaimed = false;
if (crvFee > CRV.balanceOf(pool) || cvxFee > CVX.balanceOf(pool)) {
_claimPoolEarningsAndSellRewardTokens();
rewardsClaimed = true;
}
CRV.safeTransferFrom(pool, address(this), crvFee);
CVX.safeTransferFrom(pool, address(this), cvxFee);
// Fee transfer to the CNC locker
CRV.safeApprove(address(locker), crvFee);
CVX.safeApprove(address(locker), cvxFee);
locker.receiveFees(crvFee, cvxFee);
_oldCrvBalance = CRV.balanceOf(pool);
_oldCvxBalance = CVX.balanceOf(pool);
return rewardsClaimed;
}
function _updateEarned(
bytes32 key,
uint256 earned,
uint256 _totalSupply
) internal {
_rewardsMeta[key].earnedIntegral += earned.divDown(_totalSupply);
_rewardsMeta[key].lastEarned += earned;
}
function _getEarnedRewards()
internal
view
returns (
uint256 crvEarned,
uint256 cvxEarned,
uint256 cncEarned
)
{
IConvexHandler convexHandler = IConvexHandler(controller.convexHandler());
return _getEarnedRewards(convexHandler);
}
function _getEarnedRewards(IConvexHandler convexHandler)
internal
view
returns (
uint256 crvEarned,
uint256 cvxEarned,
uint256 cncEarned
)
{
address[] memory curvePools = IConicPool(pool).allCurvePools();
uint256 claimableCRV = convexHandler.getCrvEarnedBatch(pool, curvePools);
uint256 totalCRVEarned = CRV.balanceOf(pool) - _oldCrvBalance + claimableCRV;
uint256 claimableCVX = convexHandler.computeClaimableConvex(claimableCRV);
uint256 totalCVXEarned = CVX.balanceOf(pool) - _oldCvxBalance + claimableCVX;
uint256 totalCNCEarned = controller.lpTokenStaker().claimableCnc(pool);
if (totalCRVEarned > _rewardsMeta[_CRV_KEY].lastEarned) {
crvEarned = totalCRVEarned - _rewardsMeta[_CRV_KEY].lastEarned;
}
if (totalCVXEarned > _rewardsMeta[_CVX_KEY].lastEarned) {
cvxEarned = totalCVXEarned - _rewardsMeta[_CVX_KEY].lastEarned;
}
if (totalCNCEarned > _rewardsMeta[_CNC_KEY].lastEarned) {
cncEarned = totalCNCEarned - _rewardsMeta[_CNC_KEY].lastEarned;
}
}
function accountCheckpoint(address account) external {
_accountCheckpoint(account);
}
function _accountCheckpoint(address account) internal {
uint256 accountBalance = controller.lpTokenStaker().getUserBalanceForPool(pool, account);
poolCheckpoint();
_updateAccountRewardsMeta(_CNC_KEY, account, accountBalance);
_updateAccountRewardsMeta(_CRV_KEY, account, accountBalance);
_updateAccountRewardsMeta(_CVX_KEY, account, accountBalance);
}
function _updateAccountRewardsMeta(
bytes32 key,
address account,
uint256 balance
) internal {
RewardMeta storage meta = _rewardsMeta[key];
uint256 share = balance.mulDown(meta.earnedIntegral - meta.accountIntegral[account]);
meta.accountShare[account] += share;
meta.accountIntegral[account] = meta.earnedIntegral;
}
/// @notice Claims all CRV, CVX and CNC earned by a user. All extra reward
/// tokens earned will be sold for CNC.
/// @dev Conic pool LP tokens need to be staked in the `LpTokenStaker` in
/// order to receive a share of the CRV, CVX and CNC earnings.
/// after selling all extra reward tokens.
function claimEarnings()
public
override
returns (
uint256,
uint256,
uint256
)
{
_accountCheckpoint(msg.sender);
uint256 crvAmount = _rewardsMeta[_CRV_KEY].accountShare[msg.sender];
uint256 cvxAmount = _rewardsMeta[_CVX_KEY].accountShare[msg.sender];
uint256 cncAmount = _rewardsMeta[_CNC_KEY].accountShare[msg.sender];
if (
crvAmount > CRV.balanceOf(pool) ||
cvxAmount > CVX.balanceOf(pool) ||
cncAmount > CNC.balanceOf(pool)
) {
_claimPoolEarningsAndSellRewardTokens();
}
_rewardsMeta[_CNC_KEY].accountShare[msg.sender] = 0;
_rewardsMeta[_CVX_KEY].accountShare[msg.sender] = 0;
_rewardsMeta[_CRV_KEY].accountShare[msg.sender] = 0;
CRV.safeTransferFrom(pool, msg.sender, crvAmount);
CVX.safeTransferFrom(pool, msg.sender, cvxAmount);
CNC.safeTransferFrom(pool, msg.sender, cncAmount);
_oldCrvBalance = CRV.balanceOf(pool);
_oldCvxBalance = CVX.balanceOf(pool);
emit EarningsClaimed(msg.sender, cncAmount, crvAmount, cvxAmount);
return (cncAmount, crvAmount, cvxAmount);
}
/// @notice Claims all claimable CVX and CRV from Convex for all staked Curve LP tokens.
/// Then Swaps all additional rewards tokens for CNC.
function claimPoolEarningsAndSellRewardTokens() external override {
if (!poolCheckpoint()) {
_claimPoolEarningsAndSellRewardTokens();
_oldCrvBalance = CRV.balanceOf(pool);
_oldCvxBalance = CVX.balanceOf(pool);
}
}
function _claimPoolEarningsAndSellRewardTokens() internal {
_rewardsMeta[_CRV_KEY].lastEarned = 0;
_rewardsMeta[_CVX_KEY].lastEarned = 0;
_rewardsMeta[_CNC_KEY].lastEarned = 0;
_claimPoolEarnings();
uint256 cncBalanceBefore_ = CNC.balanceOf(pool);
_sellRewardTokens();
uint256 receivedCnc_ = CNC.balanceOf(pool) - cncBalanceBefore_;
uint256 _totalStaked = controller.lpTokenStaker().getBalanceForPool(pool);
if (_totalStaked > 0)
_rewardsMeta[_CNC_KEY].earnedIntegral += receivedCnc_.divDown(_totalStaked);
emit SoldRewardTokens(receivedCnc_);
}
/// @notice Claims all claimable CVX and CRV from Convex for all staked Curve LP tokens
function _claimPoolEarnings() internal {
controller.lpTokenStaker().claimCNCRewardsForPool(pool);
uint256 cvxBalance = CVX.balanceOf(pool);
uint256 crvBalance = CRV.balanceOf(pool);
address convexHandler = controller.convexHandler();
IConvexHandler(convexHandler).claimBatchEarnings(IConicPool(pool).allCurvePools(), pool);
uint256 claimedCvx = CVX.balanceOf(pool) - cvxBalance;
uint256 claimedCrv = CRV.balanceOf(pool) - crvBalance;
emit ClaimedRewards(claimedCrv, claimedCvx);
}
/// @notice Swaps all additional rewards tokens for CNC.
function _sellRewardTokens() internal {
uint256 extraRewardsLength_ = _extraRewards.length();
if (extraRewardsLength_ == 0) return;
for (uint256 i; i < extraRewardsLength_; i++) {
_swapRewardTokenForWeth(_extraRewards.at(i));
}
_swapWethForCNC();
}
function listExtraRewards() external view returns (address[] memory) {
return _extraRewards.values();
}
function addExtraReward(address reward) public override onlyOwner returns (bool) {
require(reward != address(0), "invalid address");
require(
reward != address(CVX) &&
reward != address(CRV) &&
reward != address(underlying) &&
reward != address(CNC),
"token not allowed"
);
// Checking reward token isn't a Curve Pool LP Token
address[] memory curvePools_ = IConicPool(pool).allCurvePools();
for (uint256 i; i < curvePools_.length; i++) {
address curveLpToken_ = controller.curveRegistryCache().lpToken(curvePools_[i]);
require(reward != curveLpToken_, "token not allowed");
}
IERC20(reward).safeApprove(address(SUSHISWAP), 0);
IERC20(reward).safeApprove(address(SUSHISWAP), type(uint256).max);
emit ExtraRewardAdded(reward);
return _extraRewards.add(reward);
}
function addBatchExtraRewards(address[] memory _rewards) external override onlyOwner {
for (uint256 i; i < _rewards.length; i++) {
addExtraReward(_rewards[i]);
}
}
function removeExtraReward(address tokenAddress) external onlyOwner {
_extraRewards.remove(tokenAddress);
emit ExtraRewardRemoved(tokenAddress);
}
function setExtraRewardsCurvePool(address extraReward_, address curvePool_) external onlyOwner {
require(curvePool_ != extraRewardsCurvePool[extraReward_], "must be different to current");
if (curvePool_ != address(0)) {
IERC20(extraReward_).safeApprove(curvePool_, 0);
IERC20(extraReward_).safeApprove(curvePool_, type(uint256).max);
}
extraRewardsCurvePool[extraReward_] = curvePool_;
emit ExtraRewardsCurvePoolSet(extraReward_, curvePool_);
}
function setFeePercentage(uint256 _feePercentage) external override onlyOwner {
require(_feePercentage < MAX_FEE_PERCENTAGE, "cannot set fee percentage to more than 30%");
require(locker.totalBoosted() > 0);
feePercentage = _feePercentage;
feesEnabled = true;
emit FeesSet(feePercentage);
}
function claimableRewards(address account)
external
view
returns (
uint256 cncRewards,
uint256 crvRewards,
uint256 cvxRewards
)
{
uint256 _totalStaked = controller.lpTokenStaker().getBalanceForPool(pool);
if (_totalStaked == 0) return (0, 0, 0);
(uint256 crvEarned, uint256 cvxEarned, uint256 cncEarned) = _getEarnedRewards();
uint256 userBalance = controller.lpTokenStaker().getUserBalanceForPool(pool, account);
cncRewards = _getClaimableReward(
account,
_CNC_KEY,
cncEarned,
userBalance,
_totalStaked,
false
);
crvRewards = _getClaimableReward(
account,
_CRV_KEY,
crvEarned,
userBalance,
_totalStaked,
feesEnabled
);
cvxRewards = _getClaimableReward(
account,
_CVX_KEY,
cvxEarned,
userBalance,
_totalStaked,
feesEnabled
);
}
function _getClaimableReward(
address account,
bytes32 key,
uint256 earned,
uint256 userBalance,
uint256 _totalSupply,
bool deductFee
) internal view returns (uint256) {
RewardMeta storage meta = _rewardsMeta[key];
uint256 integral = meta.earnedIntegral;
if (deductFee) {
integral += earned.divDown(_totalSupply).mulDown(ScaledMath.ONE - feePercentage);
} else {
integral += earned.divDown(_totalSupply);
}
return
meta.accountShare[account] +
userBalance.mulDown(integral - meta.accountIntegral[account]);
}
function _swapRewardTokenForWeth(address rewardToken_) internal {
uint256 tokenBalance_ = IERC20(rewardToken_).balanceOf(address(this));
if (tokenBalance_ == 0) return;
ICurvePoolV2 curvePool_ = ICurvePoolV2(extraRewardsCurvePool[rewardToken_]);
if (address(curvePool_) != address(0)) {
(int128 i, int128 j, ) = controller.curveRegistryCache().coinIndices(
address(curvePool_),
rewardToken_,
address(WETH)
);
(uint256 from_, uint256 to_) = (uint256(uint128(i)), uint256(uint128(j)));
curvePool_.exchange(
from_,
to_,
tokenBalance_,
_minAmountOut(address(rewardToken_), address(WETH), tokenBalance_),
false,
address(this)
);
return;
}
address[] memory path_ = new address[](2);
path_[0] = rewardToken_;
path_[1] = address(WETH);
SUSHISWAP.swapExactTokensForTokens(
tokenBalance_,
_minAmountOut(address(rewardToken_), address(WETH), tokenBalance_),
path_,
address(this),
block.timestamp
);
}
function _swapWethForCNC() internal {
uint256 wethBalance_ = WETH.balanceOf(address(this));
if (wethBalance_ == 0) return;
CNC_ETH_POOL.exchange(
0,
1,
wethBalance_,
_minAmountOut(address(WETH), address(CNC), wethBalance_),
false,
pool
);
}
function _minAmountOut(
address tokenIn_,
address tokenOut_,
uint256 amountIn_
) internal view returns (uint256) {
IOracle oracle_ = controller.priceOracle();
if (tokenIn_ == tokenOut_) {
return amountIn_;
}
// If we don't have a price for either token, we can't calculate the min amount out
// This should only ever happen for very minor tokens, so we accept the risk of not having
// slippage protection in that case
if (!oracle_.isTokenSupported(tokenIn_) || !oracle_.isTokenSupported(tokenOut_)) {
return 0;
}
return
amountIn_
.mulDown(oracle_.getUSDPrice(tokenIn_))
.divDown(oracle_.getUSDPrice(tokenOut_))
.convertScale(
IERC20Metadata(tokenIn_).decimals(),
IERC20Metadata(tokenOut_).decimals()
)
.mulDown(SLIPPAGE_THRESHOLD);
}
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
import "./pools/IConicPool.sol";
import "./IOracle.sol";
import "./tokenomics/IInflationManager.sol";
import "./tokenomics/ILpTokenStaker.sol";
import "./ICurveRegistryCache.sol";
interface IController {
event PoolAdded(address indexed pool);
event PoolRemoved(address indexed pool);
event PoolShutdown(address indexed pool);
event ConvexBoosterSet(address convexBooster);
event CurveHandlerSet(address curveHandler);
event ConvexHandlerSet(address convexHandler);
event CurveRegistryCacheSet(address curveRegistryCache);
event InflationManagerSet(address inflationManager);
event PriceOracleSet(address priceOracle);
event WeightUpdateMinDelaySet(uint256 weightUpdateMinDelay);
struct WeightUpdate {
address conicPoolAddress;
IConicPool.PoolWeight[] weights;
}
// inflation manager
function inflationManager() external view returns (IInflationManager);
function setInflationManager(address manager) external;
// views
function curveRegistryCache() external view returns (ICurveRegistryCache);
/// lp token staker
function setLpTokenStaker(address _lpTokenStaker) external;
function lpTokenStaker() external view returns (ILpTokenStaker);
// oracle
function priceOracle() external view returns (IOracle);
function setPriceOracle(address oracle) external;
// pool functions
function listPools() external view returns (address[] memory);
function listActivePools() external view returns (address[] memory);
function isPool(address poolAddress) external view returns (bool);
function isActivePool(address poolAddress) external view returns (bool);
function addPool(address poolAddress) external;
function shutdownPool(address poolAddress) external;
function removePool(address poolAddress) external;
function cncToken() external view returns (address);
function lastWeightUpdate(address poolAddress) external view returns (uint256);
function updateWeights(WeightUpdate memory update) external;
function updateAllWeights(WeightUpdate[] memory weights) external;
// handler functions
function convexBooster() external view returns (address);
function curveHandler() external view returns (address);
function convexHandler() external view returns (address);
function setConvexBooster(address _convexBooster) external;
function setCurveHandler(address _curveHandler) external;
function setConvexHandler(address _convexHandler) external;
function setCurveRegistryCache(address curveRegistryCache_) external;
function emergencyMinter() external view returns (address);
function setWeightUpdateMinDelay(uint256 delay) external;
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
interface IConvexHandler {
function deposit(address _curvePool, uint256 _amount) external;
function claimBatchEarnings(address[] memory _curvePools, address _conicPool) external;
function getRewardPool(address _curvePool) external view returns (address);
function getCrvEarned(address _account, address _curvePool) external view returns (uint256);
function getCrvEarnedBatch(address _account, address[] memory _curvePools)
external
view
returns (uint256);
function computeClaimableConvex(uint256 crvAmount) external view returns (uint256);
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
interface ICurveHandler {
function deposit(
address _curvePool,
address _token,
uint256 _amount
) external;
function withdraw(
address _curvePool,
address _token,
uint256 _amount
) external;
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
import "./vendor/IBooster.sol";
import "../libraries/CurvePoolUtils.sol";
interface ICurveRegistryCache {
function BOOSTER() external view returns (IBooster);
function initPool(address pool_) external;
function initPool(address pool_, uint256 pid_) external;
function lpToken(address pool_) external view returns (address);
function assetType(address pool_) external view returns (CurvePoolUtils.AssetType);
function isRegistered(address pool_) external view returns (bool);
function hasCoinDirectly(address pool_, address coin_) external view returns (bool);
function hasCoinAnywhere(address pool_, address coin_) external view returns (bool);
function basePool(address pool_) external view returns (address);
function coinIndex(address pool_, address coin_) external view returns (int128);
function nCoins(address pool_) external view returns (uint256);
function coinIndices(
address pool_,
address from_,
address to_
)
external
view
returns (
int128,
int128,
bool
);
function decimals(address pool_) external view returns (uint256[] memory);
function interfaceVersion(address pool_) external view returns (uint256);
function poolFromLpToken(address lpToken_) external view returns (address);
function coins(address pool_) external view returns (address[] memory);
function getPid(address _pool) external view returns (uint256);
function getRewardPool(address _pool) external view returns (address);
function isShutdownPid(uint256 pid_) external view returns (bool);
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
interface IOracle {
event TokenUpdated(address indexed token, address feed, uint256 maxDelay, bool isEthPrice);
/// @notice returns the price in USD of symbol.
function getUSDPrice(address token) external view returns (uint256);
/// @notice returns if the given token is supported for pricing.
function isTokenSupported(address token) external view returns (bool);
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
import "./ILpToken.sol";
import "./IRewardManager.sol";
import "../IOracle.sol";
interface IConicPool {
event Deposit(
address indexed sender,
address indexed receiver,
uint256 depositedAmount,
uint256 lpReceived
);
event Withdraw(address indexed account, uint256 amount);
event NewWeight(address indexed curvePool, uint256 newWeight);
event NewMaxIdleCurveLpRatio(uint256 newRatio);
event ClaimedRewards(uint256 claimedCrv, uint256 claimedCvx);
event HandledDepeggedCurvePool(address curvePool_);
event HandledInvalidConvexPid(address curvePool_, uint256 pid_);
event CurvePoolAdded(address curvePool_);
event CurvePoolRemoved(address curvePool_);
event Shutdown();
event DepegThresholdUpdated(uint256 newThreshold);
event MaxDeviationUpdated(uint256 newMaxDeviation);
struct PoolWeight {
address poolAddress;
uint256 weight;
}
struct PoolWithAmount {
address poolAddress;
uint256 amount;
}
function underlying() external view returns (IERC20Metadata);
function lpToken() external view returns (ILpToken);
function rewardManager() external view returns (IRewardManager);
function depositFor(
address _account,
uint256 _amount,
uint256 _minLpReceived,
bool stake
) external returns (uint256);
function deposit(uint256 _amount, uint256 _minLpReceived) external returns (uint256);
function deposit(
uint256 _amount,
uint256 _minLpReceived,
bool stake
) external returns (uint256);
function exchangeRate() external view returns (uint256);
function usdExchangeRate() external view returns (uint256);
function allCurvePools() external view returns (address[] memory);
function curvePoolsCount() external view returns (uint256);
function getCurvePoolAtIndex(uint256 _index) external view returns (address);
function unstakeAndWithdraw(uint256 _amount, uint256 _minAmount) external returns (uint256);
function withdraw(uint256 _amount, uint256 _minAmount) external returns (uint256);
function updateWeights(PoolWeight[] memory poolWeights) external;
function getWeight(address curvePool) external view returns (uint256);
function getWeights() external view returns (PoolWeight[] memory);
function getAllocatedUnderlying() external view returns (PoolWithAmount[] memory);
function removeCurvePool(address pool) external;
function addCurvePool(address pool) external;
function totalCurveLpBalance(address curvePool_) external view returns (uint256);
function rebalancingRewardActive() external view returns (bool);
function totalDeviationAfterWeightUpdate() external view returns (uint256);
function computeTotalDeviation() external view returns (uint256);
/// @notice returns the total amount of funds held by this pool in terms of underlying
function totalUnderlying() external view returns (uint256);
function getTotalAndPerPoolUnderlying()
external
view
returns (
uint256 totalUnderlying_,
uint256 totalAllocated_,
uint256[] memory perPoolUnderlying_
);
/// @notice same as `totalUnderlying` but returns a cached version
/// that might be slightly outdated if oracle prices have changed
/// @dev this is useful in cases where we want to reduce gas usage and do
/// not need a precise value
function cachedTotalUnderlying() external view returns (uint256);
function handleInvalidConvexPid(address pool) external;
function shutdownPool() external;
function isShutdown() external view returns (bool);
function handleDepeggedCurvePool(address curvePool_) external;
function isBalanced() external view returns (bool);
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
interface ILpToken is IERC20Metadata {
function mint(address account, uint256 amount) external returns (uint256);
function burn(address _owner, uint256 _amount) external returns (uint256);
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
interface IRewardManager {
event ClaimedRewards(uint256 claimedCrv, uint256 claimedCvx);
event SoldRewardTokens(uint256 targetTokenReceived);
event ExtraRewardAdded(address reward);
event ExtraRewardRemoved(address reward);
event ExtraRewardsCurvePoolSet(address extraReward, address curvePool);
event FeesSet(uint256 feePercentage);
event FeesEnabled(uint256 feePercentage);
event EarningsClaimed(
address indexed claimedBy,
uint256 cncEarned,
uint256 crvEarned,
uint256 cvxEarned
);
struct RewardMeta {
uint256 earnedIntegral;
uint256 lastEarned;
mapping(address => uint256) accountIntegral;
mapping(address => uint256) accountShare;
}
function accountCheckpoint(address account) external;
function poolCheckpoint() external returns (bool);
function addExtraReward(address reward) external returns (bool);
function addBatchExtraRewards(address[] memory rewards) external;
function pool() external view returns (address);
function setFeePercentage(uint256 _feePercentage) external;
function claimableRewards(address account)
external
view
returns (
uint256 cncRewards,
uint256 crvRewards,
uint256 cvxRewards
);
function claimEarnings()
external
returns (
uint256,
uint256,
uint256
);
function claimPoolEarningsAndSellRewardTokens() external;
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
import "../../libraries/MerkleProof.sol";
interface ICNCLockerV2 {
event Locked(address indexed account, uint256 amount, uint256 unlockTime, bool relocked);
event UnlockExecuted(address indexed account, uint256 amount);
event Relocked(address indexed account, uint256 amount);
event KickExecuted(address indexed account, address indexed kicker, uint256 amount);
event FeesReceived(address indexed sender, uint256 crvAmount, uint256 cvxAmount);
event FeesClaimed(address indexed claimer, uint256 crvAmount, uint256 cvxAmount);
event AirdropBoostClaimed(address indexed claimer, uint256 amount);
event Shutdown();
event TokenRecovered(address indexed token);
struct VoteLock {
uint256 amount;
uint64 unlockTime;
uint128 boost;
uint64 id;
}
function lock(uint256 amount, uint64 lockTime) external;
function lock(
uint256 amount,
uint64 lockTime,
bool relock
) external;
function lockFor(
uint256 amount,
uint64 lockTime,
bool relock,
address account
) external;
function relock(uint64 lockId, uint64 lockTime) external;
function relock(uint64 lockTime) external;
function relockMultiple(uint64[] calldata lockIds, uint64 lockTime) external;
function totalBoosted() external view returns (uint256);
function shutDown() external;
function recoverToken(address token) external;
function executeAvailableUnlocks() external returns (uint256);
function executeAvailableUnlocksFor(address dst) external returns (uint256);
function executeUnlocks(address dst, uint64[] calldata lockIds) external returns (uint256);
function claimAirdropBoost(uint256 amount, MerkleProof.Proof calldata proof) external;
// This will need to include the boosts etc.
function balanceOf(address user) external view returns (uint256);
function unlockableBalance(address user) external view returns (uint256);
function unlockableBalanceBoosted(address user) external view returns (uint256);
function kick(address user, uint64 lockId) external;
function receiveFees(uint256 amountCrv, uint256 amountCvx) external;
function claimableFees(address account)
external
view
returns (uint256 claimableCrv, uint256 claimableCvx);
function claimFees() external returns (uint256 crvAmount, uint256 cvxAmount);
function computeBoost(uint128 lockTime) external view returns (uint128);
function airdropBoost(address account) external view returns (uint256);
function claimedAirdrop(address account) external view returns (bool);
function totalVoteBoost(address account) external view returns (uint256);
function totalRewardsBoost(address account) external view returns (uint256);
function userLocks(address account) external view returns (VoteLock[] memory);
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
interface IInflationManager {
event TokensClaimed(address indexed pool, uint256 cncAmount);
event RebalancingRewardHandlerAdded(address indexed pool, address indexed handler);
event RebalancingRewardHandlerRemoved(address indexed pool, address indexed handler);
event PoolWeightsUpdated();
function executeInflationRateUpdate() external;
function updatePoolWeights() external;
/// @notice returns the weights of the Conic pools to know how much inflation
/// each of them will receive, as well as the total amount of USD value in all the pools
function computePoolWeights()
external
view
returns (
address[] memory _pools,
uint256[] memory poolWeights,
uint256 totalUSDValue
);
function computePoolWeight(address pool)
external
view
returns (uint256 poolWeight, uint256 totalUSDValue);
function currentInflationRate() external view returns (uint256);
function getCurrentPoolInflationRate(address pool) external view returns (uint256);
function handleRebalancingRewards(
address account,
uint256 deviationBefore,
uint256 deviationAfter
) external;
function addPoolRebalancingRewardHandler(address poolAddress, address rebalancingRewardHandler)
external;
function removePoolRebalancingRewardHandler(
address poolAddress,
address rebalancingRewardHandler
) external;
function rebalancingRewardHandlers(address poolAddress)
external
view
returns (address[] memory);
function hasPoolRebalancingRewardHandlers(address poolAddress, address handler)
external
view
returns (bool);
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
interface ILpTokenStaker {
event LpTokenStaked(address indexed account, uint256 amount);
event LpTokenUnstaked(address indexed account, uint256 amount);
event TokensClaimed(address indexed pool, uint256 cncAmount);
event Shutdown();
function stake(uint256 amount, address conicPool) external;
function unstake(uint256 amount, address conicPool) external;
function stakeFor(
uint256 amount,
address conicPool,
address account
) external;
function unstakeFor(
uint256 amount,
address conicPool,
address account
) external;
function unstakeFrom(uint256 amount, address account) external;
function getUserBalanceForPool(address conicPool, address account)
external
view
returns (uint256);
function getBalanceForPool(address conicPool) external view returns (uint256);
function updateBoost(address user) external;
function claimCNCRewardsForPool(address pool) external;
function claimableCnc(address pool) external view returns (uint256);
function checkpoint(address pool) external returns (uint256);
function shutdown() external;
function getBoost(address user) external view returns (uint256);
}
// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.17;
interface IBooster {
function poolInfo(uint256 pid)
external
view
returns (
address lpToken,
address token,
address gauge,
address crvRewards,
address stash,
bool shutdown
);
function poolLength() external view returns (uint256);
function deposit(
uint256 _pid,
uint256 _amount,
bool _stake
) external returns (bool);
function withdraw(uint256 _pid, uint256 _amount) external returns (bool);
function withdrawAll(uint256 _pid) external returns (bool);
function depositAll(uint256 _pid, bool _stake) external returns (bool);
function earmarkRewards(uint256 _pid) external returns (bool);
function isShutdown() external view returns (bool);
}
// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.17;
interface ICurvePoolV1 {
function get_virtual_price() external view returns (uint256);
function add_liquidity(uint256[8] calldata amounts, uint256 min_mint_amount) external;
function add_liquidity(uint256[7] calldata amounts, uint256 min_mint_amount) external;
function add_liquidity(uint256[6] calldata amounts, uint256 min_mint_amount) external;
function add_liquidity(uint256[5] calldata amounts, uint256 min_mint_amount) external;
function add_liquidity(uint256[4] calldata amounts, uint256 min_mint_amount) external;
function add_liquidity(uint256[3] calldata amounts, uint256 min_mint_amount) external;
function add_liquidity(uint256[2] calldata amounts, uint256 min_mint_amount) external;
function remove_liquidity_imbalance(uint256[4] calldata amounts, uint256 max_burn_amount)
external;
function remove_liquidity_imbalance(uint256[3] calldata amounts, uint256 max_burn_amount)
external;
function remove_liquidity_imbalance(uint256[2] calldata amounts, uint256 max_burn_amount)
external;
function lp_token() external view returns (address);
function A_PRECISION() external view returns (uint256);
function A_precise() external view returns (uint256);
function remove_liquidity(uint256 _amount, uint256[3] calldata min_amounts) external;
function exchange(
int128 from,
int128 to,
uint256 _from_amount,
uint256 _min_to_amount
) external;
function coins(uint256 i) external view returns (address);
function balances(uint256 i) external view returns (uint256);
function get_dy(
int128 i,
int128 j,
uint256 _dx
) external view returns (uint256);
function calc_token_amount(uint256[4] calldata amounts, bool deposit)
external
view
returns (uint256);
function calc_token_amount(uint256[3] calldata amounts, bool deposit)
external
view
returns (uint256);
function calc_token_amount(uint256[2] calldata amounts, bool deposit)
external
view
returns (uint256);
function calc_withdraw_one_coin(uint256 _token_amount, int128 i)
external
view
returns (uint256);
function remove_liquidity_one_coin(
uint256 _token_amount,
int128 i,
uint256 min_amount
) external;
}
// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.17;
interface ICurvePoolV2 {
function token() external view returns (address);
function coins(uint256 i) external view returns (address);
function factory() external view returns (address);
function exchange(
uint256 i,
uint256 j,
uint256 dx,
uint256 min_dy,
bool use_eth,
address receiver
) external returns (uint256);
function exchange_underlying(
uint256 i,
uint256 j,
uint256 dx,
uint256 min_dy,
address receiver
) external returns (uint256);
function add_liquidity(
uint256[2] memory amounts,
uint256 min_mint_amount,
bool use_eth,
address receiver
) external returns (uint256);
function add_liquidity(uint256[2] memory amounts, uint256 min_mint_amount)
external
returns (uint256);
function add_liquidity(
uint256[3] memory amounts,
uint256 min_mint_amount,
bool use_eth,
address receiver
) external returns (uint256);
function add_liquidity(uint256[3] memory amounts, uint256 min_mint_amount)
external
returns (uint256);
function remove_liquidity(
uint256 _amount,
uint256[2] memory min_amounts,
bool use_eth,
address receiver
) external;
function remove_liquidity(uint256 _amount, uint256[2] memory min_amounts)
external;
function remove_liquidity(
uint256 _amount,
uint256[3] memory min_amounts,
bool use_eth,
address receiver
) external;
function remove_liquidity(uint256 _amount, uint256[3] memory min_amounts)
external;
function remove_liquidity_one_coin(
uint256 token_amount,
uint256 i,
uint256 min_amount,
bool use_eth,
address receiver
) external returns (uint256);
function get_dy(
uint256 i,
uint256 j,
uint256 dx
) external view returns (uint256);
function calc_token_amount(uint256[] memory amounts)
external
view
returns (uint256);
function calc_withdraw_one_coin(uint256 token_amount, uint256 i)
external
view
returns (uint256);
function get_virtual_price() external view returns (uint256);
}
// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.17;
interface UniswapRouter02 {
function swapTokensForExactTokens(
uint256 amountOut,
uint256 amountInMax,
address[] calldata path,
address to,
uint256 deadline
) external returns (uint256[] memory amounts);
function swapExactTokensForTokens(
uint256 amountIn,
uint256 amountOutMin,
address[] calldata path,
address to,
uint256 deadline
) external returns (uint256[] memory amounts);
function swapETHForExactTokens(
uint256 amountOut,
address[] calldata path,
address to,
uint256 deadline
) external payable returns (uint256[] memory amounts);
function swapExactTokensForETH(
uint256 amountIn,
uint256 amountOutMin,
address[] calldata path,
address to,
uint256 deadline
) external returns (uint256[] memory amounts);
function getAmountIn(
uint256 amountOut,
uint256 reserveIn,
uint256 reserveOut
) external returns (uint256 amountIn);
function getAmountOut(
uint256 amountIn,
uint256 reserveIn,
uint256 reserveOut
) external view returns (uint256 amountOut);
function getAmountsIn(uint256 amountOut, address[] calldata path)
external
view
returns (uint256[] memory amounts);
function getAmountsOut(uint256 amountIn, address[] memory path)
external
view
returns (uint256[] memory amounts);
function getReserves(
address factory,
address tokenA,
address tokenB
) external view returns (uint256 reserveA, uint256 reserveB);
function WETH() external pure returns (address);
}
interface UniswapV2Pair {
function getReserves()
external
view
returns (
uint112 _reserve0,
uint112 _reserve1,
uint32 _blockTimestampLast
);
}
interface UniswapV2Factory {
function getPair(address tokenA, address tokenB)
external
view
returns (address pair);
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
import "../interfaces/vendor/ICurvePoolV2.sol";
import "../interfaces/vendor/ICurvePoolV1.sol";
import "./ScaledMath.sol";
library CurvePoolUtils {
using ScaledMath for uint256;
uint256 internal constant _DEFAULT_IMBALANCE_THRESHOLD = 0.02e18;
enum AssetType {
USD,
ETH,
BTC,
OTHER,
CRYPTO
}
struct PoolMeta {
address pool;
uint256 numberOfCoins;
AssetType assetType;
uint256[] decimals;
uint256[] prices;
uint256[] thresholds;
}
function ensurePoolBalanced(PoolMeta memory poolMeta) internal view {
uint256 fromDecimals = poolMeta.decimals[0];
uint256 fromBalance = 10**fromDecimals;
uint256 fromPrice = poolMeta.prices[0];
for (uint256 i = 1; i < poolMeta.numberOfCoins; i++) {
uint256 toDecimals = poolMeta.decimals[i];
uint256 toPrice = poolMeta.prices[i];
uint256 toExpectedUnscaled = (fromBalance * fromPrice) / toPrice;
uint256 toExpected = toExpectedUnscaled.convertScale(
uint8(fromDecimals),
uint8(toDecimals)
);
uint256 toActual;
if (poolMeta.assetType == AssetType.CRYPTO) {
// Handling crypto pools
toActual = ICurvePoolV2(poolMeta.pool).get_dy(0, i, fromBalance);
} else {
// Handling other pools
toActual = ICurvePoolV1(poolMeta.pool).get_dy(0, int128(uint128(i)), fromBalance);
}
require(
_isWithinThreshold(toExpected, toActual, poolMeta.thresholds[i]),
"pool is not balanced"
);
}
}
function _isWithinThreshold(
uint256 a,
uint256 b,
uint256 imbalanceTreshold
) internal pure returns (bool) {
if (imbalanceTreshold == 0) imbalanceTreshold = _DEFAULT_IMBALANCE_THRESHOLD;
if (a > b) return (a - b).divDown(a) <= imbalanceTreshold;
return (b - a).divDown(b) <= imbalanceTreshold;
}
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
library MerkleProof {
struct Proof {
uint16 nodeIndex;
bytes32[] hashes;
}
function isValid(
Proof memory proof,
bytes32 node,
bytes32 merkleRoot
) internal pure returns (bool) {
uint256 length = proof.hashes.length;
uint16 nodeIndex = proof.nodeIndex;
for (uint256 i = 0; i < length; i++) {
if (nodeIndex % 2 == 0) {
node = keccak256(abi.encodePacked(node, proof.hashes[i]));
} else {
node = keccak256(abi.encodePacked(proof.hashes[i], node));
}
nodeIndex /= 2;
}
return node == merkleRoot;
}
}
// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity 0.8.17;
library ScaledMath {
uint256 internal constant DECIMALS = 18;
uint256 internal constant ONE = 10**DECIMALS;
function mulDown(uint256 a, uint256 b) internal pure returns (uint256) {
return (a * b) / ONE;
}
function mulDown(
uint256 a,
uint256 b,
uint256 decimals
) internal pure returns (uint256) {
return (a * b) / (10**decimals);
}
function divDown(uint256 a, uint256 b) internal pure returns (uint256) {
return (a * ONE) / b;
}
function divDown(
uint256 a,
uint256 b,
uint256 decimals
) internal pure returns (uint256) {
return (a * 10**decimals) / b;
}
function divUp(uint256 a, uint256 b) internal pure returns (uint256) {
if (a == 0) {
return 0;
}
return ((a * ONE) - 1) / b + 1;
}
function mulDown(int256 a, int256 b) internal pure returns (int256) {
return (a * b) / int256(ONE);
}
function mulDownUint128(uint128 a, uint128 b) internal pure returns (uint128) {
return (a * b) / uint128(ONE);
}
function mulDown(
int256 a,
int256 b,
uint256 decimals
) internal pure returns (int256) {
return (a * b) / int256(10**decimals);
}
function divDown(int256 a, int256 b) internal pure returns (int256) {
return (a * int256(ONE)) / b;
}
function divDownUint128(uint128 a, uint128 b) internal pure returns (uint128) {
return (a * uint128(ONE)) / b;
}
function divDown(
int256 a,
int256 b,
uint256 decimals
) internal pure returns (int256) {
return (a * int256(10**decimals)) / b;
}
function convertScale(
uint256 a,
uint8 fromDecimals,
uint8 toDecimals
) internal pure returns (uint256) {
if (fromDecimals == toDecimals) return a;
if (fromDecimals > toDecimals) return downscale(a, fromDecimals, toDecimals);
return upscale(a, fromDecimals, toDecimals);
}
function convertScale(
int256 a,
uint8 fromDecimals,
uint8 toDecimals
) internal pure returns (int256) {
if (fromDecimals == toDecimals) return a;
if (fromDecimals > toDecimals) return downscale(a, fromDecimals, toDecimals);
return upscale(a, fromDecimals, toDecimals);
}
function upscale(
uint256 a,
uint8 fromDecimals,
uint8 toDecimals
) internal pure returns (uint256) {
return a * (10**(toDecimals - fromDecimals));
}
function downscale(
uint256 a,
uint8 fromDecimals,
uint8 toDecimals
) internal pure returns (uint256) {
return a / (10**(fromDecimals - toDecimals));
}
function upscale(
int256 a,
uint8 fromDecimals,
uint8 toDecimals
) internal pure returns (int256) {
return a * int256(10**(toDecimals - fromDecimals));
}
function downscale(
int256 a,
uint8 fromDecimals,
uint8 toDecimals
) internal pure returns (int256) {
return a / int256(10**(fromDecimals - toDecimals));
}
function intPow(uint256 a, uint256 n) internal pure returns (uint256) {
uint256 result = ONE;
for (uint256 i; i < n; ) {
result = mulDown(result, a);
unchecked {
++i;
}
}
return result;
}
function absSub(uint256 a, uint256 b) internal pure returns (uint256) {
unchecked {
return a >= b ? a - b : b - a;
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
* @dev Contract module which provides a basic access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership}.
*
* This module is used through inheritance. It will make available the modifier
* `onlyOwner`, which can be applied to your functions to restrict their use to
* the owner.
*/
abstract contract Ownable is Context {
address private _owner;
event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
/**
* @dev Initializes the contract setting the deployer as the initial owner.
*/
constructor() {
_transferOwnership(_msgSender());
}
/**
* @dev Throws if called by any account other than the owner.
*/
modifier onlyOwner() {
_checkOwner();
_;
}
/**
* @dev Returns the address of the current owner.
*/
function owner() public view virtual returns (address) {
return _owner;
}
/**
* @dev Throws if the sender is not the owner.
*/
function _checkOwner() internal view virtual {
require(owner() == _msgSender(), "Ownable: caller is not the owner");
}
/**
* @dev Leaves the contract without owner. It will not be possible to call
* `onlyOwner` functions anymore. Can only be called by the current owner.
*
* NOTE: Renouncing ownership will leave the contract without an owner,
* thereby removing any functionality that is only available to the owner.
*/
function renounceOwnership() public virtual onlyOwner {
_transferOwnership(address(0));
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual onlyOwner {
require(newOwner != address(0), "Ownable: new owner is the zero address");
_transferOwnership(newOwner);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Internal function without access restriction.
*/
function _transferOwnership(address newOwner) internal virtual {
address oldOwner = _owner;
_owner = newOwner;
emit OwnershipTransferred(oldOwner, newOwner);
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(
address from,
address to,
uint256 amount
) external returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
/**
* @dev Interface for the optional metadata functions from the ERC20 standard.
*
* _Available since v4.1._
*/
interface IERC20Metadata is IERC20 {
/**
* @dev Returns the name of the token.
*/
function name() external view returns (string memory);
/**
* @dev Returns the symbol of the token.
*/
function symbol() external view returns (string memory);
/**
* @dev Returns the decimals places of the token.
*/
function decimals() external view returns (uint8);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
* https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
*
* Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
* presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
* need to send a transaction, and thus is not required to hold Ether at all.
*/
interface IERC20Permit {
/**
* @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
* given ``owner``'s signed approval.
*
* IMPORTANT: The same issues {IERC20-approve} has related to transaction
* ordering also apply here.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `deadline` must be a timestamp in the future.
* - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
* over the EIP712-formatted function arguments.
* - the signature must use ``owner``'s current nonce (see {nonces}).
*
* For more information on the signature format, see the
* https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
* section].
*/
function permit(
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external;
/**
* @dev Returns the current nonce for `owner`. This value must be
* included whenever a signature is generated for {permit}.
*
* Every successful call to {permit} increases ``owner``'s nonce by one. This
* prevents a signature from being used multiple times.
*/
function nonces(address owner) external view returns (uint256);
/**
* @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
*/
// solhint-disable-next-line func-name-mixedcase
function DOMAIN_SEPARATOR() external view returns (bytes32);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
function safeTransfer(
IERC20 token,
address to,
uint256 value
) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
}
function safeTransferFrom(
IERC20 token,
address from,
address to,
uint256 value
) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
}
/**
* @dev Deprecated. This function has issues similar to the ones found in
* {IERC20-approve}, and its usage is discouraged.
*
* Whenever possible, use {safeIncreaseAllowance} and
* {safeDecreaseAllowance} instead.
*/
function safeApprove(
IERC20 token,
address spender,
uint256 value
) internal {
// safeApprove should only be called when setting an initial allowance,
// or when resetting it to zero. To increase and decrease it, use
// 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
require(
(value == 0) || (token.allowance(address(this), spender) == 0),
"SafeERC20: approve from non-zero to non-zero allowance"
);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
}
function safeIncreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
uint256 newAllowance = token.allowance(address(this), spender) + value;
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
}
function safeDecreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
unchecked {
uint256 oldAllowance = token.allowance(address(this), spender);
require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
uint256 newAllowance = oldAllowance - value;
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
}
}
function safePermit(
IERC20Permit token,
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) internal {
uint256 nonceBefore = token.nonces(owner);
token.permit(owner, spender, value, deadline, v, r, s);
uint256 nonceAfter = token.nonces(owner);
require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
if (returndata.length > 0) {
// Return data is optional
require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
* ====
*
* [IMPORTANT]
* ====
* You shouldn't rely on `isContract` to protect against flash loan attacks!
*
* Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
* like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
* constructor.
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize/address.code.length, which returns 0
// for contracts in construction, since the code is only stored at the end
// of the constructor execution.
return account.code.length > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(address(this).balance >= amount, "Address: insufficient balance");
(bool success, ) = recipient.call{value: amount}("");
require(success, "Address: unable to send value, recipient may have reverted");
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value
) internal returns (bytes memory) {
return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(address(this).balance >= value, "Address: insufficient balance for call");
(bool success, bytes memory returndata) = target.call{value: value}(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
return functionStaticCall(target, data, "Address: low-level static call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
(bool success, bytes memory returndata) = target.staticcall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
return functionDelegateCall(target, data, "Address: low-level delegate call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
(bool success, bytes memory returndata) = target.delegatecall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
* the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
*
* _Available since v4.8._
*/
function verifyCallResultFromTarget(
address target,
bool success,
bytes memory returndata,
string memory errorMessage
) internal view returns (bytes memory) {
if (success) {
if (returndata.length == 0) {
// only check isContract if the call was successful and the return data is empty
// otherwise we already know that it was a contract
require(isContract(target), "Address: call to non-contract");
}
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
/**
* @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
* revert reason or using the provided one.
*
* _Available since v4.3._
*/
function verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) internal pure returns (bytes memory) {
if (success) {
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
function _revert(bytes memory returndata, string memory errorMessage) private pure {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
/// @solidity memory-safe-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)
pragma solidity ^0.8.0;
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.
pragma solidity ^0.8.0;
/**
* @dev Library for managing
* https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
* types.
*
* Sets have the following properties:
*
* - Elements are added, removed, and checked for existence in constant time
* (O(1)).
* - Elements are enumerated in O(n). No guarantees are made on the ordering.
*
* ```
* contract Example {
* // Add the library methods
* using EnumerableSet for EnumerableSet.AddressSet;
*
* // Declare a set state variable
* EnumerableSet.AddressSet private mySet;
* }
* ```
*
* As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
* and `uint256` (`UintSet`) are supported.
*
* [WARNING]
* ====
* Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
* unusable.
* See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
*
* In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
* array of EnumerableSet.
* ====
*/
library EnumerableSet {
// To implement this library for multiple types with as little code
// repetition as possible, we write it in terms of a generic Set type with
// bytes32 values.
// The Set implementation uses private functions, and user-facing
// implementations (such as AddressSet) are just wrappers around the
// underlying Set.
// This means that we can only create new EnumerableSets for types that fit
// in bytes32.
struct Set {
// Storage of set values
bytes32[] _values;
// Position of the value in the `values` array, plus 1 because index 0
// means a value is not in the set.
mapping(bytes32 => uint256) _indexes;
}
/**
* @dev Add a value to a set. O(1).
*
* Returns true if the value was added to the set, that is if it was not
* already present.
*/
function _add(Set storage set, bytes32 value) private returns (bool) {
if (!_contains(set, value)) {
set._values.push(value);
// The value is stored at length-1, but we add 1 to all indexes
// and use 0 as a sentinel value
set._indexes[value] = set._values.length;
return true;
} else {
return false;
}
}
/**
* @dev Removes a value from a set. O(1).
*
* Returns true if the value was removed from the set, that is if it was
* present.
*/
function _remove(Set storage set, bytes32 value) private returns (bool) {
// We read and store the value's index to prevent multiple reads from the same storage slot
uint256 valueIndex = set._indexes[value];
if (valueIndex != 0) {
// Equivalent to contains(set, value)
// To delete an element from the _values array in O(1), we swap the element to delete with the last one in
// the array, and then remove the last element (sometimes called as 'swap and pop').
// This modifies the order of the array, as noted in {at}.
uint256 toDeleteIndex = valueIndex - 1;
uint256 lastIndex = set._values.length - 1;
if (lastIndex != toDeleteIndex) {
bytes32 lastValue = set._values[lastIndex];
// Move the last value to the index where the value to delete is
set._values[toDeleteIndex] = lastValue;
// Update the index for the moved value
set._indexes[lastValue] = valueIndex; // Replace lastValue's index to valueIndex
}
// Delete the slot where the moved value was stored
set._values.pop();
// Delete the index for the deleted slot
delete set._indexes[value];
return true;
} else {
return false;
}
}
/**
* @dev Returns true if the value is in the set. O(1).
*/
function _contains(Set storage set, bytes32 value) private view returns (bool) {
return set._indexes[value] != 0;
}
/**
* @dev Returns the number of values on the set. O(1).
*/
function _length(Set storage set) private view returns (uint256) {
return set._values.length;
}
/**
* @dev Returns the value stored at position `index` in the set. O(1).
*
* Note that there are no guarantees on the ordering of values inside the
* array, and it may change when more values are added or removed.
*
* Requirements:
*
* - `index` must be strictly less than {length}.
*/
function _at(Set storage set, uint256 index) private view returns (bytes32) {
return set._values[index];
}
/**
* @dev Return the entire set in an array
*
* WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
* to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
* this function has an unbounded cost, and using it as part of a state-changing function may render the function
* uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
*/
function _values(Set storage set) private view returns (bytes32[] memory) {
return set._values;
}
// Bytes32Set
struct Bytes32Set {
Set _inner;
}
/**
* @dev Add a value to a set. O(1).
*
* Returns true if the value was added to the set, that is if it was not
* already present.
*/
function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
return _add(set._inner, value);
}
/**
* @dev Removes a value from a set. O(1).
*
* Returns true if the value was removed from the set, that is if it was
* present.
*/
function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
return _remove(set._inner, value);
}
/**
* @dev Returns true if the value is in the set. O(1).
*/
function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
return _contains(set._inner, value);
}
/**
* @dev Returns the number of values in the set. O(1).
*/
function length(Bytes32Set storage set) internal view returns (uint256) {
return _length(set._inner);
}
/**
* @dev Returns the value stored at position `index` in the set. O(1).
*
* Note that there are no guarantees on the ordering of values inside the
* array, and it may change when more values are added or removed.
*
* Requirements:
*
* - `index` must be strictly less than {length}.
*/
function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
return _at(set._inner, index);
}
/**
* @dev Return the entire set in an array
*
* WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
* to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
* this function has an unbounded cost, and using it as part of a state-changing function may render the function
* uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
*/
function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
bytes32[] memory store = _values(set._inner);
bytes32[] memory result;
/// @solidity memory-safe-assembly
assembly {
result := store
}
return result;
}
// AddressSet
struct AddressSet {
Set _inner;
}
/**
* @dev Add a value to a set. O(1).
*
* Returns true if the value was added to the set, that is if it was not
* already present.
*/
function add(AddressSet storage set, address value) internal returns (bool) {
return _add(set._inner, bytes32(uint256(uint160(value))));
}
/**
* @dev Removes a value from a set. O(1).
*
* Returns true if the value was removed from the set, that is if it was
* present.
*/
function remove(AddressSet storage set, address value) internal returns (bool) {
return _remove(set._inner, bytes32(uint256(uint160(value))));
}
/**
* @dev Returns true if the value is in the set. O(1).
*/
function contains(AddressSet storage set, address value) internal view returns (bool) {
return _contains(set._inner, bytes32(uint256(uint160(value))));
}
/**
* @dev Returns the number of values in the set. O(1).
*/
function length(AddressSet storage set) internal view returns (uint256) {
return _length(set._inner);
}
/**
* @dev Returns the value stored at position `index` in the set. O(1).
*
* Note that there are no guarantees on the ordering of values inside the
* array, and it may change when more values are added or removed.
*
* Requirements:
*
* - `index` must be strictly less than {length}.
*/
function at(AddressSet storage set, uint256 index) internal view returns (address) {
return address(uint160(uint256(_at(set._inner, index))));
}
/**
* @dev Return the entire set in an array
*
* WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
* to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
* this function has an unbounded cost, and using it as part of a state-changing function may render the function
* uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
*/
function values(AddressSet storage set) internal view returns (address[] memory) {
bytes32[] memory store = _values(set._inner);
address[] memory result;
/// @solidity memory-safe-assembly
assembly {
result := store
}
return result;
}
// UintSet
struct UintSet {
Set _inner;
}
/**
* @dev Add a value to a set. O(1).
*
* Returns true if the value was added to the set, that is if it was not
* already present.
*/
function add(UintSet storage set, uint256 value) internal returns (bool) {
return _add(set._inner, bytes32(value));
}
/**
* @dev Removes a value from a set. O(1).
*
* Returns true if the value was removed from the set, that is if it was
* present.
*/
function remove(UintSet storage set, uint256 value) internal returns (bool) {
return _remove(set._inner, bytes32(value));
}
/**
* @dev Returns true if the value is in the set. O(1).
*/
function contains(UintSet storage set, uint256 value) internal view returns (bool) {
return _contains(set._inner, bytes32(value));
}
/**
* @dev Returns the number of values in the set. O(1).
*/
function length(UintSet storage set) internal view returns (uint256) {
return _length(set._inner);
}
/**
* @dev Returns the value stored at position `index` in the set. O(1).
*
* Note that there are no guarantees on the ordering of values inside the
* array, and it may change when more values are added or removed.
*
* Requirements:
*
* - `index` must be strictly less than {length}.
*/
function at(UintSet storage set, uint256 index) internal view returns (uint256) {
return uint256(_at(set._inner, index));
}
/**
* @dev Return the entire set in an array
*
* WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
* to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
* this function has an unbounded cost, and using it as part of a state-changing function may render the function
* uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
*/
function values(UintSet storage set) internal view returns (uint256[] memory) {
bytes32[] memory store = _values(set._inner);
uint256[] memory result;
/// @solidity memory-safe-assembly
assembly {
result := store
}
return result;
}
}