// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (access/AccessControl.sol)
pragma solidity ^0.8.0;
import "./IAccessControl.sol";
import "../utils/Context.sol";
import "../utils/Strings.sol";
import "../utils/introspection/ERC165.sol";
/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }
    mapping(bytes32 => RoleData) private _roles;
    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;
    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }
    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }
    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }
    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        Strings.toHexString(account),
                        " is missing role ",
                        Strings.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }
    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }
    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }
    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }
    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");
        _revokeRole(role, account);
    }
    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * May emit a {RoleGranted} event.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }
    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }
    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }
    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)
pragma solidity ^0.8.0;
/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);
    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);
    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);
    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);
    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);
    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;
    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;
    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (security/ReentrancyGuard.sol)
pragma solidity ^0.8.0;
/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.
    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;
    uint256 private _status;
    constructor() {
        _status = _NOT_ENTERED;
    }
    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }
    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }
    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)
pragma solidity ^0.8.0;
/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;
    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);
    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);
    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);
    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);
    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);
    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);
    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);
    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);
    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);
    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";
/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;
    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }
    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }
    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }
    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }
    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }
    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.
        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.
        return account.code.length > 0;
    }
    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");
        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }
    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }
    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }
    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }
    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }
    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)
pragma solidity ^0.8.0;
/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }
    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)
pragma solidity ^0.8.0;
import "./IERC165.sol";
/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)
pragma solidity ^0.8.0;
/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/Math.sol)
pragma solidity ^0.8.0;
/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }
    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }
    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }
    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }
    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }
    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(
        uint256 x,
        uint256 y,
        uint256 denominator
    ) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }
            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                return prod0 / denominator;
            }
            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1);
            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////
            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)
                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }
            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.
            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)
                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)
                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }
            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;
            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;
            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256
            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }
    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(
        uint256 x,
        uint256 y,
        uint256 denominator,
        Rounding rounding
    ) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }
    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }
        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);
        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }
    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }
    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }
    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }
    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10**64) {
                value /= 10**64;
                result += 64;
            }
            if (value >= 10**32) {
                value /= 10**32;
                result += 32;
            }
            if (value >= 10**16) {
                value /= 10**16;
                result += 16;
            }
            if (value >= 10**8) {
                value /= 10**8;
                result += 8;
            }
            if (value >= 10**4) {
                value /= 10**4;
                result += 4;
            }
            if (value >= 10**2) {
                value /= 10**2;
                result += 2;
            }
            if (value >= 10**1) {
                result += 1;
            }
        }
        return result;
    }
    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10**result < value ? 1 : 0);
        }
    }
    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }
    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result * 8) < value ? 1 : 0);
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Strings.sol)
pragma solidity ^0.8.0;
import "./math/Math.sol";
/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;
    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }
    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }
    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }
}
// SPDX-License-Identifier: MIT
/*
    This contract makes use of a users stake in TwoWeeksNotice to delegate to a specific provider and gain rewards upon it. To use this contract,
    please stake your Chromia tokens in TwoWeeksNotice first.
    IMPORTANT: User MUST `undelegate(..)` AFTER reqesting a withdrawal, but BEFORE actually withdrawing their stake from TWN, otherwise their records
    in TWN will be gone and the contracts cannot be synced - this will lead to a loss of unclaimed rewards.
*/
pragma solidity ^0.8.17;
import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {AccessControl} from "@openzeppelin/contracts/access/AccessControl.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import {ITwoWeeksNotice} from "contracts/interfaces/ITwoWeeksNotice.sol";
struct DelegationChange {
    address delegatedTo;
    uint72 balance;
    uint16 nextChange;
}
struct DelegationState {
    uint16 claimedEpoch;
    uint16 latestChangeEpoch;
    uint96 processed;
    uint64 processedDate;
    uint96 balanceAtProcessed;
    mapping(uint16 => DelegationChange) delegationTimeline; // each uint key is a week starting from "startTime"
}
struct RateTimeline {
    uint16 latestChangeEpoch;
    mapping(uint16 => uint16) timeline;
    mapping(uint16 => uint16) nextChange;
}
struct ProviderStateChange {
    bool lostWhitelist; // provider got removed from whitelist this epoch
    bool gainedWhitelist; // provider got added to whitelist this epoch
    uint96 delegationsIncrease;
    uint96 delegationsDecrease;
    uint16 nextChangeDelegations;
    uint16 nextChangeWhitelist;
}
struct AdditionalReward {
    uint16 additionalRewardPerYieldPeriodPerToken;
    uint16 epoch;
}
struct ProviderState {
    bool whitelisted;
    uint16 claimedEpochReward;
    uint16 latestDelegationsChange;
    uint16 latestWhitelistChange;
    uint128 latestTotalDelegation;
    uint16 latestTotalDelegationEpoch;
    AdditionalReward[] additionalRewards;
    mapping(uint16 => ProviderStateChange) providerStateTimeline;
}
/// @title ChromiaProvider Delegation
/// @author Mustafa Koray Kaya
/// @notice TwoWeekNoticeProvider extension that allows delegation rewards for an existing TwoWeekNotice contract.
/// @dev Syncronizes state with the TWN contract when delegation is altered.
/// @dev Syncronization must also be performed before a TWN withdrawal
contract ChromiaDelegation is AccessControl, ReentrancyGuard {
    using SafeERC20 for IERC20Metadata;
    bytes32 public constant WHITELIST_ADMIN = keccak256("WHITELIST_ADMIN");
    bytes32 public constant RATE_ADMIN = keccak256("RATE_ADMIN");
    bytes32 public constant ADDITIONAL_REWARD_ADMIN = keccak256("ADDITIONAL_REWARD_ADMIN");
    uint32 public immutable yieldPeriod;
    uint32 public immutable epochLength;
    uint32 public immutable startTime;
    ITwoWeeksNotice public immutable twn;
    IERC20Metadata public immutable token;
    address public bank;
    uint128 private immutable minorTokenUnitsInMajor;
    mapping(address => DelegationState) public delegatorStates;
    mapping(address => ProviderState) public providerStates;
    RateTimeline private delegatorYieldTimeline; // The yield delegators get for delegating
    RateTimeline private providerRewardRateTimeline; // The reward the provider gets from the delegations that are delegated to them
    event Delegated(address indexed delegator, address indexed provider, uint128 amount);
    event Undelegated(address indexed delegator, address indexed provider, uint128 amount);
    event DelegatorYieldRateChanged(uint16 newRate);
    event ProviderTotalDelegationRateChanged(uint16 newRate);
    event AddedWhitelist(address provider);
    event RemovedWhitelist(address provider);
    event RevisedDelegation(address delegator);
    event ResetAccount(address delegator);
    event GrantedAdditionalReward(address provider, uint16 rate);
    event ClaimedYield(address delegator, uint128 amount);
    event ProviderClaimedTotalDelegationYield(address provider, uint128 amount);
    string private constant INVALID_WITHDRAW_ERROR = "Withdrawn without undelegating";
    string private constant TIMELINE_MISMATCH_ERROR = "Timeline does not match with TWN.";
    string private constant UNAUTHORISED_ERROR = "Unauthorized";
    string private constant CANNOT_CHANGE_WITHDRAWAL_ERROR = "Cannot change delegation while withdrawing";
    string private constant WITHDRAWAL_NOT_REQUESTED_ERROR = "Withdraw has not been requested";
    string private constant MUST_HAVE_STAKE_ERROR = "Must have a stake to delegate";
    string private constant MUST_WHITELISTED_ERROR = "Provider must be whitelisted";
    string private constant MUST_AFTER_START_ERROR = "Time must be after start time";
    string private constant CHANGE_TOO_RECENT_ERROR = "Change is too recent";
    string private constant ZERO_REWARD_ERROR = "Reward is 0";
    string private constant FIRST_DELEGATION_NEEDED_ERROR = "Address must make a first delegation.";
    string private constant ALREADY_SYNCRONISED_ERROR = "Stake is synced";
    constructor(
        IERC20Metadata _token,
        ITwoWeeksNotice _twn,
        address _owner,
        uint16 _delegatorYield, // Yield delegators get for delegating
        uint16 _totalDelegationYield, // Yield providers get on the total amount delegated to them
        address _bank,
        uint32 _yieldPeriodInSecs,
        uint32 _epochLengthInYieldPeriods
    ) {
        yieldPeriod = _yieldPeriodInSecs;
        epochLength = _epochLengthInYieldPeriods * yieldPeriod;
        startTime = uint32(block.timestamp) - epochLength;
        _setupRole(DEFAULT_ADMIN_ROLE, _owner);
        _setupRole(WHITELIST_ADMIN, _owner);
        _setupRole(RATE_ADMIN, _owner);
        _setupRole(ADDITIONAL_REWARD_ADMIN, _owner);
        twn = _twn;
        token = _token;
        bank = _bank;
        minorTokenUnitsInMajor = uint128(10 ** token.decimals());
        delegatorYieldTimeline.timeline[1] = _delegatorYield;
        delegatorYieldTimeline.nextChange[0] = 1;
        delegatorYieldTimeline.latestChangeEpoch = 1;
        providerRewardRateTimeline.timeline[1] = _totalDelegationYield;
        providerRewardRateTimeline.nextChange[0] = 1;
        providerRewardRateTimeline.latestChangeEpoch = 1;
    }
    /// @dev Has the delegator's stake on the TWN contract not been released or modified.
    function isStakeValid(address account) public view returns (bool) {
        (, uint128 remoteAccumulated) = twn.getAccumulated(account);
        return remoteAccumulated == delegatorStates[account].processed;
    }
    /**
     *
     * SETTERS AND GETTERS
     *
     */
    /// @notice Set the reward rate to `rewardRate` for the *next* epoch
    function setRewardRate(uint16 newRate) external {
        setNewRate(newRate, delegatorYieldTimeline);
        emit DelegatorYieldRateChanged(newRate);
    }
    /// @notice Set the provider reward rate to `newRate` at the new epoch
    function setProviderRewardRate(uint16 newRate) external {
        setNewRate(newRate, providerRewardRateTimeline);
        emit ProviderTotalDelegationRateChanged(newRate);
    }
    function setNewRate(uint16 newRate, RateTimeline storage rateTimeline) private {
        require(hasRole(DEFAULT_ADMIN_ROLE, msg.sender) || hasRole(RATE_ADMIN, msg.sender), UNAUTHORISED_ERROR);
        uint16 nextEpoch = getCurrentEpoch() + 1;
        rateTimeline.timeline[nextEpoch] = newRate;
        if (rateTimeline.latestChangeEpoch != nextEpoch) {
            rateTimeline.nextChange[rateTimeline.latestChangeEpoch] = nextEpoch;
            rateTimeline.latestChangeEpoch = nextEpoch;
        }
    }
    function journalProviderWhitelistChange(ProviderState storage providerState) private returns (uint16 newLatestChange) {
        ProviderStateChange storage nextChangeMapping = providerState.providerStateTimeline[providerState.latestWhitelistChange];
        if (providerState.latestWhitelistChange != getCurrentEpoch()) {
            nextChangeMapping.nextChangeWhitelist = getCurrentEpoch();
            return getCurrentEpoch();
        }
        return providerState.latestWhitelistChange;
    }
    function journalProviderDelegationChange(ProviderState storage ps) private returns (uint16 newLatestChange) {
        uint16 changeEpoch = getCurrentEpoch() + 1;
        ProviderStateChange storage nextChangeMapping = ps.providerStateTimeline[ps.latestDelegationsChange];
        if (ps.latestDelegationsChange != changeEpoch) {
            nextChangeMapping.nextChangeDelegations = changeEpoch;
            return changeEpoch;
        }
        return ps.latestDelegationsChange;
    }
    function journalDelegationChange(uint16 epoch, DelegationState storage userState) private returns (uint16 newLatestChange) {
        DelegationChange storage nextChangeMapping = userState.delegationTimeline[userState.latestChangeEpoch];
        if (userState.latestChangeEpoch != epoch) {
            nextChangeMapping.nextChange = epoch;
            return epoch;
        }
        return userState.latestChangeEpoch;
    }
    /// @notice Gets the current active reward rate in the present epoch
    function getActiveProviderRewardRate(uint16 epoch) public view returns (uint128 activeRate, uint16 latestEpoch) {
        return getActiveRate(epoch, providerRewardRateTimeline);
    }
    /// @notice Get the reward rate active at epoch `epoch`
    function getActiveYieldRate(uint16 epoch) public view returns (uint128 activeRate, uint16 latestEpoch) {
        return getActiveRate(epoch, delegatorYieldTimeline);
    }
    function getActiveRate(uint16 epoch, RateTimeline storage rateTimeline) private view returns (uint128 activeRate, uint16 latestEpoch) {
        if (epoch >= rateTimeline.latestChangeEpoch) {
            return (rateTimeline.timeline[rateTimeline.latestChangeEpoch], rateTimeline.latestChangeEpoch);
        }
        uint16 nextChange = 0;
        while (true) {
            if (rateTimeline.nextChange[nextChange] > epoch) {
                return (rateTimeline.timeline[nextChange], nextChange);
            }
            nextChange = rateTimeline.nextChange[nextChange];
        }
    }
    /// @notice Get the active delegates state for `account` at epoch `epoch`
    function getActiveDelegation(address account, uint16 epoch) public view returns (DelegationChange memory activeDelegation, uint16 latestEpoch) {
        DelegationState storage userState = delegatorStates[account];
        if (userState.latestChangeEpoch == 0) {
            return (activeDelegation, 0);
        }
        if (epoch >= userState.latestChangeEpoch) {
            return (userState.delegationTimeline[userState.latestChangeEpoch], userState.latestChangeEpoch);
        }
        uint16 nextChange = 0;
        while (true) {
            if (userState.delegationTimeline[nextChange].nextChange > epoch) {
                return (userState.delegationTimeline[nextChange], nextChange);
            }
            nextChange = userState.delegationTimeline[nextChange].nextChange;
        }
    }
    /// @notice Get if the account has whitelist at certain epoch
    function getWhitelisted(address account, uint16 epoch) public view returns (bool whitelisted, uint16 latestEpoch) {
        ProviderState storage providerState = providerStates[account];
        if (providerState.latestWhitelistChange == 0) {
            return (false, 0);
        }
        ProviderStateChange storage psc;
        if (epoch >= providerState.latestWhitelistChange) {
            psc = providerState.providerStateTimeline[providerState.latestWhitelistChange];
            if (psc.lostWhitelist) {
                return (false, providerState.latestWhitelistChange);
            } else if (psc.gainedWhitelist) {
                return (true, providerState.latestWhitelistChange);
            }
        }
        uint16 nextChange = 0;
        while (true) {
            if (providerState.providerStateTimeline[nextChange].nextChangeWhitelist > epoch) {
                psc = providerState.providerStateTimeline[nextChange];
                if (psc.lostWhitelist) {
                    return (false, nextChange);
                } else if (psc.gainedWhitelist) {
                    return (true, nextChange);
                }
            }
            nextChange = providerState.providerStateTimeline[nextChange].nextChangeWhitelist;
        }
    }
    function getTotalDelegations(address provider) external view returns (uint128 totalDelegations) {
        ProviderState storage providerState = providerStates[provider];
        totalDelegations = providerState.latestTotalDelegation;
        uint16 next = providerState.providerStateTimeline[providerState.latestTotalDelegationEpoch].nextChangeDelegations;
        ProviderStateChange storage psc;
        while (true) {
            if (next == 0 || next > getCurrentEpoch() - 1) {
                break;
            }
            psc = providerState.providerStateTimeline[next];
            if (psc.delegationsIncrease != 0) {
                totalDelegations += psc.delegationsIncrease;
            }
            if (psc.delegationsDecrease != 0) {
                if (totalDelegations > psc.delegationsDecrease) {
                    totalDelegations -= psc.delegationsDecrease;
                } else totalDelegations = 0;
            }
            next = providerState.providerStateTimeline[next].nextChangeDelegations;
        }
    }
    /**
     *
     * DELEGATION MANAGEMENT
     *
     */
    function removeCurrentDelegationFromProvider(DelegationChange memory currentDelegation, uint16 currDelEpoch) private {
        uint16 nextEpoch = getCurrentEpoch() + 1;
        ProviderState storage ps = providerStates[currentDelegation.delegatedTo];
        // If provider has lost whitelist since delegation, dont bother to decreae since their total is already set to 0 on
        // removeWhitelist()
        if (currDelEpoch >= ps.latestWhitelistChange) {
            // Remove previous delegation from providers pool
            ps.providerStateTimeline[nextEpoch].delegationsDecrease += currentDelegation.balance;
            ps.latestDelegationsChange = journalProviderDelegationChange(ps);
        }
    }
    function addDelegation(DelegationState storage userState, uint16 epoch, address to, uint128 acc, uint64 since, uint64 delegateAmount) private {
        userState.delegationTimeline[epoch] = DelegationChange(to, delegateAmount, 0);
        userState.latestChangeEpoch = journalDelegationChange(epoch, userState);
        userState.balanceAtProcessed = delegateAmount;
        userState.processed = uint96(acc);
        userState.processedDate = since;
    }
    /// @notice Removes delegation after a withdrawal is requested. Failure to do so prior to withdrawal may result in lost.
    function undelegate(address account) external nonReentrant {
        (, , uint64 lockedUntil, uint64 since) = twn.getStakeState(account);
        require(lockedUntil > 0, WITHDRAWAL_NOT_REQUESTED_ERROR);
        DelegationState storage userState = delegatorStates[account];
        (, uint128 acc) = twn.getAccumulated(msg.sender);
        ensureSyncronisedDelegationState(userState, acc, since);
        uint16 nextEpoch = getCurrentEpoch() + 1;
        // Remove previous delegation from providers pool
        (DelegationChange memory currentDelegation, uint16 currDelEpoch) = getActiveDelegation(msg.sender, nextEpoch);
        removeCurrentDelegationFromProvider(currentDelegation, currDelEpoch);
        uint16 requestWithdrawEpoch = getEpoch(since);
        if (currDelEpoch > requestWithdrawEpoch) {
            // if there is a change queued up, delete it and reset the pointers
            (, uint16 prevDelEpoch) = getActiveDelegation(msg.sender, currDelEpoch - 1);
            delete userState.delegationTimeline[currDelEpoch];
            userState.delegationTimeline[prevDelEpoch].nextChange = 0;
            userState.latestChangeEpoch = prevDelEpoch;
        }
        addDelegation(userState, requestWithdrawEpoch, address(0), acc, since, 0);
        emit Undelegated(account, currentDelegation.delegatedTo, currentDelegation.balance);
    }
    /// @notice Set the delegation of the caller for the *next* epoch
    function delegate(address to) external nonReentrant {
        DelegationState storage userState = delegatorStates[msg.sender];
        ProviderState storage ps = providerStates[to];
        (, uint128 acc) = twn.getAccumulated(msg.sender);
        (uint64 delegateAmount, , uint64 lockedUntil, uint64 since) = twn.getStakeState(msg.sender);
        require(delegateAmount > 0, MUST_HAVE_STAKE_ERROR);
        require(lockedUntil == 0, CANNOT_CHANGE_WITHDRAWAL_ERROR);
        require(ps.whitelisted, MUST_WHITELISTED_ERROR);
        uint16 nextEpoch = getCurrentEpoch() + 1;
        // Remove previous delegation from providers pool so that they cannot claim rewards from it if we have a new provider
        (DelegationChange memory currentDelegation, uint16 currDelEpoch) = getActiveDelegation(msg.sender, nextEpoch);
        if (currentDelegation.delegatedTo != address(0) && (currentDelegation.delegatedTo != to || currDelEpoch < ps.latestWhitelistChange)) {
            removeCurrentDelegationFromProvider(currentDelegation, currDelEpoch); // 40k gas
        }
        if (userState.latestChangeEpoch == 0) {
            userState.claimedEpoch = nextEpoch - 1; // If user has never delegated before, set claimedEpoch to current epoch
        } else {
            ensureSyncronisedDelegationState(userState, acc, since); // Make sure that the user hasnt decreased stake since last delegation
        }
        addDelegation(userState, nextEpoch, to, acc, since, delegateAmount); // 80k gas. Add delegation to users state
        // Add to new providers "totalDelegations" pool so they can claim rewards
        // 40k gas
        if (currentDelegation.delegatedTo != to || currDelEpoch < ps.latestWhitelistChange) {
            ps.providerStateTimeline[nextEpoch].delegationsIncrease += delegateAmount;
        } else {
            ps.providerStateTimeline[nextEpoch].delegationsIncrease += delegateAmount - currentDelegation.balance;
        }
        ps.latestDelegationsChange = journalProviderDelegationChange(ps);
        emit Delegated(msg.sender, to, delegateAmount);
    }
    /// @notice Remove the calling account's delegation status. Call only if state is "broken".
    function resetAccount() external {
        DelegationState storage userState = delegatorStates[msg.sender];
        require(userState.latestChangeEpoch > 0, FIRST_DELEGATION_NEEDED_ERROR);
        (DelegationChange memory currentDelegation, uint16 currDelEpoch) = getActiveDelegation(msg.sender, getCurrentEpoch() + 1);
        removeCurrentDelegationFromProvider(currentDelegation, currDelEpoch);
        uint16 currChange = 0;
        uint16 nextChange;
        while (true) {
            nextChange = userState.delegationTimeline[currChange].nextChange;
            delete userState.delegationTimeline[currChange];
            if (nextChange == 0) break;
            currChange = nextChange;
        }
        delete delegatorStates[msg.sender];
        emit ResetAccount(msg.sender);
    }
    /// @notice Matches `account`'s delegation to the underlying stake. `isStakeValid(account)` must be false before call.
    function reviseDelegation(address account) external nonReentrant onlyRole(WHITELIST_ADMIN) {
        require(!isStakeValid(account), ALREADY_SYNCRONISED_ERROR);
        (, , , uint64 since) = twn.getStakeState(account);
        require(block.timestamp - since > epochLength, CHANGE_TOO_RECENT_ERROR);
        DelegationState storage userState = delegatorStates[account];
        require(userState.latestChangeEpoch > 0, FIRST_DELEGATION_NEEDED_ERROR);
        uint16 currentEpoch = getCurrentEpoch();
        (DelegationChange memory currentDelegation, uint16 currDelEpoch) = getActiveDelegation(account, currentEpoch + 1);
        removeCurrentDelegationFromProvider(currentDelegation, currDelEpoch);
        userState.delegationTimeline[currentEpoch] = DelegationChange(address(0), 0, 0);
        userState.latestChangeEpoch = journalDelegationChange(currentEpoch, userState);
        emit RevisedDelegation(account);
    }
    /**
     *
     * REWARD FUNCTIONS
     *
     */
    /// @notice Estimates the additional reward providers get for the total amount delegated to them per epoch
    function updateProviderDelegationRewardEstimate(address account) external nonReentrant returns (uint128 reward) {
        return _updateProviderDelegationRewardEstimate(account);
    }
    function _updateProviderDelegationRewardEstimate(address account) internal returns (uint128 reward) {
        ProviderState storage providerState = providerStates[account];
        uint16 currentEpoch = getCurrentEpoch();
        if (currentEpoch - 1 <= providerState.claimedEpochReward) {
            return 0;
        }
        uint128 totalDelegations = providerState.latestTotalDelegation;
        uint16 nextDC = providerState.latestTotalDelegationEpoch;
        (uint128 activeRate, uint16 nextAR) = getActiveProviderRewardRate(providerState.claimedEpochReward + 1);
        uint16 latestTotalDelegationEpoch = nextDC;
        nextAR = providerRewardRateTimeline.nextChange[nextAR];
        nextDC = providerState.providerStateTimeline[nextDC].nextChangeDelegations;
        uint16 prev = providerState.claimedEpochReward + 1;
        uint16 next = findSmallestNonZero(nextAR, nextDC);
        if (next == 0 || next >= currentEpoch) {
            next = currentEpoch;
        }
        ProviderStateChange storage psc;
        while (true) {
            reward += uint128((activeRate) * totalDelegations * epochLength) * (next - prev);
            if (next == currentEpoch) break;
            if (next == nextAR) {
                activeRate = providerRewardRateTimeline.timeline[next];
                nextAR = providerRewardRateTimeline.nextChange[next];
            }
            if (next == nextDC) {
                psc = providerStates[account].providerStateTimeline[next];
                if (psc.delegationsIncrease != 0) {
                    totalDelegations += psc.delegationsIncrease;
                }
                if (psc.delegationsDecrease != 0) {
                    if (totalDelegations > psc.delegationsDecrease) {
                        totalDelegations -= psc.delegationsDecrease;
                    } else totalDelegations = 0;
                }
                latestTotalDelegationEpoch = nextDC;
                nextDC = providerState.providerStateTimeline[next].nextChangeDelegations;
            }
            prev = next;
            next = findSmallestNonZero(nextAR, nextDC);
            if (next == 0 || next >= currentEpoch) {
                next = currentEpoch;
            }
        }
        reward /= minorTokenUnitsInMajor * yieldPeriod;
        providerState.latestTotalDelegation = totalDelegations;
        providerState.latestTotalDelegationEpoch = latestTotalDelegationEpoch;
    }
    /// @notice Calculate the total accumulated reward available to `account`
    function estimateYield(address account) public view returns (uint128 reward) {
        DelegationState storage userState = delegatorStates[account];
        uint16 processedEpoch = userState.claimedEpoch;
        uint16 currentEpoch = getCurrentEpoch();
        if (currentEpoch - 1 <= processedEpoch) {
            return 0;
        }
        (uint128 activeRate, uint16 nextAR) = getActiveYieldRate(processedEpoch + 1);
        (DelegationChange memory activeDelegation, uint16 nextAD) = getActiveDelegation(account, processedEpoch + 1);
        (bool whitelisted, uint16 nextWL) = getWhitelisted(activeDelegation.delegatedTo, processedEpoch + 1);
        ProviderState storage providerState = providerStates[activeDelegation.delegatedTo];
        nextAR = delegatorYieldTimeline.nextChange[nextAR];
        nextAD = userState.delegationTimeline[nextAD].nextChange;
        nextWL = providerState.providerStateTimeline[nextWL].nextChangeWhitelist;
        uint16 prev = processedEpoch + 1;
        uint16 next = findSmallestNonZero(nextAR, nextAD, nextWL);
        if (next == 0 || next >= currentEpoch) {
            next = currentEpoch;
        }
        while (true) {
            if (whitelisted) {
                reward += uint128((activeRate) * activeDelegation.balance * epochLength) * (next - prev);
                if (providerState.additionalRewards.length > 0) {
                    for (uint i = providerState.additionalRewards.length - 1; i >= 0; i--) {
                        if (providerState.additionalRewards[i].epoch < prev) break;
                        if (
                            providerState.additionalRewards[i].epoch < next &&
                            providerState.additionalRewards[i].additionalRewardPerYieldPeriodPerToken > 0
                        ) {
                            reward += uint128(
                                (providerState.additionalRewards[i].additionalRewardPerYieldPeriodPerToken) * activeDelegation.balance * epochLength
                            );
                        }
                        if (i == 0) break;
                    }
                }
            }
            if (next == currentEpoch) break;
            if (next == nextAR) {
                activeRate = delegatorYieldTimeline.timeline[next];
                nextAR = delegatorYieldTimeline.nextChange[next];
            }
            if (next == nextAD) {
                DelegationChange memory oldDelegation = activeDelegation;
                activeDelegation = userState.delegationTimeline[next];
                if (oldDelegation.delegatedTo != activeDelegation.delegatedTo) {
                    providerState = providerStates[activeDelegation.delegatedTo];
                    (whitelisted, nextWL) = getWhitelisted(activeDelegation.delegatedTo, next);
                    nextWL = providerState.providerStateTimeline[nextWL].nextChangeWhitelist;
                }
                nextAD = userState.delegationTimeline[next].nextChange;
            }
            if (next == nextWL) {
                ProviderStateChange storage psc = providerState.providerStateTimeline[next];
                if (psc.lostWhitelist) {
                    whitelisted = false;
                } else if (psc.gainedWhitelist) {
                    whitelisted = true;
                }
                nextWL = providerState.providerStateTimeline[next].nextChangeWhitelist;
            }
            prev = next;
            next = findSmallestNonZero(nextAR, nextAD, nextWL);
            if (next == 0 || next >= currentEpoch) {
                next = currentEpoch;
            }
        }
        reward /= (minorTokenUnitsInMajor * yieldPeriod);
    }
    /// @notice Claims the rewards (which should be per `estimateYield(account)`) for `account`
    function claimYield(address account) external nonReentrant {
        require(delegatorStates[account].latestChangeEpoch > 0, FIRST_DELEGATION_NEEDED_ERROR);
        require(isStakeValid(account), TIMELINE_MISMATCH_ERROR);
        uint128 reward = estimateYield(account);
        require(reward > 0, ZERO_REWARD_ERROR);
        delegatorStates[account].claimedEpoch = getCurrentEpoch() - 1;
        token.safeTransferFrom(bank, account, reward);
        emit ClaimedYield(account, reward);
    }
    /// @notice Claims additional token rewards for the calling provider
    function claimProviderDelegationReward(address account) external nonReentrant {
        _claimProviderDelegationReward(account);
    }
    function _claimProviderDelegationReward(address account) internal {
        uint128 reward = _updateProviderDelegationRewardEstimate(account);
        providerStates[account].claimedEpochReward = getCurrentEpoch() - 1;
        token.safeTransferFrom(bank, account, reward);
        emit ProviderClaimedTotalDelegationYield(account, reward);
    }
    /**
     *
     * HELPERS
     *
     */
    function getCurrentEpoch() public view returns (uint16) {
        return getEpoch(block.timestamp);
    }
    function getEpoch(uint time) public view returns (uint16) {
        require(time > startTime, MUST_AFTER_START_ERROR);
        return uint16((time - startTime) / epochLength);
    }
    function ensureSyncronisedDelegationState(DelegationState storage userState, uint128 acc, uint64 since) private view {
        /// @dev This must match the calculation of acc at TWN exactly. Even the rounding errors MUST be matched.
        require(
            (userState.balanceAtProcessed * (since - userState.processedDate)) / yieldPeriod + userState.processed <= acc,
            INVALID_WITHDRAW_ERROR
        );
    }
    function findSmallestNonZero(uint16 a, uint16 b, uint16 c) private pure returns (uint16 smallestNonZero) {
        if (a == 0 && b == 0 && c == 0) {
            return 0;
        }
        smallestNonZero = type(uint16).max;
        if (a != 0 && a < smallestNonZero) {
            smallestNonZero = a;
        }
        if (b != 0 && b < smallestNonZero) {
            smallestNonZero = b;
        }
        if (c != 0 && c < smallestNonZero) {
            smallestNonZero = c;
        }
    }
    function findSmallestNonZero(uint16 a, uint16 b) private pure returns (uint16 smallestNonZero) {
        if (a == 0 && b == 0) {
            return 0;
        }
        smallestNonZero = type(uint16).max;
        if (a != 0 && a < smallestNonZero) {
            smallestNonZero = a;
        }
        if (b != 0 && b < smallestNonZero) {
            smallestNonZero = b;
        }
    }
    /**
     *
     * ADMIN
     *
     */
    /// @notice Adds `account` as a valid provider on the whitelist
    function addToWhitelist(address account) external {
        require(hasRole(DEFAULT_ADMIN_ROLE, msg.sender) || hasRole(WHITELIST_ADMIN, msg.sender), UNAUTHORISED_ERROR);
        uint16 currentEpoch = getCurrentEpoch();
        ProviderState storage providerState = providerStates[account];
        providerState.whitelisted = true;
        providerState.providerStateTimeline[currentEpoch].gainedWhitelist = true;
        providerState.latestWhitelistChange = journalProviderWhitelistChange(providerState);
        emit AddedWhitelist(account);
    }
    /// @notice Removes `account` from the provider whitelist, and process an immediate withdrawal if successful
    function removeFromWhitelist(address account) external nonReentrant {
        require(hasRole(DEFAULT_ADMIN_ROLE, msg.sender) || hasRole(WHITELIST_ADMIN, msg.sender), UNAUTHORISED_ERROR);
        ProviderState storage providerState = providerStates[account];
        uint16 currentEpoch = getCurrentEpoch();
        _claimProviderDelegationReward(account);
        providerState.latestTotalDelegation = 0;
        // remove from whitelist
        providerState.whitelisted = false;
        providerState.providerStateTimeline[currentEpoch].lostWhitelist = true;
        // Record change
        providerState.latestWhitelistChange = journalProviderWhitelistChange(providerState);
        emit RemovedWhitelist(account);
    }
    /// @notice Grants a lump `amount` award to a provider `account` at epoch `epoch`. Admin only.
    function grantAdditionalReward(address account, uint16 epoch, uint16 amount) external onlyRole(ADDITIONAL_REWARD_ADMIN) {
        require(epoch >= getCurrentEpoch(), "Cannot grant additional rewards retroactively");
        providerStates[account].additionalRewards.push(AdditionalReward(amount, epoch));
        emit GrantedAdditionalReward(account, amount);
    }
    /// @notice Changes the bank address from which rewards are drawn to `newBank`. Admin only.
    function changeBank(address newBank) external onlyRole(DEFAULT_ADMIN_ROLE) {
        bank = newBank;
    }
    /// @notice Sends all CHR tokens to the contract owner. Only admin can call.
    function drain() external onlyRole(DEFAULT_ADMIN_ROLE) {
        token.safeTransfer(msg.sender, token.balanceOf(address(this)));
    }
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;
interface ITwoWeeksNotice {
    function getStakeState(address account) external view returns (uint64, uint64, uint64, uint64);
    function getAccumulated(address account) external view returns (uint128, uint128);
}

// SPDX-License-Identifier: MIT

pragma solidity 0.6.12;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}


contract TwoWeeksNotice {
    
    struct StakeState {
        uint64 balance;
        uint64 unlockPeriod; // time it takes from requesting withdraw to being able to withdraw
        uint64 lockedUntil; // 0 if withdraw is not requested
        uint64 since;
        uint128 accumulated; // token-days staked
        uint128 accumulatedStrict; // token-days staked sans withdraw periods
    }
    
    event StakeUpdate(address indexed from, uint64 balance);
    event WithdrawRequest(address indexed from, uint64 until);
    
    mapping(address => StakeState) private _states;
    
    IERC20 private token;
    
    constructor (IERC20 _token) public {
        token = _token;
    }

    function getStakeState(address account) external view returns (uint64, uint64, uint64, uint64) {
        StakeState storage ss = _states[account];
        return (ss.balance, ss.unlockPeriod, ss.lockedUntil, ss.since);
    }
    
    function getAccumulated(address account) external view returns (uint128, uint128) {
        StakeState storage ss = _states[account];
        return (ss.accumulated, ss.accumulatedStrict);
    }

    function estimateAccumulated(address account) external view returns (uint128, uint128) {
        StakeState storage ss = _states[account];
        uint128 sum = ss.accumulated;
        uint128 sumStrict = ss.accumulatedStrict;
        if (ss.balance > 0) {
            uint256 until = block.timestamp;
            if (ss.lockedUntil > 0 && ss.lockedUntil < block.timestamp) {
                until = ss.lockedUntil;
            }
            if (until > ss.since) {
                uint128 delta = uint128( (uint256(ss.balance) * (until - ss.since))/86400 );
                sum += delta;
                if (ss.lockedUntil == 0) {
                    sumStrict += delta;
                }
            }
        }
        return (sum, sumStrict);
    }
    
    
    function updateAccumulated(StakeState storage ss) private {
        if (ss.balance > 0) {
            uint256 until = block.timestamp;
            if (ss.lockedUntil > 0 && ss.lockedUntil < block.timestamp) {
                until = ss.lockedUntil;
            }
            if (until > ss.since) {
                uint128 delta = uint128( (uint256(ss.balance) * (until - ss.since))/86400 );
                ss.accumulated += delta;
                if (ss.lockedUntil == 0) {
                    ss.accumulatedStrict += delta;
                }
            }
        }
    }

    function stake(uint64 amount, uint64 unlockPeriod) external {
        StakeState storage ss = _states[msg.sender];
        require(amount > 0, "amount must be positive");
        require(ss.balance <= amount, "cannot decrease balance");
        require(unlockPeriod <= 1000 days, "unlockPeriod cannot be higher than 1000 days");
        require(ss.unlockPeriod <= unlockPeriod, "cannot decrease unlock period");
        require(unlockPeriod >= 2 weeks, "unlock period can't be less than 2 weeks");
        
        updateAccumulated(ss);
        
        uint128 delta = amount - ss.balance;
        if (delta > 0) {
            require(token.transferFrom(msg.sender, address(this), delta), "transfer unsuccessful");
        }

        ss.balance = amount;
        ss.unlockPeriod = unlockPeriod;
        ss.lockedUntil = 0;
        ss.since = uint64(block.timestamp);
        emit StakeUpdate(msg.sender, amount);
    }
    
    function requestWithdraw() external {
         StakeState storage ss = _states[msg.sender];
         require(ss.balance > 0);
         updateAccumulated(ss);
         ss.since = uint64(block.timestamp);
         ss.lockedUntil = uint64(block.timestamp + ss.unlockPeriod);
    }

    function withdraw(address to) external {
        StakeState storage ss = _states[msg.sender];
        require(ss.balance > 0, "must have tokens to withdraw");
        require(ss.lockedUntil != 0, "unlock not requested");
        require(ss.lockedUntil < block.timestamp, "still locked");
        updateAccumulated(ss);
        uint128 balance = ss.balance;
        ss.balance = 0;
        ss.unlockPeriod = 0;
        ss.lockedUntil = 0;
        ss.since = 0;
        require(token.transfer(to, balance), "transfer unsuccessful");
        emit StakeUpdate(msg.sender, 0);
    }
}