// SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;
import "@openzeppelin/contracts/token/ERC721/ERC721A.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/utils/cryptography/MerkleProof.sol";
import "@openzeppelin/contracts/utils/Context.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
/*
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWXKNNXXNMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWXKNMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWXOkkO0XWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMNkl::oKMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWNWWMMMMMMMMMMMMWWMMMWXKKKNMMMWWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWO,.'cxKWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMNklcclxXMMMMWXxllcd0WMWN00KNWMMMMMMMMMMMMMWXKKXWMMMMMMMMMMMMMNOxlcllokXWMMk'.;lONMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMN0kc..;dNMXo,..lx0NMMMMMMMMMMWKxdONMMMMMMWKxocckNMMMMMMMMMMW0xo:c:..',c0K:,x00kdolldkKWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWWKOko;lkc;oxOXWMMWNKKXNMMMXo';xXMMMMMMMMWWNk:'lXMXkdodxKWMXd:o0KkkOdlcllkkc,,'..;;,lkNMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMXkoc;cccoxlclxxdxk0XWNkoc,:oOXo:dk000KNWNOdoccloxdcoxc;;lxkKNN0l.,0MMWKOxooloc::lkkOKKKXWWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMNOc;:;,lo:;cllccc:;..,lkXNKOkxoloddl:,;cd0Kkxdlcl:;lo:cox0NMMMWN0oo0NKdc;;llcllcdc,;:dKMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMNKKKXXKd:,ld:odcck0kdxc:xKOdoddlcclllx0NNWWMWKoc:col::clc,;xXMMMNXWNd' .okc;dOc.d0kc..,xNMMWWWMMWWMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMWXK0KXWMMMMK:..oKd'lKXl'lXWWNXkc;,dklod:dk:'cOWMMWk;,,l0k,oOcl0kl;lXMMMMWo.;coOl.oN0l.,KN0do;.xWMN0OkO0KWMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMNK0XNWMMMWl.;o0Wk..cONd.,OWMNkd0XKccKk'cXKkcc0MMNddKNWMd.:Kk'lNWX0XMMMMKcckKNx.,0Nx' 'OMMWXOodXMMMWXNMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMNNNNNWWMMXl:kXWMNl.,dKNo..kWWWWMWd'xXo.cNMWN0XMMWWWMMMM0;;0X:.OMMMMWXKK00XWW0, lWNx;.:XMMMMMNXNNNNNNMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMWO:';::ccclco0NMMMNk::xNNc 'kWMMMK,'0XdlKMMMMMMMWX00KXNMMKxKWo.lWMMMWN00XWMMWd..xMXd,:0X0kdlc::;;,'c0MMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMWO;.;ccc:;,,',cd0WMWKKWWO' 'kWMWx.'xxdkK00KNWWWNXKKK0OOOOkkx: ,0WNXXNWMMMMMX: .kMWkll:''',,;;;,..:0MMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMXo''cllldo'.',':dKWMWKk,  ,xko,..........,;;;,,,,'...........;:,,,;:oKMMWk' .xOl;',..;ll::;,.,kNMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMW0;.',:cc::lll;.'oKWO:. .........,,..';;;;;,..,,...,,,,,'.......... .ldOl. .'..:loc;;:;,'..lXMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMNo..loc:c::lc.  'c,...'..;:ccc'.,..;looool'.,,. 'looool'.,;,..:;;,'..'.     'ol:::::c;.'kWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMWNKK000KXXx'.cdoc;;c;..  .;cllo,.cooll;..,..cooooo:.',. .:oool,..;;,.'looooolc:'. . .cc,;cll;.;0XK0000KXNWMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMNklc::;;;,..,::' .',;cc;'.....;loooc,:loll'.',..colcloo,.''..;ooo;..',,'.,oooc::cc;......':c:;'...;:;'.',,,;;:cokNMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMM0;..;looooc';lc:'. .,co;..',,..'colooololo:.',.,lol:cooc.....;ool,.'''...coooc,.....,;,..:ol:.. .,:cc,,cc:::;...:0MMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMNOdc;',,;cccc::l,....;;'.',;;'.,llol,'cool,..'cool:clllc'. 'loolcllll'.,ooo:,'....,;;..'::,....:c;::::;''.';cxKWMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMWXko;.,:cc::::,,'......',;,..cool,.colll'.:oooc..clcl;..;lllooooo:.'lllo;..',,,,;'.......',;::;:::;..:d0NMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMW0d:',,,;llc,.......',,..coool;:l:;:,.':;;'...'.........'',,;..,c::l;.';,,;,.........;llc,,,',cxKWMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMNKko:....',;:;........',..:c:;;..............'.........................',,,;'........'::;,....'cdkXWMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMWKxc;,.....................''....     ...........'..       ...  .....        .........................,:lkXWMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMW0o:,,;clllll::;;;,.............   ..,;;'.    ..,'.    'cloooddxxl.   .';:clllc:'.  ..........';;;;;:cccc:;,',:dKWMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMNx:,;codddoooooooc;'..        ..  .:dxOO00k,.,ldxOOOd,  .l0OOOOOOOkc..;lxkO0OOOOO0Oo.          ..,:loollllllllc:,''cOWMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMNx;,cddoccooool::,.. ..;clodol:'.   'dOOOOOOx,.lOOOOOOOx, 'xOOOOOOkl,,cxOOOOOOkkkkOOko'.'clodolc;'.  .';cc:clcc:;:cc:'.:OWMMMMMMMMMMMMMMMM
* MMMMMMMMMMMK:..;;;;,',;:,...  .,cdkO0OOOOOOkc.  .oOOOkkOOd'.:xOOOOOOk;,xOOOOOd,'lkOOOOOko:,;dkOx;.,okOOOOOOO0Oxl;.  ....,;;;'',,''...oNMMMMMMMMMMMMMMM
* MMMMMMMMMW0c,:loxOKXXXKx,. .,cxO0OOOkkkkOOOOk:. .lOOOkxkOOx,.'okOOOOOkldOOkkl.;xOOOOOkl'. .:kOd'.ckOOOOOOOOOOOOOOko,.  'oKXXXXX0Oxoc:;oXMMMMMMMMMMMMMM
* MMMMMMMMMWXXWMMMMMMMMNd. .:dO0OOOOkkxddxkOOOOc. .ckOOxoxOOOk: .:xOOOOOOOOkc..:kOOOOOd,. .'okOO:.ckkkkkkkkkkkkkkOOOOOd;. .lXMMMMMMMMMMNXNMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMWd. .d0OOOOOkkd:'.,dOOOOk;  .:kOOklokOOOx, .,dkOOOOOOl..:kOOOOOo'  .ckOOOOl..::::::::ccclodxkkkkOOd'  ;0MMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMX: .:kOOOOOkdc,.. ;kOkkxc.   'okOOlcxOOOOo.  .lkOOOOd',oxOOOOOo' .:xOOkOOkc.  .,;,,..   ...';coxkkOk:. ;KMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMN: .:kOOOkxolokx,'xOkdolcclll;',oOd:dOOOOOc.  .ckOOk;.oOOOOOOd'...,cloolc,. .;dO0OOkd;   ... ..;oxkOO;  cXMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMWo. ,dkkkdldOOOkxkOOkkkO0OOOOOd''dOkOOOOOOx, . 'xOOd';kOOOOOx,..  .;loc.  ..lkOOOOOxc'....   ..;dkOO0x. .kMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMM0' .cxxo'.lkOOOkkkkOkkkkOOOOOOl.:kOOOOOOOOo. .lOOOl.cOOOOOkc.. .:xOOO0o..;xOOOOOxc'    ..,:ldkOOOOOOk; .xMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMWd. .,,.. .oOOOxddddoodkOOOOOOo..oxddxkOOOO:.;kOOO:.oOOOOOd. .'oOOOOOo''lkOOOOkl. ..,:ldkOOOOOOOOOOOk, .xMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMNo.   .   .oOOxc,....lOOOOOOOc..ld,.oOOOOk;'dOOOk:.oOOOOOl..;xOOOOxc.,dOOOOko;,:ldkOOOOOOOOOOOOOOOOo. .kMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMNx'       'dOOOo.  ;kOOOOOOd, .lO;.ckOOOl.cOOOOd'.lOOOOOl.ckOOkd;..ckOOOOxoldOOOOOOOOOOOOOOOOOOOxc.  :XMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMXxolldc. ,xOOk:.;kOOOOOOx;. .dOl.'dOOO:.oOkOk; .:kOOOOkxOOOx:. .okOOOOOkOOOOOOOOOOOOOOOOkxdl:,... .dWMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMNd.  ;xOOdokOOOOOkd;.  :kOd..lkOOo.':dkl.. 'dkkOOOOOkl'. .lkOOOOOOOOOOOOOOOkkxdol:;,.......  ;KMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMM0:. .'.:kO00OOOOkxl'.  .;ldl. ,odl;.  .,... .;oxkkOxl,... .okkkkkkkkkkxdolc:;,'.........    .:KMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMK; .:kkodO0OOOkkxo;.      ...   ...      ..   ..':c:'...   .':ccc:;;,,'............       .'ckNMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMk. ,kOOOOOkkkkdl;..    ..              .    ..    ....  ... ................         .';cdOXWMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMk. 'dkkkkkxdl:'.     .c00dc,...,'....;dOdc:o00;.      .,xk,   ...             ..,:ldk0XWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMNl. ':clc:;'.      .;kWMMMMWXKKNN0O0XWMMMMMMMMNKxc;;:lONMWO,         ...,;cldk0KNWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMNl.             .:kNMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWWMMMMMMMNkocclodxkOKXNWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMNd.         .;o0WMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWKd:,'',:lxKWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
* MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMWNNWMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
*/
/*
 * @title  Half BAYCD ERC-721 Smart Contract
 */
contract HalfBAYCD is ERC721A, Ownable, ReentrancyGuard {
    using SafeERC20 for IERC20;
    using Strings for uint256;
    // PUBLIC MINT
    uint256 public tokenPricePublic = 0.069 ether; 
    uint256 public tokenPriceAPE = 20000000000000000000;
    uint256 public constant MAX_PER_TXN_PUBLIC = 10;
    uint256 public constant MAX_TOKENS = 6969;
    bool public mintIsActive = false;
    string private baseURI;
    address public tokenContract = address(0x4d224452801ACEd8B2F0aebE155379bb5D594381);
    // FREE MERKLE MINT
    bool public mintIsActivePresale = false;
    bytes32 public merkleRoot;
    mapping(address => uint256) public claimed;
    constructor() ERC721A("Half BAYCD", "HBAYCD") {}
    // @title PUBLIC MINT
    function flipMintState() external onlyOwner {
        mintIsActive = !mintIsActive;
    }
    /*
    *  @notice public mint function ETH
    */
    function mintHalfBAYCD(uint256 qty) external payable nonReentrant{
        require(tx.origin == msg.sender);
        require(mintIsActive, "Mint is not active");
        require(qty <= MAX_PER_TXN_PUBLIC, "You went over max tokens per transaction");
        require(totalSupply() + qty <= MAX_TOKENS, "Not enough tokens left to mint that many");
        require(msg.value >= tokenPricePublic * qty, "You sent the incorrect amount of ETH");
        _safeMint(msg.sender, qty);
    }
    /*
    * @notice public mint for card actions
    */
    function mintHalfBAYCDWithAPECoin(uint256 qty) external nonReentrant {
        require(tx.origin == msg.sender);
        require(mintIsActive, "Public mint is not active");
        
        uint256 apeBalance = IERC20(tokenContract).balanceOf(msg.sender);
        require(tokenPriceAPE * qty <= apeBalance, "Not enough $APE to mint.");
  
        require(
            qty <= MAX_PER_TXN_PUBLIC, 
            "You can't mint that many tokens per transaction."
        );
        require(
            totalSupply() + qty <= MAX_TOKENS, 
            "Tokens are all minted."
        );
        IERC20(tokenContract).safeTransferFrom(msg.sender, address(this), tokenPriceAPE * qty);      
        _safeMint(msg.sender, qty);
    }
    // FREE CLAIM MERKLE 
    /*
     * @notice Turn on/off presale wallet mint
     */
    function flipPresaleMintState() external onlyOwner {
        mintIsActivePresale = !mintIsActivePresale;
    }
    /*
     * @notice view function to check if a merkleProof is valid before sending presale mint function
     */
    function isOnPresaleMerkle(bytes32[] calldata merkleProof) public view returns(bool) {
        bytes32 leaf = keccak256(abi.encodePacked(msg.sender));
        return MerkleProof.verify(merkleProof, merkleRoot, leaf);
    }
    /*
     * @notice reset a list of addresses to be able to presale mint again. 
     */
    function initPresaleMerkleWalletList(address[] memory walletList, uint256 qty) external onlyOwner {
\t    for (uint i; i < walletList.length; i++) {
\t\t    claimed[walletList[i]] = qty;
\t    }
    }
   
    /*
    * @notice check if wallet claimed for all potions
    */
    function checkClaimed(address wallet) external view returns (uint256) {
        return claimed[wallet];
    }
    /*
     * @notice free claim merkle mint 
     */
    function claim(uint256 qty, uint256 maxQty, bytes32[] calldata merkleProof) external nonReentrant{
        require(tx.origin == msg.sender);
        require(mintIsActivePresale, "Presale mint is not active");       
        require(
            claimed[msg.sender] + qty <= maxQty, 
            "Claim: Not allowed to claim given amount"
        );
        require(
            totalSupply() + qty <= MAX_TOKENS, 
            "Not enough tokens left to mint that many"
        );
        bytes32 node = keccak256(abi.encodePacked(msg.sender, maxQty));
        require(
            MerkleProof.verify(merkleProof, merkleRoot, node),
            "You have a bad Merkle Proof."
        );
        claimed[msg.sender] += qty;
        _safeMint(msg.sender, qty);
    }
    // OWNER FUNCTIONS
    /*
     * @notice Withdraw ETH in contract to ownership wallet 
     */
    function withdraw() external onlyOwner {
        uint256 balance = address(this).balance;
        if(balance > 0){
            Address.sendValue(payable(owner()), balance);
        }
    }
    /*
     * @notice Withdraw $APE in  $APE contract to ownership wallet 
     */
    function withdrawAPE() external onlyOwner {
        uint256 balance = IERC20(tokenContract).balanceOf(address(this));
        if(balance > 0){
            IERC20(tokenContract).safeTransfer(owner(), balance);
        }
    }
    /*
     * @notice Withdraw $APE in contract to ownership wallet by amount - only use as backup
     */
    function withdrawAPEbyAmount(uint256 amount) external onlyOwner {
        IERC20(tokenContract).safeTransfer(owner(), amount);
    }
    /*
    *  @notice reserve mint n numbers of tokens
    */
    function mintReserveTokens(uint256 qty) public onlyOwner {
        require(totalSupply() + qty <= MAX_TOKENS, "Not enough tokens left to mint that many");
        _safeMint(msg.sender, qty);
    }
    /*
    *  @notice mint n tokens to a wallet
    */
    function mintTokenToWallet(address toWallet, uint256 qty) public onlyOwner {
         require(totalSupply() + qty <= MAX_TOKENS, "Not enough tokens left to mint that many");
         _safeMint(toWallet, qty);
    }
    /*
    *  @notice get base URI of tokens
    */
   \tfunction tokenURI(uint256 _tokenId) public view override returns (string memory) {
\t\trequire(_exists(_tokenId), "ERC721Metadata: URI query for nonexistent token");
\t\treturn string(abi.encodePacked(baseURI, _tokenId.toString()));
\t}
 
    /* 
    *  @notice set base URI of tokens
    */
    function setBaseURI(string memory uri) external onlyOwner {
        baseURI = uri;
    }
    /*
     * @notice sets Merkle Root for presale
     */
    function setMerkleRoot(bytes32 _merkleRoot) public onlyOwner {
        merkleRoot = _merkleRoot;
    }
    /*
    *  @notice set token price of public sale - tokenPricePublic
    */
    function setTokenPricePublic(uint256 tokenPrice) external onlyOwner {
        require(tokenPrice >= 0, "Must be greater or equal then zer0");
        tokenPricePublic = tokenPrice;
    }
    /*
    *  @notice set token price of $APE public sale - tokenPriceAPE
    */
    function setTokenPriceAPE(uint256 tokenPrice) external onlyOwner {
        require(tokenPrice >= 0, "Must be greater or equal then zer0");
        tokenPriceAPE = tokenPrice;
    }
    /*
    *  @notice set token token contract - tokenContract
    */
    function setTokenContract(address _tokenContract) external onlyOwner {
        tokenContract = _tokenContract;
    }
}
// SPDX-License-Identifier: MIT
// Creator: Chiru Labs
pragma solidity 0.8.9;
import "@openzeppelin/contracts/token/ERC721/IERC721.sol";
import "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
import "@openzeppelin/contracts/token/ERC721/extensions/IERC721Metadata.sol";
import "@openzeppelin/contracts/token/ERC721/extensions/IERC721Enumerable.sol";
import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/utils/Context.sol";
import "@openzeppelin/contracts/utils/Strings.sol";
import "@openzeppelin/contracts/utils/introspection/ERC165.sol";
error ApprovalCallerNotOwnerNorApproved();
error ApprovalQueryForNonexistentToken();
error ApproveToCaller();
error ApprovalToCurrentOwner();
error BalanceQueryForZeroAddress();
error MintedQueryForZeroAddress();
error BurnedQueryForZeroAddress();
error AuxQueryForZeroAddress();
error MintToZeroAddress();
error MintZeroQuantity();
error OwnerIndexOutOfBounds();
error OwnerQueryForNonexistentToken();
error TokenIndexOutOfBounds();
error TransferCallerNotOwnerNorApproved();
error TransferFromIncorrectOwner();
error TransferToNonERC721ReceiverImplementer();
error TransferToZeroAddress();
error URIQueryForNonexistentToken();
/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension. Built to optimize for lower gas during batch mints.
 *
 * Assumes serials are sequentially minted starting at _startTokenId() (defaults to 0, e.g. 0, 1, 2, 3..).
 *
 * Assumes that an owner cannot have more than 2**64 - 1 (max value of uint64) of supply.
 *
 * Assumes that the maximum token id cannot exceed 2**256 - 1 (max value of uint256).
 */
contract ERC721A is Context, ERC165, IERC721, IERC721Metadata {
\tusing Address for address;
\tusing Strings for uint256;
\t// Compiler will pack this into a single 256bit word.
\tstruct TokenOwnership {
\t\t// The address of the owner.
\t\taddress addr;
\t\t// Keeps track of the start time of ownership with minimal overhead for tokenomics.
\t\tuint64 startTimestamp;
\t\t// Whether the token has been burned.
\t\tbool burned;
\t}
\t// Compiler will pack this into a single 256bit word.
\tstruct AddressData {
\t\t// Realistically, 2**64-1 is more than enough.
\t\tuint64 balance;
\t\t// Keeps track of mint count with minimal overhead for tokenomics.
\t\tuint64 numberMinted;
\t\t// Keeps track of burn count with minimal overhead for tokenomics.
\t\tuint64 numberBurned;
\t\t// For miscellaneous variable(s) pertaining to the address
\t\t// (e.g. number of whitelist mint slots used).
\t\t// If there are multiple variables, please pack them into a uint64.
\t\tuint64 aux;
\t}
\t// The tokenId of the next token to be minted.
\tuint256 internal _currentIndex;
\t// The number of tokens burned.
\tuint256 internal _burnCounter;
\t// Token name
\tstring private _name;
\t// Token symbol
\tstring private _symbol;
\t// Mapping from token ID to ownership details
\t// An empty struct value does not necessarily mean the token is unowned. See ownershipOf implementation for details.
\tmapping(uint256 => TokenOwnership) internal _ownerships;
\t// Mapping owner address to address data
\tmapping(address => AddressData) private _addressData;
\t// Mapping from token ID to approved address
\tmapping(uint256 => address) private _tokenApprovals;
\t// Mapping from owner to operator approvals
\tmapping(address => mapping(address => bool)) private _operatorApprovals;
\tconstructor(string memory name_, string memory symbol_) {
\t\t_name = name_;
\t\t_symbol = symbol_;
\t\t_currentIndex = _startTokenId();
\t}
\t/**
\t * To change the starting tokenId, please override this function.
\t */
\tfunction _startTokenId() internal view virtual returns (uint256) {
\t\treturn 0;
\t}
\t/**
\t * @dev See {IERC721Enumerable-totalSupply}.
\t * @dev Burned tokens are calculated here, use _totalMinted() if you want to count just minted tokens.
\t */
\tfunction totalSupply() public view returns (uint256) {
\t\t// Counter underflow is impossible as _burnCounter cannot be incremented
\t\t// more than _currentIndex - _startTokenId() times
\t\tunchecked {
\t\t\treturn _currentIndex - _burnCounter - _startTokenId();
\t\t}
\t}
\t/**
\t * Returns the total amount of tokens minted in the contract.
\t */
\tfunction _totalMinted() internal view returns (uint256) {
\t\t// Counter underflow is impossible as _currentIndex does not decrement,
\t\t// and it is initialized to _startTokenId()
\t\tunchecked {
\t\t\treturn _currentIndex - _startTokenId();
\t\t}
\t}
\t/**
\t * @dev See {IERC165-supportsInterface}.
\t */
\tfunction supportsInterface(bytes4 interfaceId)
\t\tpublic
\t\tview
\t\tvirtual
\t\toverride(ERC165, IERC165)
\t\treturns (bool)
\t{
\t\treturn
\t\t\tinterfaceId == type(IERC721).interfaceId ||
\t\t\tinterfaceId == type(IERC721Metadata).interfaceId ||
\t\t\tsuper.supportsInterface(interfaceId);
\t}
\t/**
\t * @dev See {IERC721-balanceOf}.
\t */
\tfunction balanceOf(address owner) public view override returns (uint256) {
\t\tif (owner == address(0)) revert BalanceQueryForZeroAddress();
\t\treturn uint256(_addressData[owner].balance);
\t}
\t/**
\t * Returns the number of tokens minted by `owner`.
\t */
\tfunction _numberMinted(address owner) internal view returns (uint256) {
\t\tif (owner == address(0)) revert MintedQueryForZeroAddress();
\t\treturn uint256(_addressData[owner].numberMinted);
\t}
\t/**
\t * Returns the number of tokens burned by or on behalf of `owner`.
\t */
\tfunction _numberBurned(address owner) internal view returns (uint256) {
\t\tif (owner == address(0)) revert BurnedQueryForZeroAddress();
\t\treturn uint256(_addressData[owner].numberBurned);
\t}
\t/**
\t * Returns the auxillary data for `owner`. (e.g. number of whitelist mint slots used).
\t */
\tfunction _getAux(address owner) internal view returns (uint64) {
\t\tif (owner == address(0)) revert AuxQueryForZeroAddress();
\t\treturn _addressData[owner].aux;
\t}
\t/**
\t * Sets the auxillary data for `owner`. (e.g. number of whitelist mint slots used).
\t * If there are multiple variables, please pack them into a uint64.
\t */
\tfunction _setAux(address owner, uint64 aux) internal {
\t\tif (owner == address(0)) revert AuxQueryForZeroAddress();
\t\t_addressData[owner].aux = aux;
\t}
\t/**
\t * Gas spent here starts off proportional to the maximum mint batch size.
\t * It gradually moves to O(1) as tokens get transferred around in the collection over time.
\t */
\tfunction ownershipOf(uint256 tokenId) internal view returns (TokenOwnership memory) {
\t\tuint256 curr = tokenId;
\t\tunchecked {
\t\t\tif (_startTokenId() <= curr && curr < _currentIndex) {
\t\t\t\tTokenOwnership memory ownership = _ownerships[curr];
\t\t\t\tif (!ownership.burned) {
\t\t\t\t\tif (ownership.addr != address(0)) {
\t\t\t\t\t\treturn ownership;
\t\t\t\t\t}
\t\t\t\t\t// Invariant:
\t\t\t\t\t// There will always be an ownership that has an address and is not burned
\t\t\t\t\t// before an ownership that does not have an address and is not burned.
\t\t\t\t\t// Hence, curr will not underflow.
\t\t\t\t\twhile (true) {
\t\t\t\t\t\tcurr--;
\t\t\t\t\t\townership = _ownerships[curr];
\t\t\t\t\t\tif (ownership.addr != address(0)) {
\t\t\t\t\t\t\treturn ownership;
\t\t\t\t\t\t}
\t\t\t\t\t}
\t\t\t\t}
\t\t\t}
\t\t}
\t\trevert OwnerQueryForNonexistentToken();
\t}
\t/**
\t * @dev See {IERC721-ownerOf}.
\t */
\tfunction ownerOf(uint256 tokenId) public view override returns (address) {
\t\treturn ownershipOf(tokenId).addr;
\t}
\t/**
\t * @dev See {IERC721Metadata-name}.
\t */
\tfunction name() public view virtual override returns (string memory) {
\t\treturn _name;
\t}
\t/**
\t * @dev See {IERC721Metadata-symbol}.
\t */
\tfunction symbol() public view virtual override returns (string memory) {
\t\treturn _symbol;
\t}
\t/**
\t * @dev See {IERC721Metadata-tokenURI}.
\t */
\tfunction tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
\t\tif (!_exists(tokenId)) revert URIQueryForNonexistentToken();
\t\tstring memory baseURI = _baseURI();
\t\treturn bytes(baseURI).length != 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
\t}
\t/**
\t * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
\t * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
\t * by default, can be overriden in child contracts.
\t */
\tfunction _baseURI() internal view virtual returns (string memory) {
\t\treturn "";
\t}
\t/**
\t * @dev See {IERC721-approve}.
\t */
\tfunction approve(address to, uint256 tokenId) public override {
\t\taddress owner = ERC721A.ownerOf(tokenId);
\t\tif (to == owner) revert ApprovalToCurrentOwner();
\t\tif (_msgSender() != owner && !isApprovedForAll(owner, _msgSender())) {
\t\t\trevert ApprovalCallerNotOwnerNorApproved();
\t\t}
\t\t_approve(to, tokenId, owner);
\t}
\t/**
\t * @dev See {IERC721-getApproved}.
\t */
\tfunction getApproved(uint256 tokenId) public view override returns (address) {
\t\tif (!_exists(tokenId)) revert ApprovalQueryForNonexistentToken();
\t\treturn _tokenApprovals[tokenId];
\t}
\t/**
\t * @dev See {IERC721-setApprovalForAll}.
\t */
\tfunction setApprovalForAll(address operator, bool approved) public override {
\t\tif (operator == _msgSender()) revert ApproveToCaller();
\t\t_operatorApprovals[_msgSender()][operator] = approved;
\t\temit ApprovalForAll(_msgSender(), operator, approved);
\t}
\t/**
\t * @dev See {IERC721-isApprovedForAll}.
\t */
\tfunction isApprovedForAll(address owner, address operator)
\t\tpublic
\t\tview
\t\tvirtual
\t\toverride
\t\treturns (bool)
\t{
\t\treturn _operatorApprovals[owner][operator];
\t}
\t/**
\t * @dev See {IERC721-transferFrom}.
\t */
\tfunction transferFrom(
\t\taddress from,
\t\taddress to,
\t\tuint256 tokenId
\t) public virtual override {
\t\t_transfer(from, to, tokenId);
\t}
\t/**
\t * @dev See {IERC721-safeTransferFrom}.
\t */
\tfunction safeTransferFrom(
\t\taddress from,
\t\taddress to,
\t\tuint256 tokenId
\t) public virtual override {
\t\tsafeTransferFrom(from, to, tokenId, "");
\t}
\t/**
\t * @dev See {IERC721-safeTransferFrom}.
\t */
\tfunction safeTransferFrom(
\t\taddress from,
\t\taddress to,
\t\tuint256 tokenId,
\t\tbytes memory _data
\t) public virtual override {
\t\t_transfer(from, to, tokenId);
\t\tif (to.isContract() && !_checkContractOnERC721Received(from, to, tokenId, _data)) {
\t\t\trevert TransferToNonERC721ReceiverImplementer();
\t\t}
\t}
\t/**
\t * @dev Returns whether `tokenId` exists.
\t *
\t * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
\t *
\t * Tokens start existing when they are minted (`_mint`),
\t */
\tfunction _exists(uint256 tokenId) internal view returns (bool) {
\t\treturn _startTokenId() <= tokenId && tokenId < _currentIndex && !_ownerships[tokenId].burned;
\t}
\tfunction _safeMint(address to, uint256 quantity) internal {
\t\t_safeMint(to, quantity, "");
\t}
\t/**
\t * @dev Safely mints `quantity` tokens and transfers them to `to`.
\t *
\t * Requirements:
\t *
\t * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called for each safe transfer.
\t * - `quantity` must be greater than 0.
\t *
\t * Emits a {Transfer} event.
\t */
\tfunction _safeMint(
\t\taddress to,
\t\tuint256 quantity,
\t\tbytes memory _data
\t) internal {
\t\t_mint(to, quantity, _data, true);
\t}
\t/**
\t * @dev Mints `quantity` tokens and transfers them to `to`.
\t *
\t * Requirements:
\t *
\t * - `to` cannot be the zero address.
\t * - `quantity` must be greater than 0.
\t *
\t * Emits a {Transfer} event.
\t */
\tfunction _mint(
\t\taddress to,
\t\tuint256 quantity,
\t\tbytes memory _data,
\t\tbool safe
\t) internal {
\t\tuint256 startTokenId = _currentIndex;
\t\tif (to == address(0)) revert MintToZeroAddress();
\t\tif (quantity == 0) revert MintZeroQuantity();
\t\t_beforeTokenTransfers(address(0), to, startTokenId, quantity);
\t\t// Overflows are incredibly unrealistic.
\t\t// balance or numberMinted overflow if current value of either + quantity > 1.8e19 (2**64) - 1
\t\t// updatedIndex overflows if _currentIndex + quantity > 1.2e77 (2**256) - 1
\t\tunchecked {
\t\t\t_addressData[to].balance += uint64(quantity);
\t\t\t_addressData[to].numberMinted += uint64(quantity);
\t\t\t_ownerships[startTokenId].addr = to;
\t\t\t_ownerships[startTokenId].startTimestamp = uint64(block.timestamp);
\t\t\tuint256 updatedIndex = startTokenId;
\t\t\tuint256 end = updatedIndex + quantity;
\t\t\tif (safe && to.isContract()) {
\t\t\t\tdo {
\t\t\t\t\temit Transfer(address(0), to, updatedIndex);
\t\t\t\t\tif (!_checkContractOnERC721Received(address(0), to, updatedIndex++, _data)) {
\t\t\t\t\t\trevert TransferToNonERC721ReceiverImplementer();
\t\t\t\t\t}
\t\t\t\t} while (updatedIndex != end);
\t\t\t\t// Reentrancy protection
\t\t\t\tif (_currentIndex != startTokenId) revert();
\t\t\t} else {
\t\t\t\tdo {
\t\t\t\t\temit Transfer(address(0), to, updatedIndex++);
\t\t\t\t} while (updatedIndex != end);
\t\t\t}
\t\t\t_currentIndex = updatedIndex;
\t\t}
\t\t_afterTokenTransfers(address(0), to, startTokenId, quantity);
\t}
\t/**
\t * @dev Transfers `tokenId` from `from` to `to`.
\t *
\t * Requirements:
\t *
\t * - `to` cannot be the zero address.
\t * - `tokenId` token must be owned by `from`.
\t *
\t * Emits a {Transfer} event.
\t */
\tfunction _transfer(
\t\taddress from,
\t\taddress to,
\t\tuint256 tokenId
\t) private {
\t\tTokenOwnership memory prevOwnership = ownershipOf(tokenId);
\t\tbool isApprovedOrOwner = (_msgSender() == prevOwnership.addr ||
\t\t\tisApprovedForAll(prevOwnership.addr, _msgSender()) ||
\t\t\tgetApproved(tokenId) == _msgSender());
\t\tif (!isApprovedOrOwner) revert TransferCallerNotOwnerNorApproved();
\t\tif (prevOwnership.addr != from) revert TransferFromIncorrectOwner();
\t\tif (to == address(0)) revert TransferToZeroAddress();
\t\t_beforeTokenTransfers(from, to, tokenId, 1);
\t\t// Clear approvals from the previous owner
\t\t_approve(address(0), tokenId, prevOwnership.addr);
\t\t// Underflow of the sender's balance is impossible because we check for
\t\t// ownership above and the recipient's balance can't realistically overflow.
\t\t// Counter overflow is incredibly unrealistic as tokenId would have to be 2**256.
\t\tunchecked {
\t\t\t_addressData[from].balance -= 1;
\t\t\t_addressData[to].balance += 1;
\t\t\t_ownerships[tokenId].addr = to;
\t\t\t_ownerships[tokenId].startTimestamp = uint64(block.timestamp);
\t\t\t// If the ownership slot of tokenId+1 is not explicitly set, that means the transfer initiator owns it.
\t\t\t// Set the slot of tokenId+1 explicitly in storage to maintain correctness for ownerOf(tokenId+1) calls.
\t\t\tuint256 nextTokenId = tokenId + 1;
\t\t\tif (_ownerships[nextTokenId].addr == address(0)) {
\t\t\t\t// This will suffice for checking _exists(nextTokenId),
\t\t\t\t// as a burned slot cannot contain the zero address.
\t\t\t\tif (nextTokenId < _currentIndex) {
\t\t\t\t\t_ownerships[nextTokenId].addr = prevOwnership.addr;
\t\t\t\t\t_ownerships[nextTokenId].startTimestamp = prevOwnership.startTimestamp;
\t\t\t\t}
\t\t\t}
\t\t}
\t\temit Transfer(from, to, tokenId);
\t\t_afterTokenTransfers(from, to, tokenId, 1);
\t}
\t/**
\t * @dev Destroys `tokenId`.
\t * The approval is cleared when the token is burned.
\t *
\t * Requirements:
\t *
\t * - `tokenId` must exist.
\t *
\t * Emits a {Transfer} event.
\t */
\tfunction _burn(uint256 tokenId) internal virtual {
\t\tTokenOwnership memory prevOwnership = ownershipOf(tokenId);
\t\t_beforeTokenTransfers(prevOwnership.addr, address(0), tokenId, 1);
\t\t// Clear approvals from the previous owner
\t\t_approve(address(0), tokenId, prevOwnership.addr);
\t\t// Underflow of the sender's balance is impossible because we check for
\t\t// ownership above and the recipient's balance can't realistically overflow.
\t\t// Counter overflow is incredibly unrealistic as tokenId would have to be 2**256.
\t\tunchecked {
\t\t\t_addressData[prevOwnership.addr].balance -= 1;
\t\t\t_addressData[prevOwnership.addr].numberBurned += 1;
\t\t\t// Keep track of who burned the token, and the timestamp of burning.
\t\t\t_ownerships[tokenId].addr = prevOwnership.addr;
\t\t\t_ownerships[tokenId].startTimestamp = uint64(block.timestamp);
\t\t\t_ownerships[tokenId].burned = true;
\t\t\t// If the ownership slot of tokenId+1 is not explicitly set, that means the burn initiator owns it.
\t\t\t// Set the slot of tokenId+1 explicitly in storage to maintain correctness for ownerOf(tokenId+1) calls.
\t\t\tuint256 nextTokenId = tokenId + 1;
\t\t\tif (_ownerships[nextTokenId].addr == address(0)) {
\t\t\t\t// This will suffice for checking _exists(nextTokenId),
\t\t\t\t// as a burned slot cannot contain the zero address.
\t\t\t\tif (nextTokenId < _currentIndex) {
\t\t\t\t\t_ownerships[nextTokenId].addr = prevOwnership.addr;
\t\t\t\t\t_ownerships[nextTokenId].startTimestamp = prevOwnership.startTimestamp;
\t\t\t\t}
\t\t\t}
\t\t}
\t\temit Transfer(prevOwnership.addr, address(0), tokenId);
\t\t_afterTokenTransfers(prevOwnership.addr, address(0), tokenId, 1);
\t\t// Overflow not possible, as _burnCounter cannot be exceed _currentIndex times.
\t\tunchecked {
\t\t\t_burnCounter++;
\t\t}
\t}
\t/**
\t * @dev Approve `to` to operate on `tokenId`
\t *
\t * Emits a {Approval} event.
\t */
\tfunction _approve(
\t\taddress to,
\t\tuint256 tokenId,
\t\taddress owner
\t) private {
\t\t_tokenApprovals[tokenId] = to;
\t\temit Approval(owner, to, tokenId);
\t}
\t/**
\t * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target contract.
\t *
\t * @param from address representing the previous owner of the given token ID
\t * @param to target address that will receive the tokens
\t * @param tokenId uint256 ID of the token to be transferred
\t * @param _data bytes optional data to send along with the call
\t * @return bool whether the call correctly returned the expected magic value
\t */
\tfunction _checkContractOnERC721Received(
\t\taddress from,
\t\taddress to,
\t\tuint256 tokenId,
\t\tbytes memory _data
\t) private returns (bool) {
\t\ttry IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (
\t\t\tbytes4 retval
\t\t) {
\t\t\treturn retval == IERC721Receiver(to).onERC721Received.selector;
\t\t} catch (bytes memory reason) {
\t\t\tif (reason.length == 0) {
\t\t\t\trevert TransferToNonERC721ReceiverImplementer();
\t\t\t} else {
\t\t\t\tassembly {
\t\t\t\t\trevert(add(32, reason), mload(reason))
\t\t\t\t}
\t\t\t}
\t\t}
\t}
\t/**
\t * @dev Hook that is called before a set of serially-ordered token ids are about to be transferred. This includes minting.
\t * And also called before burning one token.
\t *
\t * startTokenId - the first token id to be transferred
\t * quantity - the amount to be transferred
\t *
\t * Calling conditions:
\t *
\t * - When `from` and `to` are both non-zero, `from`'s `tokenId` will be
\t * transferred to `to`.
\t * - When `from` is zero, `tokenId` will be minted for `to`.
\t * - When `to` is zero, `tokenId` will be burned by `from`.
\t * - `from` and `to` are never both zero.
\t */
\tfunction _beforeTokenTransfers(
\t\taddress from,
\t\taddress to,
\t\tuint256 startTokenId,
\t\tuint256 quantity
\t) internal virtual {}
\t/**
\t * @dev Hook that is called after a set of serially-ordered token ids have been transferred. This includes
\t * minting.
\t * And also called after one token has been burned.
\t *
\t * startTokenId - the first token id to be transferred
\t * quantity - the amount to be transferred
\t *
\t * Calling conditions:
\t *
\t * - When `from` and `to` are both non-zero, `from`'s `tokenId` has been
\t * transferred to `to`.
\t * - When `from` is zero, `tokenId` has been minted for `to`.
\t * - When `to` is zero, `tokenId` has been burned by `from`.
\t * - `from` and `to` are never both zero.
\t */
\tfunction _afterTokenTransfers(
\t\taddress from,
\t\taddress to,
\t\tuint256 startTokenId,
\t\tuint256 quantity
\t) internal virtual {}
}// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;
    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }
    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }
    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }
    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }
    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }
    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }
    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (security/ReentrancyGuard.sol)
pragma solidity ^0.8.0;
/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.
    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;
    uint256 private _status;
    constructor() {
        _status = _NOT_ENTERED;
    }
    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
        _;
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/cryptography/MerkleProof.sol)
pragma solidity ^0.8.0;
/**
 * @dev These functions deal with verification of Merkle Tree proofs.
 *
 * The proofs can be generated using the JavaScript library
 * https://github.com/miguelmota/merkletreejs[merkletreejs].
 * Note: the hashing algorithm should be keccak256 and pair sorting should be enabled.
 *
 * See `test/utils/cryptography/MerkleProof.test.js` for some examples.
 *
 * WARNING: You should avoid using leaf values that are 64 bytes long prior to
 * hashing, or use a hash function other than keccak256 for hashing leaves.
 * This is because the concatenation of a sorted pair of internal nodes in
 * the merkle tree could be reinterpreted as a leaf value.
 */
library MerkleProof {
    /**
     * @dev Returns true if a `leaf` can be proved to be a part of a Merkle tree
     * defined by `root`. For this, a `proof` must be provided, containing
     * sibling hashes on the branch from the leaf to the root of the tree. Each
     * pair of leaves and each pair of pre-images are assumed to be sorted.
     */
    function verify(
        bytes32[] memory proof,
        bytes32 root,
        bytes32 leaf
    ) internal pure returns (bool) {
        return processProof(proof, leaf) == root;
    }
    /**
     * @dev Calldata version of {verify}
     *
     * _Available since v4.7._
     */
    function verifyCalldata(
        bytes32[] calldata proof,
        bytes32 root,
        bytes32 leaf
    ) internal pure returns (bool) {
        return processProofCalldata(proof, leaf) == root;
    }
    /**
     * @dev Returns the rebuilt hash obtained by traversing a Merkle tree up
     * from `leaf` using `proof`. A `proof` is valid if and only if the rebuilt
     * hash matches the root of the tree. When processing the proof, the pairs
     * of leafs & pre-images are assumed to be sorted.
     *
     * _Available since v4.4._
     */
    function processProof(bytes32[] memory proof, bytes32 leaf) internal pure returns (bytes32) {
        bytes32 computedHash = leaf;
        for (uint256 i = 0; i < proof.length; i++) {
            computedHash = _hashPair(computedHash, proof[i]);
        }
        return computedHash;
    }
    /**
     * @dev Calldata version of {processProof}
     *
     * _Available since v4.7._
     */
    function processProofCalldata(bytes32[] calldata proof, bytes32 leaf) internal pure returns (bytes32) {
        bytes32 computedHash = leaf;
        for (uint256 i = 0; i < proof.length; i++) {
            computedHash = _hashPair(computedHash, proof[i]);
        }
        return computedHash;
    }
    /**
     * @dev Returns true if the `leaves` can be proved to be a part of a Merkle tree defined by
     * `root`, according to `proof` and `proofFlags` as described in {processMultiProof}.
     *
     * _Available since v4.7._
     */
    function multiProofVerify(
        bytes32[] memory proof,
        bool[] memory proofFlags,
        bytes32 root,
        bytes32[] memory leaves
    ) internal pure returns (bool) {
        return processMultiProof(proof, proofFlags, leaves) == root;
    }
    /**
     * @dev Calldata version of {multiProofVerify}
     *
     * _Available since v4.7._
     */
    function multiProofVerifyCalldata(
        bytes32[] calldata proof,
        bool[] calldata proofFlags,
        bytes32 root,
        bytes32[] memory leaves
    ) internal pure returns (bool) {
        return processMultiProofCalldata(proof, proofFlags, leaves) == root;
    }
    /**
     * @dev Returns the root of a tree reconstructed from `leaves` and the sibling nodes in `proof`,
     * consuming from one or the other at each step according to the instructions given by
     * `proofFlags`.
     *
     * _Available since v4.7._
     */
    function processMultiProof(
        bytes32[] memory proof,
        bool[] memory proofFlags,
        bytes32[] memory leaves
    ) internal pure returns (bytes32 merkleRoot) {
        // This function rebuild the root hash by traversing the tree up from the leaves. The root is rebuilt by
        // consuming and producing values on a queue. The queue starts with the `leaves` array, then goes onto the
        // `hashes` array. At the end of the process, the last hash in the `hashes` array should contain the root of
        // the merkle tree.
        uint256 leavesLen = leaves.length;
        uint256 totalHashes = proofFlags.length;
        // Check proof validity.
        require(leavesLen + proof.length - 1 == totalHashes, "MerkleProof: invalid multiproof");
        // The xxxPos values are "pointers" to the next value to consume in each array. All accesses are done using
        // `xxx[xxxPos++]`, which return the current value and increment the pointer, thus mimicking a queue's "pop".
        bytes32[] memory hashes = new bytes32[](totalHashes);
        uint256 leafPos = 0;
        uint256 hashPos = 0;
        uint256 proofPos = 0;
        // At each step, we compute the next hash using two values:
        // - a value from the "main queue". If not all leaves have been consumed, we get the next leaf, otherwise we
        //   get the next hash.
        // - depending on the flag, either another value for the "main queue" (merging branches) or an element from the
        //   `proof` array.
        for (uint256 i = 0; i < totalHashes; i++) {
            bytes32 a = leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++];
            bytes32 b = proofFlags[i] ? leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++] : proof[proofPos++];
            hashes[i] = _hashPair(a, b);
        }
        if (totalHashes > 0) {
            return hashes[totalHashes - 1];
        } else if (leavesLen > 0) {
            return leaves[0];
        } else {
            return proof[0];
        }
    }
    /**
     * @dev Calldata version of {processMultiProof}
     *
     * _Available since v4.7._
     */
    function processMultiProofCalldata(
        bytes32[] calldata proof,
        bool[] calldata proofFlags,
        bytes32[] memory leaves
    ) internal pure returns (bytes32 merkleRoot) {
        // This function rebuild the root hash by traversing the tree up from the leaves. The root is rebuilt by
        // consuming and producing values on a queue. The queue starts with the `leaves` array, then goes onto the
        // `hashes` array. At the end of the process, the last hash in the `hashes` array should contain the root of
        // the merkle tree.
        uint256 leavesLen = leaves.length;
        uint256 totalHashes = proofFlags.length;
        // Check proof validity.
        require(leavesLen + proof.length - 1 == totalHashes, "MerkleProof: invalid multiproof");
        // The xxxPos values are "pointers" to the next value to consume in each array. All accesses are done using
        // `xxx[xxxPos++]`, which return the current value and increment the pointer, thus mimicking a queue's "pop".
        bytes32[] memory hashes = new bytes32[](totalHashes);
        uint256 leafPos = 0;
        uint256 hashPos = 0;
        uint256 proofPos = 0;
        // At each step, we compute the next hash using two values:
        // - a value from the "main queue". If not all leaves have been consumed, we get the next leaf, otherwise we
        //   get the next hash.
        // - depending on the flag, either another value for the "main queue" (merging branches) or an element from the
        //   `proof` array.
        for (uint256 i = 0; i < totalHashes; i++) {
            bytes32 a = leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++];
            bytes32 b = proofFlags[i] ? leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++] : proof[proofPos++];
            hashes[i] = _hashPair(a, b);
        }
        if (totalHashes > 0) {
            return hashes[totalHashes - 1];
        } else if (leavesLen > 0) {
            return leaves[0];
        } else {
            return proof[0];
        }
    }
    function _hashPair(bytes32 a, bytes32 b) private pure returns (bytes32) {
        return a < b ? _efficientHash(a, b) : _efficientHash(b, a);
    }
    function _efficientHash(bytes32 a, bytes32 b) private pure returns (bytes32 value) {
        /// @solidity memory-safe-assembly
        assembly {
            mstore(0x00, a)
            mstore(0x20, b)
            value := keccak256(0x00, 0x40)
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)
pragma solidity ^0.8.0;
/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }
    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);
    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);
    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);
    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);
    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);
    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);
    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";
/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;
    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }
    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }
    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }
    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }
    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }
    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.
        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC721/IERC721.sol)
pragma solidity ^0.8.0;
import "../../utils/introspection/IERC165.sol";
/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);
    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);
    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);
    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);
    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);
    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;
    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;
    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;
    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;
    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);
    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC721/IERC721Receiver.sol)
pragma solidity ^0.8.0;
/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC721.sol";
/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);
    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);
    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC721/extensions/IERC721Enumerable.sol)
pragma solidity ^0.8.0;
import "../IERC721.sol";
/**
 * @title ERC-721 Non-Fungible Token Standard, optional enumeration extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Enumerable is IERC721 {
    /**
     * @dev Returns the total amount of tokens stored by the contract.
     */
    function totalSupply() external view returns (uint256);
    /**
     * @dev Returns a token ID owned by `owner` at a given `index` of its token list.
     * Use along with {balanceOf} to enumerate all of ``owner``'s tokens.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) external view returns (uint256);
    /**
     * @dev Returns a token ID at a given `index` of all the tokens stored by the contract.
     * Use along with {totalSupply} to enumerate all tokens.
     */
    function tokenByIndex(uint256 index) external view returns (uint256);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.
        return account.code.length > 0;
    }
    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");
        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }
    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }
    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }
    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly
                /// @solidity memory-safe-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/Strings.sol)
pragma solidity ^0.8.0;
/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;
    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol
        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }
    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }
    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)
pragma solidity ^0.8.0;
import "./IERC165.sol";
/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)
pragma solidity ^0.8.0;
/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)
pragma solidity ^0.8.0;
/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;
    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);
    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}