Contract Source Code:
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)
pragma solidity ^0.8.0;
import "../utils/ContextUpgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";
/**
* @dev Contract module which provides a basic access control mechanism, where
* there is an account (an owner) that can be granted exclusive access to
* specific functions.
*
* By default, the owner account will be the one that deploys the contract. This
* can later be changed with {transferOwnership}.
*
* This module is used through inheritance. It will make available the modifier
* `onlyOwner`, which can be applied to your functions to restrict their use to
* the owner.
*/
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
address private _owner;
event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
/**
* @dev Initializes the contract setting the deployer as the initial owner.
*/
function __Ownable_init() internal onlyInitializing {
__Ownable_init_unchained();
}
function __Ownable_init_unchained() internal onlyInitializing {
_transferOwnership(_msgSender());
}
/**
* @dev Throws if called by any account other than the owner.
*/
modifier onlyOwner() {
_checkOwner();
_;
}
/**
* @dev Returns the address of the current owner.
*/
function owner() public view virtual returns (address) {
return _owner;
}
/**
* @dev Throws if the sender is not the owner.
*/
function _checkOwner() internal view virtual {
require(owner() == _msgSender(), "Ownable: caller is not the owner");
}
/**
* @dev Leaves the contract without owner. It will not be possible to call
* `onlyOwner` functions. Can only be called by the current owner.
*
* NOTE: Renouncing ownership will leave the contract without an owner,
* thereby disabling any functionality that is only available to the owner.
*/
function renounceOwnership() public virtual onlyOwner {
_transferOwnership(address(0));
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Can only be called by the current owner.
*/
function transferOwnership(address newOwner) public virtual onlyOwner {
require(newOwner != address(0), "Ownable: new owner is the zero address");
_transferOwnership(newOwner);
}
/**
* @dev Transfers ownership of the contract to a new account (`newOwner`).
* Internal function without access restriction.
*/
function _transferOwnership(address newOwner) internal virtual {
address oldOwner = _owner;
_owner = newOwner;
emit OwnershipTransferred(oldOwner, newOwner);
}
/**
* @dev This empty reserved space is put in place to allow future versions to add new
* variables without shifting down storage in the inheritance chain.
* See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
*/
uint256[49] private __gap;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)
pragma solidity ^0.8.2;
import "../../utils/AddressUpgradeable.sol";
/**
* @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
* behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
* external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
* function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
*
* The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
* reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
* case an upgrade adds a module that needs to be initialized.
*
* For example:
*
* [.hljs-theme-light.nopadding]
* ```solidity
* contract MyToken is ERC20Upgradeable {
* function initialize() initializer public {
* __ERC20_init("MyToken", "MTK");
* }
* }
*
* contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
* function initializeV2() reinitializer(2) public {
* __ERC20Permit_init("MyToken");
* }
* }
* ```
*
* TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
* possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
*
* CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
* that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
*
* [CAUTION]
* ====
* Avoid leaving a contract uninitialized.
*
* An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
* contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
* the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
*
* [.hljs-theme-light.nopadding]
* ```
* /// @custom:oz-upgrades-unsafe-allow constructor
* constructor() {
* _disableInitializers();
* }
* ```
* ====
*/
abstract contract Initializable {
/**
* @dev Indicates that the contract has been initialized.
* @custom:oz-retyped-from bool
*/
uint8 private _initialized;
/**
* @dev Indicates that the contract is in the process of being initialized.
*/
bool private _initializing;
/**
* @dev Triggered when the contract has been initialized or reinitialized.
*/
event Initialized(uint8 version);
/**
* @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
* `onlyInitializing` functions can be used to initialize parent contracts.
*
* Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
* constructor.
*
* Emits an {Initialized} event.
*/
modifier initializer() {
bool isTopLevelCall = !_initializing;
require(
(isTopLevelCall && _initialized < 1) || (!AddressUpgradeable.isContract(address(this)) && _initialized == 1),
"Initializable: contract is already initialized"
);
_initialized = 1;
if (isTopLevelCall) {
_initializing = true;
}
_;
if (isTopLevelCall) {
_initializing = false;
emit Initialized(1);
}
}
/**
* @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
* contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
* used to initialize parent contracts.
*
* A reinitializer may be used after the original initialization step. This is essential to configure modules that
* are added through upgrades and that require initialization.
*
* When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
* cannot be nested. If one is invoked in the context of another, execution will revert.
*
* Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
* a contract, executing them in the right order is up to the developer or operator.
*
* WARNING: setting the version to 255 will prevent any future reinitialization.
*
* Emits an {Initialized} event.
*/
modifier reinitializer(uint8 version) {
require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
_initialized = version;
_initializing = true;
_;
_initializing = false;
emit Initialized(version);
}
/**
* @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
* {initializer} and {reinitializer} modifiers, directly or indirectly.
*/
modifier onlyInitializing() {
require(_initializing, "Initializable: contract is not initializing");
_;
}
/**
* @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
* Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
* to any version. It is recommended to use this to lock implementation contracts that are designed to be called
* through proxies.
*
* Emits an {Initialized} event the first time it is successfully executed.
*/
function _disableInitializers() internal virtual {
require(!_initializing, "Initializable: contract is initializing");
if (_initialized != type(uint8).max) {
_initialized = type(uint8).max;
emit Initialized(type(uint8).max);
}
}
/**
* @dev Returns the highest version that has been initialized. See {reinitializer}.
*/
function _getInitializedVersion() internal view returns (uint8) {
return _initialized;
}
/**
* @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
*/
function _isInitializing() internal view returns (bool) {
return _initializing;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)
pragma solidity ^0.8.0;
import "../utils/ContextUpgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";
/**
* @dev Contract module which allows children to implement an emergency stop
* mechanism that can be triggered by an authorized account.
*
* This module is used through inheritance. It will make available the
* modifiers `whenNotPaused` and `whenPaused`, which can be applied to
* the functions of your contract. Note that they will not be pausable by
* simply including this module, only once the modifiers are put in place.
*/
abstract contract PausableUpgradeable is Initializable, ContextUpgradeable {
/**
* @dev Emitted when the pause is triggered by `account`.
*/
event Paused(address account);
/**
* @dev Emitted when the pause is lifted by `account`.
*/
event Unpaused(address account);
bool private _paused;
/**
* @dev Initializes the contract in unpaused state.
*/
function __Pausable_init() internal onlyInitializing {
__Pausable_init_unchained();
}
function __Pausable_init_unchained() internal onlyInitializing {
_paused = false;
}
/**
* @dev Modifier to make a function callable only when the contract is not paused.
*
* Requirements:
*
* - The contract must not be paused.
*/
modifier whenNotPaused() {
_requireNotPaused();
_;
}
/**
* @dev Modifier to make a function callable only when the contract is paused.
*
* Requirements:
*
* - The contract must be paused.
*/
modifier whenPaused() {
_requirePaused();
_;
}
/**
* @dev Returns true if the contract is paused, and false otherwise.
*/
function paused() public view virtual returns (bool) {
return _paused;
}
/**
* @dev Throws if the contract is paused.
*/
function _requireNotPaused() internal view virtual {
require(!paused(), "Pausable: paused");
}
/**
* @dev Throws if the contract is not paused.
*/
function _requirePaused() internal view virtual {
require(paused(), "Pausable: not paused");
}
/**
* @dev Triggers stopped state.
*
* Requirements:
*
* - The contract must not be paused.
*/
function _pause() internal virtual whenNotPaused {
_paused = true;
emit Paused(_msgSender());
}
/**
* @dev Returns to normal state.
*
* Requirements:
*
* - The contract must be paused.
*/
function _unpause() internal virtual whenPaused {
_paused = false;
emit Unpaused(_msgSender());
}
/**
* @dev This empty reserved space is put in place to allow future versions to add new
* variables without shifting down storage in the inheritance chain.
* See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
*/
uint256[49] private __gap;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)
pragma solidity ^0.8.0;
import {Initializable} from "../proxy/utils/Initializable.sol";
/**
* @dev Contract module that helps prevent reentrant calls to a function.
*
* Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
* available, which can be applied to functions to make sure there are no nested
* (reentrant) calls to them.
*
* Note that because there is a single `nonReentrant` guard, functions marked as
* `nonReentrant` may not call one another. This can be worked around by making
* those functions `private`, and then adding `external` `nonReentrant` entry
* points to them.
*
* TIP: If you would like to learn more about reentrancy and alternative ways
* to protect against it, check out our blog post
* https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
*/
abstract contract ReentrancyGuardUpgradeable is Initializable {
// Booleans are more expensive than uint256 or any type that takes up a full
// word because each write operation emits an extra SLOAD to first read the
// slot's contents, replace the bits taken up by the boolean, and then write
// back. This is the compiler's defense against contract upgrades and
// pointer aliasing, and it cannot be disabled.
// The values being non-zero value makes deployment a bit more expensive,
// but in exchange the refund on every call to nonReentrant will be lower in
// amount. Since refunds are capped to a percentage of the total
// transaction's gas, it is best to keep them low in cases like this one, to
// increase the likelihood of the full refund coming into effect.
uint256 private constant _NOT_ENTERED = 1;
uint256 private constant _ENTERED = 2;
uint256 private _status;
function __ReentrancyGuard_init() internal onlyInitializing {
__ReentrancyGuard_init_unchained();
}
function __ReentrancyGuard_init_unchained() internal onlyInitializing {
_status = _NOT_ENTERED;
}
/**
* @dev Prevents a contract from calling itself, directly or indirectly.
* Calling a `nonReentrant` function from another `nonReentrant`
* function is not supported. It is possible to prevent this from happening
* by making the `nonReentrant` function external, and making it call a
* `private` function that does the actual work.
*/
modifier nonReentrant() {
_nonReentrantBefore();
_;
_nonReentrantAfter();
}
function _nonReentrantBefore() private {
// On the first call to nonReentrant, _status will be _NOT_ENTERED
require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
// Any calls to nonReentrant after this point will fail
_status = _ENTERED;
}
function _nonReentrantAfter() private {
// By storing the original value once again, a refund is triggered (see
// https://eips.ethereum.org/EIPS/eip-2200)
_status = _NOT_ENTERED;
}
/**
* @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
* `nonReentrant` function in the call stack.
*/
function _reentrancyGuardEntered() internal view returns (bool) {
return _status == _ENTERED;
}
/**
* @dev This empty reserved space is put in place to allow future versions to add new
* variables without shifting down storage in the inheritance chain.
* See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
*/
uint256[49] private __gap;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
* @dev Collection of functions related to the address type
*/
library AddressUpgradeable {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
*
* Furthermore, `isContract` will also return true if the target contract within
* the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
* which only has an effect at the end of a transaction.
* ====
*
* [IMPORTANT]
* ====
* You shouldn't rely on `isContract` to protect against flash loan attacks!
*
* Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
* like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
* constructor.
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize/address.code.length, which returns 0
// for contracts in construction, since the code is only stored at the end
// of the constructor execution.
return account.code.length > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(address(this).balance >= amount, "Address: insufficient balance");
(bool success, ) = recipient.call{value: amount}("");
require(success, "Address: unable to send value, recipient may have reverted");
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(address(this).balance >= value, "Address: insufficient balance for call");
(bool success, bytes memory returndata) = target.call{value: value}(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
return functionStaticCall(target, data, "Address: low-level static call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
(bool success, bytes memory returndata) = target.staticcall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
return functionDelegateCall(target, data, "Address: low-level delegate call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
(bool success, bytes memory returndata) = target.delegatecall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
* the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
*
* _Available since v4.8._
*/
function verifyCallResultFromTarget(
address target,
bool success,
bytes memory returndata,
string memory errorMessage
) internal view returns (bytes memory) {
if (success) {
if (returndata.length == 0) {
// only check isContract if the call was successful and the return data is empty
// otherwise we already know that it was a contract
require(isContract(target), "Address: call to non-contract");
}
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
/**
* @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
* revert reason or using the provided one.
*
* _Available since v4.3._
*/
function verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) internal pure returns (bytes memory) {
if (success) {
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
function _revert(bytes memory returndata, string memory errorMessage) private pure {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
/// @solidity memory-safe-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)
pragma solidity ^0.8.0;
import {Initializable} from "../proxy/utils/Initializable.sol";
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract ContextUpgradeable is Initializable {
function __Context_init() internal onlyInitializing {
}
function __Context_init_unchained() internal onlyInitializing {
}
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
function _contextSuffixLength() internal view virtual returns (uint256) {
return 0;
}
/**
* @dev This empty reserved space is put in place to allow future versions to add new
* variables without shifting down storage in the inheritance chain.
* See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
*/
uint256[50] private __gap;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (interfaces/draft-IERC1822.sol)
pragma solidity ^0.8.0;
/**
* @dev ERC1822: Universal Upgradeable Proxy Standard (UUPS) documents a method for upgradeability through a simplified
* proxy whose upgrades are fully controlled by the current implementation.
*/
interface IERC1822Proxiable {
/**
* @dev Returns the storage slot that the proxiable contract assumes is being used to store the implementation
* address.
*
* IMPORTANT: A proxy pointing at a proxiable contract should not be considered proxiable itself, because this risks
* bricking a proxy that upgrades to it, by delegating to itself until out of gas. Thus it is critical that this
* function revert if invoked through a proxy.
*/
function proxiableUUID() external view returns (bytes32);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (interfaces/IERC1967.sol)
pragma solidity ^0.8.0;
/**
* @dev ERC-1967: Proxy Storage Slots. This interface contains the events defined in the ERC.
*
* _Available since v4.8.3._
*/
interface IERC1967 {
/**
* @dev Emitted when the implementation is upgraded.
*/
event Upgraded(address indexed implementation);
/**
* @dev Emitted when the admin account has changed.
*/
event AdminChanged(address previousAdmin, address newAdmin);
/**
* @dev Emitted when the beacon is changed.
*/
event BeaconUpgraded(address indexed beacon);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (proxy/beacon/BeaconProxy.sol)
pragma solidity ^0.8.0;
import "./IBeacon.sol";
import "../Proxy.sol";
import "../ERC1967/ERC1967Upgrade.sol";
/**
* @dev This contract implements a proxy that gets the implementation address for each call from an {UpgradeableBeacon}.
*
* The beacon address is stored in storage slot `uint256(keccak256('eip1967.proxy.beacon')) - 1`, so that it doesn't
* conflict with the storage layout of the implementation behind the proxy.
*
* _Available since v3.4._
*/
contract BeaconProxy is Proxy, ERC1967Upgrade {
/**
* @dev Initializes the proxy with `beacon`.
*
* If `data` is nonempty, it's used as data in a delegate call to the implementation returned by the beacon. This
* will typically be an encoded function call, and allows initializing the storage of the proxy like a Solidity
* constructor.
*
* Requirements:
*
* - `beacon` must be a contract with the interface {IBeacon}.
*/
constructor(address beacon, bytes memory data) payable {
_upgradeBeaconToAndCall(beacon, data, false);
}
/**
* @dev Returns the current beacon address.
*/
function _beacon() internal view virtual returns (address) {
return _getBeacon();
}
/**
* @dev Returns the current implementation address of the associated beacon.
*/
function _implementation() internal view virtual override returns (address) {
return IBeacon(_getBeacon()).implementation();
}
/**
* @dev Changes the proxy to use a new beacon. Deprecated: see {_upgradeBeaconToAndCall}.
*
* If `data` is nonempty, it's used as data in a delegate call to the implementation returned by the beacon.
*
* Requirements:
*
* - `beacon` must be a contract.
* - The implementation returned by `beacon` must be a contract.
*/
function _setBeacon(address beacon, bytes memory data) internal virtual {
_upgradeBeaconToAndCall(beacon, data, false);
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (proxy/beacon/IBeacon.sol)
pragma solidity ^0.8.0;
/**
* @dev This is the interface that {BeaconProxy} expects of its beacon.
*/
interface IBeacon {
/**
* @dev Must return an address that can be used as a delegate call target.
*
* {BeaconProxy} will check that this address is a contract.
*/
function implementation() external view returns (address);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/ERC1967/ERC1967Upgrade.sol)
pragma solidity ^0.8.2;
import "../beacon/IBeacon.sol";
import "../../interfaces/IERC1967.sol";
import "../../interfaces/draft-IERC1822.sol";
import "../../utils/Address.sol";
import "../../utils/StorageSlot.sol";
/**
* @dev This abstract contract provides getters and event emitting update functions for
* https://eips.ethereum.org/EIPS/eip-1967[EIP1967] slots.
*
* _Available since v4.1._
*/
abstract contract ERC1967Upgrade is IERC1967 {
// This is the keccak-256 hash of "eip1967.proxy.rollback" subtracted by 1
bytes32 private constant _ROLLBACK_SLOT = 0x4910fdfa16fed3260ed0e7147f7cc6da11a60208b5b9406d12a635614ffd9143;
/**
* @dev Storage slot with the address of the current implementation.
* This is the keccak-256 hash of "eip1967.proxy.implementation" subtracted by 1, and is
* validated in the constructor.
*/
bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
/**
* @dev Returns the current implementation address.
*/
function _getImplementation() internal view returns (address) {
return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
}
/**
* @dev Stores a new address in the EIP1967 implementation slot.
*/
function _setImplementation(address newImplementation) private {
require(Address.isContract(newImplementation), "ERC1967: new implementation is not a contract");
StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
}
/**
* @dev Perform implementation upgrade
*
* Emits an {Upgraded} event.
*/
function _upgradeTo(address newImplementation) internal {
_setImplementation(newImplementation);
emit Upgraded(newImplementation);
}
/**
* @dev Perform implementation upgrade with additional setup call.
*
* Emits an {Upgraded} event.
*/
function _upgradeToAndCall(address newImplementation, bytes memory data, bool forceCall) internal {
_upgradeTo(newImplementation);
if (data.length > 0 || forceCall) {
Address.functionDelegateCall(newImplementation, data);
}
}
/**
* @dev Perform implementation upgrade with security checks for UUPS proxies, and additional setup call.
*
* Emits an {Upgraded} event.
*/
function _upgradeToAndCallUUPS(address newImplementation, bytes memory data, bool forceCall) internal {
// Upgrades from old implementations will perform a rollback test. This test requires the new
// implementation to upgrade back to the old, non-ERC1822 compliant, implementation. Removing
// this special case will break upgrade paths from old UUPS implementation to new ones.
if (StorageSlot.getBooleanSlot(_ROLLBACK_SLOT).value) {
_setImplementation(newImplementation);
} else {
try IERC1822Proxiable(newImplementation).proxiableUUID() returns (bytes32 slot) {
require(slot == _IMPLEMENTATION_SLOT, "ERC1967Upgrade: unsupported proxiableUUID");
} catch {
revert("ERC1967Upgrade: new implementation is not UUPS");
}
_upgradeToAndCall(newImplementation, data, forceCall);
}
}
/**
* @dev Storage slot with the admin of the contract.
* This is the keccak-256 hash of "eip1967.proxy.admin" subtracted by 1, and is
* validated in the constructor.
*/
bytes32 internal constant _ADMIN_SLOT = 0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103;
/**
* @dev Returns the current admin.
*/
function _getAdmin() internal view returns (address) {
return StorageSlot.getAddressSlot(_ADMIN_SLOT).value;
}
/**
* @dev Stores a new address in the EIP1967 admin slot.
*/
function _setAdmin(address newAdmin) private {
require(newAdmin != address(0), "ERC1967: new admin is the zero address");
StorageSlot.getAddressSlot(_ADMIN_SLOT).value = newAdmin;
}
/**
* @dev Changes the admin of the proxy.
*
* Emits an {AdminChanged} event.
*/
function _changeAdmin(address newAdmin) internal {
emit AdminChanged(_getAdmin(), newAdmin);
_setAdmin(newAdmin);
}
/**
* @dev The storage slot of the UpgradeableBeacon contract which defines the implementation for this proxy.
* This is bytes32(uint256(keccak256('eip1967.proxy.beacon')) - 1)) and is validated in the constructor.
*/
bytes32 internal constant _BEACON_SLOT = 0xa3f0ad74e5423aebfd80d3ef4346578335a9a72aeaee59ff6cb3582b35133d50;
/**
* @dev Returns the current beacon.
*/
function _getBeacon() internal view returns (address) {
return StorageSlot.getAddressSlot(_BEACON_SLOT).value;
}
/**
* @dev Stores a new beacon in the EIP1967 beacon slot.
*/
function _setBeacon(address newBeacon) private {
require(Address.isContract(newBeacon), "ERC1967: new beacon is not a contract");
require(
Address.isContract(IBeacon(newBeacon).implementation()),
"ERC1967: beacon implementation is not a contract"
);
StorageSlot.getAddressSlot(_BEACON_SLOT).value = newBeacon;
}
/**
* @dev Perform beacon upgrade with additional setup call. Note: This upgrades the address of the beacon, it does
* not upgrade the implementation contained in the beacon (see {UpgradeableBeacon-_setImplementation} for that).
*
* Emits a {BeaconUpgraded} event.
*/
function _upgradeBeaconToAndCall(address newBeacon, bytes memory data, bool forceCall) internal {
_setBeacon(newBeacon);
emit BeaconUpgraded(newBeacon);
if (data.length > 0 || forceCall) {
Address.functionDelegateCall(IBeacon(newBeacon).implementation(), data);
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (proxy/Proxy.sol)
pragma solidity ^0.8.0;
/**
* @dev This abstract contract provides a fallback function that delegates all calls to another contract using the EVM
* instruction `delegatecall`. We refer to the second contract as the _implementation_ behind the proxy, and it has to
* be specified by overriding the virtual {_implementation} function.
*
* Additionally, delegation to the implementation can be triggered manually through the {_fallback} function, or to a
* different contract through the {_delegate} function.
*
* The success and return data of the delegated call will be returned back to the caller of the proxy.
*/
abstract contract Proxy {
/**
* @dev Delegates the current call to `implementation`.
*
* This function does not return to its internal call site, it will return directly to the external caller.
*/
function _delegate(address implementation) internal virtual {
assembly {
// Copy msg.data. We take full control of memory in this inline assembly
// block because it will not return to Solidity code. We overwrite the
// Solidity scratch pad at memory position 0.
calldatacopy(0, 0, calldatasize())
// Call the implementation.
// out and outsize are 0 because we don't know the size yet.
let result := delegatecall(gas(), implementation, 0, calldatasize(), 0, 0)
// Copy the returned data.
returndatacopy(0, 0, returndatasize())
switch result
// delegatecall returns 0 on error.
case 0 {
revert(0, returndatasize())
}
default {
return(0, returndatasize())
}
}
}
/**
* @dev This is a virtual function that should be overridden so it returns the address to which the fallback function
* and {_fallback} should delegate.
*/
function _implementation() internal view virtual returns (address);
/**
* @dev Delegates the current call to the address returned by `_implementation()`.
*
* This function does not return to its internal call site, it will return directly to the external caller.
*/
function _fallback() internal virtual {
_beforeFallback();
_delegate(_implementation());
}
/**
* @dev Fallback function that delegates calls to the address returned by `_implementation()`. Will run if no other
* function in the contract matches the call data.
*/
fallback() external payable virtual {
_fallback();
}
/**
* @dev Fallback function that delegates calls to the address returned by `_implementation()`. Will run if call data
* is empty.
*/
receive() external payable virtual {
_fallback();
}
/**
* @dev Hook that is called before falling back to the implementation. Can happen as part of a manual `_fallback`
* call, or as part of the Solidity `fallback` or `receive` functions.
*
* If overridden should call `super._beforeFallback()`.
*/
function _beforeFallback() internal virtual {}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
* https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
*
* Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
* presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
* need to send a transaction, and thus is not required to hold Ether at all.
*
* ==== Security Considerations
*
* There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
* expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
* considered as an intention to spend the allowance in any specific way. The second is that because permits have
* built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
* take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
* generally recommended is:
*
* ```solidity
* function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
* try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
* doThing(..., value);
* }
*
* function doThing(..., uint256 value) public {
* token.safeTransferFrom(msg.sender, address(this), value);
* ...
* }
* ```
*
* Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
* `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
* {SafeERC20-safeTransferFrom}).
*
* Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
* contracts should have entry points that don't rely on permit.
*/
interface IERC20Permit {
/**
* @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
* given ``owner``'s signed approval.
*
* IMPORTANT: The same issues {IERC20-approve} has related to transaction
* ordering also apply here.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `deadline` must be a timestamp in the future.
* - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
* over the EIP712-formatted function arguments.
* - the signature must use ``owner``'s current nonce (see {nonces}).
*
* For more information on the signature format, see the
* https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
* section].
*
* CAUTION: See Security Considerations above.
*/
function permit(
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external;
/**
* @dev Returns the current nonce for `owner`. This value must be
* included whenever a signature is generated for {permit}.
*
* Every successful call to {permit} increases ``owner``'s nonce by one. This
* prevents a signature from being used multiple times.
*/
function nonces(address owner) external view returns (uint256);
/**
* @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
*/
// solhint-disable-next-line func-name-mixedcase
function DOMAIN_SEPARATOR() external view returns (bytes32);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(address from, address to, uint256 amount) external returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
/**
* @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeTransfer(IERC20 token, address to, uint256 value) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
}
/**
* @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
* calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
*/
function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
}
/**
* @dev Deprecated. This function has issues similar to the ones found in
* {IERC20-approve}, and its usage is discouraged.
*
* Whenever possible, use {safeIncreaseAllowance} and
* {safeDecreaseAllowance} instead.
*/
function safeApprove(IERC20 token, address spender, uint256 value) internal {
// safeApprove should only be called when setting an initial allowance,
// or when resetting it to zero. To increase and decrease it, use
// 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
require(
(value == 0) || (token.allowance(address(this), spender) == 0),
"SafeERC20: approve from non-zero to non-zero allowance"
);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
}
/**
* @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
uint256 oldAllowance = token.allowance(address(this), spender);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
}
/**
* @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful.
*/
function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
unchecked {
uint256 oldAllowance = token.allowance(address(this), spender);
require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
}
}
/**
* @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
* non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
* to be set to zero before setting it to a non-zero value, such as USDT.
*/
function forceApprove(IERC20 token, address spender, uint256 value) internal {
bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);
if (!_callOptionalReturnBool(token, approvalCall)) {
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
_callOptionalReturn(token, approvalCall);
}
}
/**
* @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
* Revert on invalid signature.
*/
function safePermit(
IERC20Permit token,
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) internal {
uint256 nonceBefore = token.nonces(owner);
token.permit(owner, spender, value, deadline, v, r, s);
uint256 nonceAfter = token.nonces(owner);
require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*
* This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
*/
function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
// and not revert is the subcall reverts.
(bool success, bytes memory returndata) = address(token).call(data);
return
success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
*
* Furthermore, `isContract` will also return true if the target contract within
* the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
* which only has an effect at the end of a transaction.
* ====
*
* [IMPORTANT]
* ====
* You shouldn't rely on `isContract` to protect against flash loan attacks!
*
* Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
* like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
* constructor.
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize/address.code.length, which returns 0
// for contracts in construction, since the code is only stored at the end
// of the constructor execution.
return account.code.length > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(address(this).balance >= amount, "Address: insufficient balance");
(bool success, ) = recipient.call{value: amount}("");
require(success, "Address: unable to send value, recipient may have reverted");
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(address(this).balance >= value, "Address: insufficient balance for call");
(bool success, bytes memory returndata) = target.call{value: value}(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
return functionStaticCall(target, data, "Address: low-level static call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
(bool success, bytes memory returndata) = target.staticcall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
return functionDelegateCall(target, data, "Address: low-level delegate call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
(bool success, bytes memory returndata) = target.delegatecall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
* the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
*
* _Available since v4.8._
*/
function verifyCallResultFromTarget(
address target,
bool success,
bytes memory returndata,
string memory errorMessage
) internal view returns (bytes memory) {
if (success) {
if (returndata.length == 0) {
// only check isContract if the call was successful and the return data is empty
// otherwise we already know that it was a contract
require(isContract(target), "Address: call to non-contract");
}
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
/**
* @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
* revert reason or using the provided one.
*
* _Available since v4.3._
*/
function verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) internal pure returns (bytes memory) {
if (success) {
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
function _revert(bytes memory returndata, string memory errorMessage) private pure {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
/// @solidity memory-safe-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/StorageSlot.sol)
// This file was procedurally generated from scripts/generate/templates/StorageSlot.js.
pragma solidity ^0.8.0;
/**
* @dev Library for reading and writing primitive types to specific storage slots.
*
* Storage slots are often used to avoid storage conflict when dealing with upgradeable contracts.
* This library helps with reading and writing to such slots without the need for inline assembly.
*
* The functions in this library return Slot structs that contain a `value` member that can be used to read or write.
*
* Example usage to set ERC1967 implementation slot:
* ```solidity
* contract ERC1967 {
* bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
*
* function _getImplementation() internal view returns (address) {
* return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
* }
*
* function _setImplementation(address newImplementation) internal {
* require(Address.isContract(newImplementation), "ERC1967: new implementation is not a contract");
* StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
* }
* }
* ```
*
* _Available since v4.1 for `address`, `bool`, `bytes32`, `uint256`._
* _Available since v4.9 for `string`, `bytes`._
*/
library StorageSlot {
struct AddressSlot {
address value;
}
struct BooleanSlot {
bool value;
}
struct Bytes32Slot {
bytes32 value;
}
struct Uint256Slot {
uint256 value;
}
struct StringSlot {
string value;
}
struct BytesSlot {
bytes value;
}
/**
* @dev Returns an `AddressSlot` with member `value` located at `slot`.
*/
function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
/// @solidity memory-safe-assembly
assembly {
r.slot := slot
}
}
/**
* @dev Returns an `BooleanSlot` with member `value` located at `slot`.
*/
function getBooleanSlot(bytes32 slot) internal pure returns (BooleanSlot storage r) {
/// @solidity memory-safe-assembly
assembly {
r.slot := slot
}
}
/**
* @dev Returns an `Bytes32Slot` with member `value` located at `slot`.
*/
function getBytes32Slot(bytes32 slot) internal pure returns (Bytes32Slot storage r) {
/// @solidity memory-safe-assembly
assembly {
r.slot := slot
}
}
/**
* @dev Returns an `Uint256Slot` with member `value` located at `slot`.
*/
function getUint256Slot(bytes32 slot) internal pure returns (Uint256Slot storage r) {
/// @solidity memory-safe-assembly
assembly {
r.slot := slot
}
}
/**
* @dev Returns an `StringSlot` with member `value` located at `slot`.
*/
function getStringSlot(bytes32 slot) internal pure returns (StringSlot storage r) {
/// @solidity memory-safe-assembly
assembly {
r.slot := slot
}
}
/**
* @dev Returns an `StringSlot` representation of the string storage pointer `store`.
*/
function getStringSlot(string storage store) internal pure returns (StringSlot storage r) {
/// @solidity memory-safe-assembly
assembly {
r.slot := store.slot
}
}
/**
* @dev Returns an `BytesSlot` with member `value` located at `slot`.
*/
function getBytesSlot(bytes32 slot) internal pure returns (BytesSlot storage r) {
/// @solidity memory-safe-assembly
assembly {
r.slot := slot
}
}
/**
* @dev Returns an `BytesSlot` representation of the bytes storage pointer `store`.
*/
function getBytesSlot(bytes storage store) internal pure returns (BytesSlot storage r) {
/// @solidity memory-safe-assembly
assembly {
r.slot := store.slot
}
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
import "@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol";
import "@openzeppelin/contracts-upgradeable/security/PausableUpgradeable.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "../../interfaces/IInceptionAssetHandler.sol";
import "../../interfaces/IInceptionVaultErrors.sol";
import "../lib/Convert.sol";
/// @author The InceptionLRT team
/// @title The InceptionAssetsHandler contract
/// @dev Handles operations with the corresponding asset
contract InceptionAssetsHandler is
PausableUpgradeable,
ReentrancyGuardUpgradeable,
OwnableUpgradeable,
IInceptionVaultErrors,
IInceptionAssetHandler
{
using SafeERC20 for IERC20;
IERC20 internal _asset;
uint256[49] private __reserver;
function __InceptionAssetsHandler_init(
IERC20 assetAddress
) internal onlyInitializing {
__Pausable_init();
__ReentrancyGuard_init();
_asset = assetAddress;
}
/// @dev returns the balance of iVault in the asset
function totalAssets() public view override returns (uint256) {
return _asset.balanceOf(address(this));
}
function _transferAssetFrom(address staker, uint256 amount) internal {
if (!_asset.transferFrom(staker, address(this), amount)) {
revert TransferAssetFromFailed(address(_asset));
}
}
function _transferAssetTo(address receiver, uint256 amount) internal {
if (!_asset.transfer(receiver, amount)) {
revert TransferAssetFailed(address(_asset));
}
}
/// @dev The functions below serve the proper withdrawal and claiming operations
/// @notice Since a particular LST loses some wei on each transfer,
/// this needs to be taken into account
function _getAssetWithdrawAmount(
uint256 amount
) internal view virtual returns (uint256) {
return amount;
}
function _getAssetReceivedAmount(
uint256 amount
) internal view virtual returns (uint256) {
return amount;
}
function _getAssetRedeemAmount(
uint256 amount
) internal view virtual returns (uint256) {
return amount;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "../assets-handler/InceptionAssetsHandler.sol";
import "../../interfaces/IStrategyManager.sol";
import "../../interfaces/IDelegationManager.sol";
import "../../interfaces/IEigenLayerHandler.sol";
import "../../interfaces/IInceptionRestaker.sol";
/// @author The InceptionLRT team
/// @title The EigenLayerHandler contract
/// @dev Serves communication with external EigenLayer protocol
/// @dev Specifically, this includes depositing, and handling withdrawal requests
contract EigenLayerHandler is InceptionAssetsHandler, IEigenLayerHandler {
IStrategyManager public strategyManager;
IStrategy public strategy;
uint256 public epoch;
/// @dev inception operator
address internal _operator;
/// @dev represents the pending amount to be redeemed by claimers,
/// @notice + amount to undelegate from EigenLayer
uint256 public totalAmountToWithdraw;
/// @dev represents the amount pending processing until it is claimed
/// @dev amount measured in asset
uint256 internal _pendingWithdrawalAmount;
IDelegationManager public delegationManager;
Withdrawal[] public claimerWithdrawalsQueue;
address internal constant _MOCK_ADDRESS =
0x0000000000000000000000000012345000000000;
/// @dev heap reserved for the claimers
uint256 public redeemReservedAmount;
/// @dev EigenLayer operator -> inception staker
mapping(address => address) internal _operatorRestakers;
address[] public restakers;
/// @dev constants are not stored in the storage
uint256[50 - 11] private __reserver;
modifier onlyOperator() {
require(
msg.sender == _operator,
"EigenLayerHandler: only operator allowed"
);
_;
}
function __EigenLayerHandler_init(
IStrategyManager _strategyManager,
IStrategy _assetStrategy
) internal onlyInitializing {
strategyManager = _strategyManager;
strategy = _assetStrategy;
__InceptionAssetsHandler_init(_assetStrategy.underlyingToken());
// approve spending by strategyManager
require(
_asset.approve(address(strategyManager), type(uint256).max),
"EigenLayerHandler: approve failed"
);
}
/*//////////////////////////////
////// Deposit functions //////
////////////////////////////*/
/// @dev checks whether it's still possible to deposit into the strategy
function _beforeDepositAssetIntoStrategy(uint256 amount) internal view {
if (amount > totalAssets() - redeemReservedAmount) {
revert InsufficientCapacity(totalAssets());
}
(uint256 maxPerDeposit, uint256 maxTotalDeposits) = strategy
.getTVLLimits();
if (amount > maxPerDeposit) {
revert ExceedsMaxPerDeposit(maxPerDeposit, amount);
}
uint256 currentBalance = _asset.balanceOf(address(strategy));
if (currentBalance + amount > maxTotalDeposits) {
revert ExceedsMaxTotalDeposited(maxTotalDeposits, currentBalance);
}
}
/// @dev deposits asset to the corresponding strategy
function _depositAssetIntoStrategy(
address restaker,
uint256 amount
) internal {
_asset.approve(restaker, amount);
IInceptionRestaker(restaker).depositAssetIntoStrategy(amount);
emit DepositedToEL(restaker, amount);
}
function depositAssetIntoStrategyFromVault(
uint256 amount
) external nonReentrant onlyOperator {
_beforeDepositAssetIntoStrategy(amount);
strategyManager.depositIntoStrategy(strategy, _asset, amount);
emit DepositedToEL(address(this), amount);
}
/// @dev deposits asset to the corresponding strategy
function _depositAssetIntoStrategyFromVault(uint256 amount) internal {
strategyManager.depositIntoStrategy(strategy, _asset, amount);
}
/// @dev delegates assets held in the strategy to the EL operator.
function _delegateToOperator(
address restaker,
address elOperator,
bytes32 approverSalt,
IDelegationManager.SignatureWithExpiry memory approverSignatureAndExpiry
) internal {
IInceptionRestaker(restaker).delegateToOperator(
elOperator,
approverSalt,
approverSignatureAndExpiry
);
}
function _delegateToOperatorFromVault(
address elOperator,
bytes32 approverSalt,
IDelegationManager.SignatureWithExpiry memory approverSignatureAndExpiry
) internal {
delegationManager.delegateTo(
elOperator,
approverSignatureAndExpiry,
approverSalt
);
}
/*/////////////////////////////////
////// Withdrawal functions //////
///////////////////////////////*/
/// @dev performs creating a withdrawal request from EigenLayer
/// @dev requires a specific amount to withdraw
function undelegateFrom(
address elOperatorAddress,
uint256 amount
) external whenNotPaused nonReentrant onlyOperator {
address stakerAddress = _operatorRestakers[elOperatorAddress];
if (stakerAddress == address(0)) {
revert OperatorNotRegistered();
}
if (stakerAddress == _MOCK_ADDRESS) {
revert NullParams();
}
uint256 nonce = delegationManager.cumulativeWithdrawalsQueued(
stakerAddress
);
uint256 totalAssetSharesInEL = strategyManager.stakerStrategyShares(
stakerAddress,
strategy
);
uint256 shares = strategy.underlyingToSharesView(amount);
// we need to withdraw the remaining dust from EigenLayer
if (totalAssetSharesInEL < shares + 5) {
shares = totalAssetSharesInEL;
}
amount = strategy.sharesToUnderlyingView(shares);
emit StartWithdrawal(
stakerAddress,
strategy,
shares,
uint32(block.number),
elOperatorAddress,
nonce
);
_pendingWithdrawalAmount += amount;
IInceptionRestaker(stakerAddress).withdrawFromEL(shares);
}
/// @dev performs creating a withdrawal request from EigenLayer
/// @dev requires a specific amount to withdraw
function undelegateVault(
uint256 amount
) external whenNotPaused nonReentrant onlyOperator {
address staker = address(this);
uint256 nonce = delegationManager.cumulativeWithdrawalsQueued(staker);
uint256 totalAssetSharesInEL = strategyManager.stakerStrategyShares(
staker,
strategy
);
uint256 shares = strategy.underlyingToSharesView(amount);
// we need to withdraw the remaining dust from EigenLayer
if (totalAssetSharesInEL < shares + 5) {
shares = totalAssetSharesInEL;
}
amount = strategy.sharesToUnderlyingView(shares);
uint256[] memory sharesToWithdraw = new uint256[](1);
IStrategy[] memory strategies = new IStrategy[](1);
strategies[0] = strategy;
sharesToWithdraw[0] = shares;
IDelegationManager.QueuedWithdrawalParams[]
memory withdrawals = new IDelegationManager.QueuedWithdrawalParams[](
1
);
withdrawals[0] = IDelegationManager.QueuedWithdrawalParams({
strategies: strategies,
shares: sharesToWithdraw,
withdrawer: address(this)
});
_pendingWithdrawalAmount += amount;
delegationManager.queueWithdrawals(withdrawals);
emit StartWithdrawal(
staker,
strategy,
shares,
uint32(block.number),
delegationManager.delegatedTo(staker),
nonce
);
}
/// @dev claims completed withdrawals from EigenLayer, if they exist
function claimCompletedWithdrawals(
address restaker,
IDelegationManager.Withdrawal[] calldata withdrawals
) public whenNotPaused nonReentrant {
uint256 withdrawalsNum = withdrawals.length;
IERC20[][] memory tokens = new IERC20[][](withdrawalsNum);
uint256[] memory middlewareTimesIndexes = new uint256[](withdrawalsNum);
bool[] memory receiveAsTokens = new bool[](withdrawalsNum);
for (uint256 i = 0; i < withdrawalsNum; ) {
tokens[i] = new IERC20[](1);
tokens[i][0] = _asset;
receiveAsTokens[i] = true;
unchecked {
i++;
}
}
uint256 withdrawnAmount;
if (restaker == address(this)) {
withdrawnAmount = _claimCompletedWithdrawalsForVault(
withdrawals,
tokens,
middlewareTimesIndexes,
receiveAsTokens
);
} else {
if (!_restakerExists(restaker)) revert RestakerNotRegistered();
withdrawnAmount = IInceptionRestaker(restaker).claimWithdrawals(
withdrawals,
tokens,
middlewareTimesIndexes,
receiveAsTokens
);
}
emit WithdrawalClaimed(withdrawnAmount);
_pendingWithdrawalAmount = _pendingWithdrawalAmount < withdrawnAmount
? 0
: _pendingWithdrawalAmount - withdrawnAmount;
if (_pendingWithdrawalAmount < 7) {
_pendingWithdrawalAmount = 0;
}
_updateEpoch();
}
function _claimCompletedWithdrawalsForVault(
IDelegationManager.Withdrawal[] memory withdrawals,
IERC20[][] memory tokens,
uint256[] memory middlewareTimesIndexes,
bool[] memory receiveAsTokens
) internal returns (uint256) {
uint256 balanceBefore = _asset.balanceOf(address(this));
delegationManager.completeQueuedWithdrawals(
withdrawals,
tokens,
middlewareTimesIndexes,
receiveAsTokens
);
// send tokens to the vault
uint256 withdrawnAmount = _asset.balanceOf(address(this)) -
balanceBefore;
return withdrawnAmount;
}
function updateEpoch() external whenNotPaused {
_updateEpoch();
}
/**
* @dev let's calculate how many withdrawals we can cover with the withdrawnAmount
* @dev #init state:
* - balance of the vault: X
* - epoch: means that the vault can handle the withdrawal queue up to the epoch index
* withdrawalQueue[... : epoch];
*
* @dev #new state:
* - balance of the vault: X + withdrawnAmount
* - we need to recalculate a new value for epoch, new_epoch, to cover withdrawals:
* withdrawalQueue[epoch : new_epoch];
*/
function _updateEpoch() internal {
uint256 withdrawalsNum = claimerWithdrawalsQueue.length;
uint256 availableBalance = totalAssets() - redeemReservedAmount;
for (uint256 i = epoch; i < withdrawalsNum; ) {
uint256 amount = claimerWithdrawalsQueue[i].amount;
unchecked {
if (amount > availableBalance) {
break;
}
redeemReservedAmount += amount;
availableBalance -= amount;
epoch++;
i++;
}
}
}
function _restakerExists(
address restakerAddress
) internal view returns (bool) {
uint256 numOfRestakers = restakers.length;
for (uint256 i = 0; i < numOfRestakers; ) {
if (restakerAddress == restakers[i]) return true;
unchecked {
++i;
}
}
return false;
}
/*//////////////////////////
////// GET functions //////
////////////////////////*/
function getPendingWithdrawalAmountFromEL()
public
view
returns (uint256 total)
{
return _pendingWithdrawalAmount;
}
/*//////////////////////////
////// SET functions //////
////////////////////////*/
function setDelegationManager(
IDelegationManager newDelegationManager
) external onlyOwner {
if (address(delegationManager) != address(0))
revert DelegationManagerImmutable();
emit DelegationManagerChanged(
address(delegationManager),
address(newDelegationManager)
);
delegationManager = newDelegationManager;
}
function forceUndelegateRecovery(
uint256 amount,
address restaker
) external onlyOperator {
if (restaker == address(0)) revert NullParams();
for (uint256 i = 0; i < restakers.length; ) {
if (
restakers[i] == restaker &&
!delegationManager.isDelegated(restakers[i])
) {
restakers[i] == _MOCK_ADDRESS;
break;
}
unchecked {
++i;
}
}
_pendingWithdrawalAmount += amount;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.7;
library Convert {
function saturatingMultiply(
uint256 a,
uint256 b
) internal pure returns (uint256) {
unchecked {
if (a == 0) return 0;
uint256 c = a * b;
if (c / a != b) return type(uint256).max;
return c;
}
}
function saturatingAdd(
uint256 a,
uint256 b
) internal pure returns (uint256) {
unchecked {
uint256 c = a + b;
if (c < a) return type(uint256).max;
return c;
}
}
// Preconditions:
// 1. a may be arbitrary (up to 2 ** 256 - 1)
// 2. b * c < 2 ** 256
// Returned value: min(floor((a * b) / c), 2 ** 256 - 1)
function multiplyAndDivideFloor(
uint256 a,
uint256 b,
uint256 c
) internal pure returns (uint256) {
return
saturatingAdd(
saturatingMultiply(a / c, b),
((a % c) * b) / c // can't fail because of assumption 2.
);
}
// Preconditions:
// 1. a may be arbitrary (up to 2 ** 256 - 1)
// 2. b * c < 2 ** 256
// Returned value: min(ceil((a * b) / c), 2 ** 256 - 1)
function multiplyAndDivideCeil(
uint256 a,
uint256 b,
uint256 c
) internal pure returns (uint256) {
require(c != 0, "c == 0");
return
saturatingAdd(
saturatingMultiply(a / c, b),
((a % c) * b + (c - 1)) / c // can't fail because of assumption 2.
);
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "@openzeppelin/contracts/proxy/beacon/BeaconProxy.sol";
import "../eigenlayer-handler/EigenLayerHandler.sol";
import "../../interfaces/IOwnable.sol";
import "../../interfaces/IInceptionVault.sol";
import "../../interfaces/IInceptionToken.sol";
import "../../interfaces/IRebalanceStrategy.sol";
import "../../interfaces/IDelegationManager.sol";
/// @author The InceptionLRT team
/// @title The InceptionVault contract
/// @notice Aims to maximize the profit of EigenLayer for a certain asset.
contract InceptionVault is IInceptionVault, EigenLayerHandler {
/// @dev Inception restaking token
IInceptionToken public inceptionToken;
/// @dev Reduces rounding issues
uint256 public minAmount;
mapping(address => Withdrawal) private _claimerWithdrawals;
/// @dev the unique InceptionVault name
string public name;
/// @dev Factory variables
address private _stakerImplementation;
function __InceptionVault_init(
string memory vaultName,
address operatorAddress,
IStrategyManager _strategyManager,
IInceptionToken _inceptionToken,
IStrategy _assetStrategy
) internal {
__Ownable_init();
__EigenLayerHandler_init(_strategyManager, _assetStrategy);
name = vaultName;
_operator = operatorAddress;
inceptionToken = _inceptionToken;
minAmount = 100;
}
/*//////////////////////////////
////// Deposit functions //////
////////////////////////////*/
function __beforeDeposit(address receiver, uint256 amount) internal view {
if (receiver == address(0)) revert NullParams();
require(
amount >= minAmount,
"InceptionVault: deposited less than min amount"
);
if (!_verifyDelegated()) revert InceptionOnPause();
}
function __afterDeposit(uint256 iShares) internal pure {
require(iShares > 0, "InceptionVault: result iShares 0");
}
/// @dev Transfers the msg.sender's assets to the vault.
/// @dev Mints Inception tokens in accordance with the current ratio.
/// @dev Issues the tokens to the specified receiver address.
function deposit(
uint256 amount,
address receiver
) public nonReentrant whenNotPaused returns (uint256) {
return _deposit(amount, msg.sender, receiver);
}
/// @notice The deposit function but with a referral code
function depositWithReferral(
uint256 amount,
address receiver,
bytes32 code
) public nonReentrant whenNotPaused returns (uint256) {
emit ReferralCode(code);
return _deposit(amount, msg.sender, receiver);
}
function _deposit(
uint256 amount,
address sender,
address receiver
) internal returns (uint256) {
uint256 currentRatio = ratio();
// transfers assets from the sender and returns the received amount
// the actual received amount might slightly differ from the specified amount,
// approximately by -2 wei
__beforeDeposit(receiver, amount);
uint256 depositedBefore = totalAssets();
// get the amount from the sender
_transferAssetFrom(sender, amount);
amount = totalAssets() - depositedBefore;
uint256 iShares = Convert.multiplyAndDivideFloor(
amount,
currentRatio,
1e18
);
inceptionToken.mint(receiver, iShares);
__afterDeposit(iShares);
emit Deposit(sender, receiver, amount, iShares);
return iShares;
}
/*/////////////////////////////////
////// Delegation functions //////
///////////////////////////////*/
function delegateToOperator(
uint256 amount,
address elOperator,
bytes32 approverSalt,
IDelegationManager.SignatureWithExpiry memory approverSignatureAndExpiry
) external nonReentrant whenNotPaused onlyOperator {
if (elOperator == address(0)) {
revert NullParams();
}
_beforeDepositAssetIntoStrategy(amount);
// try to find a restaker for the specific EL operator
address restaker = _operatorRestakers[elOperator];
if (restaker == address(0)) {
revert OperatorNotRegistered();
}
bool delegate = false;
if (restaker == _MOCK_ADDRESS) {
delegate = true;
// deploy a new restaker
restaker = _deployNewStub();
_operatorRestakers[elOperator] = restaker;
restakers.push(restaker);
}
_depositAssetIntoStrategy(restaker, amount);
if (delegate)
_delegateToOperator(
restaker,
elOperator,
approverSalt,
approverSignatureAndExpiry
);
emit DelegatedTo(restaker, elOperator);
}
function delegateToOperatorFromVault(
address elOperator,
bytes32 approverSalt,
IDelegationManager.SignatureWithExpiry memory approverSignatureAndExpiry
) external nonReentrant whenNotPaused onlyOperator {
if (elOperator == address(0)) {
revert NullParams();
}
if (delegationManager.delegatedTo(address(this)) != address(0))
revert AlreadyDelegated();
_delegateToOperatorFromVault(
elOperator,
approverSalt,
approverSignatureAndExpiry
);
emit DelegatedTo(address(this), elOperator);
}
/*///////////////////////////////////////
///////// Withdrawal functions /////////
/////////////////////////////////////*/
function __beforeWithdraw(address receiver, uint256 iShares) internal view {
if (iShares == 0) {
revert NullParams();
}
if (receiver == address(0)) {
revert NullParams();
}
if (!_verifyDelegated()) revert InceptionOnPause();
}
/// @dev Performs burning iToken from mgs.sender
/// @dev Creates a withdrawal requests based on the current ratio
/// @param iShares is measured in Inception token(shares)
function withdraw(
uint256 iShares,
address receiver
) external whenNotPaused nonReentrant {
__beforeWithdraw(receiver, iShares);
address claimer = msg.sender;
uint256 amount = Convert.multiplyAndDivideFloor(iShares, 1e18, ratio());
require(
amount >= minAmount,
"InceptionVault: amount is less than the minimum withdrawal"
);
// burn Inception token in view of the current ratio
inceptionToken.burn(claimer, iShares);
// update global state and claimer's state
totalAmountToWithdraw += amount;
Withdrawal storage genRequest = _claimerWithdrawals[receiver];
genRequest.amount += _getAssetReceivedAmount(amount);
claimerWithdrawalsQueue.push(
Withdrawal({
epoch: claimerWithdrawalsQueue.length,
receiver: receiver,
amount: _getAssetReceivedAmount(amount)
})
);
emit Withdraw(claimer, receiver, claimer, amount, iShares);
}
function redeem(address receiver) public whenNotPaused nonReentrant {
(bool isAble, uint256[] memory availableWithdrawals) = isAbleToRedeem(
receiver
);
require(isAble, "InceptionVault: redeem can not be proceed");
uint256 numOfWithdrawals = availableWithdrawals.length;
uint256[] memory redeemedWithdrawals = new uint256[](numOfWithdrawals);
Withdrawal storage genRequest = _claimerWithdrawals[receiver];
uint256 redeemedAmount;
for (uint256 i = 0; i < numOfWithdrawals; ) {
uint256 withdrawalNum = availableWithdrawals[i];
Withdrawal memory request = claimerWithdrawalsQueue[withdrawalNum];
uint256 amount = request.amount;
// update the genRequest and the global state
genRequest.amount -= amount;
totalAmountToWithdraw -= _getAssetWithdrawAmount(amount);
redeemReservedAmount -= amount;
redeemedAmount += amount;
redeemedWithdrawals[i] = withdrawalNum;
delete claimerWithdrawalsQueue[availableWithdrawals[i]];
unchecked {
++i;
}
}
// let's update the lowest epoch associated with the claimer
genRequest.epoch = availableWithdrawals[numOfWithdrawals - 1];
_transferAssetTo(receiver, redeemedAmount);
emit RedeemedRequests(redeemedWithdrawals);
emit Redeem(msg.sender, receiver, redeemedAmount);
}
/*//////////////////////////////
////// Factory functions //////
////////////////////////////*/
function _deployNewStub() internal returns (address) {
if (_stakerImplementation == address(0)) {
revert ImplementationNotSet();
}
// deploy new beacon proxy and do init call
bytes memory data = abi.encodeWithSignature(
"initialize(address,address,address,address)",
delegationManager,
strategyManager,
strategy,
_operator
);
address deployedAddress = address(new BeaconProxy(address(this), data));
IOwnable asOwnable = IOwnable(deployedAddress);
asOwnable.transferOwnership(owner());
emit RestakerDeployed(deployedAddress);
return deployedAddress;
}
function implementation() external view returns (address) {
return _stakerImplementation;
}
function upgradeTo(
address newImplementation
) external whenNotPaused onlyOwner {
require(
Address.isContract(newImplementation),
"InceptionVault: implementation is not a contract"
);
emit ImplementationUpgraded(_stakerImplementation, newImplementation);
_stakerImplementation = newImplementation;
}
function isAbleToRedeem(
address claimer
) public view returns (bool able, uint256[] memory) {
// get the general request
uint256 index;
Withdrawal memory genRequest = _claimerWithdrawals[claimer];
uint256 from = genRequest.epoch;
uint256[] memory availableWithdrawals = new uint256[](epoch - from);
if (genRequest.amount == 0) {
return (false, availableWithdrawals);
}
for (uint256 i = 0; i < epoch; ) {
if (claimerWithdrawalsQueue[i].receiver == claimer) {
able = true;
availableWithdrawals[index] = i;
++index;
}
unchecked {
++i;
}
}
// decrease arrays
if (availableWithdrawals.length - index > 0) {
assembly {
mstore(availableWithdrawals, index)
}
}
return (able, availableWithdrawals);
}
function ratio() public view returns (uint256) {
uint256 totalDeposited = getTotalDeposited();
uint256 totalSupply = IERC20(address(inceptionToken)).totalSupply();
// take into account the pending withdrawn amount
uint256 denominator = totalDeposited < totalAmountToWithdraw
? 0
: totalDeposited - totalAmountToWithdraw;
if (denominator == 0 || totalSupply == 0) return 1e18;
return Convert.multiplyAndDivideCeil(totalSupply, 1e18, denominator);
}
/// @dev returns the total deposited into asset strategy
function getTotalDeposited() public view returns (uint256) {
return getTotalDelegated() + totalAssets() + _pendingWithdrawalAmount;
}
function getTotalDelegated() public view returns (uint256 total) {
uint256 stakersNum = restakers.length;
for (uint256 i = 0; i < stakersNum; ) {
if (restakers[i] == address(0)) {
continue;
}
total += strategy.userUnderlyingView(restakers[i]);
unchecked {
++i;
}
}
return total + strategy.userUnderlyingView(address(this));
}
function _verifyDelegated() internal view returns (bool) {
for (uint256 i = 0; i < restakers.length; ) {
if (restakers[i] == address(0)) {
unchecked {
++i;
}
continue;
}
if (!delegationManager.isDelegated(restakers[i])) return false;
unchecked {
++i;
}
}
if (
strategy.userUnderlyingView(address(this)) > 0 &&
!delegationManager.isDelegated(address(this))
) return false;
return true;
}
function getDelegatedTo(address elOperator) public view returns (uint256) {
return strategy.userUnderlyingView(_operatorRestakers[elOperator]);
}
function getPendingWithdrawalOf(
address claimer
) public view returns (uint256) {
return _claimerWithdrawals[claimer].amount;
}
/*//////////////////////////////
////// Convert functions //////
////////////////////////////*/
function convertToShares(
uint256 assets
) public view returns (uint256 shares) {
return Convert.multiplyAndDivideFloor(assets, ratio(), 1e18);
}
function convertToAssets(
uint256 iShares
) public view returns (uint256 assets) {
return Convert.multiplyAndDivideFloor(iShares, 1e18, ratio());
}
/*//////////////////////////
////// SET functions //////
////////////////////////*/
function setOperator(address newOperator) external onlyOwner {
if (newOperator == address(0)) {
revert NullParams();
}
emit OperatorChanged(_operator, newOperator);
_operator = newOperator;
}
function setMinAmount(uint256 newMinAmount) external onlyOwner {
emit MinAmountChanged(minAmount, newMinAmount);
minAmount = newMinAmount;
}
function setName(string memory newVaultName) external onlyOwner {
if (bytes(newVaultName).length == 0) {
revert NullParams();
}
emit NameChanged(name, newVaultName);
name = newVaultName;
}
function addELOperator(address newELOperator) external onlyOwner {
require(
delegationManager.isOperator(newELOperator),
"InceptionVault: it is not an EL operator"
);
require(
_operatorRestakers[newELOperator] == address(0),
"InceptionVault: operator already exists"
);
_operatorRestakers[newELOperator] = _MOCK_ADDRESS;
emit ELOperatorAdded(newELOperator);
}
/*///////////////////////////////
////// Pausable functions //////
/////////////////////////////*/
function pause() external onlyOwner {
_pause();
}
function unpause() external onlyOwner {
_unpause();
}
/*///////////////////////////////////
/////////// M2 migration ///////////
/////////////////////////////////*/
function setWithdrawalQueue(
address[] memory receivers
) external onlyOperator {
uint256 numberOfReceivers = receivers.length;
// let's update redeemReservedAmount and epoch
for (uint256 i = 0; i < numberOfReceivers; ) {
address receiver = receivers[i];
Withdrawal storage request = _claimerWithdrawals[receiver];
uint256 amount = request.amount;
if (amount == 0) {
unchecked {
++i;
}
continue;
}
request.epoch = 0;
// update global state and claimer's state
claimerWithdrawalsQueue.push(
Withdrawal({
epoch: claimerWithdrawalsQueue.length,
receiver: receiver,
amount: amount
})
);
unchecked {
++i;
}
}
}
function setUpdatedEpoch(address[] memory receivers) external onlyOperator {
uint256 numberOfReceivers = receivers.length;
// let's update redeemReservedAmount and epoch
for (uint256 i = 0; i < numberOfReceivers; ) {
address receiver = receivers[i];
Withdrawal storage request = _claimerWithdrawals[receiver];
request.epoch = 0;
unchecked {
++i;
}
}
}
function getWithdrawal(
address claimer
) public view returns (Withdrawal memory) {
return _claimerWithdrawals[claimer];
}
function updateEpoch(uint256 newEpoch) external onlyOperator {
epoch = newEpoch;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "../InceptionVault.sol";
import "../../../interfaces/IStEth.sol";
/// @author The InceptionLRT team
contract InVault_E1 is InceptionVault {
/// @custom:oz-upgrades-unsafe-allow constructor
constructor() {
_disableInitializers();
}
function initialize(
string memory vaultName,
address operatorAddress,
IStrategyManager _strategyManager,
IInceptionToken _inceptionToken,
IStrategy _assetStrategy
) external initializer {
__InceptionVault_init(
vaultName,
operatorAddress,
_strategyManager,
_inceptionToken,
_assetStrategy
);
}
function _getAssetWithdrawAmount(
uint256 amount
) internal pure override returns (uint256) {
return amount + 1;
}
function _getAssetReceivedAmount(
uint256 amount
) internal pure override returns (uint256) {
return amount - 1;
}
function _getAssetRedeemAmount(
uint256 amount
) internal pure override returns (uint256) {
return amount + 1;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "./IStrategy.sol";
interface IDelegationManager {
// @notice Struct that bundles together a signature and an expiration time for the signature. Used primarily for stack management.
struct SignatureWithExpiry {
// the signature itself, formatted as a single bytes object
bytes signature;
// the expiration timestamp (UTC) of the signature
uint256 expiry;
}
// @notice Struct that bundles together a signature, a salt for uniqueness, and an expiration time for the signature. Used primarily for stack management.
struct SignatureWithSaltAndExpiry {
// the signature itself, formatted as a single bytes object
bytes signature;
// the salt used to generate the signature
bytes32 salt;
// the expiration timestamp (UTC) of the signature
uint256 expiry;
}
struct QueuedWithdrawalParams {
// Array of strategies that the QueuedWithdrawal contains
IStrategy[] strategies;
// Array containing the amount of shares in each Strategy in the `strategies` array
uint256[] shares;
// The address of the withdrawer
address withdrawer;
}
struct Withdrawal {
// The address that originated the Withdrawal
address staker;
// The address that the staker was delegated to at the time that the Withdrawal was created
address delegatedTo;
// The address that can complete the Withdrawal + will receive funds when completing the withdrawal
address withdrawer;
// Nonce used to guarantee that otherwise identical withdrawals have unique hashes
uint256 nonce;
// Block number when the Withdrawal was created
uint32 startBlock;
// Array of strategies that the Withdrawal contains
IStrategy[] strategies;
// Array containing the amount of shares in each Strategy in the `strategies` array
uint256[] shares;
}
function delegateTo(
address operator,
SignatureWithExpiry memory approverSignatureAndExpiry,
bytes32 approverSalt
) external;
function undelegate(address staker) external;
event WithdrawalQueued(bytes32 withdrawalRoot, Withdrawal withdrawal);
function completeQueuedWithdrawal(
Withdrawal calldata withdrawal,
IERC20[] calldata tokens,
uint256 middlewareTimesIndex,
bool receiveAsTokens
) external;
function completeQueuedWithdrawals(
Withdrawal[] calldata withdrawals,
IERC20[][] calldata tokens,
uint256[] calldata middlewareTimesIndexes,
bool[] calldata receiveAsTokens
) external;
function queueWithdrawals(
QueuedWithdrawalParams[] calldata queuedWithdrawalParams
) external returns (bytes32[] memory);
function delegatedTo(address staker) external view returns (address);
function operatorShares(
address operator,
address strategy
) external view returns (uint256);
function cumulativeWithdrawalsQueued(
address staker
) external view returns (uint256);
function withdrawalDelayBlocks() external view returns (uint256);
function isOperator(address operator) external view returns (bool);
function isDelegated(address staker) external view returns (bool);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "./IStrategyManager.sol";
interface IEigenLayerHandler {
/// @dev Epoch represents the period of the rebalancing process
/// @dev Receiver is a receiver of assets in claim()
/// @dev Amount represents the exact amount of the asset to be claimed
struct Withdrawal {
uint256 epoch;
address receiver;
uint256 amount;
}
event StartWithdrawal(
address indexed stakerAddress,
IStrategy strategy,
uint256 shares,
uint32 withdrawalStartBlock,
address delegatedAddress,
uint256 nonce
);
event DepositedToEL(address indexed stakerAddress, uint256 amount);
event DelegatedTo(
address indexed stakerAddress,
address indexed operatorAddress
);
event Withdrawn(address asset, uint256 shares, uint256 ethAmount);
event WithdrawalClaimed(uint256 totalAmount);
event DelegationManagerChanged(address prevValue, address newValue);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
interface IInceptionAssetHandler {
/*//////////////////////////
////// GET functions //////
////////////////////////*/
/// @dev returns total balance of Vault in the asset
function totalAssets() external view returns (uint256);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "./IDelegationManager.sol";
interface IInceptionRestaker {
event StartWithdrawal(
address indexed stakerAddress,
bytes32 withdrawalRoot,
IStrategy[] strategies,
uint256[] shares,
uint32 withdrawalStartBlock,
address delegatedAddress,
uint256 nonce
);
event Withdrawal(
bytes32 withdrawalRoot,
IStrategy[] strategies,
uint256[] shares,
uint32 withdrawalStartBlock
);
function depositAssetIntoStrategy(uint256 amount) external;
function delegateToOperator(
address operator,
bytes32 approverSalt,
IDelegationManager.SignatureWithExpiry memory approverSignatureAndExpiry
) external;
function withdrawFromEL(uint256 shares) external;
function claimWithdrawals(
IDelegationManager.Withdrawal[] calldata withdrawals,
IERC20[][] calldata tokens,
uint256[] calldata middlewareTimesIndexes,
bool[] calldata receiveAsTokens
) external returns (uint256);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
interface IInceptionToken {
event VaultChanged(address prevValue, address newValue);
event Paused(address account);
event Unpaused(address account);
function mint(address account, uint256 amount) external;
function burn(address account, uint256 amount) external;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "./IInceptionToken.sol";
interface IInceptionVault {
/*///////////////////
////// Events //////
/////////////////*/
event Deposit(
address indexed sender,
address indexed receiver,
uint256 amount,
uint256 iShares
);
event Withdraw(
address indexed sender,
address indexed receiver,
address indexed owner,
uint256 amount,
uint256 iShares
);
event Redeem(
address indexed sender,
address indexed receiver,
uint256 amount
);
event RedeemedRequests(uint256[] withdrawals);
event WithdrawalQueued(
address depositor,
uint96 nonce,
address withdrawer,
address delegatedAddress,
bytes32 withdrawalRoot
);
event OperatorChanged(address prevValue, address newValue);
event DepositFeeChanged(uint256 prevValue, uint256 newValue);
event MinAmountChanged(uint256 prevValue, uint256 newValue);
event ELOperatorAdded(address indexed newELOperator);
event RestakerDeployed(address indexed restaker);
event ImplementationUpgraded(address prevValue, address newValue);
event NameChanged(string prevValue, string newValue);
event ReferralCode(bytes32 indexed code);
function inceptionToken() external view returns (IInceptionToken);
function ratio() external view returns (uint256);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
interface IInceptionVaultErrors {
error TransferAssetFailed(address assetAddress);
error TransferAssetFromFailed(address assetAddress);
error InsufficientCapacity(uint256 capacity);
error InceptionOnPause();
error InconsistentData();
error NullParams();
error WithdrawFutile();
error OperatorNotRegistered();
error RestakerNotRegistered();
error ImplementationNotSet();
error NotEigenLayerOperator();
error EigenLayerOperatorAlreadyExists();
error AlreadyDelegated();
error DelegationManagerImmutable();
/// TVL errors
error ExceedsMaxPerDeposit(uint256 max, uint256 amount);
error ExceedsMaxTotalDeposited(uint256 max, uint256 amount);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
interface IOwnable {
function transferOwnership(address newOwner) external;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
interface IRebalanceStrategy {
function rebalance(bytes calldata data) external returns (bool);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
interface IStEth is IERC20 {
function sharesOf(address accounts) external returns (uint256);
function getPooledEthByShares(
uint256 _sharesAmount
) external view returns (uint256);
function getSharesByPooledEth(
uint256 _ethAmount
) external view returns (uint256);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
interface IStrategy {
function deposit(IERC20 token, uint256 amount) external returns (uint256);
function withdraw(
address depositor,
IERC20 token,
uint256 amountShares
) external;
function sharesToUnderlying(
uint256 amountShares
) external returns (uint256);
function underlyingToShares(
uint256 amountUnderlying
) external returns (uint256);
function userUnderlying(address user) external returns (uint256);
function sharesToUnderlyingView(
uint256 amountShares
) external view returns (uint256);
function underlyingToSharesView(
uint256 amountUnderlying
) external view returns (uint256);
/**
* @notice convenience function for fetching the current underlying value of all of the `user`'s shares in
* this strategy. In contrast to `userUnderlying`, this function guarantees no state modifications
*/
function userUnderlyingView(address user) external view returns (uint256);
/// @notice The underlying token for shares in this Strategy
function underlyingToken() external view returns (IERC20);
/// @notice The total number of extant shares in this Strategy
function totalShares() external view returns (uint256);
/// @notice Returns either a brief string explaining the strategy's goal & purpose, or a link to metadata that explains in more detail.
function explanation() external view returns (string memory);
/// @notice Simple getter function that returns the current values of `maxPerDeposit` and `maxTotalDeposits`.
function getTVLLimits() external view returns (uint256, uint256);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;
import "./IStrategy.sol";
interface IStrategyManager {
struct WithdrawerAndNonce {
address withdrawer;
uint96 nonce;
}
struct QueuedWithdrawal {
IStrategy[] strategies;
uint256[] shares;
address depositor;
WithdrawerAndNonce withdrawerAndNonce;
uint32 withdrawalStartBlock;
address delegatedAddress;
}
function withdrawalRootPending(bytes32) external returns (bool);
function depositIntoStrategy(
IStrategy strategy,
IERC20 token,
uint256 amount
) external returns (uint256 shares);
function stakerStrategyShares(
address user,
IStrategy strategy
) external view returns (uint256 shares);
function getDeposits(
address depositor
) external view returns (IStrategy[] memory, uint256[] memory);
function stakerStrategyListLength(
address staker
) external view returns (uint256);
function queueWithdrawal(
uint256[] calldata strategyIndexes,
IStrategy[] calldata strategies,
uint256[] calldata shares,
address withdrawer,
bool undelegateIfPossible
) external returns (bytes32);
function completeQueuedWithdrawal(
QueuedWithdrawal calldata queuedWithdrawal,
IERC20[] calldata tokens,
uint256 middlewareTimesIndex,
bool receiveAsTokens
) external;
function completeQueuedWithdrawals(
QueuedWithdrawal[] calldata queuedWithdrawals,
IERC20[][] calldata tokens,
uint256[] calldata middlewareTimesIndexes,
bool[] calldata receiveAsTokens
) external;
function slashShares(
address slashedAddress,
address recipient,
IStrategy[] calldata strategies,
IERC20[] calldata tokens,
uint256[] calldata strategyIndexes,
uint256[] calldata shareAmounts
) external;
function slashQueuedWithdrawal(
address recipient,
QueuedWithdrawal calldata queuedWithdrawal,
IERC20[] calldata tokens,
uint256[] calldata indicesToSkip
) external;
function calculateWithdrawalRoot(
QueuedWithdrawal memory queuedWithdrawal
) external pure returns (bytes32);
function addStrategiesToDepositWhitelist(
IStrategy[] calldata strategiesToWhitelist
) external;
function removeStrategiesFromDepositWhitelist(
IStrategy[] calldata strategiesToRemoveFromWhitelist
) external;
function withdrawalDelayBlocks() external view returns (uint256);
function numWithdrawalsQueued(
address account
) external view returns (uint256);
function delegation() external view returns (address);
}