// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "@openzeppelin/contracts/proxy/ERC1967/ERC1967Proxy.sol";
import "@openzeppelin/contracts/proxy/transparent/TransparentUpgradeableProxy.sol";
import "@openzeppelin/contracts/proxy/transparent/ProxyAdmin.sol";
// Kept for backwards compatibility with older versions of Hardhat and Truffle plugins.
contract AdminUpgradeabilityProxy is TransparentUpgradeableProxy {
    constructor(address logic, address admin, bytes memory data) payable TransparentUpgradeableProxy(logic, admin, data) {}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "../Proxy.sol";
import "./ERC1967Upgrade.sol";
/**
 * @dev This contract implements an upgradeable proxy. It is upgradeable because calls are delegated to an
 * implementation address that can be changed. This address is stored in storage in the location specified by
 * https://eips.ethereum.org/EIPS/eip-1967[EIP1967], so that it doesn't conflict with the storage layout of the
 * implementation behind the proxy.
 */
contract ERC1967Proxy is Proxy, ERC1967Upgrade {
    /**
     * @dev Initializes the upgradeable proxy with an initial implementation specified by `_logic`.
     *
     * If `_data` is nonempty, it's used as data in a delegate call to `_logic`. This will typically be an encoded
     * function call, and allows initializating the storage of the proxy like a Solidity constructor.
     */
    constructor(address _logic, bytes memory _data) payable {
        assert(_IMPLEMENTATION_SLOT == bytes32(uint256(keccak256("eip1967.proxy.implementation")) - 1));
        _upgradeToAndCall(_logic, _data, false);
    }
    /**
     * @dev Returns the current implementation address.
     */
    function _implementation() internal view virtual override returns (address impl) {
        return ERC1967Upgrade._getImplementation();
    }
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "../ERC1967/ERC1967Proxy.sol";
/**
 * @dev This contract implements a proxy that is upgradeable by an admin.
 *
 * To avoid https://medium.com/nomic-labs-blog/malicious-backdoors-in-ethereum-proxies-62629adf3357[proxy selector
 * clashing], which can potentially be used in an attack, this contract uses the
 * https://blog.openzeppelin.com/the-transparent-proxy-pattern/[transparent proxy pattern]. This pattern implies two
 * things that go hand in hand:
 *
 * 1. If any account other than the admin calls the proxy, the call will be forwarded to the implementation, even if
 * that call matches one of the admin functions exposed by the proxy itself.
 * 2. If the admin calls the proxy, it can access the admin functions, but its calls will never be forwarded to the
 * implementation. If the admin tries to call a function on the implementation it will fail with an error that says
 * "admin cannot fallback to proxy target".
 *
 * These properties mean that the admin account can only be used for admin actions like upgrading the proxy or changing
 * the admin, so it's best if it's a dedicated account that is not used for anything else. This will avoid headaches due
 * to sudden errors when trying to call a function from the proxy implementation.
 *
 * Our recommendation is for the dedicated account to be an instance of the {ProxyAdmin} contract. If set up this way,
 * you should think of the `ProxyAdmin` instance as the real administrative interface of your proxy.
 */
contract TransparentUpgradeableProxy is ERC1967Proxy {
    /**
     * @dev Initializes an upgradeable proxy managed by `_admin`, backed by the implementation at `_logic`, and
     * optionally initialized with `_data` as explained in {ERC1967Proxy-constructor}.
     */
    constructor(address _logic, address admin_, bytes memory _data) payable ERC1967Proxy(_logic, _data) {
        assert(_ADMIN_SLOT == bytes32(uint256(keccak256("eip1967.proxy.admin")) - 1));
        _changeAdmin(admin_);
    }
    /**
     * @dev Modifier used internally that will delegate the call to the implementation unless the sender is the admin.
     */
    modifier ifAdmin() {
        if (msg.sender == _getAdmin()) {
            _;
        } else {
            _fallback();
        }
    }
    /**
     * @dev Returns the current admin.
     *
     * NOTE: Only the admin can call this function. See {ProxyAdmin-getProxyAdmin}.
     *
     * TIP: To get this value clients can read directly from the storage slot shown below (specified by EIP1967) using the
     * https://eth.wiki/json-rpc/API#eth_getstorageat[`eth_getStorageAt`] RPC call.
     * `0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103`
     */
    function admin() external ifAdmin returns (address admin_) {
        admin_ = _getAdmin();
    }
    /**
     * @dev Returns the current implementation.
     *
     * NOTE: Only the admin can call this function. See {ProxyAdmin-getProxyImplementation}.
     *
     * TIP: To get this value clients can read directly from the storage slot shown below (specified by EIP1967) using the
     * https://eth.wiki/json-rpc/API#eth_getstorageat[`eth_getStorageAt`] RPC call.
     * `0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc`
     */
    function implementation() external ifAdmin returns (address implementation_) {
        implementation_ = _implementation();
    }
    /**
     * @dev Changes the admin of the proxy.
     *
     * Emits an {AdminChanged} event.
     *
     * NOTE: Only the admin can call this function. See {ProxyAdmin-changeProxyAdmin}.
     */
    function changeAdmin(address newAdmin) external virtual ifAdmin {
        _changeAdmin(newAdmin);
    }
    /**
     * @dev Upgrade the implementation of the proxy.
     *
     * NOTE: Only the admin can call this function. See {ProxyAdmin-upgrade}.
     */
    function upgradeTo(address newImplementation) external ifAdmin {
        _upgradeToAndCall(newImplementation, bytes(""), false);
    }
    /**
     * @dev Upgrade the implementation of the proxy, and then call a function from the new implementation as specified
     * by `data`, which should be an encoded function call. This is useful to initialize new storage variables in the
     * proxied contract.
     *
     * NOTE: Only the admin can call this function. See {ProxyAdmin-upgradeAndCall}.
     */
    function upgradeToAndCall(address newImplementation, bytes calldata data) external payable ifAdmin {
        _upgradeToAndCall(newImplementation, data, true);
    }
    /**
     * @dev Returns the current admin.
     */
    function _admin() internal view virtual returns (address) {
        return _getAdmin();
    }
    /**
     * @dev Makes sure the admin cannot access the fallback function. See {Proxy-_beforeFallback}.
     */
    function _beforeFallback() internal virtual override {
        require(msg.sender != _getAdmin(), "TransparentUpgradeableProxy: admin cannot fallback to proxy target");
        super._beforeFallback();
    }
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "./TransparentUpgradeableProxy.sol";
import "../../access/Ownable.sol";
/**
 * @dev This is an auxiliary contract meant to be assigned as the admin of a {TransparentUpgradeableProxy}. For an
 * explanation of why you would want to use this see the documentation for {TransparentUpgradeableProxy}.
 */
contract ProxyAdmin is Ownable {
    /**
     * @dev Returns the current implementation of `proxy`.
     *
     * Requirements:
     *
     * - This contract must be the admin of `proxy`.
     */
    function getProxyImplementation(TransparentUpgradeableProxy proxy) public view virtual returns (address) {
        // We need to manually run the static call since the getter cannot be flagged as view
        // bytes4(keccak256("implementation()")) == 0x5c60da1b
        (bool success, bytes memory returndata) = address(proxy).staticcall(hex"5c60da1b");
        require(success);
        return abi.decode(returndata, (address));
    }
    /**
     * @dev Returns the current admin of `proxy`.
     *
     * Requirements:
     *
     * - This contract must be the admin of `proxy`.
     */
    function getProxyAdmin(TransparentUpgradeableProxy proxy) public view virtual returns (address) {
        // We need to manually run the static call since the getter cannot be flagged as view
        // bytes4(keccak256("admin()")) == 0xf851a440
        (bool success, bytes memory returndata) = address(proxy).staticcall(hex"f851a440");
        require(success);
        return abi.decode(returndata, (address));
    }
    /**
     * @dev Changes the admin of `proxy` to `newAdmin`.
     *
     * Requirements:
     *
     * - This contract must be the current admin of `proxy`.
     */
    function changeProxyAdmin(TransparentUpgradeableProxy proxy, address newAdmin) public virtual onlyOwner {
        proxy.changeAdmin(newAdmin);
    }
    /**
     * @dev Upgrades `proxy` to `implementation`. See {TransparentUpgradeableProxy-upgradeTo}.
     *
     * Requirements:
     *
     * - This contract must be the admin of `proxy`.
     */
    function upgrade(TransparentUpgradeableProxy proxy, address implementation) public virtual onlyOwner {
        proxy.upgradeTo(implementation);
    }
    /**
     * @dev Upgrades `proxy` to `implementation` and calls a function on the new implementation. See
     * {TransparentUpgradeableProxy-upgradeToAndCall}.
     *
     * Requirements:
     *
     * - This contract must be the admin of `proxy`.
     */
    function upgradeAndCall(TransparentUpgradeableProxy proxy, address implementation, bytes memory data) public payable virtual onlyOwner {
        proxy.upgradeToAndCall{value: msg.value}(implementation, data);
    }
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
 * @dev This abstract contract provides a fallback function that delegates all calls to another contract using the EVM
 * instruction `delegatecall`. We refer to the second contract as the _implementation_ behind the proxy, and it has to
 * be specified by overriding the virtual {_implementation} function.
 *
 * Additionally, delegation to the implementation can be triggered manually through the {_fallback} function, or to a
 * different contract through the {_delegate} function.
 *
 * The success and return data of the delegated call will be returned back to the caller of the proxy.
 */
abstract contract Proxy {
    /**
     * @dev Delegates the current call to `implementation`.
     *
     * This function does not return to its internall call site, it will return directly to the external caller.
     */
    function _delegate(address implementation) internal virtual {
        // solhint-disable-next-line no-inline-assembly
        assembly {
            // Copy msg.data. We take full control of memory in this inline assembly
            // block because it will not return to Solidity code. We overwrite the
            // Solidity scratch pad at memory position 0.
            calldatacopy(0, 0, calldatasize())
            // Call the implementation.
            // out and outsize are 0 because we don't know the size yet.
            let result := delegatecall(gas(), implementation, 0, calldatasize(), 0, 0)
            // Copy the returned data.
            returndatacopy(0, 0, returndatasize())
            switch result
            // delegatecall returns 0 on error.
            case 0 { revert(0, returndatasize()) }
            default { return(0, returndatasize()) }
        }
    }
    /**
     * @dev This is a virtual function that should be overriden so it returns the address to which the fallback function
     * and {_fallback} should delegate.
     */
    function _implementation() internal view virtual returns (address);
    /**
     * @dev Delegates the current call to the address returned by `_implementation()`.
     *
     * This function does not return to its internall call site, it will return directly to the external caller.
     */
    function _fallback() internal virtual {
        _beforeFallback();
        _delegate(_implementation());
    }
    /**
     * @dev Fallback function that delegates calls to the address returned by `_implementation()`. Will run if no other
     * function in the contract matches the call data.
     */
    fallback () external payable virtual {
        _fallback();
    }
    /**
     * @dev Fallback function that delegates calls to the address returned by `_implementation()`. Will run if call data
     * is empty.
     */
    receive () external payable virtual {
        _fallback();
    }
    /**
     * @dev Hook that is called before falling back to the implementation. Can happen as part of a manual `_fallback`
     * call, or as part of the Solidity `fallback` or `receive` functions.
     *
     * If overriden should call `super._beforeFallback()`.
     */
    function _beforeFallback() internal virtual {
    }
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.2;
import "../beacon/IBeacon.sol";
import "../../utils/Address.sol";
import "../../utils/StorageSlot.sol";
/**
 * @dev This abstract contract provides getters and event emitting update functions for
 * https://eips.ethereum.org/EIPS/eip-1967[EIP1967] slots.
 *
 * _Available since v4.1._
 *
 * @custom:oz-upgrades-unsafe-allow delegatecall
 */
abstract contract ERC1967Upgrade {
    // This is the keccak-256 hash of "eip1967.proxy.rollback" subtracted by 1
    bytes32 private constant _ROLLBACK_SLOT = 0x4910fdfa16fed3260ed0e7147f7cc6da11a60208b5b9406d12a635614ffd9143;
    /**
     * @dev Storage slot with the address of the current implementation.
     * This is the keccak-256 hash of "eip1967.proxy.implementation" subtracted by 1, and is
     * validated in the constructor.
     */
    bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
    /**
     * @dev Emitted when the implementation is upgraded.
     */
    event Upgraded(address indexed implementation);
    /**
     * @dev Returns the current implementation address.
     */
    function _getImplementation() internal view returns (address) {
        return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
    }
    /**
     * @dev Stores a new address in the EIP1967 implementation slot.
     */
    function _setImplementation(address newImplementation) private {
        require(Address.isContract(newImplementation), "ERC1967: new implementation is not a contract");
        StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
    }
    /**
     * @dev Perform implementation upgrade
     *
     * Emits an {Upgraded} event.
     */
    function _upgradeTo(address newImplementation) internal {
        _setImplementation(newImplementation);
        emit Upgraded(newImplementation);
    }
    /**
     * @dev Perform implementation upgrade with additional setup call.
     *
     * Emits an {Upgraded} event.
     */
    function _upgradeToAndCall(address newImplementation, bytes memory data, bool forceCall) internal {
        _setImplementation(newImplementation);
        emit Upgraded(newImplementation);
        if (data.length > 0 || forceCall) {
            Address.functionDelegateCall(newImplementation, data);
        }
    }
    /**
     * @dev Perform implementation upgrade with security checks for UUPS proxies, and additional setup call.
     *
     * Emits an {Upgraded} event.
     */
    function _upgradeToAndCallSecure(address newImplementation, bytes memory data, bool forceCall) internal {
        address oldImplementation = _getImplementation();
        // Initial upgrade and setup call
        _setImplementation(newImplementation);
        if (data.length > 0 || forceCall) {
            Address.functionDelegateCall(newImplementation, data);
        }
        // Perform rollback test if not already in progress
        StorageSlot.BooleanSlot storage rollbackTesting = StorageSlot.getBooleanSlot(_ROLLBACK_SLOT);
        if (!rollbackTesting.value) {
            // Trigger rollback using upgradeTo from the new implementation
            rollbackTesting.value = true;
            Address.functionDelegateCall(
                newImplementation,
                abi.encodeWithSignature(
                    "upgradeTo(address)",
                    oldImplementation
                )
            );
            rollbackTesting.value = false;
            // Check rollback was effective
            require(oldImplementation == _getImplementation(), "ERC1967Upgrade: upgrade breaks further upgrades");
            // Finally reset to the new implementation and log the upgrade
            _setImplementation(newImplementation);
            emit Upgraded(newImplementation);
        }
    }
    /**
     * @dev Perform beacon upgrade with additional setup call. Note: This upgrades the address of the beacon, it does
     * not upgrade the implementation contained in the beacon (see {UpgradeableBeacon-_setImplementation} for that).
     *
     * Emits a {BeaconUpgraded} event.
     */
    function _upgradeBeaconToAndCall(address newBeacon, bytes memory data, bool forceCall) internal {
        _setBeacon(newBeacon);
        emit BeaconUpgraded(newBeacon);
        if (data.length > 0 || forceCall) {
            Address.functionDelegateCall(IBeacon(newBeacon).implementation(), data);
        }
    }
    /**
     * @dev Storage slot with the admin of the contract.
     * This is the keccak-256 hash of "eip1967.proxy.admin" subtracted by 1, and is
     * validated in the constructor.
     */
    bytes32 internal constant _ADMIN_SLOT = 0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103;
    /**
     * @dev Emitted when the admin account has changed.
     */
    event AdminChanged(address previousAdmin, address newAdmin);
    /**
     * @dev Returns the current admin.
     */
    function _getAdmin() internal view returns (address) {
        return StorageSlot.getAddressSlot(_ADMIN_SLOT).value;
    }
    /**
     * @dev Stores a new address in the EIP1967 admin slot.
     */
    function _setAdmin(address newAdmin) private {
        require(newAdmin != address(0), "ERC1967: new admin is the zero address");
        StorageSlot.getAddressSlot(_ADMIN_SLOT).value = newAdmin;
    }
    /**
     * @dev Changes the admin of the proxy.
     *
     * Emits an {AdminChanged} event.
     */
    function _changeAdmin(address newAdmin) internal {
        emit AdminChanged(_getAdmin(), newAdmin);
        _setAdmin(newAdmin);
    }
    /**
     * @dev The storage slot of the UpgradeableBeacon contract which defines the implementation for this proxy.
     * This is bytes32(uint256(keccak256('eip1967.proxy.beacon')) - 1)) and is validated in the constructor.
     */
    bytes32 internal constant _BEACON_SLOT = 0xa3f0ad74e5423aebfd80d3ef4346578335a9a72aeaee59ff6cb3582b35133d50;
    /**
     * @dev Emitted when the beacon is upgraded.
     */
    event BeaconUpgraded(address indexed beacon);
    /**
     * @dev Returns the current beacon.
     */
    function _getBeacon() internal view returns (address) {
        return StorageSlot.getAddressSlot(_BEACON_SLOT).value;
    }
    /**
     * @dev Stores a new beacon in the EIP1967 beacon slot.
     */
    function _setBeacon(address newBeacon) private {
        require(
            Address.isContract(newBeacon),
            "ERC1967: new beacon is not a contract"
        );
        require(
            Address.isContract(IBeacon(newBeacon).implementation()),
            "ERC1967: beacon implementation is not a contract"
        );
        StorageSlot.getAddressSlot(_BEACON_SLOT).value = newBeacon;
    }
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
 * @dev This is the interface that {BeaconProxy} expects of its beacon.
 */
interface IBeacon {
    /**
     * @dev Must return an address that can be used as a delegate call target.
     *
     * {BeaconProxy} will check that this address is a contract.
     */
    function implementation() external view returns (address);
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.
        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }
    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");
        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }
    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }
    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");
        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: value }(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");
        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");
        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }
    function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly
                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
 * @dev Library for reading and writing primitive types to specific storage slots.
 *
 * Storage slots are often used to avoid storage conflict when dealing with upgradeable contracts.
 * This library helps with reading and writing to such slots without the need for inline assembly.
 *
 * The functions in this library return Slot structs that contain a `value` member that can be used to read or write.
 *
 * Example usage to set ERC1967 implementation slot:
 * ```
 * contract ERC1967 {
 *     bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
 *
 *     function _getImplementation() internal view returns (address) {
 *         return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
 *     }
 *
 *     function _setImplementation(address newImplementation) internal {
 *         require(Address.isContract(newImplementation), "ERC1967: new implementation is not a contract");
 *         StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
 *     }
 * }
 * ```
 *
 * _Available since v4.1 for `address`, `bool`, `bytes32`, and `uint256`._
 */
library StorageSlot {
    struct AddressSlot {
        address value;
    }
    struct BooleanSlot {
        bool value;
    }
    struct Bytes32Slot {
        bytes32 value;
    }
    struct Uint256Slot {
        uint256 value;
    }
    /**
     * @dev Returns an `AddressSlot` with member `value` located at `slot`.
     */
    function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
        assembly {
            r.slot := slot
        }
    }
    /**
     * @dev Returns an `BooleanSlot` with member `value` located at `slot`.
     */
    function getBooleanSlot(bytes32 slot) internal pure returns (BooleanSlot storage r) {
        assembly {
            r.slot := slot
        }
    }
    /**
     * @dev Returns an `Bytes32Slot` with member `value` located at `slot`.
     */
    function getBytes32Slot(bytes32 slot) internal pure returns (Bytes32Slot storage r) {
        assembly {
            r.slot := slot
        }
    }
    /**
     * @dev Returns an `Uint256Slot` with member `value` located at `slot`.
     */
    function getUint256Slot(bytes32 slot) internal pure returns (Uint256Slot storage r) {
        assembly {
            r.slot := slot
        }
    }
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;
    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }
    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }
    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }
    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }
    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }
    function _msgData() internal view virtual returns (bytes calldata) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "../ERC1967/ERC1967Upgrade.sol";
/**
 * @dev Base contract for building openzeppelin-upgrades compatible implementations for the {ERC1967Proxy}. It includes
 * publicly available upgrade functions that are called by the plugin and by the secure upgrade mechanism to verify
 * continuation of the upgradability.
 *
 * The {_authorizeUpgrade} function MUST be overridden to include access restriction to the upgrade mechanism.
 *
 * _Available since v4.1._
 */
abstract contract UUPSUpgradeable is ERC1967Upgrade {
    function upgradeTo(address newImplementation) external virtual {
        _authorizeUpgrade(newImplementation);
        _upgradeToAndCallSecure(newImplementation, bytes(""), false);
    }
    function upgradeToAndCall(address newImplementation, bytes memory data) external payable virtual {
        _authorizeUpgrade(newImplementation);
        _upgradeToAndCallSecure(newImplementation, data, true);
    }
    function _authorizeUpgrade(address newImplementation) internal virtual;
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.2;
import "@openzeppelin/contracts/proxy/utils/UUPSUpgradeable.sol";
abstract contract Proxiable is UUPSUpgradeable {
    function _authorizeUpgrade(address newImplementation) internal override {
        _beforeUpgrade(newImplementation);
    }
    function _beforeUpgrade(address newImplementation) internal virtual;
}
contract ChildOfProxiable is Proxiable {
    function _beforeUpgrade(address newImplementation) internal virtual override {}
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.7;
import "@openzeppelin/contracts-upgradeable/token/ERC20/ERC20Upgradeable.sol";
import "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import "@openzeppelin/contracts-upgradeable/token/ERC20/utils/SafeERC20Upgradeable.sol";
import "@openzeppelin/contracts-upgradeable/security/PausableUpgradeable.sol";
import "./interfaces/IValidatorShare.sol";
import "./interfaces/IValidatorRegistry.sol";
import "./interfaces/IStakeManager.sol";
import "./interfaces/IMaticX.sol";
import "./interfaces/IFxStateRootTunnel.sol";
contract MaticX is
\tIMaticX,
\tERC20Upgradeable,
\tAccessControlUpgradeable,
\tPausableUpgradeable
{
\tusing SafeERC20Upgradeable for IERC20Upgradeable;
\taddress private validatorRegistry;
\taddress private stakeManager;
\taddress private polygonERC20;
\taddress public override treasury;
\tstring public override version;
\tuint8 public override feePercent;
\tbytes32 public constant INSTANT_POOL_OWNER = keccak256("IPO");
\taddress public override instantPoolOwner;
\tuint256 public override instantPoolMatic;
\tuint256 public override instantPoolMaticX;
\t/// @notice Mapping of all user ids with withdraw requests.
\tmapping(address => WithdrawalRequest[]) private userWithdrawalRequests;
\tbytes32 public constant PREDICATE_ROLE = keccak256("PREDICATE_ROLE");
\taddress public override fxStateRootTunnel;
\tbytes32 public constant BOT = keccak256("BOT");
\t/**
\t * @param _validatorRegistry - Address of the validator registry
\t * @param _stakeManager - Address of the stake manager
\t * @param _polygonERC20 - Address of matic token on Ethereum
\t * @param _manager - Address of the manager
\t * @param _instantPoolOwner - Address of the instant pool owner
\t * @param _treasury - Address of the treasury
\t */
\tfunction initialize(
\t\taddress _validatorRegistry,
\t\taddress _stakeManager,
\t\taddress _polygonERC20,
\t\taddress _manager,
\t\taddress _instantPoolOwner,
\t\taddress _treasury
\t) external override initializer {
\t\t__AccessControl_init();
\t\t__Pausable_init();
\t\t__ERC20_init("Liquid Staking Matic", "MaticX");
\t\t_setupRole(DEFAULT_ADMIN_ROLE, _manager);
\t\t_setupRole(INSTANT_POOL_OWNER, _instantPoolOwner);
\t\tinstantPoolOwner = _instantPoolOwner;
\t\tvalidatorRegistry = _validatorRegistry;
\t\tstakeManager = _stakeManager;
\t\ttreasury = _treasury;
\t\tpolygonERC20 = _polygonERC20;
\t\tfeePercent = 5;
\t\tIERC20Upgradeable(polygonERC20).safeApprove(
\t\t\tstakeManager,
\t\t\ttype(uint256).max
\t\t);
\t}
\tfunction setupBotAdmin()
\t\texternal
\t\toverride
\t\twhenNotPaused
\t\tonlyRole(DEFAULT_ADMIN_ROLE)
\t{
\t\t_setRoleAdmin(BOT, INSTANT_POOL_OWNER);
\t}
\t////////////////////////////////////////////////////////////
\t/////                                                    ///
\t/////             ***Instant Pool Interactions***        ///
\t/////                                                    ///
\t////////////////////////////////////////////////////////////
\t// Uses instantPoolOwner funds.
\tfunction provideInstantPoolMatic(uint256 _amount)
\t\texternal
\t\toverride
\t\twhenNotPaused
\t\tonlyRole(INSTANT_POOL_OWNER)
\t{
\t\trequire(_amount > 0, "Invalid amount");
\t\tIERC20Upgradeable(polygonERC20).safeTransferFrom(
\t\t\tmsg.sender,
\t\t\taddress(this),
\t\t\t_amount
\t\t);
\t\tinstantPoolMatic += _amount;
\t}
\tfunction provideInstantPoolMaticX(uint256 _amount)
\t\texternal
\t\toverride
\t\twhenNotPaused
\t\tonlyRole(INSTANT_POOL_OWNER)
\t{
\t\trequire(_amount > 0, "Invalid amount");
\t\tIERC20Upgradeable(address(this)).safeTransferFrom(
\t\t\tmsg.sender,
\t\t\taddress(this),
\t\t\t_amount
\t\t);
\t\tinstantPoolMaticX += _amount;
\t}
\tfunction withdrawInstantPoolMaticX(uint256 _amount)
\t\texternal
\t\toverride
\t\twhenNotPaused
\t\tonlyRole(INSTANT_POOL_OWNER)
\t{
\t\trequire(
\t\t\tinstantPoolMaticX >= _amount,
\t\t\t"Withdraw amount cannot exceed maticX in instant pool"
\t\t);
\t\tinstantPoolMaticX -= _amount;
\t\tIERC20Upgradeable(address(this)).safeTransfer(
\t\t\tinstantPoolOwner,
\t\t\t_amount
\t\t);
\t}
\tfunction withdrawInstantPoolMatic(uint256 _amount)
\t\texternal
\t\toverride
\t\twhenNotPaused
\t\tonlyRole(INSTANT_POOL_OWNER)
\t{
\t\trequire(
\t\t\tinstantPoolMatic >= _amount,
\t\t\t"Withdraw amount cannot exceed matic in instant pool"
\t\t);
\t\tinstantPoolMatic -= _amount;
\t\tIERC20Upgradeable(polygonERC20).safeTransfer(instantPoolOwner, _amount);
\t}
\t// Uses instantPoolMatic funds
\tfunction mintMaticXToInstantPool()
\t\texternal
\t\toverride
\t\twhenNotPaused
\t\tonlyRole(INSTANT_POOL_OWNER)
\t{
\t\trequire(instantPoolMatic > 0, "Matic amount cannot be 0");
\t\tuint256 maticxMinted = helper_delegate_to_mint(
\t\t\taddress(this),
\t\t\tinstantPoolMatic
\t\t);
\t\tinstantPoolMaticX += maticxMinted;
\t\tinstantPoolMatic = 0;
\t}
\tfunction swapMaticForMaticXViaInstantPool(uint256 _amount)
\t\texternal
\t\toverride
\t\twhenNotPaused
\t{
\t\trequire(_amount > 0, "Invalid amount");
\t\tIERC20Upgradeable(polygonERC20).safeTransferFrom(
\t\t\tmsg.sender,
\t\t\taddress(this),
\t\t\t_amount
\t\t);
\t\t(uint256 amountToMint, , ) = convertMaticToMaticX(_amount);
\t\trequire(
\t\t\tinstantPoolMaticX >= amountToMint,
\t\t\t"Not enough maticX to instant swap"
\t\t);
\t\tIERC20Upgradeable(address(this)).safeTransfer(msg.sender, amountToMint);
\t\tinstantPoolMatic += _amount;
\t\tinstantPoolMaticX -= amountToMint;
\t}
\t////////////////////////////////////////////////////////////
\t/////                                                    ///
\t/////             ***Staking Contract Interactions***    ///
\t/////                                                    ///
\t////////////////////////////////////////////////////////////
\t/**
\t * @dev Send funds to MaticX contract and mints MaticX to msg.sender
\t * @notice Requires that msg.sender has approved _amount of MATIC to this contract
\t * @param _amount - Amount of MATIC sent from msg.sender to this contract
\t * @return Amount of MaticX shares generated
\t */
\tfunction submit(uint256 _amount)
\t\texternal
\t\toverride
\t\twhenNotPaused
\t\treturns (uint256)
\t{
\t\trequire(_amount > 0, "Invalid amount");
\t\tIERC20Upgradeable(polygonERC20).safeTransferFrom(
\t\t\tmsg.sender,
\t\t\taddress(this),
\t\t\t_amount
\t\t);
\t\treturn helper_delegate_to_mint(msg.sender, _amount);
\t}
\t/**
\t * @dev Stores user's request to withdraw into WithdrawalRequest struct
\t * @param _amount - Amount of maticX that is requested to withdraw
\t */
\tfunction requestWithdraw(uint256 _amount) external override whenNotPaused {
\t\trequire(_amount > 0, "Invalid amount");
\t\t(
\t\t\tuint256 totalAmount2WithdrawInMatic,
\t\t\tuint256 totalShares,
\t\t\tuint256 totalPooledMatic
\t\t) = convertMaticXToMatic(_amount);
\t\t_burn(msg.sender, _amount);
\t\tuint256 leftAmount2WithdrawInMatic = totalAmount2WithdrawInMatic;
\t\tuint256 totalDelegated = getTotalStakeAcrossAllValidators();
\t\trequire(
\t\t\ttotalDelegated >= totalAmount2WithdrawInMatic,
\t\t\t"Too much to withdraw"
\t\t);
\t\tuint256[] memory validators = IValidatorRegistry(validatorRegistry)
\t\t\t.getValidators();
\t\tuint256 preferredValidatorId = IValidatorRegistry(validatorRegistry)
\t\t\t.preferredWithdrawalValidatorId();
\t\tuint256 currentIdx = 0;
\t\tfor (; currentIdx < validators.length; ++currentIdx) {
\t\t\tif (preferredValidatorId == validators[currentIdx]) break;
\t\t}
\t\twhile (leftAmount2WithdrawInMatic > 0) {
\t\t\tuint256 validatorId = validators[currentIdx];
\t\t\taddress validatorShare = IStakeManager(stakeManager)
\t\t\t\t.getValidatorContract(validatorId);
\t\t\t(uint256 validatorBalance, ) = getTotalStake(
\t\t\t\tIValidatorShare(validatorShare)
\t\t\t);
\t\t\tuint256 amount2WithdrawFromValidator = (validatorBalance <=
\t\t\t\tleftAmount2WithdrawInMatic)
\t\t\t\t? validatorBalance
\t\t\t\t: leftAmount2WithdrawInMatic;
\t\t\tIValidatorShare(validatorShare).sellVoucher_new(
\t\t\t\tamount2WithdrawFromValidator,
\t\t\t\ttype(uint256).max
\t\t\t);
\t\t\tuserWithdrawalRequests[msg.sender].push(
\t\t\t\tWithdrawalRequest(
\t\t\t\t\tIValidatorShare(validatorShare).unbondNonces(address(this)),
\t\t\t\t\tIStakeManager(stakeManager).epoch() +
\t\t\t\t\t\tIStakeManager(stakeManager).withdrawalDelay(),
\t\t\t\t\tvalidatorShare
\t\t\t\t)
\t\t\t);
\t\t\tleftAmount2WithdrawInMatic -= amount2WithdrawFromValidator;
\t\t\tcurrentIdx = currentIdx + 1 < validators.length
\t\t\t\t? currentIdx + 1
\t\t\t\t: 0;
\t\t}
\t\tIFxStateRootTunnel(fxStateRootTunnel).sendMessageToChild(
\t\t\tabi.encode(
\t\t\t\ttotalShares - _amount,
\t\t\t\ttotalPooledMatic - totalAmount2WithdrawInMatic
\t\t\t)
\t\t);
\t\temit RequestWithdraw(msg.sender, _amount, totalAmount2WithdrawInMatic);
\t}
\t/**
\t * @dev Claims tokens from validator share and sends them to the
\t * address if the request is in the userWithdrawalRequests
\t * @param _idx - User withdrawal request array index
\t */
\tfunction claimWithdrawal(uint256 _idx) external override whenNotPaused {
\t\t_claimWithdrawal(msg.sender, _idx);
\t}
\tfunction _withdrawRewards(uint256 _validatorId) internal returns (uint256) {
\t\taddress validatorShare = IStakeManager(stakeManager)
\t\t\t.getValidatorContract(_validatorId);
\t\tuint256 balanceBeforeRewards = IERC20Upgradeable(polygonERC20)
\t\t\t.balanceOf(address(this));
\t\tIValidatorShare(validatorShare).withdrawRewards();
\t\tuint256 rewards = IERC20Upgradeable(polygonERC20).balanceOf(
\t\t\taddress(this)
\t\t) - balanceBeforeRewards;
\t\temit WithdrawRewards(_validatorId, rewards);
\t\treturn rewards;
\t}
\t/**
\t * @dev This function is deprecated. Please use withdrawValidatorsReward instead.
\t */
\tfunction withdrawRewards(uint256 _validatorId)
\t\tpublic
\t\toverride
\t\twhenNotPaused
\t\treturns (uint256)
\t{
\t\treturn _withdrawRewards(_validatorId);
\t}
\tfunction withdrawValidatorsReward(uint256[] calldata _validatorIds)
\t\tpublic
\t\toverride
\t\twhenNotPaused
\t\treturns (uint256[] memory)
\t{
\t\tuint256[] memory rewards = new uint256[](_validatorIds.length);
\t\tfor (uint256 i = 0; i < _validatorIds.length; i++) {
\t\t\trewards[i] = _withdrawRewards(_validatorIds[i]);
\t\t}
\t\treturn rewards;
\t}
\tfunction stakeRewardsAndDistributeFees(uint256 _validatorId)
\t\texternal
\t\toverride
\t\twhenNotPaused
\t\tonlyRole(BOT)
\t{
\t\trequire(
\t\t\tIValidatorRegistry(validatorRegistry).validatorIdExists(
\t\t\t\t_validatorId
\t\t\t),
\t\t\t"Doesn't exist in validator registry"
\t\t);
\t\taddress validatorShare = IStakeManager(stakeManager)
\t\t\t.getValidatorContract(_validatorId);
\t\tuint256 rewards = IERC20Upgradeable(polygonERC20).balanceOf(
\t\t\taddress(this)
\t\t) - instantPoolMatic;
\t\trequire(rewards > 0, "Reward is zero");
\t\tuint256 treasuryFees = (rewards * feePercent) / 100;
\t\tif (treasuryFees > 0) {
\t\t\tIERC20Upgradeable(polygonERC20).safeTransfer(
\t\t\t\ttreasury,
\t\t\t\ttreasuryFees
\t\t\t);
\t\t\temit DistributeFees(treasury, treasuryFees);
\t\t}
\t\tuint256 amountStaked = rewards - treasuryFees;
\t\tIValidatorShare(validatorShare).buyVoucher(amountStaked, 0);
\t\tuint256 totalShares = totalSupply();
\t\tuint256 totalPooledMatic = getTotalPooledMatic();
\t\tIFxStateRootTunnel(fxStateRootTunnel).sendMessageToChild(
\t\t\tabi.encode(totalShares, totalPooledMatic)
\t\t);
\t\temit StakeRewards(_validatorId, amountStaked);
\t}
\t/**
\t * @dev Migrate the staked tokens to another validaor
\t */
\tfunction migrateDelegation(
\t\tuint256 _fromValidatorId,
\t\tuint256 _toValidatorId,
\t\tuint256 _amount
\t) external override whenNotPaused onlyRole(INSTANT_POOL_OWNER) {
\t\trequire(
\t\t\tIValidatorRegistry(validatorRegistry).validatorIdExists(
\t\t\t\t_fromValidatorId
\t\t\t),
\t\t\t"From validator id does not exist in our registry"
\t\t);
\t\trequire(
\t\t\tIValidatorRegistry(validatorRegistry).validatorIdExists(
\t\t\t\t_toValidatorId
\t\t\t),
\t\t\t"To validator id does not exist in our registry"
\t\t);
\t\tIStakeManager(stakeManager).migrateDelegation(
\t\t\t_fromValidatorId,
\t\t\t_toValidatorId,
\t\t\t_amount
\t\t);
\t\temit MigrateDelegation(_fromValidatorId, _toValidatorId, _amount);
\t}
\t/**
\t * @dev Flips the pause state
\t */
\tfunction togglePause() external override onlyRole(DEFAULT_ADMIN_ROLE) {
\t\tpaused() ? _unpause() : _pause();
\t}
\t/**
\t * @dev API for getting total stake of this contract from validatorShare
\t * @param _validatorShare - Address of validatorShare contract
\t * @return Total stake of this contract and MATIC -> share exchange rate
\t */
\tfunction getTotalStake(IValidatorShare _validatorShare)
\t\tpublic
\t\tview
\t\toverride
\t\treturns (uint256, uint256)
\t{
\t\treturn _validatorShare.getTotalStake(address(this));
\t}
\t////////////////////////////////////////////////////////////
\t/////                                                    ///
\t/////            ***Helpers & Utilities***               ///
\t/////                                                    ///
\t////////////////////////////////////////////////////////////
\tfunction helper_delegate_to_mint(address deposit_sender, uint256 _amount)
\t\tinternal
\t\twhenNotPaused
\t\treturns (uint256)
\t{
\t\t(
\t\t\tuint256 amountToMint,
\t\t\tuint256 totalShares,
\t\t\tuint256 totalPooledMatic
\t\t) = convertMaticToMaticX(_amount);
\t\t_mint(deposit_sender, amountToMint);
\t\temit Submit(deposit_sender, _amount);
\t\tuint256 preferredValidatorId = IValidatorRegistry(validatorRegistry)
\t\t\t.preferredDepositValidatorId();
\t\taddress validatorShare = IStakeManager(stakeManager)
\t\t\t.getValidatorContract(preferredValidatorId);
\t\tIValidatorShare(validatorShare).buyVoucher(_amount, 0);
\t\tIFxStateRootTunnel(fxStateRootTunnel).sendMessageToChild(
\t\t\tabi.encode(totalShares + amountToMint, totalPooledMatic + _amount)
\t\t);
\t\temit Delegate(preferredValidatorId, _amount);
\t\treturn amountToMint;
\t}
\t/**
\t * @dev Claims tokens from validator share and sends them to the
\t * address if the request is in the userWithdrawalRequests
\t * @param _to - Address of the withdrawal request owner
\t * @param _idx - User withdrawal request array index
\t */
\tfunction _claimWithdrawal(address _to, uint256 _idx)
\t\tinternal
\t\treturns (uint256)
\t{
\t\tuint256 amountToClaim = 0;
\t\tuint256 balanceBeforeClaim = IERC20Upgradeable(polygonERC20).balanceOf(
\t\t\taddress(this)
\t\t);
\t\tWithdrawalRequest[] storage userRequests = userWithdrawalRequests[_to];
\t\tWithdrawalRequest memory userRequest = userRequests[_idx];
\t\trequire(
\t\t\tIStakeManager(stakeManager).epoch() >= userRequest.requestEpoch,
\t\t\t"Not able to claim yet"
\t\t);
\t\tIValidatorShare(userRequest.validatorAddress).unstakeClaimTokens_new(
\t\t\tuserRequest.validatorNonce
\t\t);
\t\t// swap with the last item and pop it.
\t\tuserRequests[_idx] = userRequests[userRequests.length - 1];
\t\tuserRequests.pop();
\t\tamountToClaim =
\t\t\tIERC20Upgradeable(polygonERC20).balanceOf(address(this)) -
\t\t\tbalanceBeforeClaim;
\t\tIERC20Upgradeable(polygonERC20).safeTransfer(_to, amountToClaim);
\t\temit ClaimWithdrawal(_to, _idx, amountToClaim);
\t\treturn amountToClaim;
\t}
\t/**
\t * @dev Function that converts arbitrary maticX to Matic
\t * @param _balance - Balance in maticX
\t * @return Balance in Matic, totalShares and totalPooledMATIC
\t */
\tfunction convertMaticXToMatic(uint256 _balance)
\t\tpublic
\t\tview
\t\toverride
\t\treturns (
\t\t\tuint256,
\t\t\tuint256,
\t\t\tuint256
\t\t)
\t{
\t\tuint256 totalShares = totalSupply();
\t\ttotalShares = totalShares == 0 ? 1 : totalShares;
\t\tuint256 totalPooledMATIC = getTotalPooledMatic();
\t\ttotalPooledMATIC = totalPooledMATIC == 0 ? 1 : totalPooledMATIC;
\t\tuint256 balanceInMATIC = (_balance * (totalPooledMATIC)) / totalShares;
\t\treturn (balanceInMATIC, totalShares, totalPooledMATIC);
\t}
\t/**
\t * @dev Function that converts arbitrary Matic to maticX
\t * @param _balance - Balance in Matic
\t * @return Balance in maticX, totalShares and totalPooledMATIC
\t */
\tfunction convertMaticToMaticX(uint256 _balance)
\t\tpublic
\t\tview
\t\toverride
\t\treturns (
\t\t\tuint256,
\t\t\tuint256,
\t\t\tuint256
\t\t)
\t{
\t\tuint256 totalShares = totalSupply();
\t\ttotalShares = totalShares == 0 ? 1 : totalShares;
\t\tuint256 totalPooledMatic = getTotalPooledMatic();
\t\ttotalPooledMatic = totalPooledMatic == 0 ? 1 : totalPooledMatic;
\t\tuint256 balanceInMaticX = (_balance * totalShares) / totalPooledMatic;
\t\treturn (balanceInMaticX, totalShares, totalPooledMatic);
\t}
\t// TODO: Add logic and enable it in V2
\tfunction mint(address _user, uint256 _amount)
\t\texternal
\t\toverride
\t\twhenNotPaused
\t\tonlyRole(PREDICATE_ROLE)
\t{
\t\temit MintFromPolygon(_user, _amount);
\t}
\t////////////////////////////////////////////////////////////
\t/////                                                    ///
\t/////                 ***Setters***                      ///
\t/////                                                    ///
\t////////////////////////////////////////////////////////////
\t/**
\t * @dev Function that sets fee percent
\t * @notice Callable only by manager
\t * @param _feePercent - Fee percent (10 = 10%)
\t */
\tfunction setFeePercent(uint8 _feePercent)
\t\texternal
\t\toverride
\t\tonlyRole(DEFAULT_ADMIN_ROLE)
\t{
\t\trequire(_feePercent <= 100, "_feePercent must not exceed 100");
\t\tfeePercent = _feePercent;
\t\temit SetFeePercent(_feePercent);
\t}
\tfunction setInstantPoolOwner(address _address)
\t\texternal
\t\toverride
\t\tonlyRole(DEFAULT_ADMIN_ROLE)
\t{
\t\trequire(instantPoolOwner != _address, "Old address == new address");
\t\t_revokeRole(INSTANT_POOL_OWNER, instantPoolOwner);
\t\tinstantPoolOwner = _address;
\t\t_setupRole(INSTANT_POOL_OWNER, _address);
\t\temit SetInstantPoolOwner(_address);
\t}
\tfunction setTreasury(address _address)
\t\texternal
\t\toverride
\t\tonlyRole(INSTANT_POOL_OWNER)
\t{
\t\ttreasury = _address;
\t\temit SetTreasury(_address);
\t}
\tfunction setValidatorRegistry(address _address)
\t\texternal
\t\toverride
\t\tonlyRole(DEFAULT_ADMIN_ROLE)
\t{
\t\tvalidatorRegistry = _address;
\t\temit SetValidatorRegistry(_address);
\t}
\tfunction setFxStateRootTunnel(address _address)
\t\texternal
\t\toverride
\t\tonlyRole(DEFAULT_ADMIN_ROLE)
\t{
\t\tfxStateRootTunnel = _address;
\t\temit SetFxStateRootTunnel(_address);
\t}
\t/**
\t * @dev Function that sets the new version
\t * @param _version - New version that will be set
\t */
\tfunction setVersion(string calldata _version)
\t\texternal
\t\toverride
\t\tonlyRole(DEFAULT_ADMIN_ROLE)
\t{
\t\tversion = _version;
\t\temit SetVersion(_version);
\t}
\t////////////////////////////////////////////////////////////
\t/////                                                    ///
\t/////                 ***Getters***                      ///
\t/////                                                    ///
\t////////////////////////////////////////////////////////////
\t/**
\t * @dev Helper function for that returns total pooled MATIC
\t * @return Total pooled MATIC
\t */
\tfunction getTotalStakeAcrossAllValidators()
\t\tpublic
\t\tview
\t\toverride
\t\treturns (uint256)
\t{
\t\tuint256 totalStake;
\t\tuint256[] memory validators = IValidatorRegistry(validatorRegistry)
\t\t\t.getValidators();
\t\tfor (uint256 i = 0; i < validators.length; ++i) {
\t\t\taddress validatorShare = IStakeManager(stakeManager)
\t\t\t\t.getValidatorContract(validators[i]);
\t\t\t(uint256 currValidatorShare, ) = getTotalStake(
\t\t\t\tIValidatorShare(validatorShare)
\t\t\t);
\t\t\ttotalStake += currValidatorShare;
\t\t}
\t\treturn totalStake;
\t}
\t/**
\t * @dev Function that calculates total pooled Matic
\t * @return Total pooled Matic
\t */
\tfunction getTotalPooledMatic() public view override returns (uint256) {
\t\tuint256 totalStaked = getTotalStakeAcrossAllValidators();
\t\treturn totalStaked;
\t}
\t/**
\t * @dev Retrieves all withdrawal requests initiated by the given address
\t * @param _address - Address of an user
\t * @return userWithdrawalRequests array of user withdrawal requests
\t */
\tfunction getUserWithdrawalRequests(address _address)
\t\texternal
\t\tview
\t\toverride
\t\treturns (WithdrawalRequest[] memory)
\t{
\t\treturn userWithdrawalRequests[_address];
\t}
\t/**
\t * @dev Retrieves shares amount of a given withdrawal request
\t * @param _address - Address of an user
\t * @return _idx index of the withdrawal request
\t */
\tfunction getSharesAmountOfUserWithdrawalRequest(
\t\taddress _address,
\t\tuint256 _idx
\t) external view override returns (uint256) {
\t\tWithdrawalRequest memory userRequest = userWithdrawalRequests[_address][
\t\t\t_idx
\t\t];
\t\tIValidatorShare validatorShare = IValidatorShare(
\t\t\tuserRequest.validatorAddress
\t\t);
\t\tIValidatorShare.DelegatorUnbond memory unbond = validatorShare
\t\t\t.unbonds_new(address(this), userRequest.validatorNonce);
\t\treturn unbond.shares;
\t}
\tfunction getContracts()
\t\texternal
\t\tview
\t\toverride
\t\treturns (
\t\t\taddress _stakeManager,
\t\t\taddress _polygonERC20,
\t\t\taddress _validatorRegistry
\t\t)
\t{
\t\t_stakeManager = stakeManager;
\t\t_polygonERC20 = polygonERC20;
\t\t_validatorRegistry = validatorRegistry;
\t}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/ERC20.sol)
pragma solidity ^0.8.0;
import "./IERC20Upgradeable.sol";
import "./extensions/IERC20MetadataUpgradeable.sol";
import "../../utils/ContextUpgradeable.sol";
import "../../proxy/utils/Initializable.sol";
/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20Upgradeable is Initializable, ContextUpgradeable, IERC20Upgradeable, IERC20MetadataUpgradeable {
    mapping(address => uint256) private _balances;
    mapping(address => mapping(address => uint256)) private _allowances;
    uint256 private _totalSupply;
    string private _name;
    string private _symbol;
    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * The default value of {decimals} is 18. To select a different value for
     * {decimals} you should overload it.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    function __ERC20_init(string memory name_, string memory symbol_) internal onlyInitializing {
        __ERC20_init_unchained(name_, symbol_);
    }
    function __ERC20_init_unchained(string memory name_, string memory symbol_) internal onlyInitializing {
        _name = name_;
        _symbol = symbol_;
    }
    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }
    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }
    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless this function is
     * overridden;
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }
    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }
    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }
    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }
    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }
    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }
    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }
    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, _allowances[owner][spender] + addedValue);
        return true;
    }
    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = _allowances[owner][spender];
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }
        return true;
    }
    /**
     * @dev Moves `amount` of tokens from `sender` to `recipient`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");
        _beforeTokenTransfer(from, to, amount);
        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
        }
        _balances[to] += amount;
        emit Transfer(from, to, amount);
        _afterTokenTransfer(from, to, amount);
    }
    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");
        _beforeTokenTransfer(address(0), account, amount);
        _totalSupply += amount;
        _balances[account] += amount;
        emit Transfer(address(0), account, amount);
        _afterTokenTransfer(address(0), account, amount);
    }
    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");
        _beforeTokenTransfer(account, address(0), amount);
        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
        }
        _totalSupply -= amount;
        emit Transfer(account, address(0), amount);
        _afterTokenTransfer(account, address(0), amount);
    }
    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");
        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }
    /**
     * @dev Spend `amount` form the allowance of `owner` toward `spender`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }
    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[45] private __gap;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (access/AccessControl.sol)
pragma solidity ^0.8.0;
import "./IAccessControlUpgradeable.sol";
import "../utils/ContextUpgradeable.sol";
import "../utils/StringsUpgradeable.sol";
import "../utils/introspection/ERC165Upgradeable.sol";
import "../proxy/utils/Initializable.sol";
/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it.
 */
abstract contract AccessControlUpgradeable is Initializable, ContextUpgradeable, IAccessControlUpgradeable, ERC165Upgradeable {
    function __AccessControl_init() internal onlyInitializing {
    }
    function __AccessControl_init_unchained() internal onlyInitializing {
    }
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }
    mapping(bytes32 => RoleData) private _roles;
    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;
    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role, _msgSender());
        _;
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControlUpgradeable).interfaceId || super.supportsInterface(interfaceId);
    }
    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }
    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        StringsUpgradeable.toHexString(uint160(account), 20),
                        " is missing role ",
                        StringsUpgradeable.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }
    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }
    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }
    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }
    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");
        _revokeRole(role, account);
    }
    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }
    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }
    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }
    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }
    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20Upgradeable {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);
    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);
    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);
    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);
    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);
    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);
    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "../IERC20Upgradeable.sol";
import "../../../utils/AddressUpgradeable.sol";
/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20Upgradeable {
    using AddressUpgradeable for address;
    function safeTransfer(
        IERC20Upgradeable token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }
    function safeTransferFrom(
        IERC20Upgradeable token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }
    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20Upgradeable token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }
    function safeIncreaseAllowance(
        IERC20Upgradeable token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }
    function safeDecreaseAllowance(
        IERC20Upgradeable token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }
    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20Upgradeable token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.
        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (security/Pausable.sol)
pragma solidity ^0.8.0;
import "../utils/ContextUpgradeable.sol";
import "../proxy/utils/Initializable.sol";
/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract PausableUpgradeable is Initializable, ContextUpgradeable {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);
    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);
    bool private _paused;
    /**
     * @dev Initializes the contract in unpaused state.
     */
    function __Pausable_init() internal onlyInitializing {
        __Pausable_init_unchained();
    }
    function __Pausable_init_unchained() internal onlyInitializing {
        _paused = false;
    }
    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }
    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        require(!paused(), "Pausable: paused");
        _;
    }
    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        require(paused(), "Pausable: not paused");
        _;
    }
    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }
    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}
// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.7;
interface IValidatorShare {
\tstruct DelegatorUnbond {
\t\tuint256 shares;
\t\tuint256 withdrawEpoch;
\t}
\tfunction minAmount() external view returns (uint256);
\tfunction unbondNonces(address _address) external view returns (uint256);
\tfunction validatorId() external view returns (uint256);
\tfunction delegation() external view returns (bool);
\tfunction buyVoucher(uint256 _amount, uint256 _minSharesToMint)
\t\texternal
\t\treturns (uint256);
\tfunction sellVoucher_new(uint256 claimAmount, uint256 maximumSharesToBurn)
\t\texternal;
\tfunction unstakeClaimTokens_new(uint256 unbondNonce) external;
\tfunction restake() external returns (uint256, uint256);
\tfunction withdrawRewards() external;
\tfunction getTotalStake(address user)
\t\texternal
\t\tview
\t\treturns (uint256, uint256);
\tfunction unbonds_new(address _address, uint256 _unbondNonce)
\t\texternal
\t\tview
\t\treturns (DelegatorUnbond memory);
}
// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.7;
/// @title IValidatorRegistry
/// @notice Node validator registry interface
interface IValidatorRegistry {
\tfunction addValidator(uint256 _validatorId) external;
\tfunction removeValidator(uint256 _validatorId) external;
\tfunction setPreferredDepositValidatorId(uint256 _validatorId) external;
\tfunction setPreferredWithdrawalValidatorId(uint256 _validatorId) external;
\tfunction setMaticX(address _maticX) external;
\tfunction setVersion(string memory _version) external;
\tfunction togglePause() external;
\tfunction version() external view returns (string memory);
\tfunction preferredDepositValidatorId() external view returns (uint256);
\tfunction preferredWithdrawalValidatorId() external view returns (uint256);
\tfunction validatorIdExists(uint256 _validatorId)
\t\texternal
\t\tview
\t\treturns (bool);
\tfunction getContracts()
\t\texternal
\t\tview
\t\treturns (
\t\t\taddress _stakeManager,
\t\t\taddress _polygonERC20,
\t\t\taddress _maticX
\t\t);
\tfunction getValidatorId(uint256 _index) external view returns (uint256);
\tfunction getValidators() external view returns (uint256[] memory);
\tevent AddValidator(uint256 indexed _validatorId);
\tevent RemoveValidator(uint256 indexed _validatorId);
\tevent SetPreferredDepositValidatorId(uint256 indexed _validatorId);
\tevent SetPreferredWithdrawalValidatorId(uint256 indexed _validatorId);
\tevent SetMaticX(address _address);
\tevent SetVersion(string _version);
}
// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.7;
/// @title polygon stake manager interface.
/// @notice User to interact with the polygon stake manager.
interface IStakeManager {
\t/// @notice Request unstake a validator.
\t/// @param validatorId validator id.
\tfunction unstake(uint256 validatorId) external;
\t/// @notice Get the validator id using the user address.
\t/// @param user user that own the validator in our case the validator contract.
\t/// @return return the validator id
\tfunction getValidatorId(address user) external view returns (uint256);
\t/// @notice get the validator contract used for delegation.
\t/// @param validatorId validator id.
\t/// @return return the address of the validator contract.
\tfunction getValidatorContract(uint256 validatorId)
\t\texternal
\t\tview
\t\treturns (address);
\t/// @notice Withdraw accumulated rewards
\t/// @param validatorId validator id.
\tfunction withdrawRewards(uint256 validatorId) external;
\t/// @notice Get validator total staked.
\t/// @param validatorId validator id.
\tfunction validatorStake(uint256 validatorId)
\t\texternal
\t\tview
\t\treturns (uint256);
\t/// @notice Allows to unstake the staked tokens on the stakeManager.
\t/// @param validatorId validator id.
\tfunction unstakeClaim(uint256 validatorId) external;
\t/// @notice Allows to migrate the staked tokens to another validator.
\t/// @param fromValidatorId From validator id.
\t/// @param toValidatorId To validator id.
\t/// @param amount amount in Matic.
\tfunction migrateDelegation(
\t\tuint256 fromValidatorId,
\t\tuint256 toValidatorId,
\t\tuint256 amount
\t) external;
\t/// @notice Returns a withdrawal delay.
\tfunction withdrawalDelay() external view returns (uint256);
\t/// @notice Transfers amount from delegator
\tfunction delegationDeposit(
\t\tuint256 validatorId,
\t\tuint256 amount,
\t\taddress delegator
\t) external returns (bool);
\tfunction epoch() external view returns (uint256);
\tenum Status {
\t\tInactive,
\t\tActive,
\t\tLocked,
\t\tUnstaked
\t}
\tstruct Validator {
\t\tuint256 amount;
\t\tuint256 reward;
\t\tuint256 activationEpoch;
\t\tuint256 deactivationEpoch;
\t\tuint256 jailTime;
\t\taddress signer;
\t\taddress contractAddress;
\t\tStatus status;
\t\tuint256 commissionRate;
\t\tuint256 lastCommissionUpdate;
\t\tuint256 delegatorsReward;
\t\tuint256 delegatedAmount;
\t\tuint256 initialRewardPerStake;
\t}
\tfunction validators(uint256 _index)
\t\texternal
\t\tview
\t\treturns (Validator memory);
\t// TODO: Remove it and use stakeFor instead
\tfunction createValidator(uint256 _validatorId) external;
}
// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.7;
import "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import "./IValidatorShare.sol";
import "./IValidatorRegistry.sol";
/// @title MaticX interface.
interface IMaticX is IERC20Upgradeable {
\tstruct WithdrawalRequest {
\t\tuint256 validatorNonce;
\t\tuint256 requestEpoch;
\t\taddress validatorAddress;
\t}
\tfunction setupBotAdmin() external;
\tfunction version() external view returns (string memory);
\tfunction treasury() external view returns (address);
\tfunction feePercent() external view returns (uint8);
\tfunction instantPoolOwner() external view returns (address);
\tfunction instantPoolMatic() external view returns (uint256);
\tfunction instantPoolMaticX() external view returns (uint256);
\tfunction fxStateRootTunnel() external view returns (address);
\tfunction initialize(
\t\taddress _validatorRegistry,
\t\taddress _stakeManager,
\t\taddress _token,
\t\taddress _manager,
\t\taddress _instant_pool_manager,
\t\taddress _treasury
\t) external;
\tfunction provideInstantPoolMatic(uint256 _amount) external;
\tfunction provideInstantPoolMaticX(uint256 _amount) external;
\tfunction withdrawInstantPoolMaticX(uint256 _amount) external;
\tfunction withdrawInstantPoolMatic(uint256 _amount) external;
\tfunction mintMaticXToInstantPool() external;
\tfunction swapMaticForMaticXViaInstantPool(uint256 _amount) external;
\tfunction submit(uint256 _amount) external returns (uint256);
\tfunction requestWithdraw(uint256 _amount) external;
\tfunction claimWithdrawal(uint256 _idx) external;
\tfunction withdrawRewards(uint256 _validatorId) external returns (uint256);
\tfunction withdrawValidatorsReward(uint256[] calldata _validatorIds)
\t\texternal
\t\treturns (uint256[] memory);
\tfunction stakeRewardsAndDistributeFees(uint256 _validatorId) external;
\tfunction migrateDelegation(
\t\tuint256 _fromValidatorId,
\t\tuint256 _toValidatorId,
\t\tuint256 _amount
\t) external;
\tfunction togglePause() external;
\tfunction convertMaticXToMatic(uint256 _balance)
\t\texternal
\t\tview
\t\treturns (
\t\t\tuint256,
\t\t\tuint256,
\t\t\tuint256
\t\t);
\tfunction convertMaticToMaticX(uint256 _balance)
\t\texternal
\t\tview
\t\treturns (
\t\t\tuint256,
\t\t\tuint256,
\t\t\tuint256
\t\t);
\tfunction mint(address _user, uint256 _amount) external;
\tfunction setFeePercent(uint8 _feePercent) external;
\tfunction setInstantPoolOwner(address _address) external;
\tfunction setValidatorRegistry(address _address) external;
\tfunction setTreasury(address _address) external;
\tfunction setFxStateRootTunnel(address _address) external;
\tfunction setVersion(string calldata _version) external;
\tfunction getUserWithdrawalRequests(address _address)
\t\texternal
\t\tview
\t\treturns (WithdrawalRequest[] memory);
\tfunction getSharesAmountOfUserWithdrawalRequest(
\t\taddress _address,
\t\tuint256 _idx
\t) external view returns (uint256);
\tfunction getTotalStake(IValidatorShare _validatorShare)
\t\texternal
\t\tview
\t\treturns (uint256, uint256);
\tfunction getTotalStakeAcrossAllValidators() external view returns (uint256);
\tfunction getTotalPooledMatic() external view returns (uint256);
\tfunction getContracts()
\t\texternal
\t\tview
\t\treturns (
\t\t\taddress _stakeManager,
\t\t\taddress _polygonERC20,
\t\t\taddress _validatorRegistry
\t\t);
\tevent Submit(address indexed _from, uint256 _amount);
\tevent Delegate(uint256 indexed _validatorId, uint256 _amountDelegated);
\tevent RequestWithdraw(
\t\taddress indexed _from,
\t\tuint256 _amountMaticX,
\t\tuint256 _amountMatic
\t);
\tevent ClaimWithdrawal(
\t\taddress indexed _from,
\t\tuint256 indexed _idx,
\t\tuint256 _amountClaimed
\t);
\tevent WithdrawRewards(uint256 indexed _validatorId, uint256 _rewards);
\tevent StakeRewards(uint256 indexed _validatorId, uint256 _amountStaked);
\tevent DistributeFees(address indexed _address, uint256 _amount);
\tevent MigrateDelegation(
\t\tuint256 indexed _fromValidatorId,
\t\tuint256 indexed _toValidatorId,
\t\tuint256 _amount
\t);
\tevent MintFromPolygon(address indexed _user, uint256 _amount);
\tevent SetFeePercent(uint8 _feePercent);
\tevent SetInstantPoolOwner(address _address);
\tevent SetTreasury(address _address);
\tevent SetValidatorRegistry(address _address);
\tevent SetFxStateRootTunnel(address _address);
\tevent SetVersion(string _version);
}
// SPDX-License-Identifier: GPL-3.0
pragma solidity 0.8.7;
interface IFxStateRootTunnel {
\tfunction latestData() external view returns (bytes memory);
\tfunction setFxChildTunnel(address _fxChildTunnel) external;
\tfunction sendMessageToChild(bytes memory message) external;
\tfunction setMaticX(address _maticX) external;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC20Upgradeable.sol";
/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20MetadataUpgradeable is IERC20Upgradeable {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);
    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);
    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)
pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";
/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }
    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }
    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (proxy/utils/Initializable.sol)
pragma solidity ^0.8.0;
import "../../utils/AddressUpgradeable.sol";
/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To initialize the implementation contract, you can either invoke the
 * initializer manually, or you can include a constructor to automatically mark it as initialized when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() initializer {}
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     */
    bool private _initialized;
    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;
    /**
     * @dev Modifier to protect an initializer function from being invoked twice.
     */
    modifier initializer() {
        // If the contract is initializing we ignore whether _initialized is set in order to support multiple
        // inheritance patterns, but we only do this in the context of a constructor, because in other contexts the
        // contract may have been reentered.
        require(_initializing ? _isConstructor() : !_initialized, "Initializable: contract is already initialized");
        bool isTopLevelCall = !_initializing;
        if (isTopLevelCall) {
            _initializing = true;
            _initialized = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
        }
    }
    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} modifier, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }
    function _isConstructor() private view returns (bool) {
        return !AddressUpgradeable.isContract(address(this));
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.
        return account.code.length > 0;
    }
    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");
        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }
    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }
    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }
    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)
pragma solidity ^0.8.0;
/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControlUpgradeable {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);
    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);
    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);
    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);
    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);
    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;
    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;
    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Strings.sol)
pragma solidity ^0.8.0;
/**
 * @dev String operations.
 */
library StringsUpgradeable {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";
    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol
        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }
    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }
    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)
pragma solidity ^0.8.0;
import "./IERC165Upgradeable.sol";
import "../../proxy/utils/Initializable.sol";
/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165Upgradeable is Initializable, IERC165Upgradeable {
    function __ERC165_init() internal onlyInitializing {
    }
    function __ERC165_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165Upgradeable).interfaceId;
    }
    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)
pragma solidity ^0.8.0;
/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165Upgradeable {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}