pragma solidity ^0.4.18;

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {
  function mul(uint256 a, uint256 b) internal pure returns (uint256) {
    if (a == 0) {
      return 0;
    }
    uint256 c = a * b;
    assert(c / a == b);
    return c;
  }

  function div(uint256 a, uint256 b) internal pure returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return c;
  }

  function sub(uint256 a, uint256 b) internal pure returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  function add(uint256 a, uint256 b) internal pure returns (uint256) {
    uint256 c = a + b;
    assert(c >= a);
    return c;
  }
}

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
  uint256 public totalSupply;
  function balanceOf(address who) public view returns (uint256);
  function transfer(address to, uint256 value) public returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender) public view returns (uint256);
  function transferFrom(address from, address to, uint256 value) public returns (bool);
  function approve(address spender, uint256 value) public returns (bool);
  event Approval(address indexed owner, address indexed spender, uint256 value);
}

/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances.
 */
contract BasicToken is ERC20Basic {
  using SafeMath for uint256;

  mapping(address => uint256) balances;

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) public returns (bool) {
    require(_to != address(0));
    require(_value <= balances[msg.sender]);

    // SafeMath.sub will throw if there is not enough balance.
    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    emit Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of.
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) public view returns (uint256 balance) {
    return balances[_owner];
  }

}

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * @dev https://github.com/ethereum/EIPs/issues/20
 * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) internal allowed;

  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amount of tokens to be transferred
   */
  function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
    require(_to != address(0));
    require(_value <= balances[_from]);
    require(_value <= allowed[_from][msg.sender]);

    balances[_from] = balances[_from].sub(_value);
    balances[_to] = balances[_to].add(_value);
    allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
    emit Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
   *
   * Beware that changing an allowance with this method brings the risk that someone may use both the old
   * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
   * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
   * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) public returns (bool) {
    allowed[msg.sender][_spender] = _value;
    emit Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifying the amount of tokens still available for the spender.
   */
  function allowance(address _owner, address _spender) public view returns (uint256) {
    return allowed[_owner][_spender];
  }

  /**
   * @dev Increase the amount of tokens that an owner allowed to a spender.
   *
   * approve should be called when allowed[_spender] == 0. To increment
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _addedValue The amount of tokens to increase the allowance by.
   */
  function increaseApproval(address _spender, uint _addedValue) public returns (bool) {
    allowed[msg.sender][_spender] = allowed[msg.sender][_spender].add(_addedValue);
    emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
    return true;
  }

  /**
   * @dev Decrease the amount of tokens that an owner allowed to a spender.
   *
   * approve should be called when allowed[_spender] == 0. To decrement
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _subtractedValue The amount of tokens to decrease the allowance by.
   */
  function decreaseApproval(address _spender, uint _subtractedValue) public returns (bool) {
    uint oldValue = allowed[msg.sender][_spender];
    if (_subtractedValue > oldValue) {
      allowed[msg.sender][_spender] = 0;
    } else {
      allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
    }
    emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
    return true;
  }

}

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {
  address public owner;

  event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  function Ownable() public {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) public onlyOwner {
    require(newOwner != address(0));
    emit OwnershipTransferred(owner, newOwner);
    owner = newOwner;
  }
}

/**
 * @title YOUToken
 * @dev YOUChain.
 */
contract YOUToken is StandardToken, Ownable {

  string public constant name = "YOU Chain";
  string public constant symbol = "YOU";
  uint8 public constant decimals = 18;

  uint256 private constant TOKEN_UNIT = 10 ** uint256(decimals);
  uint256 private constant INITIAL_SUPPLY = 32 * (10 ** 8) * TOKEN_UNIT;

  uint256 private constant ANGEL_SUPPLY                 = INITIAL_SUPPLY * 10 / 100;  // 10% for angel sale
  uint256 private constant PRIVATE_SUPPLY               = INITIAL_SUPPLY * 20 / 100;  // 20% for private sale
  uint256 private constant TEAM_SUPPLY                  = INITIAL_SUPPLY * 15 / 100;  // 15% for team
  uint256 private constant FOUNDATION_SUPPLY            = INITIAL_SUPPLY * 25 / 100;  // 25% for foundation
  uint256 private constant COMMUNITY_SUPPLY	            = INITIAL_SUPPLY * 30 / 100;  // 30% for community rewards
  
  uint256 private constant ANGEL_SUPPLY_VESTING         = ANGEL_SUPPLY * 80 / 100;    // 50% of angel sale
  struct VestingGrant {
        address beneficiary;
        uint256 start;
        uint256 duration; //duration for each release
        uint256 amount; //total grant amount
        uint256 transfered; // transfered amount
        uint8 releaseCount; // schedule release count
  }

  address public constant ANGEL_ADDRESS = 0xAe195643020657B00d7DE6Cb98dE091A856059Cf; // angel sale vesting beneficiary address
  address public constant PRIVATE_ADDRESS = 0x3C69915E58b972e4D17cc1e657b834EB7E9127A8; // private sale vesting beneficiary address
  address public constant TEAM_ADDRESS = 0x781204E71681D2d70b3a46201c6e60Af93372a31; // team vesting beneficiary address
  address public constant FOUNDATION_ADDRESS = 0xFC6423B399fC99E6ED044Ab5E872cAA915845A6f; // foundation vesting beneficiary address
  address public constant COMMUNITY_ADDRESS = 0x790F7bd778d5c81aaD168598004728Ca8AF1b0A0; // community vesting beneficiary address

  VestingGrant angelVestingGrant;
  VestingGrant teamVestingGrant;
  bool angelFirstVested = false;

  function YOUToken() public {

    totalSupply = PRIVATE_SUPPLY.add(FOUNDATION_SUPPLY).add(COMMUNITY_SUPPLY);
    balances[PRIVATE_ADDRESS] = PRIVATE_SUPPLY;
    balances[FOUNDATION_ADDRESS] = FOUNDATION_SUPPLY;
    balances[COMMUNITY_ADDRESS] = COMMUNITY_SUPPLY;

    angelVestingGrant = makeGrant(ANGEL_ADDRESS, now + 1 days, (30 days), ANGEL_SUPPLY_VESTING, 4);
    teamVestingGrant = makeGrant(TEAM_ADDRESS, now + 1 days, (30 days), TEAM_SUPPLY, 60);
  }

  function releaseAngelFirstVested() public onlyOwner {
    require(!angelFirstVested && now >= angelVestingGrant.start);
    uint256 angelFirstSupplyBalance = ANGEL_SUPPLY.sub(ANGEL_SUPPLY_VESTING);
    totalSupply = totalSupply.add(angelFirstSupplyBalance);
    balances[angelVestingGrant.beneficiary] = angelFirstSupplyBalance;
    angelFirstVested = true;
    emit Transfer(address(0), angelVestingGrant.beneficiary, angelFirstSupplyBalance);
  }

  function releaseAngelVested() public onlyOwner {
     releaseVestingGrant(angelVestingGrant);
  }

  function releaseTeamVested() public onlyOwner {
     releaseVestingGrant(teamVestingGrant);
  }

  function makeGrant(address _beneficiary, uint256 _start, uint256 _duration, uint256 _amount, uint8 _releaseCount)
    internal pure returns (VestingGrant) 
    {
    return VestingGrant({beneficiary : _beneficiary, start: _start, duration:_duration, amount:_amount, transfered:0, releaseCount:_releaseCount});
  }

  function releasableAmount(uint256 time, VestingGrant grant) internal pure returns (uint256) {
    if (grant.amount == grant.transfered) {
        return 0;
    }
    uint256 amountPerRelease = grant.amount.div(grant.releaseCount);
    uint256 amount = amountPerRelease.mul((time.sub(grant.start)).div(grant.duration));
    if (amount > grant.amount) {
    amount = grant.amount;
    }
    amount = amount.sub(grant.transfered);
    return amount;
  }

  function releaseVestingGrant(VestingGrant storage grant) internal {
    uint256 amount = releasableAmount(now, grant);
    require(amount > 0);

    grant.transfered = grant.transfered.add(amount);
    totalSupply = totalSupply.add(amount);
    balances[grant.beneficiary] = balances[grant.beneficiary].add(amount);
    emit Transfer(address(0), grant.beneficiary, amount);
  }
}