Contract Name:
SpaceApeDividends
Contract Source Code:
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
* @dev Contract module which provides a basic access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership}.
*
* This module is used through inheritance. It will make available the modifier
* `onlyOwner`, which can be applied to your functions to restrict their use to
* the owner.
*/
abstract contract Ownable is Context {
address private _owner;
event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
/**
* @dev Initializes the contract setting the deployer as the initial owner.
*/
constructor() {
_transferOwnership(_msgSender());
}
/**
* @dev Throws if called by any account other than the owner.
*/
modifier onlyOwner() {
_checkOwner();
_;
}
/**
* @dev Returns the address of the current owner.
*/
function owner() public view virtual returns (address) {
return _owner;
}
/**
* @dev Throws if the sender is not the owner.
*/
function _checkOwner() internal view virtual {
require(owner() == _msgSender(), "Ownable: caller is not the owner");
}
/**
* @dev Leaves the contract without owner. It will not be possible to call
* `onlyOwner` functions anymore. Can only be called by the current owner.
*
* NOTE: Renouncing ownership will leave the contract without an owner,
* thereby removing any functionality that is only available to the owner.
*/
function renounceOwnership() public virtual onlyOwner {
_transferOwnership(address(0));
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual onlyOwner {
require(newOwner != address(0), "Ownable: new owner is the zero address");
_transferOwnership(newOwner);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Internal function without access restriction.
*/
function _transferOwnership(address newOwner) internal virtual {
address oldOwner = _owner;
_owner = newOwner;
emit OwnershipTransferred(oldOwner, newOwner);
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (security/ReentrancyGuard.sol)
pragma solidity ^0.8.0;
/**
* @dev Contract module that helps prevent reentrant calls to a function.
*
* Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
* available, which can be applied to functions to make sure there are no nested
* (reentrant) calls to them.
*
* Note that because there is a single `nonReentrant` guard, functions marked as
* `nonReentrant` may not call one another. This can be worked around by making
* those functions `private`, and then adding `external` `nonReentrant` entry
* points to them.
*
* TIP: If you would like to learn more about reentrancy and alternative ways
* to protect against it, check out our blog post
* https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
*/
abstract contract ReentrancyGuard {
// Booleans are more expensive than uint256 or any type that takes up a full
// word because each write operation emits an extra SLOAD to first read the
// slot's contents, replace the bits taken up by the boolean, and then write
// back. This is the compiler's defense against contract upgrades and
// pointer aliasing, and it cannot be disabled.
// The values being non-zero value makes deployment a bit more expensive,
// but in exchange the refund on every call to nonReentrant will be lower in
// amount. Since refunds are capped to a percentage of the total
// transaction's gas, it is best to keep them low in cases like this one, to
// increase the likelihood of the full refund coming into effect.
uint256 private constant _NOT_ENTERED = 1;
uint256 private constant _ENTERED = 2;
uint256 private _status;
constructor() {
_status = _NOT_ENTERED;
}
/**
* @dev Prevents a contract from calling itself, directly or indirectly.
* Calling a `nonReentrant` function from another `nonReentrant`
* function is not supported. It is possible to prevent this from happening
* by making the `nonReentrant` function external, and making it call a
* `private` function that does the actual work.
*/
modifier nonReentrant() {
_nonReentrantBefore();
_;
_nonReentrantAfter();
}
function _nonReentrantBefore() private {
// On the first call to nonReentrant, _status will be _NOT_ENTERED
require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
// Any calls to nonReentrant after this point will fail
_status = _ENTERED;
}
function _nonReentrantAfter() private {
// By storing the original value once again, a refund is triggered (see
// https://eips.ethereum.org/EIPS/eip-2200)
_status = _NOT_ENTERED;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/ERC20.sol)
pragma solidity ^0.8.0;
import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";
/**
* @dev Implementation of the {IERC20} interface.
*
* This implementation is agnostic to the way tokens are created. This means
* that a supply mechanism has to be added in a derived contract using {_mint}.
* For a generic mechanism see {ERC20PresetMinterPauser}.
*
* TIP: For a detailed writeup see our guide
* https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
* to implement supply mechanisms].
*
* We have followed general OpenZeppelin Contracts guidelines: functions revert
* instead returning `false` on failure. This behavior is nonetheless
* conventional and does not conflict with the expectations of ERC20
* applications.
*
* Additionally, an {Approval} event is emitted on calls to {transferFrom}.
* This allows applications to reconstruct the allowance for all accounts just
* by listening to said events. Other implementations of the EIP may not emit
* these events, as it isn't required by the specification.
*
* Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
* functions have been added to mitigate the well-known issues around setting
* allowances. See {IERC20-approve}.
*/
contract ERC20 is Context, IERC20, IERC20Metadata {
mapping(address => uint256) private _balances;
mapping(address => mapping(address => uint256)) private _allowances;
uint256 private _totalSupply;
string private _name;
string private _symbol;
/**
* @dev Sets the values for {name} and {symbol}.
*
* The default value of {decimals} is 18. To select a different value for
* {decimals} you should overload it.
*
* All two of these values are immutable: they can only be set once during
* construction.
*/
constructor(string memory name_, string memory symbol_) {
_name = name_;
_symbol = symbol_;
}
/**
* @dev Returns the name of the token.
*/
function name() public view virtual override returns (string memory) {
return _name;
}
/**
* @dev Returns the symbol of the token, usually a shorter version of the
* name.
*/
function symbol() public view virtual override returns (string memory) {
return _symbol;
}
/**
* @dev Returns the number of decimals used to get its user representation.
* For example, if `decimals` equals `2`, a balance of `505` tokens should
* be displayed to a user as `5.05` (`505 / 10 ** 2`).
*
* Tokens usually opt for a value of 18, imitating the relationship between
* Ether and Wei. This is the value {ERC20} uses, unless this function is
* overridden;
*
* NOTE: This information is only used for _display_ purposes: it in
* no way affects any of the arithmetic of the contract, including
* {IERC20-balanceOf} and {IERC20-transfer}.
*/
function decimals() public view virtual override returns (uint8) {
return 18;
}
/**
* @dev See {IERC20-totalSupply}.
*/
function totalSupply() public view virtual override returns (uint256) {
return _totalSupply;
}
/**
* @dev See {IERC20-balanceOf}.
*/
function balanceOf(address account) public view virtual override returns (uint256) {
return _balances[account];
}
/**
* @dev See {IERC20-transfer}.
*
* Requirements:
*
* - `to` cannot be the zero address.
* - the caller must have a balance of at least `amount`.
*/
function transfer(address to, uint256 amount) public virtual override returns (bool) {
address owner = _msgSender();
_transfer(owner, to, amount);
return true;
}
/**
* @dev See {IERC20-allowance}.
*/
function allowance(address owner, address spender) public view virtual override returns (uint256) {
return _allowances[owner][spender];
}
/**
* @dev See {IERC20-approve}.
*
* NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
* `transferFrom`. This is semantically equivalent to an infinite approval.
*
* Requirements:
*
* - `spender` cannot be the zero address.
*/
function approve(address spender, uint256 amount) public virtual override returns (bool) {
address owner = _msgSender();
_approve(owner, spender, amount);
return true;
}
/**
* @dev See {IERC20-transferFrom}.
*
* Emits an {Approval} event indicating the updated allowance. This is not
* required by the EIP. See the note at the beginning of {ERC20}.
*
* NOTE: Does not update the allowance if the current allowance
* is the maximum `uint256`.
*
* Requirements:
*
* - `from` and `to` cannot be the zero address.
* - `from` must have a balance of at least `amount`.
* - the caller must have allowance for ``from``'s tokens of at least
* `amount`.
*/
function transferFrom(
address from,
address to,
uint256 amount
) public virtual override returns (bool) {
address spender = _msgSender();
_spendAllowance(from, spender, amount);
_transfer(from, to, amount);
return true;
}
/**
* @dev Atomically increases the allowance granted to `spender` by the caller.
*
* This is an alternative to {approve} that can be used as a mitigation for
* problems described in {IERC20-approve}.
*
* Emits an {Approval} event indicating the updated allowance.
*
* Requirements:
*
* - `spender` cannot be the zero address.
*/
function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
address owner = _msgSender();
_approve(owner, spender, allowance(owner, spender) + addedValue);
return true;
}
/**
* @dev Atomically decreases the allowance granted to `spender` by the caller.
*
* This is an alternative to {approve} that can be used as a mitigation for
* problems described in {IERC20-approve}.
*
* Emits an {Approval} event indicating the updated allowance.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `spender` must have allowance for the caller of at least
* `subtractedValue`.
*/
function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
address owner = _msgSender();
uint256 currentAllowance = allowance(owner, spender);
require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
unchecked {
_approve(owner, spender, currentAllowance - subtractedValue);
}
return true;
}
/**
* @dev Moves `amount` of tokens from `from` to `to`.
*
* This internal function is equivalent to {transfer}, and can be used to
* e.g. implement automatic token fees, slashing mechanisms, etc.
*
* Emits a {Transfer} event.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `from` must have a balance of at least `amount`.
*/
function _transfer(
address from,
address to,
uint256 amount
) internal virtual {
require(from != address(0), "ERC20: transfer from the zero address");
require(to != address(0), "ERC20: transfer to the zero address");
_beforeTokenTransfer(from, to, amount);
uint256 fromBalance = _balances[from];
require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
unchecked {
_balances[from] = fromBalance - amount;
// Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
// decrementing then incrementing.
_balances[to] += amount;
}
emit Transfer(from, to, amount);
_afterTokenTransfer(from, to, amount);
}
/** @dev Creates `amount` tokens and assigns them to `account`, increasing
* the total supply.
*
* Emits a {Transfer} event with `from` set to the zero address.
*
* Requirements:
*
* - `account` cannot be the zero address.
*/
function _mint(address account, uint256 amount) internal virtual {
require(account != address(0), "ERC20: mint to the zero address");
_beforeTokenTransfer(address(0), account, amount);
_totalSupply += amount;
unchecked {
// Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
_balances[account] += amount;
}
emit Transfer(address(0), account, amount);
_afterTokenTransfer(address(0), account, amount);
}
/**
* @dev Destroys `amount` tokens from `account`, reducing the
* total supply.
*
* Emits a {Transfer} event with `to` set to the zero address.
*
* Requirements:
*
* - `account` cannot be the zero address.
* - `account` must have at least `amount` tokens.
*/
function _burn(address account, uint256 amount) internal virtual {
require(account != address(0), "ERC20: burn from the zero address");
_beforeTokenTransfer(account, address(0), amount);
uint256 accountBalance = _balances[account];
require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
unchecked {
_balances[account] = accountBalance - amount;
// Overflow not possible: amount <= accountBalance <= totalSupply.
_totalSupply -= amount;
}
emit Transfer(account, address(0), amount);
_afterTokenTransfer(account, address(0), amount);
}
/**
* @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
*
* This internal function is equivalent to `approve`, and can be used to
* e.g. set automatic allowances for certain subsystems, etc.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `owner` cannot be the zero address.
* - `spender` cannot be the zero address.
*/
function _approve(
address owner,
address spender,
uint256 amount
) internal virtual {
require(owner != address(0), "ERC20: approve from the zero address");
require(spender != address(0), "ERC20: approve to the zero address");
_allowances[owner][spender] = amount;
emit Approval(owner, spender, amount);
}
/**
* @dev Updates `owner` s allowance for `spender` based on spent `amount`.
*
* Does not update the allowance amount in case of infinite allowance.
* Revert if not enough allowance is available.
*
* Might emit an {Approval} event.
*/
function _spendAllowance(
address owner,
address spender,
uint256 amount
) internal virtual {
uint256 currentAllowance = allowance(owner, spender);
if (currentAllowance != type(uint256).max) {
require(currentAllowance >= amount, "ERC20: insufficient allowance");
unchecked {
_approve(owner, spender, currentAllowance - amount);
}
}
}
/**
* @dev Hook that is called before any transfer of tokens. This includes
* minting and burning.
*
* Calling conditions:
*
* - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
* will be transferred to `to`.
* - when `from` is zero, `amount` tokens will be minted for `to`.
* - when `to` is zero, `amount` of ``from``'s tokens will be burned.
* - `from` and `to` are never both zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _beforeTokenTransfer(
address from,
address to,
uint256 amount
) internal virtual {}
/**
* @dev Hook that is called after any transfer of tokens. This includes
* minting and burning.
*
* Calling conditions:
*
* - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
* has been transferred to `to`.
* - when `from` is zero, `amount` tokens have been minted for `to`.
* - when `to` is zero, `amount` of ``from``'s tokens have been burned.
* - `from` and `to` are never both zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _afterTokenTransfer(
address from,
address to,
uint256 amount
) internal virtual {}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
/**
* @dev Interface for the optional metadata functions from the ERC20 standard.
*
* _Available since v4.1._
*/
interface IERC20Metadata is IERC20 {
/**
* @dev Returns the name of the token.
*/
function name() external view returns (string memory);
/**
* @dev Returns the symbol of the token.
*/
function symbol() external view returns (string memory);
/**
* @dev Returns the decimals places of the token.
*/
function decimals() external view returns (uint8);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(
address from,
address to,
uint256 amount
) external returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)
pragma solidity ^0.8.0;
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
/// Partial DividendPayingToken (only functions called in SpaceApe contract)
interface IDividendPayingToken {
function distributeTokenRewardDividends(uint256 amount) external;
}
/// Partial TokenDividendTracker (only functions called in SpaceApe contract)
interface ITokenDividendTracker is IERC20, IDividendPayingToken {
function excludeFromDividends(address account) external;
function includeInDividends(address account) external;
function isexcludeFromDividends(address account) external view returns (bool);
function setBalance(address payable account, uint256 newBalance) external;
function process(uint256 gas) external returns (uint256, uint256, uint256);
}
// /// Ownable (only functions called in SpaceApe contract)
// interface IOwnable {
// function owner() external view returns (address);
// }
// /// TokenDividendTracker from SpaceApe contract
// interface ITokenDividendTrackerFull is IERC20, IOwnable, IDividendPayingToken {
// // uint256 public lastProcessedIndex;
// // mapping(address => bool) public excludedFromDividends;
// // mapping(address => uint256) public lastClaimTimes;
// // uint256 public claimWait;
// // uint256 public immutable minimumTokenBalanceForDividends;
// event ExcludeFromDividends(address indexed account);
// event IncludeInDividends(address indexed account);
// event ClaimWaitUpdated(uint256 indexed newValue, uint256 indexed oldValue);
// function withdrawDividend() external pure;
// function excludeFromDividends(address account) external;
// function includeInDividends(address account) external;
// function isexcludeFromDividends(address account) external view returns (bool);
// function updateClaimWait(uint256 newClaimWait) external;
// function dividendTokenBalanceOf(address account) external view returns (uint256);
// function getLastProcessedIndex() external view returns (uint256);
// function getNumberOfTokenHolders() external view returns (uint256);
// function getAccount(address _account) external view returns (
// address account,
// int256 index,
// int256 iterationsUntilProcessed,
// uint256 withdrawableDividends,
// uint256 totalDividends,
// uint256 lastClaimTime,
// uint256 nextClaimTime,
// uint256 secondsUntilAutoClaimAvailable
// );
// function getAccountAtIndex(uint256 index) external view returns (
// address,
// int256,
// int256,
// uint256,
// uint256,
// uint256,
// uint256,
// uint256
// );
// function setBalance(address payable account, uint256 newBalance) external;
// function process(uint256 gas) external returns (uint256, uint256, uint256);
// function processAccount(address payable account, bool automatic) external returns (bool);
// }
/*
____ _
/ ___| _ __ __ _ ___ ___ / \ _ __ ___
\___ \| '_ \ / _` |/ __/ _ \ / _ \ | '_ \ / _ \
___) | |_) | (_| | (_| __// ___ \| |_) | __/
|____/| .__/ \__,_|\___\___/_/ \_\ .__/ \___|
|_| |_|
SpaceApe Dividends 🐒+🍌=🚀→🌕
Designed to work around the existing SpaceApe contract (and its quirks), rather
than an ideal implementation. Dividend concepts based on EIP-2222.
$APED tokens tracked in this contract represent non-transferable dividend
shares. Shares provide points which can be exchanged to withdraw $WORM rewards.
🦄 Buy $APE on Uniswap @
https://app.uniswap.org/#/swap?outputCurrency=0x07bd9efbe87ba5ec52272a4fc0855e5b5b818b85&chain=mainnet
🐵 Get your rewards at https://app.spaceape.army
🌎 https://SpaceApe.army
*/
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "./ITokenDividendTracker.sol";
contract SpaceApeDividends is ERC20, Ownable, ReentrancyGuard, ITokenDividendTracker {
/// Token which must be held for eligibility ($APE).
IERC20 private constant _HOLDER_TOKEN = ERC20(0x07bD9efBe87Ba5EC52272A4fc0855E5B5B818b85);
/// Token used to pay dividends ($WORM).
IERC20 private constant _FUNDS_TOKEN = ERC20(0xF7Ecb2E5ddaD17506E62F51A442f725a26053fb2);
/// Minimum amount of $APE held required to receive dividends.
uint256 private constant _MINIMUM_BALANCE = 10**14; // 0.0001% of $APE total supply
/// Magnitude points multiplier for dealing with small numbers.
uint256 private constant _MAGNITUDE = 2**128;
/// Pause dividend distribution and payout (withdrawals).
bool private _paused = false;
/// The total amount of dividend shares that have been distributed.
uint256 private _totalDistributed;
/// Rewards token pool balance ($WORM).
uint256 private _fundsTokenBalance;
/// Points per share (multiplied by _MAGNITUDE).
uint256 private _pointsPerShare;
/// Points correction for share balance changes (multiplied by _MAGNITUDE).
mapping(address => int256) private _pointsCorrection;
/// Total funds withdrawn per holder ($WORM).
mapping(address => uint256) private _withdrawnFunds;
/// Exclude address from receiving dividend shares.
mapping(address => bool) private _excluded;
event Withdraw(address indexed account, uint256 amount);
event Paused(bool value);
error NonTransferable();
constructor() ERC20("SpaceApeDividends", "$APED") {}
function _distribute(uint256 amount) private {
require(totalSupply() > 0, "NO_SUPPLY");
if (amount > 0) {
_pointsPerShare += (amount * _MAGNITUDE) / totalSupply();
_totalDistributed += amount;
}
}
function _updateFundsTokenBalance() private returns (int256) {
uint256 prevFundsTokenBalance = _fundsTokenBalance;
_fundsTokenBalance = _FUNDS_TOKEN.balanceOf(address(this));
return int256(_fundsTokenBalance) - int256(prevFundsTokenBalance);
}
function _updateFundsReceived() private {
int256 newFunds = _updateFundsTokenBalance();
if (newFunds > 0) {
_distribute(uint256(newFunds));
}
}
function _setBalance(address account, uint256 newBalance) private {
uint256 balance = balanceOf(account);
if (newBalance > balance) {
if (newBalance >= _MINIMUM_BALANCE && !_excluded[account]) {
_mint(account, newBalance - balance);
}
} else if (newBalance < balance) {
_burn(account, balance - newBalance);
}
}
function _transfer(address, address, uint256) internal pure override {
revert NonTransferable();
}
function _mint(address account, uint256 amount) internal override {
super._mint(account, amount);
_pointsCorrection[account] -= int256(_pointsPerShare * amount);
}
function _burn(address account, uint256 amount) internal override {
super._burn(account, amount);
_pointsCorrection[account] += int256(_pointsPerShare * amount);
}
function _accumulativeFundsOf(address account) private view returns (uint256) {
return uint256(int256(_pointsPerShare * balanceOf(account)) + _pointsCorrection[account]) / _MAGNITUDE;
}
function _withdrawableFundsOf(address account) private view returns (uint256) {
return _accumulativeFundsOf(account) - _withdrawnFunds[account];
}
function _prepareWithdraw() private returns (uint256) {
uint256 _withdrawableDividend = _withdrawableFundsOf(msg.sender);
_withdrawnFunds[msg.sender] += _withdrawableDividend;
emit Withdraw(msg.sender, _withdrawableDividend);
return _withdrawableDividend;
}
function withdraw() external nonReentrant {
require(!_paused, "PAUSED");
uint256 withdrawableFunds = _prepareWithdraw();
require(_FUNDS_TOKEN.transfer(msg.sender, withdrawableFunds), "TRANSFER_FAILED");
_updateFundsTokenBalance();
}
function dividendsOf(address account) public view returns (
uint256 withdrawable,
uint256 paid
) {
return (
_withdrawableFundsOf(account),
_withdrawnFunds[account]
);
}
function stats() public view returns (
uint256 totalDistributed,
bool paused
) {
return (
_totalDistributed,
_paused
);
}
function _exclude(address account, bool excluded) private {
_excluded[account] = excluded;
if (excluded) {
_setBalance(account, 0);
} else {
_setBalance(account, _HOLDER_TOKEN.balanceOf(account));
}
}
function pause(bool paused) external onlyOwner {
_paused = paused;
emit Paused(paused);
}
/* Remap functions for compatibility with ITokenDividendTracker. */
function setBalance(address payable account, uint256 newBalance) external onlyOwner {
if (_paused) return;
_setBalance(account, newBalance);
}
function process(uint256) external returns (uint256, uint256, uint256) {
// noop
}
function distributeTokenRewardDividends(uint256) external {
_updateFundsReceived();
}
function excludeFromDividends(address account) external onlyOwner {
_exclude(account, true);
}
function includeInDividends(address account) external onlyOwner {
_exclude(account, false);
}
function isexcludeFromDividends(address account) external view returns (bool) {
return _excluded[account];
}
/* Unclaimed shares functions to get owed shares e.g., for previous $APE balance. */
function updateShares() external {
require(!_paused, "PAUSED");
_setBalance(msg.sender, _HOLDER_TOKEN.balanceOf(msg.sender));
}
function unclaimedSharesOf(address account) external view returns (uint256) {
return _excluded[account] ? 0 : _HOLDER_TOKEN.balanceOf(account) - balanceOf(account);
}
}
/// @dev 0xf09f8cb2